Re:[HELP] VBA로 이부분도 가능할까요?

[곽완근]

Sheet2에서 다음 매크로를 실행해 보세요.

파일 첨부 드립니다.

셈플.xls

Sub test()
   
    Dim 날짜 As String
    Dim 총매출액 As Long
    Dim 총매출객 As Long
    Dim 총도매액 As Long
    Dim 총도매객 As Long
    Dim 총직판액 As Long
    Dim 총직판객 As Long
    Dim 붙힐위치 As Range
    Dim 붙힐내용 As String
   
    Dim iX1 As Integer '총매출액시작위치
    Dim ix2 As Integer '총매출객시작위치
    Dim ix3 As Integer '총도매액시작위치
    Dim ix4 As Integer '총도매객시작위치
    Dim ix5 As Integer '총직만액시작위치
    Dim ix6 As Integer '총직판객시작위치
   
    날짜 = Format(Date, "mmdd")
    총매출액 = Int(Range("B11") / 10000)
    총매출객 = Range("C11")
    총도매액 = Int(Range("B9") / 10000)
    총도매객 = Range("C9")
    총직판액 = Int(Range("B10") / 10000)
    총직판객 = Range("C10")
   
    Set 붙힐위치 = Sheet1.Range("D65536").End(xlUp)
    Set 붙힐위치 = 붙힐위치.Offset(1)
   
   
    붙힐내용 = 붙힐내용 & "[오늘("
   
    붙힐내용 = 붙힐내용 & 날짜
   
    붙힐내용 = 붙힐내용 & ")의 매출]총("
    iX1 = Len(붙힐내용) + 1
   
    붙힐내용 = 붙힐내용 & 총매출액 & "만/"
    ix2 = Len(붙힐내용) + 1
   
    붙힐내용 = 붙힐내용 & 총매출객 & "객) 도매("
    ix3 = Len(붙힐내용) + 1
   
    붙힐내용 = 붙힐내용 & 총도매액 & "만/"
    ix4 = Len(붙힐내용) + 1
   
    붙힐내용 = 붙힐내용 & 총도매객 & "객) 직판("
    ix5 = Len(붙힐내용) + 1
   
    붙힐내용 = 붙힐내용 & 총직판액 & "만/"
    ix6 = Len(붙힐내용) + 1
   
    붙힐내용 = 붙힐내용 & 총직판객 & "객)"

    붙힐위치.Value = 붙힐내용
   
    붙힐위치.Characters(5, 4).Font.ColorIndex = 50
    붙힐위치.Characters(iX1, Len(CStr(총매출액))).Font.ColorIndex = 3
    붙힐위치.Characters(ix2, Len(CStr(총매출객))).Font.ColorIndex = 5
    붙힐위치.Characters(ix3, Len(CStr(총도매액))).Font.ColorIndex = 3
    붙힐위치.Characters(ix4, Len(CStr(총도매객))).Font.ColorIndex = 5
    붙힐위치.Characters(ix5, Len(CStr(총직판액))).Font.ColorIndex = 3
    붙힐위치.Characters(ix6, Len(CStr(총직판객))).Font.ColorIndex = 5
   
End Sub

[고재우]

운영자님!! 아주유용하게 잘 활용하고 있답니다.
정말 감사 합니다.
저도 열심히 노력해야 겠다는 생각이 듭니다. 정말 감사드려요