[04] 숨어지내는 Personal.xls(b) 파일 활용기 - 이전시트로 가기

[이현욱]

오늘의 팁은 이전 시트로 가기입니다.

이 팁은 시트 작업을 많이 하시는 분들에게 필요한 기능으로 워크시트간 이동이 많을 경우에 효과적입니다.  Sheet1이라는 시트에서 작업을 하다가 Sheet5라는 시트로 갔다가 다시 처음 작업하던 Sheet1시트로 찾아갈 경우 마우스로 시트를 일일이 선택해서 찾아가야 합니다. 시트가 많을 경우 스크롤 바도 움직여야 하고 좀 불편함을 느끼셨을 겁니다.

 이전시트로 가기 즉 바로 이전에 작업하던 시트로 분기하는 것입니다. 단축키로 분기할 수도 있고 마우스 오른쪽 버턴을 눌러 셀 메뉴에서 선택 할 수도 있습니다.

그럼 아래 코드를 먼저 살펴 보면 이해하기 편할 겁니다.

전역변수를 몇 개 설정했습니다. 이전시트와 현재시트를 기억하기 위함입니다.

Option Explicit

Dim BeforeSheet As Worksheet

Dim ActSheet As Worksheet

Const BWS_MNU_ADD As String = "이전작업시트로 가기"

---

 

 

Sub Auto_Open()

 

    Call GotoBeforeSheet '이전 시트로 가기

 

    Application.OnKey "^k", "BeforeSheetSelect" '지정된 키(Ctrl + k )를 눌렀을 때 실행되는 프로시저 지정

End Sub

 

Sub Auto_close()

 

    Application.OnSheetActivate = "" '시트이벤트 해제

    Application.OnKey "^k", "" 'Onkey 프로시저 해제

 

End Sub

 

Function ActiveSheetSave()

    On Error Resume Next

    Set BeforeSheet = ActSheet

    Set ActSheet = ActiveSheet

End Function

 

Sub BeforeSheetSelect()

    On Error Resume Next

    BeforeSheet.Activate

    Set BeforeSheet = ActSheet

    Set ActSheet = ActiveSheet

End Sub

 

Sub GotoBeforeSheet()

    Dim oMnu As CommandBarControl

    Dim oCtl As CommandBarButton

    On Error Resume Next

    Application.OnSheetActivate = "ActiveSheetSave"

    Set BeforeSheet = ActiveSheet

    Set ActSheet = ActiveSheet

 

    'Cell shortcut menu에 menu item 추가

    Application.CommandBars("Cell").Controls(BWS_MNU_ADD).Delete

    Set oCtl = Application.CommandBars("Cell").Controls.Add(Type:=msoControlButton, ID:=1, temporary:=True, Before:=1)

    With oCtl

        .FaceId = 250

        .Caption = BWS_MNU_ADD

        .Style = msoButtonIconAndCaption

        .OnAction = ThisWorkbook.Name & "!BeforeSheetSelect"

        .BeginGroup = True

    End With

 

End Sub

---

바로가기 키(Ctrl + k )를 누르면 이전 시트로 분기를 합니다.

이쪽 시트 저쪽 시트 키를 누를때 마다 왔다 갔다 합니다. 물론 통합문서간에도 이동합니다.

코드는 조금 복잡해 보이지만 천천히 살펴 보면 눈에 익은 것들일 겁니다.

단지, Application.OnSheetActivate 가 생소하신 분들이 있을 겁니다.

OnSheetActivate 메서드는 엑셀 97 이전 버전에서 있었는데 SheetActivate 이벤트 프로시저 등으로 대처 되었습니다.

그때 유용한 on 프로시저가 몇 개 있었습니다.

지금은 도움말에도 나타 나지 않을 겁니다. 엑셀 95 도움말을 구해 보시면 나옵니다.

물론 개체 구성원에도 나타나지 않습니다. Application 입력후 . 을 입력하여 개체를 확인해 보세요. 없을겁니다. 기능만 살아 있고 나타나 있지는 않습니다.

On으로 시작하는 몇 개의 항목들을 나열해 보겠습니다. 대부분 이벤트와 관련 있습니다.

OnAction

OnKey
OnRepeat

OnTime

OnUndo

OnWindow

OnCalculate

OnData
OnDoubleClick

OnEntry

OnSheetActivate

OnSheetDeactivate

이중에서 OnSheetActivate 와 같은 색으로 구성된것 들이 숨겨진 항목입니다.

예전에 매크로 바이러스가 한참 유행일때 그 코드 들을 보면 대부분 OnSheetActivate 가 사용되었었답니다.

참고로 바로가기 키(Ctrl + k ) 는 하이퍼링크 삽입 입니다. 저는 하이퍼 링크를 삽입할 일이 별로 없어서 이 키로 활당했습니다.

적절하게 변경하여 사용하시길 바랍니다.

그럼... 왔다 갔다 편하게 사용하시길...

[윤슬]

onkey 메서드를 익힐 수 있는 유용한 팁입니다...
더불어 잊고 있던 OnSheetActivate...
수고하셨습니다...!

[smkim]

이것도 역시 좋은 팁입니다. 근데 역시 다른 파일을 여니까 안되네요...