Re:단면은 같아야 겠지요?!. MAT,1--E,,,---아래 요소는 MAT1요소가됩니다.

[빙구^^]

아래 파일을 앤시스 명령어 창에 붙여넣기 하여 해석해 보시기 바랍니다


/COM,ANSYS MEDIA REL. 60 (090601) REF. VERIF. MANUAL: REL. 60
/VERIFY,VM146
/PREP7
/TITLE, VM146, BENDING OF A REINFORCED CONCRETE BEAM
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 221
ANTYPE,STATIC
ET,1,SOLID65,,,,,2 ! REINFORCED CONCRETE SOLID ELEMENT
ET,2,LINK8 ! STEEL RODS
ET,3,PIPE16,,,,,,,1 ! DUMMY ELEMENTS FOR CONSTRAINT EQUATIONS
R,1
R,2,.15 ! HALF AREA OF ROD
R,3,1,.5 ! ARBITRARY CONSTANTS FOR DUMMY ELEMENTS
MP,EX,1,2E6 ! CONCRETE PROPERTIES
MP,NUXY,1,0
TB,CONCR,1
TBDATA,3,0.0,-1 ! ZERO TENSILE CRACKING STRENGTH
! REMOVE CRUSHING CAPABILITY
MP,EX,2,30E6 ! STEEL PROPERTIES
MP,NUXY,2,0.3
N,1
N,2,1.5
NGEN,5,2,1,2,1,,1.5
NGEN,2,10,1,10,1,,,5
E,7,8,10,9,17,18,20,19
TYPE,3 ! DEFINE DUMMY ELEMENTS FOR ROTZ DOF
REAL,3
E,10,8
E,20,18
EGEN,4,-2,1,3
TYPE,2 ! REINFORCING RODS AT THE BOTTOM SURFACE
MAT,2
REAL,2
E,1,2
E,11,12
CE,1,, 2,UX,-1, 6,UX,1, 6,ROTZ,3 ! CONSTRAINT EQUATION TO ENSURE
CE,2,,12,UX,-1,16,UX,1,16,ROTZ,3 ! PLANE SECTION REMAINS PLANE
CE,3,, 4,UX,-1, 6,UX,1, 6,ROTZ,1.5
CE,4,,14,UX,-1,16,UX,1,16,ROTZ,1.5
CE,5,, 8,UX,-1, 6,UX,1, 6,ROTZ,-1.5
CE,6,,18,UX,-1,16,UX,1,16,ROTZ,-1.5
CE,7,,10,UX,-1, 6,UX,1, 6,ROTZ,-3
CE,8,,20,UX,-1,16,UX,1,16,ROTZ,-3
NSEL,S,LOC,X
D,ALL,ALL ! FIX NODES IN Y-Z PLANE
NSEL,ALL
D,ALL,ROTY ! CONSTRAIN UNNEEDED PIPE ROTATIONS
F,6,MZ,300,,16,10 ! APPLY BENDING MOMENT
FINISH
/SOLU
AUTOTS,ON
NSUBST,5
OUTPR,,LAST
SOLVE
/POST1
ESEL,S,ELEM,,1,1
*GET,SCON,NODE,9,S,X
ESEL,S,ELEM,,13,13
ETAB,ST,LS,1
ESORT,ST
*GET,STL,SORT,,MAX
*status,parm
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'TSTR STL ','TSTR CON'
LABEL(1,2) = ' psi',' psi'
*VFILL,VALUE(1,1),DATA,387.28,-18.54
*VFILL,VALUE(1,2),DATA,STL,SCON
*VFILL,VALUE(1,3),DATA,ABS(STL/387.28),ABS(SCON/18.54)
/COM
/OUT,vm146,vrt
/COM,------------------- VM146 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F12.2,' ',F12.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM146 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm146,vrt






--------------------- [원본 메세지] ---------------------
안녕하세여.. 저는 건축구조를 전공하고 있는 학생인데여... 철근 콘크리트 보를 앤시스를 이용해서 해석을 하려고 하는데.... 고수님들의 도움이 필요한것 같습니다.ㅠㅠ 제가 워낙 초보라서...
일단 철근 콘크리트 보 단면의 형상은 사각형의 콘크리트 속에 철근이 뭍혀져 있는 형상이구여... 이 철근과 콘크리트의 재료적 물성치는 다르지만 일체화가 되어야 합니다. 이러한 상태에서 보에 2 점에서 하중을 받게 되면 콘크리트와 철근이 함께 거동해야하구여... 2차원 해석을 하려다가 앤스트 도움말의 Tutorial에서 3차원 해석이 있길래.. 따라해 보려구 했는데... 몇가지 의문점이 생기더군여....

먼저 첫째... 철근과 콘크리트가 일체화가 되려면 콘크리트 단면에 뚫은 철근 구멍과 철근의 직경이 같은 사이즈이여야 하는가?
둘째, 두 이질재료를 일체화시키는 방법.
세째, 재료의 종류가 2가지인데 이 두가지를 적용시키는 방법..

일단 질문은 이렇구여... 제가 질문한게 이해가 안가시면 답글주시기 바랍니다.

다시 한번 부탁드립니다. 꼭 좀 도와주세요..