VM4 (Deflection of a Hinged Support) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM4
/PREP7
/TITLE, VM4, DEFLECTION OF A HINGED SUPPORT
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 10, PROB. 2
L=15*12 ! LENGTH OF BAR IN INCHES
*AFUN,DEG ! TRIG FUNCTIONS IN DEGREES
THETA=30 ! ANGLE TO BE USED TO CALCULATE A AND B
A=2*L*COS(THETA) ! CALCULATED X LOCATION - NODE 3
B=L*SIN(THETA) ! CALCULATED Y LOCATION - NODE 2
ET,1,LINK1
R,1,.5
MP,EX,1,30E6
N,1
N,2,A/2,-B ! X LOCATION = A/2; A AND B AS ABOVE
N,3,A
E,1,2
E,2,3
D,1,ALL,,,3,2
F,2,FY,-5000
OUTPR,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
MID_NODE = NODE (A/2,-B,0 )
*GET,DISP,NODE,MID_NODE,U,Y
LEFT_EL = ENEARN (MID_NODE)
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,LEFT_EL,ETAB,STRS
VM5 (Laterally Loaded Tapered Support Structure) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM5
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM5, LATERALLY LOADED TAPERED SUPPORT STRUCTURE (QUAD. ELEMENTS)
C*** MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 342, PROB. 7.18
C*** USING PLANE42 ELEMENTS
ANTYPE,STATIC
ET,1,PLANE42,,,3,,,2 ! TURN ON SURFACE PRINTOUT TO GET RESULTS AT MID-LENGTH
R,1,2
MP,EX,1,30E6
MP,NUXY,1,0.0 ! POISSON'S RATIO SET TO 0.0 TO AGREE WITH BEAM THEORY
N,1,25
N,7,75
FILL
N,8,25,-3
N,14,75,-9
FILL
E,2,1,8,9
EGEN,6,1,1
NSEL,S,LOC,X,75
D,ALL,ALL ! CONSTRAIN NODES AT FIXED END
NSEL,ALL
F,1,FY,-4000
FINISH
/SOLU
OUTPR,,1
SOLVE
FINISH
/POST1
END_NODE = NODE (75,0,0)
*GET,STS_E_42,NODE,END_NODE,S,X ! STRESS AT FIXED END (END NODE )
PLDISP,2
MID_NODE = NODE (50,0,0)
*GET,STS_M_42,NODE,MID_NODE,S,EQV
FINISH
/PREP7
/TITLE, VM5, LATERALLY LOADED TAPERED SUPPORT STRUCTURE (QUAD. ELEMENTS)
C*** MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 342, PROB. 7.18
C*** USING PLANE82 ELEMENTS
C*** ! CHANGE ELEMENT TYPE TO HIGHER ORDER PLANE82
ET,1,PLANE82,,,3,,,2 ! TURN ON FACE PRINTOUT TO GET RESULTS AT MID-LENGTH
EMID ! ADD MIDSIDE NODES TO PLANE82 ELEMENTS
NSEL,R,LOC,X,75
NSEL,R,LOC,Y,-4.5 ! SELECT MIDSIDE NODE AT FIXED END
D,ALL,ALL ! CONSTRAIN MIDSIDE NODE AT FIXED END
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
END_NODE = NODE (75,0,0)
*GET,STS_E_82,NODE,END_NODE,S,X ! STRESS AT FIXED END (END NODE )
MID_NODE = NODE (50,0,0)
*GET,STS_M_82,NODE,MID_NODE,S,EQV
*DIM,LABEL,CHAR,2,2
*DIM,VALUEI,,2,3
*DIM,VALUEII,,2,3
LABEL(1,1) = 'MID_STRS','END-STRS'
LABEL(1,2) = ' (psi) ',' (psi) '
*VFILL,VALUEI(1,1),DATA,8333,7407
*VFILL,VALUEI(1,2),DATA,STS_M_42,STS_E_42
*VFILL,VALUEI(1,3),DATA,(STS_M_42/8333),(STS_E_42/7407)
*VFILL,VALUEII(1,1),DATA,8333,7407
*VFILL,VALUEII(1,2),DATA,STS_M_82,STS_E_82
*VFILL,VALUEII(1,3),DATA,(STS_M_82/8333),(STS_E_82/7407)
/COM,STS_M_42 = STRESS AT MID-LENGTH USING ELEMENT 42
/COM,STS_E_42 = STRESS AT FIXED END USING ELEMENT 42
/COM,STS_M_82 = STRESS AT MID-LENGTH USING ELEMENT 82
/COM,STS_E_82 = STRESS AT FIXED END USING ELEMENT 82
/COM,
/OUT,vm5,vrt
/COM,------------------- VM5 RESULTS COMPARISON ---------------------
/COM,
/COM,RESULTS FOR PLANE42:
/COM,
/COM, | TARGET | ANSYS | RATIO
*VWRITE,LABEL(1,1),LABEL(1,2),VALUEI(1,1),VALUEI(1,2),VALUEI(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,
/COM,RESULTS FOR PLANE82:
/COM,
/COM, | TARGET | ANSYS | RATIO
*VWRITE,LABEL(1,1),LABEL(1,2),VALUEII(1,1),VALUEII(1,2),VALUEII(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------------
/OUT
VM7 (Plastic Compression of a Pipe Assembly) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM7
/PREP7
/TITLE, VM7, PLASTIC COMPRESSION OF A PIPE ASSEMBLY
C*** MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 180, EX. 5.1
C*** USING PIPE20, SOLID45 AND SHELL43 ELEMENTS
ANTYPE,STATIC
ET,1,PIPE20
ET,2,SOLID45
ET,3,SHELL43
R,1,4.9563384,0.5 ! OUTSIDE DIA. AND WALL THICKNESS FOR INSIDE TUBE (PIPE20)
R,2,8.139437,0.5 ! OUTSIDE DIA. AND WALL THICKNESS FOR OUTSIDE TUBE
R,3,0.5 ! THICKNESS (SHELL43)
MP,EX,1,26.875E6 ! STEEL
MP,NUXY,1,0.3
MP,EX,2,11E6 ! ALUMINUM
MP,NUXY,2,0.3
TB,BKIN,1,1 ! DEFINE NON-LINEAR MATERIAL PROPERTY FOR STEEL
TBTEMP,0
TBDATA,1,86000,0
TB,BKIN,2,1 ! DEFINE NON-LINEAR MATERIAL PROPERTY FOR ALUMINUM
TBTEMP,0
TBDATA,1,55000,0
N,1 ! GENERATE NODES AND ELEMENTS FOR PIPE20
N,2,,,10
MAT,1
REAL,1 ! STEEL (INSIDE) TUBE
E,1,2
MAT,2
REAL,2 ! ALUMINUM (OUTSIDE) TUBE
E,1,2
CSYS,1
N,101,1.9781692 ! GENERATE NODES AND ELEMENTS FOR SOLID45
N,102,2.4781692
N,103,3.5697185
N,104,4.0697185
N,105,1.9781692,,10
N,106,2.4781692,,10
N,107,3.5697185,,10
N,108,4.0697185,,10
NGEN,2,10,101,108,,,6 ! GENERATE 2ND SET OF NODES TO FORM A 6 DEGREE SLICE
NROTAT,101,118,1
TYPE,2
MAT,1 ! INSIDE (STEEL) TUBE
E,101,102,112,111,105,106,116,115
MAT,2 ! OUTSIDE (ALUMINUM) TUBE
E,103,104,114,113,107,108,118,117
N,201,2.2281692 ! GENERATE NODES AND ELEMENTS FOR SHELL43
N,203,2.2281692,,10
N,202,3.8197185
N,204,3.8197185,,10
NGEN,2,4,201,204,,,6 ! GENERATE NODES TO FORM A 6 DEGREE SLICE
TYPE,3
REAL,3
MAT,1 ! INSIDE (STEEL) TUBE
E,203,201,205,207
MAT,2 ! OUTSIDE (ALUMINUM) TUBE
E,204,202,206,208
C*** APPLY CONSTRAINTS TO PIPE20 MODEL
D,1,ALL ! FIX ALL DOFS FOR BOTTOM END OF PIPE20
D,2,UX,,,,,UY,ROTX,ROTY,ROTZ ! ALLOW ONLY UZ DOF AT TOP END OF PIPE20 MODEL
C*** APPLY CONSTRAINTS TO SOLID45 AND SHELL43 MODELS
CP,1,UX,101,111,105,115 ! COUPLE NODES AT BOUNDARY IN RADIAL DIR FOR SOLID45
CPSGEN,4,,1
CP,5,UX,201,205,203,20 ! COUPLE NODES AT BOUNDARY IN RADIAL DIR FOR SHELL43
CPSGEN,2,,5
CP,7,ROTY,201,205 ! COUPLE NODES AT BOUNDARY IN ROTY DIR FOR SHELL43
CPSGEN,4,,7
NSEL,S,NODE,,101,212 ! SELECT ONLY NODES IN SOLID45 AND SHELL43 MODELS
NSEL,R,LOC,Y,0 ! SELECT NODES AT THETA = 0 FROM THE SELECTED SET
DSYM,SYMM,Y,1 ! APPLY SYMMETRY BOUNDARY CONDITIONS
NSEL,S,NODE,,101,212 ! SELECT ONLY NODES IN SOLID45 AND SHELL43 MODELS
NSEL,R,LOC,Y,6 ! SELECT NODES AT THETA = 6 FROM THE SELECTED SET
DSYM,SYMM,Y,1 ! APPLY SYMMETRY BOUNDARY CONDITIONS
NSEL,ALL
NSEL,R,LOC,Z,0 ! SELECT ONLY NODES AT Z = 0
D,ALL,UZ,0 ! CONSTRAIN BOTTOM NODES IN Z DIRECTION
NSEL,ALL
FINISH
/SOLU
OUTPR,BASIC,LAST ! PRINT BASIC SOLUTION AT END OF LOAD STEP
C*** APPLY DISPLACEMENT LOADS TO ALL MODELS
*CREATE,DISP
NSEL,R,LOC,Z,10 ! SELECT NODES AT Z = 10 TO APPLY DISPLACEMENT
D,ALL,UZ,ARG1
NSEL,ALL
SOLVE
*END
*USE,DISP,-.032
*USE,DISP,-.05
*USE,DISP,-.1
FINISH
/POST1
C*** CREATE MACRO TO GET RESULTS FOR EACH MODEL
*CREATE,GETLOAD
NSEL,S,NODE,,1,2 ! SELECT NODES IN PIPE20 MODEL
NSEL,R,LOC,Z,0
FSUM ! FZ IS TOTAL LOAD FOR PIPE20 MODEL
*GET,LOAD_20,FSUM,,ITEM,FZ
NSEL,S,NODE,,101,118 ! SELECT NODES IN SOLID45 MODEL
NSEL,R,LOC,Z,0
FSUM
*GET,ZFRC,FSUM,0,ITEM,FZ
LOAD=ZFRC*60 ! MULTIPLY BY 60 FOR FULL 360 DEGREE RESULTS
*STATUS,LOAD
LOAD_45 = LOAD
NSEL,S,NODE,,201,212 ! SELECT NODES IN SHELL43 MODEL
NSEL,R,LOC,Z,0
FSUM
*GET,ZFRC,FSUM,0,ITEM,FZ
LOAD=ZFRC*60 ! MULTIPLY BY 60 FOR FULL 360 DEGREE RESULTS
*STATUS,LOAD
LOAD_43 = LOAD
*VFILL,VALUE_20(1,1),DATA,1024400,1262000,1262000
*VFILL,VALUE_20(I,2),DATA,ABS(LOAD_20)
*VFILL,VALUE_20(I,3),DATA,ABS(LOAD_20)/(VALUE_20(I,1))
*VFILL,VALUE_45(1,1),DATA,1024400,1262000,1262000
*VFILL,VALUE_45(J,2),DATA,ABS(LOAD_45)
*VFILL,VALUE_45(J,3),DATA,ABS(LOAD_45)/(VALUE_45(J,1))
*VFILL,VALUE_43(1,1),DATA,1024400,1262000,1262000
*VFILL,VALUE_43(K,2),DATA,ABS(LOAD_43)
*VFILL,VALUE_43(K,3),DATA,ABS(LOAD_43)/(VALUE_43(K,1))
*END
C*** GET TOTAL LOAD FOR DISPLACEMENT = 0.032
C*** ---------------------------------------
SET,1,1
I = 1
J = 1
K = 1
*DIM,LABEL,CHAR,3,2
*DIM,VALUE_20,,3,3
*DIM,VALUE_45,,3,3
*DIM,VALUE_43,,3,3
*USE,GETLOAD
C*** GET TOTAL LOAD FOR DISPLACEMENT = 0.05
C*** --------------------------------------
SET,2,1
I = I + 1
J = J + 1
K = K + 1
*USE,GETLOAD
C*** GET TOTAL LOAD FOR DISPLACEMENT = 0.1
C*** -------------------------------------
SET,3,1
I = I +1
J = J + 1
K = K + 1
*USE,GETLOAD
VM8 (Parametric Calculation of Point-to-Point Distances) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM8
*CREATE,MAC
LENGTH ! LABEL FOR THIS BLOCK IN THE USER FILE
!
! THIS BLOCK IN THE USER FILE CALCULATES THE STRAIGHT LINE
! DISTANCE BETWEEN TWO POINTS IN SPACE DEFINED BY EITHER
! KEYPOINTS OR NODES ( CONTROLLED BY ARG1 ). OTHER INPUT
! AND OUTPUT ARGUMENTS ARE DEFINED BELOW.
!
! INPUT- ARG1 == IF ZERO, ARG2 AND ARG3 REPRESENT NODES (DEFAULT)
! == IF NONZERO, ARG2 AND ARG3 REPRESENT KEYPOINTS
! ARG2 == NUMBER OF THE FIRST NODE OR KEYPOINT
! ARG3 == NUMBER OF THE SECOND NODE OR KEYPOINT
!
! OUTPUT- PDIS == EXTERNAL PARAMETER ASSIGNED WITH THE DISTANCE VALUE
!
!
! NOTES: 1. "NORMALLY" THIS BLOCK WOULD ALREADY EXIST IN A LOCALLY
! ATTACHED USER FILE, AND WOULDN'T REQUIRE THE "*CREATE"
! OPERATION TO MAKE IT.
! 2. THE CHARACTER ":" USED IN THE FIRST COLUMN OF AN ANSYS
! INPUT LINE HAS THE EFFECT OF MAKING THE ENTIRE LINE A
! NON-ECHOING COMMENT (USUALLY USED FOR A BRANCHING LABEL).
!
/NOPR ! SUPPRESS PRINTOUT DURING MACRO EXECUTION
*GET,AR10,CSYS ! SAVE CURRENT COORDINATE SYSTEM FOR LATER RESTORATION
CSYS,0 ! CHANGE TO GLOBAL CARTESIAN SYSTEM
*IF,ARG1,EQ,0,THEN
*GET,ARG4,NX,ARG2 ! RETRIEVE COORDINATE LOCATIONS OF BOTH NODES
*GET,ARG5,NY,ARG2
*GET,ARG6,NZ,ARG2
*GET,ARG7,NX,ARG3
*GET,ARG8,NY,ARG3
*GET,ARG9,NZ,ARG3
*ELSE
*GET,ARG4,KX,ARG2 ! RETRIEVE COORDINATE LOCATIONS OF BOTH KEYPOINTS
*GET,ARG5,KY,ARG2
*GET,ARG6,KZ,ARG2
*GET,ARG7,KX,ARG3
*GET,ARG8,KY,ARG3
*GET,ARG9,KZ,ARG3
*ENDIF
! ----- NOW CALCULATE DISTANCE WITH LOCATIONS OBTAINED ABOVE -----
PDIS=((ARG7-ARG4)*(ARG7-ARG4))+((ARG8-ARG5)*(ARG8-ARG5))
PDIS=SQRT(PDIS+((ARG9-ARG6)*(ARG9-ARG6)))
CSYS,AR10 ! RESTORE ORIGINAL COORDINATE SYSTEM
*IF,ARG1,EQ,0,THEN ! BRANCH TO KEYPOINT LOGIC IF APPROPRIATE
/COM LENGTH BETWEEN NODES HAS BEEN DEFINED AS PARAMETER PDIS (FROM USERFILE)
*ELSE
/COM LENGTH BETWEEN KEYPOINTS DEFINED AS PARAMETER PDIS (FROM USERFILE)
*ENDIF
/GOPR ! TURN PRINTOUT BACK ON
*END
/PREP7
/TITLE, VM8, MACRO TO CALCULATE DISTANCES BETWEEN POINTS
C*** ANY BASIC GEOMETRY TEXT
*ULIB,MAC ! ASSIGN MACRO LIBRARY FILE
*ABBR,KLEN,*USE,LENGTH,1 ! ASSIGN ABBREVIATIONS FOR "CALLS" TO USERFILE
*ABBR,NLEN,*USE,LENGTH,0
N,1,1.5,2.5,3.5 ! DEFINE TEST NODE AND KEYPOINT LOCATIONS
N,2,-3.7,4.6,-3
K,3,100,0,30
K,4,-200,25,80
KLEN,4,3 ! USE KEYPOINT DISTANCE PART OF MACRO
LEN1=PDIS
KDIS = LEN1
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM (SHOULDN'T AFFECT CALCULATION)
NLEN,1,2 ! USE NODE DISTANCE PART OF MACRO
LEN2=PDIS
NDIS = LEN2
*STATUS
VM9 (Large Lateral Deflection of Unequal Stiffness Springs) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM9
/PREP7
/TITLE, VM9, LARGE LATERAL DEFLECTION OF UNEQUAL STIFFNESS SPRINGS
/COM, REF: G.N. VANDERPLAATS, "NUMERICAL OPTIMIZATION TECHNIQUES FOR
/COM, ENGINEERING DESIGN", PP 72-73, MCGRAW-HILL, 1984
ET,1,COMBIN14,,,2 ! UX AND UY DOF ELEMENT
ET,3,COMBIN40,,,,,,2 ! ALL MASS IS AT NODE J, UX DOF ELEMENT
ET,4,COMBIN40,,,2,,,2 ! ALL MASS IS AT NODE J, UY DOF ELEMENT
R,1,1 ! SPRING STIFFNESS = 1
R,2,8 ! SPRING STIFFNESS = 8
/COM USE COMBIN40 MASS, K, AND DAMPING C, TO APPROX. CRITICAL DAMPING
R,3,,1.41,1 ! C = 1.41, M = 1
R,4,,2,1 ! C = 2, M = 1
N,1
N,2,,10
N,3,,20
N,4,-1,10
N,5,,9
LOCAL,11,0,0,0,0,45
NROTAT,2 ! ROTATE NODE SO LOAD CAN BE DIRECTLY APPLIED
E,1,2 ! ELEMENT 1 IS SPRING ELEMENT WITH STIFFNESS 1
REAL,2
E,2,3 ! ELEMENT 2 IS SPRING ELEMENT WITH STIFFNESS 8
TYPE,3
REAL,3
E,4,2 ! ELEMENT 3 IS COMBINATION ELEMENT WITH C = 1.41
TYPE,4
REAL,4
E,5,2 ! ELEMENT 4 IS COMBINATION ELEMENT WITH C = 2
NSEL,U,NODE,,2
D,ALL,ALL
NSEL,ALL
FINISH
/SOLU
ANTYPE,TRANS ! FULL TRANSIENT DYNAMIC ANALYSIS
NLGEOM,ON ! LARGE DEFLECTION
KBC,1 ! STEP BOUNDARY CONDITION
F,2,FX,7.071068 ! FORCE IS IN ROTATED NODAL COORDINATE SYSTEM
AUTOTS,ON
NSUBST,20
OUTPR,,20
OUTPR,VENG,20
TIME,15 ! ARBITRARY TIME FOR SLOW DYNAMICS
SOLVE
FINISH
/POST1
SET,,,,,15 ! USE ITERATION WHEN TIME = 15
ETABLE,SENE,SENE ! STORE STRAIN ENERGY
SSUM ! SUM ALL ACTIVE ENTRIES IN ELEMENT STRESS TABLE
*GET,ST_EN,SSUM,,ITEM,SENE
PRNSOL,U,COMP ! PRINT DISPLACEMENTS IN GLOBAL COORDINATE SYSTEM
*GET,DEF_X,NODE,2,U,X
*GET,DEF_Y,NODE,2,U,Y
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'STRAIN E','DEF_X (C','DEF_Y (C'
LABEL(1,2) = ', N-cm ','m) ','m) '
*VFILL,VALUE(1,1),DATA,24.01,8.631,4.533
*VFILL,VALUE(1,2),DATA,ST_EN ,DEF_X,DEF_Y
*VFILL,VALUE(1,3),DATA,ABS(ST_EN/24.01), ABS(8.631/DEF_X), ABS(DEF_Y/4.533 )
/COM
/OUT,vm9,vrt
/COM,------------------- VM9 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vm9,vrt
VM10 (Bending of a Tee-Shaped Beam) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM10
/PREP7
MP,PRXY,,0.3
/TITLE, VM10, BENDING OF A TEE SHAPED BEAM
C*** MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 294, EX. 7.2
ANTYPE,STATIC
ET,1,BEAM54
R,1,60,2000,14,6 !AREA, IZ, DISTANCE TO TOP AND BOT HEIGHT
MP,EX,1,30E6
N,1
N,2,100
E,1,2
D,1,ALL
F,2,MZ,100000
FINISH
/SOLU
NSUBST,1
OUTPR,ALL,1
SOLVE
FINISH
/POST1
ETABLE,STRS_B,LS,3
ETABLE,STRS_T,LS,2
*GET,STRSS_B,ELEM,1,ETAB,STRS_B
*GET,STRSS_T,ELEM,1,ETAB,STRS_T
VM16 (Bending of a Solid Beam (Plane Elements)) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM16
/PREP7
/TITLE, VM16, BENDING OF A SOLID BEAM (PLANE ELEMENTS)
C*** FORMULAS FOR STRESS AND STRAIN, ROARK, 4TH ED.,PG. 104,106
C*** USING PLANE42 ELEMENTS
ANTYPE,STATIC
ET,1,PLANE42,,,,,,2 ! PLANE42 WITH SURFACE PRINTOUT FOR FACES 1 AND 3
MP,EX,1,30E6
MP,NUXY,1,0.0
N,1
N,6,10
FILL
NGEN,2,10,1,6,1,,2
E,1,2,12,11
EGEN,5,1,1
/COM, VM16, CASE 1 - END MOMENT, ROARK, PAGE 106, NO. 9
D,1,ALL,,,11,10
F,6,FX,1000
F,16,FX,-1000
OUTPR,NSOL,1
OUTPR,ESOL,1
FINISH
/SOLU
SOLVE
/POST1
*GET,U1,NODE,16,U,Y
FINI
/SOLU
/COM, VM16, CASE 2 - END LOAD, ROARK, PAGE 104, NO. 1
F,6,FX,,,16,10
F,6,FY,150,,16,10
SOLVE
FINISH
/POST1
*GET,U2,NODE,16,U,Y
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
*DIM,VALUE2,,1,3
LABEL(1,1) = 'DEFL'
LABEL(1,2) = ' (in) '
*VFILL,VALUE(1,1),DATA,.00500
*VFILL,VALUE(1,2),DATA,U1
*VFILL,VALUE(1,3),DATA,ABS(U1/.005)
SAVE,TABLE_1
*VFILL,VALUE2(1,1),DATA,.00500
*VFILL,VALUE2(1,2),DATA,U2
*VFILL,VALUE2(1,3),DATA,ABS(U2/.005)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm16,vrt
/COM,------------------- VM16 RESULTS COMPARISON ---------------------
/COM,
/COM,CASE 1: | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,CASE 2:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,-----------------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM16 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------------
/OUT
FINISH
/DELETE,TABLE_1
/DELETE,TABLE_2
FINISH
*LIST,vm16,vrt
VM17 (Snap-Through Buckling of a Hinged Shell) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM17
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
smrt,off
/TITLE, VM17, SNAP-THROUGH BUCKLING OF A HINGED SHELL
:COM CHANG, C.C.,"PERIODICALLY RESTARTED QUASI-NEWTON UPDATES IN
:COM IN CONSTANT ARC-LENGTH METHOD", COMPUTERS AND STRUCTURES,
:COM VOL. 41, NO. 5, PP. 963-972, 1991.
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,SHELL63,,1
R,1,6.350 ! SHELL THICKNESS
MP,EX,1,3102.75
MP,NUXY,1,0.3
:COM CREATE FINITE ELEMENT MODEL
R1 = 2540 ! SHELL MID-SURFACE RADIUS
L = 254 ! HALF THE LENGTH
PI = 4*ATAN(1) ! VALUE OF PI COMPUTED
THETA = 0.1*180/PI ! 0.1 RADIANS CONVERTED TO DEGREES
CSYS,1 ! CYLINDRICAL CO-ORDINATE SYSTEM
N,1,R1,90 ! NODES 1 AND 2 ARE CREATED AT POINTS
N,2,R1,90,L ! A AND B RESPECTIVELY.
K,1,R1,90
K,2,R1,(90-THETA)
K,3,R1,90,L
K,4,R1,(90-THETA),L
ESIZE,,2 ! TWO DIVISION ALONG THE REGION BOUNDARY
A,1,3,4,2
AMESH,1
NUMMRG,NODE
:COM APPLY BOUNDARY CONDITIONS
NSEL,S,LOC,Z,0
DSYM,SYMM,Z
NSEL,S,LOC,Y,90
DSYM,SYMM,X
NSEL,S,LOC,Y,(90-THETA)
D,ALL,UX,,,,,UY,UZ
NSEL,ALL
FINISH
:COM SOLUTION PHASE
:COM SINCE THE SOLUTION OUTPUT IS SUBSTANTIAL IT IS DIVERTED TO A
:COM SCRATCH FILE
/OUTPUT,SCRATCH
/SOLUTION
NLGEOM,ON ! LARGE DEFLECTION TURNED ON
OUTRES,,1 ! WRITE SOLUTION ON RESULTS FILE FOR EVERY SUBSTEP
F,1,FY,-250 ! 1/4 TH OF THE TOTAL LOAD APPLIED DUE TO SYMMETRY
NSUBST,30 ! BEGIN WITH 30 SUBSTEPS
ARCLEN,ON,4 ! ARC-LENGTH SOLUTION TECHNIQUE TURNED ON WITH
! MAX. ARC-LENGTH KEPT AT 4 TO COMPUTE AND STORE
! SUFFICIENT INTERMEDIATE SOLUTION INFORMATION
SOLVE
FINISH
/OUTPUT
:COM POSTPROCESSING PHASE
/POST26
NSOL,2,1,U,Y ! STORE UY DISPLACEMENT OF NODE 1
NSOL,3,2,U,Y ! STORE UY DISPLACEMENT OF NODE 2
PROD,4,1,,,LOAD,,,4*250 ! TOTAL LOAD IS 4*250 DUE TO QUARTER SYMMETRY
PROD,5,2,,,,,,-1 ! CHANGE SIGNS OF THE DISPLACEMENT VALUES
PROD,6,3,,,,,,-1
*GET,UY1,VARI,2,EXTREM,VMIN
*GET,UY2,VARI,3,EXTREM,VMIN
PRVAR,2,3,4 ! PRINT STORED INFORMATION
/AXLAB,X, DEFLECTION (MM)
/AXLAB,Y, TOTAL LOAD (N)
/GRID,1
/XRANGE,0,35
/YRANGE,-500,1050
XVAR,5
PLVAR,4 ! PLOT LOAD WITH RESPECT TO -UY OF NODE 1
/NOERASE
XVAR,6
PLVAR,4 ! PLOT LOAD WITH RESPECT TO -UY OF NODE 2
/ERASE
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'UY @A ','UY @B '
LABEL(1,2) = 'mm ','mm '
*VFILL,VALUE(1,1),DATA,-30,-26
*VFILL,VALUE(1,2),DATA,UY1,UY2
*VFILL,VALUE(1,3),DATA,ABS(UY1/30) ,ABS(UY2/26 )
/COM
/OUT,vm17,vrt
/COM,------------------- VM17 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,-------------------------------------------------------------
/OUT
FINISH
*LIST,vm17,vrt
/DELETE,SCRATCH
VM18 (Out-of-Plane Bending of a Curved Bar) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM18
/PREP7
/TITLE, VM18, OUT-OF-PLANE BENDING OF A CURVED BAR
! STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 412, EQN. 241
ANTYPE,STATIC
ET,1,PIPE18,,,,,,2 ! KEYOPT(6)=2 PRINTS MEMBER FORCES
MP,EX,1,30E6
MP,NUXY,1,.3
R,1,2,1,100 ! OD = 2, WALL THICKNESS = 1, RADIUS = 100
N,1,100 ! DEFINE NODES
N,2,,100
N,10
E,1,2,10 ! DEFINE ELEMENT
D,1,ALL ! BOUNDARY CONDITIONS + LOAD
F,2,FZ,-50
FINISH
/SOLU
OUTPR,BASIC,1
SOLVE
FINISH
/POST1
*GET,DEF,NODE,2,U,Z
ETABLE,STRS_BEN,LS,1
ETABLE,STRS_SHR,LS,4
*GET,STRSS_B,ELEM,1,ETAB,STRS_BEN
*GET,STRSS_T,ELEM,1,ETAB,STRS_SHR
VM19 (Random Vibration Analysis of a Deep Simply-Supported Beam) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM19
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM19, RANDOM VIBRATION ANALYSIS OF A DEEP SIMPLY-SUPPORTED BEAM
/COM REFERENCE: NAFEMS FORCED VIBRATION BENCHMARKS TEST 5R
ET,1,BEAM4 ! DEFINE ELEMENT TYPE
MP,EX,1,200E9 ! DEFINE MATERIAL PROPERTIES
MP,NUXY,1,0.3
MP,ALPX,1,0.1E-5
MP,DENS,1,8000
R,1,4,1.333,1.333,2,2,0 ! DEFINE REAL CONSTANTS
RMORE,0,2.2496,1.177,1.177
N,1,0
N,11,10
FILL
E,1,2
EGEN,10,1,1
FINISH
VM24 (Plastic Hinge in a Rectangular Beam) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM24
/PREP7
/TITLE, VM24, PLASTIC HINGE IN A RECTANGULAR BEAM
C*** STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PG. 349, ART. 64
C*** USING BILINEAR KINEMATIC HARDENING PLASTICITY BEHAVIOR TO DESCRIBE
C*** THE MATERIAL NONLINEARITY
ANTYPE,STATIC
ET,1,BEAM23
R,1,2,(2/3),2 ! AREA = 2, IZZ = 2/3, H = 2
MP,EX,1,30E6
MP,NUXY,1,0.3
TB,BKIN,1,1 ! BILINEAR KINEMATIC HARDENING
TBTEMP,70
TBDATA,1,36000,0 ! YIELD POINT AND ZERO TANGENT MODULUS
N,1 ! DEFINE NODES
N,2,10
E,1,2 ! DEFINE ELEMENT
D,1,ALL ! BOUNDARY CONDITIONS AND LOADS
SAVE ! SAVE DATABASE
FINISH
/SOLU
SOLCONTROL,0
NEQIT,5 ! MAXIMUM 5 EQUILIBRIUM ITERATIONS PER STEP
NCNV,0 ! DO NOT TERMINATE THE ANALYSIS IF THE SOLUTION FAILS
! TO CONVERGE
OUTRES,EPPL,1 ! STORE PLASTIC STRAINS FOR EVERY SUBSTEP
CNVTOL,U ! CONVERGENCE CRITERION BASED UPON DISPLACEMENTS AND
CNVTOL,ROT ! ROTATIONS
*DO,I,1,4
F,2,MZ,(20000+(I*4000)) ! APPLY MOMENT LOAD
SOLVE
*ENDDO
FINISH
/POST26
NSOL,2,2,U,Y,UY2 ! NODE 2 DISPLACEMENT
ESOL,3,1,,LEPPL,1,EPPLAXL ! AXIAL PLASTIC STRAIN
PRVAR,2,3
FINISH
/CLEAR, NOSTART ! CLEAR PREVIOUS DATABASE BEFORE STARTING PART2
/PREP7
C*** USING BILINEAR ISOTROPIC HARDENING PLASTICITY BEHAVIOR TO DESCRIBE
C*** THE MATERIAL NONLINEARITY
RESUME
TBDELE,BKIN,1 ! DELETE NONLINEAR MATERIAL TABLE BKIN
TB,BISO,1,1 ! BILINEAR ISOTROPIC HARDENING
TBTEMP,70
TBDATA,1,36000,0 ! YIELD POINT AND ZERO TANGENT MODULUS
FINISH
/SOLU
SOLCONTROL,0
NEQIT,5 ! MAXIMUM 5 EQUILIBRIUM ITERATIONS PER STEP
NCNV,0 ! DO NOT TERMINATE THE ANALYSIS IF THE SOLUTION FAILS
! TO CONVERGE
OUTRES,EPPL,1 ! STORE PLASTIC STRAINS FOR EVERY SUBSTEP
CNVTOL,U ! CONVERGENCE CRITERION BASED UPON DISPLACEMENTS AND
CNVTOL,ROT ! ROTATIONS
*DO,I,1,4
F,2,MZ,(20000+(I*4000)) ! APPLY MOMENT LOAD
SOLVE
*ENDDO
FINISH
/POST26
NSOL,2,2,U,Y,UY2 ! NODE 2 DISPLACEMENT
ESOL,3,1,,LEPPL,1,EPPLAXL ! AXIAL PLASTIC STRAIN
PRVAR,2,3
/OUT,vm24,vrt
/OUT
FINISH
*LIST,vm24,vrt
VM25 (Stresses in a Long Cylinder) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM25
/PREP7
SMRT,OFF
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM25, STRESSES IN A LONG CYLINDER
C*** STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 213, PROB. 1
C*** INTERNAL PRESSURE
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,PLANE82,,,1,,2,4 ! AXISYMM, PRINT STRESSES ON NONZERO PRESS. FACES
MP,EX,1,30E6 ! MATERIAL PROPERTIES
MP,DENS,1,.00073
MP,NUXY,1,0.3 ! DEFINE KEYPOINTS, LINES, AND AREAS
K,1,4
K,2,8
KGEN,2,1,2,1,,1
L,1,2,7
ESIZE,.5
LESIZE,1,,,14
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USING QUADS
A,3,1,2,4
AMESH,1
SAVE,MODEL ! SAVE MODEL FOR SECOND LOAD CASE
NSEL,S,LOC,Y,0 ! SET UP LONG CYLINDER EFFECT
D,ALL,UY
NSEL,S,LOC,Y,1
CP,1,UY,ALL ! COUPLE AXIAL DISPLACEMENTS AT UNCONSTRAINED Y EDGE
NSEL,ALL
FINISH
/SOLU
NSEL,S,LOC,X,4
SF,,PRES,30000 ! APPLY INTERNAL PRESSURE ON CYLINDER
NSEL,S,LOC,X,8
SF,,PRES,1E-10 ! APPLY DUMMY PRESSURE FOR SURFACE PRINTOUT
NSEL,ALL
OUTPR,,ALL
SOLVE ! LOAD STEP 1 - INTERNAL PRESSURE
FINISH
/POST1
SET,1,1
LFT_NODE = NODE (4,0,0)
MID_NODE = NODE (6,0,0)
RT_NODE = NODE (8,0,0)
PRNSOL,S,COMP ! PRINT NODAL STRESS SOLUTION
PATH,STRESS,2,,48 ! DEFINE PATH WITH NAME = "STRESS"
PPATH,1,LFT_NODE ! DEFINE PATH POINTS BY NODE
PPATH,2,RT_NODE
PLSECT,S,Z,-1 ! DISPLAY SZ STRESSES
PLSECT,S,X,-1 ! DISPLAY SX STRESSES
PRSECT,-1 ! PRINT LINEARIZED STRESSES
*GET,DEF_4,NODE,LFT_NODE,U,X
*GET,RST_4_C1,NODE,LFT_NODE,S,X
*GET,RST_6_C1,NODE,MID_NODE,S,X
*GET,RST_8_C1,NODE,RT_NODE ,S,X
*GET,TST_4_C1,NODE,LFT_NODE,S,Z
*GET,TST_6_C1,NODE,MID_NODE,S,Z
*GET,TST_8_C1,NODE,RT_NODE ,S,Z
*DIM,VALUE_C1,,7,3
*VFILL,VALUE_C1(1,1),DATA,.0078666,-30000,-7778,0,50000,27778,20000
*VFILL,VALUE_C1(1,2),DATA,DEF_4,RST_4_C1,RST_6_C1,RST_8_C1,TST_4_C1,TST_6_C1,TST_8_C1
*VFILL,VALUE_C1(1,3),DATA,ABS(DEF_4/.0078666),ABS(RST_4_C1/30000),ABS(RST_6_C1/7778),0
*VFILL,VALUE_C1(5,3),DATA,ABS(TST_4_C1/50000),ABS(TST_6_C1/27778),ABS(TST_8_C1/20000)
*DIM,LABEL_C1,CHAR,7,2
LABEL_C1(1,1)='DEF (R=4','STRS_R p','STRS_R p','STRS_R p','STRS_T p'
LABEL_C1(6,1)='STRS_T p','STRS_T p'
LABEL_C1(1,2) = ') in ','si (R=4)','si (R=6)','si (R=8)','si (R=4)'
LABEL_C1(6,2) ='si (R=6)','si (R=8)'
SAVE,TABLE_1
FINISH
/SOLU
RESUME,MODEL
C*** ROTATION ABOUT AXIS
NSEL,S,LOC,Y,0 ! PREVENT RIGID BODY MOTION
NSEL,R,LOC,X,4
D,ALL,UY
NSEL,S,LOC,X,4
SF,,PRES,1E-10 ! LEAVE A SMALL PRESSURE TO ALLOW STRESS PRINTOUT
NSEL,ALL
OMEGA,,1000 ! ROTATE CYLINDER WITH ANGULAR VELOCITY OMEGA
OUTPR,,ALL
SOLVE ! LOAD STEP 2 - CENTRIFUGAL LOADING
FINISH
/POST1
LFT_NODE = NODE (4,0,0)
XI_NODE = NODE (5.43,0,0)
VM26 (Large Deflection of a Cantilever) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,vm26
/FILNAM,vm26
/PREP7
/TITLE, VM26 LARGE DEFLECTION OF A CANTILEVERED PLATE
/COM REF: BATHE AND DVORKIN, " A FORMULATION OF GENERAL SHELL ELEMENTS... "
/COM IJNME, VOL 22, NO. 3 (1986) PAGE 720
/NOPR
SMRT,OFF
ANTYPE,STATIC ! STATIC ANALYSIS
NLGEOM,ON ! LARGE DEFLECTION OPTION
ET,1,SHELL43
R,1,1 ! PLATE THICKNESS = 1
MP,EX,1,1800 ! MATERIAL PROPERTIES
MP,NUXY,,0
K,1 ! DEFINE KEYPOINTS
K,2,12
K,3,12,1
K,4,,1
L,1,2 ! DEFINE LINE SEGMENTS
L,3,4
LESIZE,ALL,,,2 ! 2 DIVISIONS ALONG LENGTH
ESIZE,,1 ! ONE DIVISION ON UNSPECIFIED LINE SEGMENTS
A,1,2,3,4
AMESH,1 ! CREATE MESH
NSEL,S,LOC,X
D,ALL,ALL ! FIXED END B.C.'S
NSEL,S,LOC,X,12
CP,1,ROTY,ALL ! COUPLE ROTATIONS AT FREE END
TORQ=7.854 ! DEFINE HALF TOTAL LOAD
F,2,MY,TORQ
NSEL,ALL ! RESELECT ALL NODES
FINISH
/SOLU
AUTOTS,ON ! USE AUTOMATIC LOAD STEPPING
NSUBST,10 ! START WITH MAX OF 10 SUBSTEPS FOR EACH LOAD STEP
LNSRCH,ON ! USE LINE SEARCH METHOD
OUTPR,BASIC,LAST ! BASIC PRINTOUT IN THE LAST SUBSTEP
OUTRES,ALL,ALL ! WRITE SOLUTION TO THE RESULTS FILE FOR EACH SUBSTEP
SOLVE
FINISH
! THE FOLLOWING 4 COMMANDS ARE NOT NEEDED SINCE THE INITIAL AND THE
! RESTART ANALYSES ARE IN ONE ANSYS RUN. THE USE OF THESE COMMANDS WAS DONE
! IN ORDER TO DEMONSTRATE THE USE OF THE FILES NEEDED FOR A RESTART
/COPY,vm26,rdb,,vm26r,rdb ! COPY THE FILES NEEDED FOR RESTART TO
/COPY,vm26,ldhi,,vm26r,ldhi ! FILES NAMED VM26R.***
/COPY,vm26,r001,,vm26r,r001 !
/COPY,vm26,rst,,vm26r,rst ! NEEDED FOR POSTPROCESSOR ONLY
/CLEAR,NOSTART ! CLEAR THE DATA BASE
/FILNAM,vm26r ! CONTINUE WITH FILES NAMED VM26R.***
/SOLU
ANTYPE,,REST ! RESTART ANALYSIS
F,2,MY,TORQ*2 ! APPLY FULL LOAD
SOLVE
FINISH
/POST1
RSYS,SOLU ! CHOOSE "AS-GENERATED" COORDINATE SYSTEM
SET,2 ! USE LOAD STEP 2 (FROM RESTART ANALYSIS)
SHELL,TOP ! CHOOSE TOP SURFACE OF SHELL FOR STRESS PRINTOUT
PRNSOL,S,COMP ! PRINT NODAL STRESSES AND DISPLACEMENTS
PRNSOL,DOF
*GET,UX_N4,NODE,4,U,X
*GET,UZ_N4,NODE,4,U,Z
*GET,ROTY_N4,NODE,4,ROT,Y
*GET,STRSS_N1,NODE,1,S,X
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'UX,NODE ','UZ,NODE ','ROTY,NOD','STS_X,N_'
LABEL(1,2) = '4 (mm) ','4 (mm) ','E 4(rad)','1 N/mm^2'
*VFILL,VALUE(1,1),DATA,-2.9,-6.5,1.26,94.25
*VFILL,VALUE(1,2),DATA,UX_N4,UZ_N4,ROTY_N4,STRSS_N1
*VFILL,VALUE(1,3),DATA,ABS(UX_N4/2.9),ABS(UZ_N4/6.5),ABS(ROTY_N4/1.26),ABS(STRSS_N1/94.25)
SAVE,TABLE_1
FINI
/DELETE,vm26r,rdb
/DELETE,vm26r,ldhi
/DELETE,vm26r,r001
/DELETE,vm26r,rst
/CLEAR,NOSTART
/PREP7
smrt,off
/NOPR
ANTYPE,STATIC ! STATIC ANALYSIS
NLGEOM,ON ! LARGE DEFLECTION OPTION
ET,1,SHELL181
R,1,1 ! PLATE THICKNESS = 1
RMORE,,,,,10.0
MP,EX,1,1800 ! MATERIAL PROPERTIES
MP,NUXY,,0
K,1 ! DEFINE KEYPOINTS
K,2,12
K,3,12,1
K,4,,1
L,1,2 ! DEFINE LINE SEGMENTS
L,3,4
LESIZE,ALL,,,2 ! 2 DIVISIONS ALONG LENGTH
ESIZE,,1 ! ONE DIVISION ON UNSPECIFIED LINE SEGMENTS
A,1,2,3,4
AMESH,1 ! CREATE MESH
NSEL,S,LOC,X
D,ALL,ALL ! FIXED END B.C.'S
NSEL,S,LOC,X,12
CP,1,ROTY,ALL ! COUPLE ROTATIONS AT FREE END
TORQ=7.854 ! DEFINE HALF TOTAL LOAD
F,2,MY,TORQ
NSEL,ALL ! RESELECT ALL NODES
FINISH
/SOLU
AUTOTS,ON ! USE AUTOMATIC LOAD STEPPING
NSUBST,10 ! START WITH MAX OF 10 SUBSTEPS FOR EACH LOAD STEP
LNSRCH,ON ! USE LINE SEARCH METHOD
OUTPR,BASIC,LAST ! BASIC PRINTOUT IN THE LAST SUBSTEP
OUTRES,ALL,ALL ! WRITE SOLUTION TO THE RESULTS FILE FOR EACH SUBSTEP
SOLVE
FINISH
/SOLU
ANTYPE,,REST ! RESTART ANALYSIS
F,2,MY,TORQ*2 ! APPLY FULL LOAD
SOLVE
FINISH
/POST1
RSYS,SOLU ! CHOOSE "AS-GENERATED" COORDINATE SYSTEM
SET,2 ! USE LOAD STEP 2 (FROM RESTART ANALYSIS)
SHELL,TOP ! CHOOSE TOP SURFACE OF SHELL FOR STRESS PRINTOUT
PRNSOL,S,COMP ! PRINT NODAL STRESSES AND DISPLACEMENTS
PRNSOL,DOF
*GET,UX_N4,NODE,4,U,X
*GET,UZ_N4,NODE,4,U,Z
*GET,ROTY_N4,NODE,4,ROT,Y
*GET,STRSS_N1,NODE,1,S,X
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM29
/PREP7
/TITLE, VM29, FRICTION ON A SUPPORT BLOCK
C***VECTOR MECHANICS FOR ENGINEERS, BEER AND JOHNSTON, 1962, PAGE 283, PROB. 8.2
ANTYPE,STATIC
ET,1,CONTAC12
R,1,-20,1E6 ! THETA = -20, STIFFNESS = 1E6
MP,MU,1,.3 ! COEFFICIENT OF FRICTION
N,1 ! CREATE NODES
N,2
E,1,2 ! CREATE ELEMENT
D,1,ALL ! BOUNDARY CONDITIONS AND LOADS
F,2,FX,-5.76729 ! STICKING LOAD
F,2,FY,-100
NSUBST,1 ! LIMIT TO ONE ITERATION TO PREVENT DIVERGENCE
OUTPR,BASIC,ALL ! PRINT NODAL DOF, REACTION & ELEMENT SOLUTION
OUTPR,NLOAD,ALL ! PRINT ELEMENT NODAL LOADS
KBC,1 ! STEP CHANGE IN B.C.'S
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETAB,NOR_FC1,SMISC,1
ETAB,SLI_FC1,SMISC,2
*GET,NORM_FC1,ELEM,1,ETAB,NOR_FC1
*GET,SLID_FC1,ELEM,1,ETAB,SLI_FC1
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C1,,2,3
LABEL(1,1) = 'NORMAL F','SLIDING '
LABEL(1,2) = 'ORCE lb','FORCE lb'
*VFILL,VALUE_C1(1,1),DATA,-95.942,28.783
*VFILL,VALUE_C1(1,2),DATA,NORM_FC1,SLID_FC1
*VFILL,VALUE_C1(1,3),DATA,ABS(NORM_FC1/95.942),ABS(SLID_FC1/28.783)
SAVE,TABLE_1
FINISH
/SOLU
F,2,FX,-5.76720 ! SLIDING LOAD
SOLVE
FINISH
/POST1
ETAB,NOR_FC2,SMISC,1
ETAB,SLI_FC2,SMISC,2
*GET,NORM_FC2,ELEM,1,ETAB,NOR_FC2
*GET,SLID_FC2,ELEM,1,ETAB,SLI_FC2
*DIM,VALUE_C2,,2,3
LABEL(1,1) = 'NORMAL F','SLIDING '
LABEL(1,2) = 'ORCE lb','FORCE lb'
*VFILL,VALUE_C2(1,1),DATA,-95.942,28.783
*VFILL,VALUE_C2(1,2),DATA,NORM_FC2,SLID_FC2
*VFILL,VALUE_C2(1,3),DATA,ABS(NORM_FC2/95.942),ABS(SLID_FC2/28.783)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm29,vrt
/COM,------------------- VM29 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,FX = 5.76729 LB AND MODEL IS STICKING:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,FX = 5.76720 LB AND MODEL IS SLIDING:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm29,vrt
VM30 (Solid Model of Surface Fillet) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM30
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM30, SOLID MODEL OF SURFACE FILLET
/COM, REF: NAFEMS BENCHMARKS FOR FINITE ELEMENT PRE-PROCESSORS
/COM, D.R. HOSE, I.A. RUTHERFORD, REF R0001, ISSUED 12/2/93, PP. 23.
/COM,
ET,1,SHELL93 ! 8-NODE STRUCTURAL SHELL
L=8.0 ! BASE LENGTH
H=2.0 ! BASE HEIGHT
RECTNG,,L/2,,H, ! CREATE RECTANGULAR AREA
WPROTA,,90 ! ROTATE POSITIVE Y TOWARDS Z
PTXY,0,0,-2,2,6,2,4,0, ! DEFINE COORDINATE PAIRS FOR POLYGON
POLY ! DEFINE POLYGONAL AREA
AGLUE,1,2 ! GLUE AREAS 1 AND 2
AFILLT,1,3,1 ! CREATE AREA FILLET WITH CONSTANT RADIUS=1
/FACET,WIRE
/VIEW,1,1,2,3
/PNUM,AREA,1 ! TURN ON AREA NUMBERING
APLOT ! PLOT AREAS
ACCAT,ALL ! CONCATENATE AREAS
LSEL,S,LINE,,5 ! SELECT LINES TO CONCATENATE
LSEL,A,LINE,,21,24,3
LCCAT,ALL ! CONCATENATE LINES
LSEL,S,LINE,,20,23,3 ! SELECT LINES TO CONCATENATE
LSEL,A,LINE,,7
LCCAT,ALL ! CONCATENATE LINES
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USING QUADS
AMESH,1 ! MESH USING DEFAULT ELEMENT SIZE
EPLOT ! PLOT ELEMENTS
LOCAL,11,,,,,,,-45 ! ROTATE X TOWARDS Z
DSYS,11
NROTAT,ALL
NSEL,S,LOC,X,-.1,.1
*GET,NXMAX,NODE,,MXLOC,X ! CHECK THE POSITIVE DEVIATION FROM ZERO
*GET,NXMIN,NODE,,MNLOC,X ! CHECK THE NEGATIVE DEVIATION FROM ZERO
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'MAX LOCA','MIN LOCA'
LABEL(1,2) = 'TION ','TION '
*VFILL,VALUE(1,1),DATA,0,0
*VFILL,VALUE(1,2),DATA,NXMAX,NXMIN
*VFILL,VALUE(1,3),DATA,0,0
/COM
/OUT,vm30,vrt
/COM,------------------- VM30 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,DEVIATION:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',E10.3,' ',1F5.3)
/COM,
/COM,NOTE: THE LARGER OF THE TWO DEVIATIONS LISTED IS THE 'MAXIMUM DEVIATION'
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm30,vrt
VM33 (Transient Thermal Stress in a Cylinder) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM33
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM33, TRANSIENT THERMAL STRESS IN A CYLINDER
/COM, REF: ROARK AND YOUNG "FORMULAS FOR STRESS AND STRAIN",5TH
/COM, EDITION, MCGRAW-HILL, PG. 585
/COM,
ET,1,SOLID5 ! SOLID5 UX,UY,UZ,TEMP,VOLT,MAG DOF SET
MP,KXX,1,625E-6 ! DEFINE THERMAL CONDUCTIVITY
MP,EX,1,30E6 ! MODULUS OF ELASTICITY
MP,NUXY,1,.3 ! POISSON'S RATIO
MP,ALPX,1,8.4E-6 ! COEFFICIENT OF THERMAL EXPANSION
MP,DENS,1,.284 ! DENSITY (LB/IN**3)
MP,C,1,.10 ! SPECIFIC HEAT
CSYS,1
H=.20 ! MODEL HEIGHT
TH=2.5 ! MODEL HALF-ANGLE
A=1 ! INNER RADIUS
B=3 ! OUTER RADIUS
K,1,A,TH ! DEFINE KEYPOINTS
K,2,B,TH
KGEN,2,1,2,1,,,H
KGEN,2,1,4,1,,-(TH*2)
L,1,2 ! DEFINE LINE SEGMENTS
*REPEAT,4,2,2
LESIZE,ALL,,,15,5
ESIZE,,1
V,1,2,4,3,5,6,8,7 ! DEFINE VOLUME
MSHK,1 ! MAPPED VOLUME MESH
MSHA,0,3D ! USING HEX
VMESH,1 ! MESH VOLUME
NSEL,S,LOC,Y,TH
NSEL,A,LOC,Y,-TH
DSYM,SYMM,Y,1 ! DEFINE STRUCTURAL B.C.
NSEL,S,LOC,Z
DSYM,SYMM,Z,1
NSEL,S,LOC,Z,H ! SELECT NODES ON TOP SURFACE
CP,1,UZ,ALL ! COUPLE ALL NODES IN UZ
NSEL,S,LOC,X,B ! SELECT NODES AT OUTER RADIUS
D,ALL,TEMP,500 ! DEFINE FINAL SURFACE TEMPERATURE
NSEL,ALL
FINISH
/SOLU
ANTYPE,TRANS ! TRANSIENT ANALYSIS
TIMINT,OFF,STRUC ! SUPPRESS STRUCTURAL DYNAMICS
CNVTOL,HEAT ! CONVERGENCE BASED ON HEAT FLOWS
CNVTOL,F ! AND FORCES ONLY
AUTOTS,ON ! AUTOMATIC TIME STEPPING
OUTRES,,ALL ! RESULTS FOR ALL TIME POINTS
KBC,0 ! RAMP LOAD OVER LOAD STEP
TREF,70 ! SET REFERENCE TEMPERATURE
TUNIF,70 ! SET INITIAL UNIFORM TEMPERATURE
DELTIM,1,,60 ! MINIMUM TIME STEP OF 1 SEC
TIME,430 ! TIME AT END OF LOAD STEP
SOLVE
FINISH
/POST1
*GET,IN_STRS,NODE,1,S,Y
*GET,OUT_STRS,NODE,2,S,Y
FINISH
/POST26
NSOL,2,1,TEMP ! STORE TEMP AT INNER RADIUS
NSOL,3,2,TEMP ! STORE TEMP AT OUTER RADIUS
ESOL,4,1,1,S,Y,SYB ! STORE SY AT INNER RADIUS
ESOL,5,15,2,S,Y,SYC ! STORE SY AT OUTER RADIUS
ADD,6,3,2,,DELT,,,1,-1 ! CALCULATE DELTA TEMP. (OUTER-INNER)
PRVAR,2,3,4,5,6 ! PRINT VARIABLES VS. TIME
/GRID,1
/AXLAB,Y,DELT
PLVAR,6 ! DISPLAY DELTA TEMP. VS TIME
/AXLAB,Y,SY
PLVAR,4,5 ! DISPLAY SY VS. TIME
VM34 (Bending of a Tapered Plate (Beam)) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM34
/PREP7
/TITLE, VM34, BENDING OF A TAPERED PLATE (BEAM)
! INTROD. TO STRESS ANALYSIS, HARRIS, 1ST PRINTING, PAGE 114, PROB. 61
! PLATE ELEMENTS (SHELL63)
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,SHELL63,2
R,1,.5 ! THICKNESS = 0.5
MP,EX,1,30E6
MP,NUXY,1,0 ! POISSON'S RATIO IS ZERO
N,1
N,8,20,-1.5
FILL
N,11
N,18,20,1.5
FILL
E,1,2,12
E,2,3,12
E,13,12,3
E,3,4,14
E,14,13,3
EGEN,3,2,2,5
CP,1,UZ,2,12 ! COUPLE APPROPRIATE DEGREES OF FREEDOM
CP,2,ROTY,2,12
CPSGEN,6,1,1,2 ! GENERATE 6 SETS OF EQUATIONS
OUTPR,ALL,ALL
D,8,ALL,,,18,10
D, ALL,ROTX,0 ! REMOVE "TORSIONAL" DEGREES OF FREEDOM
F,1,FZ,-10
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,STRS,S,1 ! STORE S1(TOP) FOR SHELL63
ESORT,STRS ! SORT ELEMENTS BASED ON S1(TOP)
*GET,SMAX,SORT,,MAX ! GET MAXIMUM S1 AS SMAX
PRNSOL,DOF ! PRINT NODAL DISPLACEMENTS
LFT_NODE = NODE (0,0,0)
*GET,DEFL,NODE,LFT_NODE,U,Z
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C1,,2,3
LABEL(1,1) = 'DEFLECTI','MX_PRIN_'
LABEL(1,2) = 'ON (in) ','STRS psi'
*VFILL,VALUE_C1(1,1),DATA,-.042667,1600
*VFILL,VALUE_C1(1,2),DATA,DEFL,SMAX
*VFILL,VALUE_C1(1,3),DATA,ABS(DEFL/.042667 ) ,ABS( SMAX/1600 )
SAVE,TABLE_1
FINISH
/CLEAR, NOSTART
/PREP7
/TITLE, VM34, BENDING OF A TAPERED PLATE (BEAM)
! TAPERED BEAM ELEMENTS (BEAM44)
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,BEAM44
*DO,I,1,10 ! CREATE DO LOOP FOR REAL CONSTANTS
R,I, 1,1,.003125*(I-1),.25,1
RMORE,1,1,.003125* I ,.25,1
*ENDDO
RMOD,1,3,.5E-3 ! GIVE FREE END A POSITIVE MOMENT OF INERTIA
RLIST
MP,EX,1,30E6
N,1
N,11,20
FILL
N,12,,,1 ! NODE 12 FOR ALIGNING BEAM AXES
NGEN,10,1,12 ! NODES 12 TO 21 ARE COINCIDENT
E,1,2,12
EGEN,10,1,1,,,,,1 ! GENERATE ELEMENTS WITH REAL CONSTANT INCREASED BY 1
D,11,ALL
D,1,UY,,,10,,ROTX,ROTZ
F,1,FZ,-10
OUTPR,ALL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,STRS,NMISC,1 ! STORE SMAX (MAXIMUM STRESS) FOR BEAM44
ESORT,STRS ! SORT ELEMENTS BASED ON SMAX (MAXIMUM STRESS)
*GET,SMAX,SORT,,MAX ! GET MAXIMUM STRESS AS SMAX
PRNSOL,DOF ! PRINT NODAL DISPLACEMENTS
LFT_NODE = NODE (0,0,0)
*GET,DEFL,NODE,LFT_NODE,U,Z
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C2,,2,3
LABEL(1,1) = 'DEFLECTI','MX_PRIN_'
LABEL(1,2) = 'ON (in) ','STRS psi'
*VFILL,VALUE_C2(1,1),DATA,-.042667,1600
*VFILL,VALUE_C2(1,2),DATA,DEFL,SMAX
*VFILL,VALUE_C2(1,3),DATA,ABS(DEFL/.042667 ) ,ABS( SMAX/1600 )
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm34,vrt
/COM,------------------- VM34 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING SHELL63:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F12.6,' ',F12.6,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,' ',F12.6,' ',F12.6,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm34,vrt
VM35 (Bimetallic Layered Cantilever Plate with Thermal Loading) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM35
/PREP7
SMRT,OFF
/TITLE,VM35: BIMETALLIC LAYERED CANTILEVER PLATE WITH THERMAL LOADING
C*** ROARK AND YOUNG, FORMULAS FOR STRESS AND STRAIN, PP. 113-114.
ANTYPE,STATIC
ET,1,SHELL91,,1,,0,4,1,1
R,1,2
RMORE
RMORE,1,0,.05 ! LAYER 1 IS MAT'L 1, .05 THICK
RMORE,2,,.05 ! LAYER 2 IS MAT'L 2, .05 THICK
MP,EX,1,3E7 ! MATERIAL PROPERTIES
MP,EX,2,3E7
MP,ALPX,1,1E-5
MP,ALPX,2,2E-5
MP,NUXY,1,0
MP,NUXY,2,0
K,1 ! DEFINE GEOMETRY
K,2,,1
K,3,10,1
K,4,10
A,1,2,3,4
ESIZE,2 ! ELEMENT SIDE LENGTHS = 2
AMESH,1
NSEL,S,LOC,X
NSEL,R,LOC,Y,.5
D,ALL,ALL ! FIX ONE END OF CANTILEVER
NSEL,S,LOC,Y,0.5
DSYM,SYMM,Y ! SYMMETRY PLANE DOWN CENTERLINE
NSEL,ALL
TREF,70
BFUNIF,TEMP,170 ! DEFINE UNIFORM TEMPERATURE
FINISH
/SOLU
OUTPR,BASIC,1
SOLVE
FINISH
/POST1
SHELL,TOP ! SELECT TOP SURFACE FOR STRESS PRINT
PRNSOL,S,COMP
NSEL,S,LOC,X,10 ! SELECT CENTERLINE OF FREE END FOR DISPLACEMENT PRINT
NSEL,R,LOC,Y,.5
PRNSOL,U,COMP
RT_NODE = NODE (10,.5,0)
*GET,DEF_Z,NODE,RT_NODE,U,Z
*GET,DEF_X,NODE,RT_NODE,U,X
*GET,OUT_STRS,NODE,1,S,X
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'RT_END U','RT_END U','LFT_END '
LABEL(1,2) = 'Z (in) ','X (in) ','STRS psi'
*VFILL,VALUE(1,1),DATA,.750,.015,7500
*VFILL,VALUE(1,2),DATA,DEF_Z,DEF_X,OUT_STRS
*VFILL,VALUE(1,3),DATA,ABS(DEF_Z/.750) ,ABS(DEF_X/.015),ABS(OUT_STRS/7500)
/COM
/OUT,vm35,vrt
/COM,------------------- VM35 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm35,vrt
VM36 (Limit Moment Analysis) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM36
/PREP7
/TITLE, VM36, LIMIT MOMENT ANALYSIS
! MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 389, EX. 8.9
ANTYPE,STATIC
ET,1,BEAM4
ET,2,COMBIN40,,,5 ! ROTY D.O.F. SPRING
R,1,1,20,20,3.93597,3.93597 ! DEFINE THREE SETS OF REAL CONSTANTS
R,2,1E12,,,,27777.8
R,3,1,,,,1E6
MP,EX,1,30E6 ! DEFINE MATERIAL PROPERTIES
MP,NUXY,1,.3
N,1 ! BEGIN NODES DEFINITION
N,2,100
N,3,100
N,4,150
N,5,150
E,1,2 ! DEFINE BEAM ELEMENTS
E,3,4
TYPE,2 ! DEFINE BREAKAWAY HINGE ELEMENTS
REAL,2
E,2,3
E,4,5
REAL,3
E,2,3
E,4,5 ! EXTRA ELEMENTS FOR SOLUTION STABILITY
OUTPR,ALL,ALL
CNVTOL,M,27778,.001
CP,1,UX,2,3 ! COUPLE TRANSLATIONS ACROSS PLASTIC HINGE
CPLGEN,1,UZ ! GENERATE 2ND SET IN DIRECTION UZ W/ SAME NODES
CPSGEN,2,2,1,2,1 ! GENERATE TWO ADDITIONAL SETS W/ DIFFERENT NODES
DSYM,SYMM,Y ! CONSTRAIN MODEL SYMMETRICALLY IN Y DIRECTION
D,1,UZ ! CONSTRAIN SIMPLY SUPPORTED END AGAINST DISP.
D,4,UZ,,,,,UX ! CONSTRAIN RIGID END AGAINST TWO DIRECTIONAL DISP
D,5,ROTY ! CONSTRAIN RIGID END AGAINST ROTATIONAL MOVEMENT
F,2,FZ,-1000 ! APPLY ELASTIC FORCE AT HINGE B
FINISH
/SOLU
SOLCONTROL,0
SOLVE ! WRITE LOAD STEP
FINISH
/POST26
RFORCE,2,1,F,Z
RFORCE,3,5,M,Y
STORE
*GET,RA,VARI,2,EXTREM,VMAX
*GET,MC,VARI,3,EXTREM,VMAX
*GET,UB,NODE,2,U,Z
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFLECTI','REACTION','MOMENT_C'
LABEL(1,2) = 'ON (in) ','_A (lb) ',' (ib-lb)'
*VFILL,VALUE(1,1),DATA,-.02829,148.15,27778
*VFILL,VALUE(1,2),DATA,UB,RA,MC
*VFILL,VALUE(1,3),DATA,ABS(UB/.02829) ,ABS(RA/148.15 ),ABS(MC/27778)
SAVE,TABLE_1
finish
/solution
NSUBST,3 ! USE CONVERGENCE CRITERIA,3 SUBSTEPS MAX
OUTPR,ALL,LAST ! PRINT LAST ITERATION.
F,2,FZ,-1388.8 ! APPLY VALUE SLIGHTLY SMALLER THAN PL TO HINGE B
SOLVE
F,2,FZ,-1390 ! APPLY VALUE SLIGHTLY LARGER THAN PL TO HINGE B
! LARGE DISPLACEMENT VALUES INDICATE COLLAPSE
! AND PLASTIC DEFORMATION
SOLVE
finish
RESUME,TABLE_1
/COM
/OUT,vm36,vrt
/COM,------------------- VM36 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS FOR P=1000 LBS (ELSTIC):
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.5,' ',F11.5,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM36 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm36,vrt
VM37 (Elongation of a Solid Bar) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM37
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
smrt,off
/TITLE, VM37, ELONGATION OF A SOLID BAR
/COM INTROD. TO STRESS ANALYSIS, HARRIS, 1ST PRINTING, PAGE 237, PROB. 4
/COM USING 3-D STRUCTURAL SOLID ELEMENTS
ANTYPE,STATIC
ET,1,SOLID45
MP,EX,1,10.4E6
MP,NUXY,1,.3
K,1,1,,1 ! DEFINE KEYPOINTS
K,2,-1,,1
K,3,-1,,-1
K,4,1,,-1
K,5,.5,10,.5
K,6,-.5,10,.5
K,7,-.5,10,-.5
K,8,.5,10,-.5
V,1,2,3,4,5,6,7,8 ! DEFINE VOLUME
LSEL,S,LINE,,5,11,2 ! SELECT LINES
LESIZE,ALL,,,7 ! DEVIDE SELECTED LINES BY 7 DIVISIONS
LSEL,ALL ! SELECT ALL LINES
ESIZE,,1 ! USE 1 ELEMENT PER LINE DIVISION
/OUT,SCRATCH
VMESH,1 ! MESH THE VOLUME
/OUT
OUTPR,BASIC,ALL
NSEL,S,LOC,Y,0 ! APPLY BOUNDARY CONDITIONS AT THE BASE OF THE MODEL
D,ALL,ALL ! FIX ALL DEGREES OF FREEDOM AT SELECTED NODE SET
NSEL,ALL
NSEL,S,LOC,Y,10 ! APPLY LOAD ON FREE END OF THE MODEL
SF,,PRES,-10000
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,SIGY,S,Y ! RETRIEVE CENTROIDAL SY
/VIEW,1,1 ! CHANGE VIEW TO LOOKING DOWN X-AXIS
/VUP,1,-Y ! REORIENT MODEL ON SCREEN
!/CLABEL,1,1 ! LABEL CONTOUR LINES
!/CVAL,1,2700,3500,4300,5100,5900,6700,7500,8300 ! USER DEFINED CONTOURS
NSLE,S ! SELECT NODES ATTACHED TO ELEMENTS
PLNSOL,S,Y ! DISPLAY AXIAL STRESS
ESEL,S,ELEM,,4 ! SELECT MID-LENGTH ELEMENT
PRETAB,SIGY ! PRINT OUT STORED STRESS ITEM
PRNSOL,S,COMP ! PRINT NODAL STRESSES
ESEL,ALL ! SELECT ALL ELEMENTS
NSEL,S,LOC,Y,10 ! SELECT ALL NODES AT Y=10 (FREE END OF MODEL)
PRNSOL,DOF ! PRINT OUT DISPLACEMENTS OF NODES
NSEL,ALL
/NOPR
MID_NODE = NODE(0,5,0)
MID_ELM = ENEARN(MID_NODE)
BOT_NODE = NODE (0,10,0)
*GET,DEF,NODE,BOT_NODE,U,Y
*GET,STRSS,ELEM,MID_ELM,ETAB,SIGY
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C1,,2,3
LABEL(1,1) = 'MAX DEF ','SIGY MID'
LABEL(1,2) = '(in) ','_ELM psi'
*VFILL,VALUE_C1(1,1),DATA,.0048077,4444
*VFILL,VALUE_C1(1,2),DATA,DEF,STRSS
*VFILL,VALUE_C1(1,3),DATA,ABS(DEF/.0048077) ,ABS(STRSS/4444)
/GOPR
FINISH
/COM
/OUT,vm37,vrt
/COM,------------------- VM37 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS FOR SOLID45:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F12.7,' ',F12.7,' ',1F5.3)
/NOPR
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm37,vrt
/DELETE,SCRATCH
FINISH
VM38 (Plastic Loading of a Thick-Walled Cylinder Under Pressure) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM38
/PREP7
/TITLE, VM38, PLASTIC LOADING OF A THICK-WALLED CYLINDER UNDER PRESSURE
C*** STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 388, ART. 70
ET,1,PLANE42,,1,1 ! AXISYMMETRIC SOLID, SUPPRESS EXTRA SHAPES
ET,2,SURF153,,,1,1 ! AXISYMMETRIC 2-D SURFACE EFFECT ELEMENT WITHOUT
! MIDSIDE NODES
MP,EX,1,30E6
MP,NUXY,1,.3
TB,BKIN,1,1 ! BILINEAR KINEMATIC HARDENING
TBTEMP,70
TBDATA,1,30000,0 ! YIELD STRESS AND ZERO TANGENT MODULUS
N,1,4 ! DEFINE NODES
N,6,8
FILL
NGEN,2,10,1,6,1,,1
E,11,1,2,12 ! DEFINE ELEMENTS
EGEN,5,1,1
CPNGEN,1,UY,11,16 ! COUPLE NODES
TYPE,2 ! CREATE SURF153 TO APPLY SURFACE PRESSURE LOADING
NSEL,S,LOC,X,4
ESURF
NSEL,ALL
TREF,70 ! BOUNDARY CONDITIONS AND LOADING
D,1,UY,,,6
FINISH
/SOLU
ESEL,S,TYPE,,2 ! SELECT SURF153 ELEMENTS TO APPLY SURFACE PRESSURE
! LOADING FOR ELASTIC ANALYSIS
SFE,ALL,1,PRES,,12990
ESEL,ALL
OUTPR,BASIC,1
SOLVE
FINISH
/POST1
ETABLE,STRS_R,S,X
ETABLE,STRS_T,S,Z
*GET,SIGR_I,ELEM,1,ETAB,STRS_R
*GET,SIGT_I,ELEM,1,ETAB,STRS_T
*GET,SIGR_O,ELEM,5,ETAB,STRS_R
*GET,SIGT_O,ELEM,5,ETAB,STRS_T
ESEL,S,TYPE,,2 ! SELECT SURF154 ELEMENTS TO APPLY SURFACE PRESSURE
! LOADING FOR PLASTIC ANALYSIS
SFE,ALL,1,PRES,,24012
ESEL,ALL
SOLVE
FINISH
/POST1
RESUME,TABLE_1
/COM
/OUT,vm38,vrt
/COM,------------------- VM38 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,FULLY ELASTIC, PLANE42 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM,FULLY ELASTIC, PLANE45 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM38 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm38,vrt
VM39 (Bending of a Circular Plate with a Center Hole) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM39
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM39, BENDING OF A CIRCULAR PLATE WITH A CENTER HOLE
C*** STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 111, EQNS. (E,F)
ANTYPE,STATIC
ET,1,SHELL63
R,1,.25 ! DEFINE PLATE THICKNESS = .25
MP,EX,1,30.E6
MP,NUXY,1,.3
CSYS,1 ! DEFINE CYLINDRICAL C.S.
N,1,10 ! BEGIN NODE DEFINITION
N,7,30
FILL,,,,,,,,3 ! USE 3:1 SPACING RATIO FOR FILLING IN NODES
NGEN,2,10,1,7,1,,10
NROTAT,1,17,1
E,1,2,12,11 ! DEFINE FIRST ELEMENT
EGEN,6,1,1 ! GENERATE NEXT 5 ELEMENTS
D,1,ALL,,,11,10 ! CONSTRAIN INNER EDGE IN ALL D.O.F.
D,2,UY,,,7,,ROTX,ROTZ ! CONSTRAIN LOWER EDGE AGAINST ROTATIONS IN X & Z
D,12,UY,,,17,,ROTX,ROTZ ! CONSTRAIN UPPER EDGE AGAINST ROTATIONS IN X & Z
F,7,MY,-26.18,,17,10 ! APPLY MOMENT LOAD AT OUTER EDGE
OUTPR,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
/WINDOW,1,TOP ! SET UP WINDOW 1 FOR DISPLACEMENT CONTOUR DISPLAY
/PLOPTS,MINM,OFF ! TURN OFF MN AND MX DUE TO INSTABILITY
PLNSOL,U,Z ! DISPLAY PERPENDICULAR DISPLACEMENTS AS CONTOURS
/WINDOW,1,OFF ! TURN OFF WINDOW 1
/NOERASE ! TURN OFF AUTOMATIC ERASE BETWEEN DISPLAYS
/WINDOW,2,BOT ! SET UP WINDOW 2 FOR EDGE DISPLACEMENT DISPLAY
/VIEW,2,,-1 ! CHANGE VIEW FOR WINDOW 2
PLDISP,1 ! DISPLAY UNDISPLACED & DISPLACED SHAPES
SHELL,TOP
ESEL,,,,1 ! SELECT INNER ELEMENT(ELEM #1)
ETABLE,MOMX,SMISC,4 ! RETRIEVE MOMENT(X) AND SX AT TOP
ETABLE,SIGX,S,X
PRETAB,GRP1 ! PRINT STORED VALUES
*GET,M1,ETAB,1,ELEM,1
*GET,P1,ETAB,2,ELEM,1
ESEL,,,,6 ! SELECT OUTER ELEMENT(ELEM#6)
ETABLE,REFL
PRETAB,GRP1 ! PRINT STORED VALUES
*GET,M2,ETAB,1,ELEM,6
*GET,P2,ETAB,2,ELEM,6
ESEL,ALL
RSYS,1
PRNSOL,S,COMP ! PRINT NODAL STRESSES
NSEL,S,LOC,X,30 ! SELECT NODES AT R=A
PRNSOL,DOF ! PRINT DISPLACEMENTS
*GET,DEF,NODE,7,U,Z
*GET,ROT,NODE,7,ROT,Y
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'DEFLECTI','MX_SLOPE'
LABEL(1,2) = 'ON (in) ','(rad) '
*VFILL,VALUE(1,1),DATA,.049064,-.0045089
*VFILL,VALUE(1,2),DATA,DEF,ROT
*VFILL,VALUE(1,3),DATA,ABS(DEF/.049064 ) ,ABS( ROT/.0045089)
/COM
/OUT,vm39,vrt
/COM,------------------- VM39 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.7,' ',F10.7,' ',1F5.3)
/COM,----------------------------------------------------------
/NOPR
LABEL(1,1) = 'MOMENT ','PRESSURE'
LABEL(1,2) = 'in-lb/in',' psi '
*VFILL,VALUE(1,1),DATA,-13.783,-1323.2
*VFILL,VALUE(1,2),DATA,M1,P1
*VFILL,VALUE(1,3),DATA,ABS(M1/13.783),ABS(P1/1323.2)
/GOPR
/COM,----------------------------------------------------------
/COM,
/COM,X=10.81 in | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/NOPR
LABEL(1,1) = 'MOMENT ','PRESSURE'
LABEL(1,2) = 'in-lb/in',' psi '
*VFILL,VALUE(1,1),DATA,-10.127,-972.22
*VFILL,VALUE(1,2),DATA,M2,P2
*VFILL,VALUE(1,3),DATA,ABS(M2/10.127),ABS(P2/972.22)
/GOPR
/COM,----------------------------------------------------------
/COM,
/COM,X=27.1 in | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm39,vrt
VM40 (Large Deflection and Rotation of a Beam Pinned at One End) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM40
/PREP7
MP,PRXY,,0.3
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM40, LARGE DEFLECTION AND ROTATION OF A BEAM PINNED AT ONE END
C*** REFERENCE - ANY BASIC MATHEMATICS BOOK
PI=(4.0)*ATAN(1.0) ! ANALYST FORGETS VALUE OF PI - LETS ANSYS CALCULATE IT
ANTYPE,TRANS ! NONLINEAR TRANSIENT DYNAMIC ANALYSES
NLGEOM,ON ! LARGE DEFLECTIONS
ET,1,BEAM3
R,1,1,1,1 ! ARBITRARY GEOMETRIC PROPERTIES
MP,EX,1,30E6 ! DEFINE MATERIAL PROPERTIES
MP,DENS,1,1E-10 ! DEFINE DENSITY OF ALMOST ZERO
N,1 ! BEGIN NODAL DEFINITION
N,2,10
E,1,2 ! DEFINE ELEMENT
FINISH
/SOLU
SOLCONTROL,0
D,1,ROTZ,PI*2 ! ONE COMPLETE REVOLUTION
D,1,UX,,,,,UY ! CONSTRAIN NODE 1 (PINNED END OF BEAM)
NSUBST,24
TIME,.15 ! TIME STEP OF 0.00625 SEC. (.15/24)
OUTRES,NSOL,1 ! SAVE NODAL DOF SOLUTION FOR EVERY SUBSTEP
OUTRES,ESOL,1 ! SAVE ELEMENT SOLUTION FOR EVERY SUBSTEP
CNVTOL,F,1,0.00001 ! CONVERGENCE CRITERION BASED UPON FORCES
CNVTOL,M,1,0.00001 ! CONVERGENCE CRITERION BASED UPON MOMENTS
SOLVE
FINISH
/POST26
NSOL,2,2,U,X,UX ! DEFINE NODE 2 UX DISP AS VARIABLE 2
NSOL,3,2,U,Y,UY ! DEFINE NODE 2 UY DISP AS VARIABLE 3
NSOL,4,1,ROT,Z,ROTZ ! DEFINE NODE 1 ROTZ AS VARIABLE 4
ESOL,6,1,,LS,4,SDIR ! GET AXIAL STRESS OF ELEMENT AT NODE 2
DERIV,5,4,,,INPUT_W ! CALCULATE DERIVATIVE OF VAR. 4 WRT VARIABLE 1 (TIME)
PRVAR,2,3,4,5,6 ! PRINT VARIABLES 1 THRU 6
PLVAR,2,3 ! DISPLAY VARIABLES 2 AND 3 AS A FUNCTION OF TIME
STORE
*GET,MX_STRS,VARI,6,EXTREM,VMAX
*GET,DEFX_60,VARI,2,RSET,4
*GET,DEFY_90,VARI,3,RSET,6
*GET,DEFX_180,VARI,2,RSET,12
*GET,DEFY_210,VARI,3,RSET,14
*GET,DEFX_315,VARI,2,RSET,21
*GET,DEFY_360,VARI,3,RSET,24
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
*DIM,STRSS,,1,1
*VFILL,STRSS(1,1),DATA,MX_STRS
LABEL(1,1) = '60 DEG, ','90 DEG, ','180 DEG,','180 DEG,','180 DEG,','180 DEG,'
LABEL(1,2) = ' UX (in)',' UY (in)',' UX (in)',' UX (in)',' UX (in)',' UX (in)'
*VFILL,VALUE(1,1),DATA,-5,10,-20,-5,2.93,0
*VFILL,VALUE(1,2),DATA,DEFX_60,DEFY_90,DEFX_180,DEFY_210,DEFX_315,DEFY_360
*VFILL,VALUE(1,3),DATA,ABS(DEFX_60/5),ABS(DEFY_90/10),ABS(DEFX_180/20),ABS(DEFY_210/5)
*VFILL,VALUE(5,3),DATA,ABS(DEFX_315/2.93),0
/COM
/OUT,vm40,vrt
/COM,------------------- VM40 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,
/COM,THE MAXIMUM AXIAL STRESS IS:
*VWRITE,STRSS(1,1)
(1X,F4.2)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm40,vrt
VM41 (Small Deflection of a Rigid Beam) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM41
/PREP7
MP,PRXY,,0.3
/TITLE, VM41, SMALL DEFLECTION OF A RIGID BEAM
!COM REFERENCE - ANY BASIC STRENGTH OF MATERIAL BOOK
!COM USING THICK BEAM GEOMETRY
ET,1,MATRIX27,,,4 ! KEYOPT(3)=4, INPUT DATA AS 12 X 12 STIFFNESS MATRIX
ET,2,BEAM3
R,1 ! TABLE 1 REAL CONSTANTS FOR MATRIX27 STIFFNESS MATRIX
RMODIF,1,51,10000 ! MODIFY POSITIONS 51, 57 AND 78 IN TABLE 1
RMODIF,1,78,10000 ! RMODIF USED, RATHER THAN RMORE, FOR EASIER INPUT
RMODIF,1,57,-10000
R,2,100,1000,10 ! RIGID BEAM PROPERTIES
MP,EX,1,30E6
N,1
N,2
N,3,10
E,1,2 ! STIFFNESS MATRIX ELEMENT
TYPE,2
REAL,2
E,2,3 ! BEAM ELEMENT
OUTPR,ALL,1 ! PRINT ALL ITEMS
D,1,ROTZ
D,2,UX,,,,,UY
F,3,FY,-10
FINISH
/SOLU
SOLVE
FINISH
/POST26
ESOL,2,2,,LS,2,SBEN
STORE
*GET,STRS_BEN,VARI,2,EXTREM,VMAX
FINISH
/POST1
*GET,DEF_X,NODE,3,U,X
*GET,DEF_Y,NODE,3,U,Y
*GET,ROT_Z,NODE,3,ROT,Z
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'DEFLECTI','DEFLECTI','ROTATION','SIG_BEND'
LABEL(1,2) = 'ON_X(in)','ON_Y(in)',' (rad)',' (psi)'
*VFILL,VALUE(1,1),DATA,0,-.1,-.01,0
*VFILL,VALUE(1,2),DATA,DEF_X,DEF_Y,ROT_Z,STRS_BEN
*VFILL,VALUE(1,3),DATA,0,ABS(DEF_Y/.1 ),ABS(ROT_Z/.01),0
SAVE,TABLE_1
FINISH
/PREP7
!COM USING CONSTRAINT EQUATIONS
R,2,.0625,.00032552,.25 ! BEAM PROPERTIES
CE,1,,3,UY,1,2,ROTZ,-10 ! CONSTRAINT EQUATION
FINISH
/SOLU
SOLVE
FINISH
/POST26
ESOL,2,2,,LS,2,SBEN
STORE
*GET,STRS_BEN,VARI,2,EXTREM,VMAX
FINISH
/POST1
*GET,DEF_X,NODE,3,U,X
*GET,DEF_Y,NODE,3,U,Y
*GET,ROT_Z,NODE,3,ROT,Z
LABEL(1,1) = 'DEFLECTI','DEFLECTI','ROTATION','SIG_BEND'
LABEL(1,2) = 'ON_X(in)','ON_Y(in)',' (rad)',' (psi)'
*VFILL,VALUE(1,1),DATA,0,-.1,-.01,0
*VFILL,VALUE(1,2),DATA,DEF_X,DEF_Y,ROT_Z,STRS_BEN
*VFILL,VALUE(1,3),DATA,0,ABS(DEF_Y/.1 ),ABS(ROT_Z/.01),0
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm41,vrt
/COM,------------------- VM41 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS FOR THICK BEAM:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS WITH CONSTRAINT EQUATION:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm41,vrt
VM42 (Barrel Vault Roof Under Self Weight) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM42
/PREP7
smrt,off
/TITLE, VM42, BARREL VAULT ROOF UNDER SELF WEIGHT
/COM, REF: COOK, CONCEPTS AND APPL. OF F.E.A., 2ND ED., 1981, PP. 284-287.
ANTYPE,STATIC
ET,1,SHELL93
R,1,0.25
MP,EX,1,4.32E8 ! MATERIAL PROPERTIES
MP,NUXY,1,0.0
MP,DENS,1,36.7347
CSYS,1
K,1,25,50
K,2,25,50,25 ! DEFINE KEYPOINTS AND AREA
KGEN,2,1,2,1,,40
A,1,3,4,2
ESIZE,,4
AMESH,1
CSYS,0 ! SWITCH BACK TO GLOBAL CARTESIAN C.S.
NSEL,S,LOC,X
DSYM,SYMM,X ! CONSTRAIN SYMMETRY PLANES
NSEL,S,LOC,Z
DSYM,SYMM,Z
NSEL,S,LOC,Z,25
D,ALL,UX,0,,,,UY,ROTZ ! CONSTRAIN END OF ROOF
NSEL,ALL
ACEL,,9.8
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,NODE,,1,2,1 ! SELECT NODES AT POINTS A AND B
ESLN,S ! SELECT ELEMENTS CONTAINING NODES
PRNSOL,U,COMP
*GET,UYA,NODE,1,U,Y
*GET,UXA,NODE,1,U,X
RSYS,1 ! DISPLAY RESULTS IN CYLINDRICAL SYSTEM
SHELL,TOP
PRNSOL,S,COMP
*GET,SIGZ_TOP,NODE,1,S,Z
*GET,SIGY_TOP,NODE,2,S,Y
SHELL,BOT
PRNSOL,S,COMP
*GET,SIGZ_BOT,NODE,1,S,Z
*GET,SIGY_BOT,NODE,2,S,Y
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
LABEL(1,1) = 'UYA ','UXA ','SIGZ, TO','SIGZ, BO','SIGTH,TO','SIGTH,BO'
LABEL(1,2) = ' (m)',' (m)','P_A (PA)','T_A (PA)','P_B (PA)','T_B (PA)'
*VFILL,VALUE(1,1),DATA,-.3019,-.1593,215570,340700,191230,-218740
*VFILL,VALUE(1,2),DATA,UYA,UXA,SIGZ_TOP,SIGZ_BOT,SIGY_TOP,SIGY_BOT
*VFILL,VALUE(1,3),DATA,ABS(UYA/.3019 ),ABS(UXA/.1593 ),ABS(SIGZ_TOP/215570 )
*VFILL,VALUE(4,3),DATA,ABS(SIGZ_BOT/340700),ABS(SIGY_TOP/191230),ABS(SIGY_BOT/218740)
/COM
/OUT,vm42,vrt
/COM,------------------- VM42 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F12.4,' ',F12.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm42,vrt
VM43 (Bending of an Axisymmetric Thick Pipe Under Gravity Loading) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM43
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM43, BENDING OF AN AXISYMMETRIC THICK PIPE UNDER GRAVITY LOADING
C*** FORMULAS FOR STRESS AND STRAIN, ROARK, 4TH ED., PAGE 112, NO. 33
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,PLANE25,,,,,,2 ! PLANE25
MP,EX,1,30.E6 ! DEFINE MATERIAL PROPERTIES
MP,DENS,1,.00073
MP,NUXY,1,0 ! DEFINE NUXY AS 0.0
K,1,.5 ! DEFINE KEYPOINTS
K,2,.5,100
KGEN,2,1,2,1,.5 ! GENERATE 2 ADDITIONAL KEYPOINTS IN X DIRECTION
L,1,2 ! DEFINE LINES AND NUMBER OF DIVISIONS
LESIZE,1,,,12
L,2,4
LESIZE,2,,,1
L,3,4
LESIZE,3,,,12
L,1,3
LESIZE,4,,,1
A,3,1,2,4 ! DEFINE AREA
AMESH,1 ! MESH AREA 1
ACEL,386,,-386 ! GRAVITY AS THE SUM OF TWO HARMONICALLY VARYING LOADS
MODE,1,1 ! SYMMETRIC HARMONIC LOAD
NSEL,S,LOC,Y,0 ! SELECT NODES AT Y=0
D,ALL,ALL ! CONSTRAIN IN ALL DOF
NSEL,S,LOC,Y,100 ! SELECT NODES AT Y=100
D,ALL,UY ! CONSTRAIN IN Y DISPLACEMENT DOF (SYMMETRY PLANE)
NSEL,ALL
FINISH
/SOLU
OUTPR,BASIC,LAST ! PRINT BASIC SOLUTION
SOLVE
FINISH
/POST1
SET,1,1,,,,0.0 ! READ IN RESULTS AT ANGLE=0.0
/VUP,1,X ! DEFINE X AXIS AS VERTICAL AXIS FOR DISPLAYS
/WINDOW,1,-1,1,0,1 ! DEFINE AND TURN ON WINDOW 1
PLDISP,1 ! DISPLAY UNDISPLACED AND DISPLACED SHAPE OF PIPE
PRNSOL,U,COMP ! PRINT DISPLACEMENTS
*GET,DEF_X,NODE,3,U,X
SET,1,1,,,,90.0 ! READ IN RESULTS AT ANGLE=90.0
/WINDOW,1,OFF ! TURN OFF WINDOW 1
/NOERASE ! DON'T ERASE EXISTING DISPLAY
/WINDOW,2,-1,1,-1,0 ! DEFINE AND TURN ON WINDOW 2
/VUP,2,X ! DEFINE X AXIS AS VERTICAL AXIS FOR DISPLAYS
PLDISP,1 ! DISPLAY UNDIS. AND DISP. SHAPE AT NEW ANGLE
PRNSOL,U,COMP ! PRINT DISPLACEMENTS
*GET,DEF_Z,NODE,3,U,Z
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'UX, IN ','UZ, IN ('
LABEL(1,2) = '(ANG=0) ','ANG=90) '
*VFILL,VALUE(1,1),DATA,-.12524,.12524
*VFILL,VALUE(1,2),DATA,DEF_X,DEF_Z
*VFILL,VALUE(1,3),DATA,ABS(DEF_X/.12524 ) ,ABS( DEF_Z/.12524)
/COM
/OUT,vm43,vrt
/COM,------------------- VM43 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM43 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm43,vrt
VM44 (Bending of an Axisymmetric Thin Pipe Under Gravity Loading) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM44
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM44, BENDING OF AN AXISYMMETRIC THIN PIPE UNDER GRAVITY LOADING
C*** FORMULAS FOR STRESS AND STRAIN, ROARK, 4TH ED., PAGE 112, NO. 33
ANTYPE,STATIC
ET,1,SHELL61,,,,,,1 ! PRINT DISP. AT ELEMENT ENDS AS WELL AS MIDPOINT
R,1,.1 ! DEFINE WALL THICKNESS
MP,EX,1,30.E6 ! DEFINE MATERIAL PROPERTIES
MP,DENS,1,.00073 ! DEFINE DENSITY
MP,NUXY,1,0 ! DEFINE NUXY AS 0.0
N,1,1 ! BEGIN NODE DEFINITION
N,8,1,125
FILL ! PLACE NODES 2 THRU 7 BETWEEN NODES 1 & 8
E,1,2 ! BEGIN ELEMENT DEFINITION
EGEN,7,1,1 ! GENERATE NEXT 6 ELEMENTS
CE,1,,2,UY,1,2,ROTZ,-1 ! DEFINE FIRST CONSTRAINT EQN. (UY(2) = ROTZ(2))
*REPEAT,6,1,,1,,,1 ! REPEAT FOR NODES 3 TO 7
CE,7,,2,UX,1,2,UZ,1 ! UX(2) = -UZ(2) AND FOR 6 INTERIOR NODES
*REPEAT,6,1,,1,,,1
OUTPR,ALL,ALL
ACEL,386,,-386 ! GRAVITY AS THE SUM OF TWO HARMONICALLY VARYING LOADS
MODE,1,1 ! MODE NUMBER 1, SYMMETRIC LOADING
D,1,ALL ! FIXED END
NSEL,S,LOC,Y,125
DSYM,SYMM,Y ! CENTER PLANE END
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
SET,1,1,,,,0.0 ! GET RESULTS AT 0 DEGREES
/VUP,1,X ! DEFINE X AXIS AS VERTICAL FOR VIEWING
/WINDOW,1,TOP ! DEFINE WINDOW 1 AS TOP HALF OF SCREEN
PLDISP,1 ! DISPLAY BOTH DISTORTED AND UNDISTORTED GEOMETRY
PRNSOL,DOF ! PRINT DEGREE OF FREEDOM VALUES
LCOPER,LPRIN ! CALCULATE PRINCIPAL STRESSES
PRESOL,ELEM ! PRINT ELEMENT SOLUTION RESULTS
ETABLE,STRS,NMISC,11
*GET,STRSS,ELEM,1,ETAB,STRS
*GET,DEF_X,NODE,8,U,X
SET,1,1,,,,90.0 ! STUDY RESULTS AT 90.0 DEGREES
/WINDOW,1,OFF ! TURN-OFF WINDOW 1
/WINDOW,2,BOT ! DEFINE WINDOW 2 AS BOTTOM HALF OF SCREEN
/NOERASE ! OVERLAY NEXT DISPLAY (DON'T ERASE WINDOW 1)
/VUP,2,X
PLDISP ! DISPLAY ONLY DISTORTED GEOMETRY
PRNSOL,U,COMP ! PRINT DISPLACEMENTS
*GET,DEF_Z,NODE,8,U,Z
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'UX, in ','UZ, in ','SIGMX,ps'
LABEL(1,2) = ' (ANG=0)','(ANG=90)','i(ANG=90'
*VFILL,VALUE(1,1),DATA,-.19062,.19062,3074.3
*VFILL,VALUE(1,2),DATA,DEF_X,DEF_Z,STRSS
*VFILL,VALUE(1,3),DATA,ABS(DEF_X/.19062),ABS(DEF_Z/.19062),ABS(STRSS/3074.3)
/COM
/OUT,vm44,vrt
/COM,------------------- VM44 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm44,vrt
VM45 (Natural Frequency of a Spring-mass System) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM45
/PREP7
/TITLE, VM45, NATURAL FREQUENCY OF A SPRING-MASS SYSTEM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 6, EX. 1.2-2
ANTYPE,MODAL
MODOPT,REDUC,1,,,1 ! PRINT ALL REDUCED MODE SHAPES
ET,1,COMBIN14,,,2 ! TWO-DIMENSIONAL LONGITUDINAL SPRING
ET,2,MASS21,,,4 ! TWO-DIMENSIONAL MASS
R,1,48
R,2,.006477
N,1
N,2,,1
E,1,2
TYPE,2
REAL,2
E,2
M,2,UY ! MASTER DOF IN Y DIRECTION AT FREE END OF SPRING
OUTPR,ALL,1
OUTRES,ALL,0
D,1,ALL
D,2,UX
FINISH
/SOLU
SOLVE
*GET,FREQ,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' F,'
LABEL(1,2) = ' (Hz) '
*VFILL,VALUE(1,1),DATA,13.701
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/13.701)
/COM
/OUT,vm45,vrt
/COM,------------------- VM45 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm45,vrt
VM46 (Flow Between Rotating Concentric Cylinders) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM46
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM46, FLOW BETWEEN ROTATING CONCENTRIC CYLINDERS
! VISCOUS FLUID FLOW, WHITE, P. 110
!
! -- PARAMETERS --
R1 = 1.0 ! RADIUS OF INNER CYLINDER
R2 = 2.0 ! RADIUS OF OUTER CYLINDER
NX = 30 ! NUMBER OF X DIVISIONS
THETA = 10.0 ! CYLINDER ENDING ANGLE
NY = 2 ! NUMBER OF Y DIVISIONS
LZ = 1.0 ! LENGTH IN Z DIRECTION
NZ = 2 ! NUMBER OF Z DIVISIONS
OMEGA = 1.0 ! ANGULAR VELOCITY
RHO = 1.0 ! FLUID DENSITY
MU = 1.0 ! FLUID VISCOSITY
! -- MODEL --
/PREP7
smrt,off
ET,1,FLUID142,,,3 ! 3D RTZ SYSTEM
MSHK,1 ! MAPPED VOLUME MESH
MSHA,0,3D ! USING HEX
CYLIND,R1,R2,,LZ,,THETA
LSEL,S,,,1,8,7
LSEL,A,,,3,6,3
LESIZE,ALL,,,NX,-20
LSEL,S,,,2,7,5
LSEL,A,,,4,5
LESIZE,ALL,,,NY
LSEL,S,,,9,12
LESIZE,ALL,,,NZ
ALLSEL
VMESH,1
ASEL,S,,,4 ! INNER CYLINDER BOUNDARY CONDITIONS
NSLA,S,1
D,ALL,VX
D,ALL,VY
D,ALL,VZ
ASEL,S,,,3 ! OUTER CYLINDER BOUNDARY CONDITIONS
NSLA,S,1
D,ALL,VX
D,ALL,VY,-R2*OMEGA
D,ALL,VZ
D,ALL,PRES
D,ALL,ENKE,-1
ASEL,S,,,5 ! PERIODIC BOUNDARY CONDITIONS
NSLA,S,1
D,ALL,VX
D,ALL,VX
PERI,,THETA ! PERIODIC BC MACRO
ASEL,S,,,1,2 ! SYMMETRY BOUNDARY CONDITIONS
NSLA,S,1
D,ALL,VX
D,ALL,VZ
ALLSEL
FINISH
! -- SOLUTION --
/SOLU
FLDATA,ITER,EXEC,200 ! NUMBER OF GLOBAL ITERATIONS
FLDATA,NOMI,DENS,RHO ! NOMINAL DENSITY
FLDATA,NOMI,VISC,MU ! NOMINAL VISCOSITY
FLDATA,OUTP,TAUW,T ! OUTPUT WALL SHEAR STRESS
CGOMGA,,,OMEGA ! ANGULAR VELOCITY OF ROTATING CS
SAVE
/OUTPUT,SCRATCH ! DIVERT OUTPUT
SOLVE
/OUTPUT
FINISH
!
! -- POST PROCESSING --
/POST1
SET,LAST
CSYS,1 ! GLOBAL CYLINDRICAL CS
RSYS,1 ! CYLINDRICAL RESULTS CS
*DIM,RES1,,NX+1,6 ! DIMENSION RESULTS ARRAY #1
NSEL,S,LOC,Y,THETA/2 ! RESULTS ACROSS FLOW SECTION
NSEL,R,LOC,Z,LZ/2
*DO,I,1,NX+1
*GET,XMAX,NODE,,MXLOC,X
N = NODE(XMAX,THETA/2,LZ/2)
RES1(I,1) = N ! NODE NUMBER
RES1(I,2) = NX(N) ! X-COORDINATE
RES1(I,3) = VY(N) ! VY (FLOTRAN)
RES1(I,4) = R1**2*OMEGA*(R2**2/NX(N) - NX(N))/(R2**2 - R1**2)
RES1(I,4) = RES1(I,4) - OMEGA*NX(N) ! VY (EXACT)
NSEL,U,,,N
*ENDDO
/COM
/COM
/COM
/COM CIRCUMFERENTIAL VELOCITY BETWEEN CYLINDERS AT (X,THETA/2,LZ/2):
/COM
*VWRITE
(4X,'NODE',12X,'X',9X,'VY (FLOTRAN)',7X,'VY (EXACT)')
*VWRITE,RES1(1,1),RES1(1,2),RES1(1,3),RES1(1,4)
(3X,F5.0,3(1PE17.5))
/COM
/COM
ALLSEL
PATH,CYLS,2,,48 ! DEFINE PATH WITH NAME = "CYLS"
PPATH,1,,R1,0,0 ! DEFINE PATH POINTS BY LOCATION
PPATH,2,,R2,0,0
PDEF,VY,VY
/AXLAB,X,RADIAL PATH COORDINATE
/AXLAB,Y,CIRCUMFERENTIAL VELOCITY
PLPATH,VY ! VELOCITY DISTRIBUTION
/DEVICE,VECTOR,ON
/PLOPTS,MINM,OFF
PLNSOL,PRES ! PRESSURE CONTOURS
FINISH
CSYS,1
VY_R = NODE(1.5,0,0)
*GET,VELY,NODE,VY_R,V,Y
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'VY (R=1.'
LABEL(1,2) = '5) '
*VFILL,VALUE(1,1),DATA,-1.111
*VFILL,VALUE(1,2),DATA,VELY
*VFILL,VALUE(1,3),DATA,ABS(VELY /1.111 )
/COM
/OUT,vm46,vrt
/COM,------------------- VM46 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
/DELETE,SCRATCH
/DELETE,vm46,pfl
/DELETE,vm46,rsw
FINISH
*LIST,vm46,vrt
VM47 (Torsional Frequency of a Suspended Disk) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM47
/PREP7
/TITLE, VM47, TORSIONAL FREQUENCY OF A SUSPENDED DISK
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 10, EX 1.3-2
ANTYPE,MODAL
MODOPT,REDUC,,,,1 ! PRINT REDUCED MODE SHAPE
ET,1,COMBIN14,,,1 ! THREE-DIMENSIONAL TORSIONAL SPRING
ET,2,MASS21,,,3 ! TWO-DIMENSIONAL MASS WITH ROTARY INERTIA
R,1,4.8 ! REAL CONSTANT SET #1 SPRING CONSTANT
R,2,1,.30312 ! REAL CONSTANT SET #2 MASS & IZZ(J)
N,1 ! BEGIN NODE DEFINITION
N,2,,,-1
E,1,2 ! DEFINE BEAM ELEMENT
TYPE,2 ! DEFINE ACTIVE ELEMENT TYPE AS SET 2
REAL,2 ! DEFINE ACTIVE REAL CONSTANT TYPE AS SET 2
E,2 ! DEFINE MASS AT END OF WIRE
M,2,ROTZ ! MASTER DOF IN ROTZ DIRECTION AT FREE END OF SPRING
OUTPR,BASIC,1
D,1,ALL ! CONSTRAIN END OF WIRE IN ALL DOF
D,2,UX,,, ,,UY,UX ! PREVENT TRANSLATION OF THE MASS
FINISH
/SOLU
SOLVE
*GET,FREQ,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' F,'
LABEL(1,2) = ' (Hz) '
*VFILL,VALUE(1,1),DATA,.63333
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/.63333 )
/COM
/OUT,vm47,vrt
/COM,------------------- VM47 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm47,vrt
VM48 (Natural Frequency of a Motor-Generator) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM48
/PREP7
MP,PRXY,,0.3
/TITLE, VM48, NATURAL FREQUENCY OF A MOTOR-GENERATOR
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 10, EX 1.3-3
ANTYPE,MODAL
MODOPT,REDUC,1,,,1 ! PRINT ALL REDUCED MODE SHAPES
ET,1,PIPE16 ! ELASTIC STRAIGHT PIPE
ET,2,MASS21 ! GENERALIZED MASS
R,1,.375,.1875 ! REAL CONSTANT SET 1 O.D. OF PIPE AND WALL THICKNESS
R,2,,,,31E-3 ! REAL CONSTANT SET 2 IXX
MP,EX,1,31.2E6 ! DEFINE MODULUS OF ELASTICITY
N,1 ! BEGIN NODE DEFINITION
N,2,8
E,1,2 ! DEFINE PIPE ELEMENT
TYPE,2 ! DEFINE ACTIVE ELEMENT TYPE AS SET #2
REAL,2 ! DEFINE ACTIVE REAL CONSTANT TYPE AS SET #2
E,2 ! DEFINE MASS AT END OF PIPE
M,2,ROTX ! MASTER DOF IN ROTX DIRECTION AT FREE END OF PIPE
OUTPR,BASIC,1
D,ALL,ALL ! CONSTRAIN ALL DOF'S
DDELE,2,ROTX ! RELEASE TORSIONAL DOF AT NODE 2
FINISH
/SOLU
SOLVE
*GET,FREQ,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' F,'
LABEL(1,2) = ' (Hz) '
*VFILL,VALUE(1,1),DATA,48.781
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/48.781)
/COM
/OUT,vm48,vrt
/COM,------------------- VM48 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm48,vrt
VM49 (Electrostatic Field Analysis of Quadpole Wires in Open Air) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM49
/PREP7
SMRT,OFF
/TITLE, VM49, ELECTROSTATIC FIELD ANALYSIS OF QUADPOLE WIRES IN OPEN AIR
C*** ANY BASIC STATIC AND DYNAMIC ELECTRICITY BOOK
ANTYPE,STATIC
ET,1,PLANE121 ! 2-D 8-NODE ELECTROSTATIC ELEMENT
ET,2,INFIN110,1 ! 2-D 4-NODE INFINITE ELEMENT WITH VOLT DOF
EMUNIT,MKS ! MKS UNIT
MP,PERX,1,1 ! ELECTRICAL PERMITTIVITY
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM
PCIRC,25.4/1000,0,90 ! QUARTER CIRCULAR AREA
PCIRC,50.8/1000,0,90
PCIRC,470/1000,0,90
AOVLAP,1,2,3 ! OVERLAP AREAS
KPSCALE,7,8,1,2 ! SCALE KEYPOINTS 7 & 8 TO DOUBLE
L,7,6
L,6,9
L,8,9
AL,7,5,6,8
LSEL,S,LINE,,1,4,1 ! SELECT LINES
LSEL,A,LINE,,6,7
LSEL,A,LINE,,10,11
LESIZE,ALL,,,10 ! DIVIDE THE SELECTED LINES INTO TEN
! DIVISION
LSEL,ALL
LSEL,S,LINE,,12,13
LESIZE,ALL,,,30,10
LSEL,ALL
LSEL,S,LINE,,5,8,3
LESIZE,ALL,,,1
LSEL,ALL
TYPE,2 ! USE ELEMENT TYPE 2
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USING QUADS
ESIZE,,1 ! CREATE 1 ELEMENT PER LINE DIVISION
ASEL,S,AREA,,2
AMESH,ALL ! MESH THE AREA 2
ASEL,ALL
ESIZE,,10 ! CREATE 10 ELEMENTS PER LINE DIVISION
TYPE,1 ! USE ELEMENT TYPE 1
ASEL,S,AREA,,1,4,3 ! SELECT AREAS
ASEL,A,AREA,,5
AMESH,ALL
NSEL,S,LOC,X,25.4/1000 ! SELECT NODES
NSEL,R,LOC,Y,0
F,ALL,CHRG,.5E-6 ! APPLY CHARGE AS POINT LOAD
NSEL,S,LOC,X,25.4/1000
NSEL,R,LOC,Y,90
F,ALL,CHRG,-.5E-6
NSEL,ALL
NSEL,S,LOC,X,940/1000
SF,ALL,INF ! FLAG THE EXTERIOR FACE OF INFIN110 AT
! INFINITE DISTANCE
NSEL,ALL
FINISH
/SOLU
OUTRES,ALL,ALL
OUTPR,,NONE
SOLVE
FINISH
/POST1
/COM SELECT THE NODES AT ANGLES FROM 0 TO 90 DEGREE WITH 10
/COM DIVISION ON SURFACE OF RADIUS 470 MM AND RETRIEVE THE
/COM ELECTRIC POTENTIAL, V
DSYS,1
*DIM,ANG,,11,2
*VFILL,ANG(1,1),RAMP,0,9
*DO,J,1,11
NSEL,S,LOC,X,470/1000
NSEL,R,LOC,Y,ANG(J,1)
*GET,NOD,NODE,,NUM,MAX
*GET,ANG(J,2),NODE,NOD,VOLT
NSEL,ALL
*ENDDO
*DIM,VLT,,11
*VFUN,VLT(1),COPY,ANG(1,2)
*DIM,VALUE,,11,2
*VFILL,VALUE(1,1),DATA,105.05,99.9,84.98,61.74,32.46,0,-32.46,-61.74,-84.98
*VFILL,VALUE(10,1),DATA,-99.98,-105.05
*VFILL,VALUE(1,2),DATA,ABS(VLT(1,1)/105.05 ),ABS(VLT(2,1)/99.9),ABS(VLT(3,1)/84.98)
*VFILL,VALUE(4,2),DATA,ABS(VLT(4,1)/61.74),ABS(VLT(5,1)/32.46),0
*VFILL,VALUE(7,2),DATA,ABS(VLT(7,1)/32.46),ABS(VLT(8,1)/61.74),ABS(VLT(9,1)/84.98)
*VFILL,VALUE(10,2),DATA,ABS(VLT(10,1)/99.98),ABS(VLT(11,1)/105.05 )
*DIM,LABEL,CHAR,11,2
*DO,I,1,11,1
LABEL(I,1) = 'V(VOLT) '
LABEL(I,2) = 'AT ANGLE'
*ENDDO
! WRITE DESIRED ANGLE AND POTENTIAL VALUES
/COM
/OUT,vm49,vrt
/COM,------------------- VM49 RESULTS COMPARISON ---------------
/COM,
/COM, |TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),ANG(1,1),VALUE(1,1),VLT(1),VALUE(1,2)
(1X,A8,A8,': ',F4.1,' ',F7.2,' ',F7.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm49,vrt
VM50 (Fundamental Frequency of a Simply Supported Beam) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM50
/PREP7
/TITLE, VM50, FUNDAMENTAL FREQUENCY OF A SIMPLY SUPPORTED BEAM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 18, EX 1.5-1
ET,1,BEAM3 ! TWO DIMENSIONAL ELASTIC BEAM
MP,EX,1,30E6 ! DEFINE MATERIAL PROPERTIES
MP,DENS,1,728E-6
R,1,4,(4/3),2 ! DEFINE REAL CONSTANT SET FOR BEAM-AREA,IZZ & HEIGHT
K,1 ! BEGIN DEFINING KEYPOINTS
K,2,80
L,1,2 ! DEFINE LINE WITH
LESIZE,ALL,,,4 ! 4 DIVISIONS
LMESH,1 ! MESH LINE
FINISH
/SOLU
ANTYPE,MODAL
MODOPT,REDUC,3,,,3 ! PRINT ALL REDUCED MODE SHAPES
MXPAND,1 ! EXPAND FIRST MODE
M,3,UY,5 ! MASTER DOF IN Y DIRECTION AT NODES 3 THROUGH 5
OUTPR,ALL,1
DK,ALL,UX ! CONSTRAIN ENDS OF BEAM IN DISP. X DOF
DK,ALL,UY ! CONSTRAIN ENDS OF BEAM IN DISP. Y DOF
PSOLVE,ELFORM ! CREATE THE ELEMENT MATRICES
PSOLVE,TRIANG ! TRIANGULARIZE THE MATRICES
PSOLVE,EIGREDUC ! CALCULATE THE EIGENVALUES AND EIGENVECTORS USING HOUSEHOLDER
PSOLVE,EIGEXP ! EXPAND THE EIGENVECTOR SOLUTION
FINISH
/POST26
*GET,FREQ,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' f'
LABEL(1,2) = ', (Hz) '
*VFILL,VALUE(1,1),DATA,28.766
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/28.766)
/COM
/OUT,vm50,vrt
/COM,------------------- VM50 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm50,vrt
VM51 (Electrostatic Forces Between Charged Spheres) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM51
/config,nproc,4
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE,VM51, FORCE BETWEEN CHARGED SPHERES
! THE ELECTROMAGNETIC FIELD, SHADOWITZ, PAGE 61
/PREP7
smrt,off $ shpp,warn
mopt,amesh,alte
mopt,qmesh,alte
R1 = 1 ! SPHERE RADIUS
R2 = 3 ! DISTANCE BETWEEN SPHERES
R3 = 6 ! RADIUS OF FINITE ELEMENT DOMAIN
R4 = 1.25 ! MAXWELL SURFACE RADIUS
PER=8.854E-12 ! FREE SPACE PERMITIVITY
PI=3.14159265359
Q = 4*PI*PER ! TOTAL CHARGE
ALPHA = 30 ! SLICE ANGLE
AREA = 4*PI*(R1**2) ! TOTAL SPHERE AREA
CHRGS = Q/AREA ! SURFACE CHARGE
/NOPR
PCIRC,,R2,0,90 ! CIRCLE RADIUS R2, 0 TO 90 DEGREES
WPOFFS,,R2/2 ! WORKING PLANE OFFSET Y = R2/2
PCIRC,,R1,0,90 ! CIRCLE RADIUS R1, 0 TO 90 DEGREES
PCIRC,,R1,-90,0 ! CIRCLE RADIUS R1, 0 TO -90 DEGREES
PCIRC,,R4,-90,90 ! CIRCLE RADIUS R4, -90 TO 90 DEGREES
AOVLAP,ALL
NUMCMP,AREA
ET,1,PLANE121 ! 2-D 8-NODE ELECTROSTATIC SOLID
ET,2,SOLID122 ! 3-D 20-NODE ELECTROSTATIC SOLID
ET,3,MESH200,7 ! NEW MESH200 2-D 8-NODE ELEMENT TYPE
ET,4,INFIN111,2,1 ! 3-D INFINITE SOLID ELEMENT
MP,PERX,1,1
MP,PERX,2,1
CSYS,2 ! SPHERICAL COORDINATE SYSTEM
LSEL,S,LOC,X,R2
LESIZE,ALL,,,30 ! SET ELEMENT DIVISIONS = 20
ESIZE,,25 ! SET ELEMENT DIVISIONS FOR EXTRUDE REGION
TYPE,1
LOCAL,11,2,,R2/2 ! DEFINE COORDINATE SYSTEM AT SPHERE CENTER
LSEL,S,LOC,X,R1 ! SELECT LINES ON SPHERE SURFACE
LESIZE,ALL,,,25 ! SET ELEMENT DIVISIONS
LSEL,A,LOC,X,R4 ! SELECT LINES FOR MAXWELL SURFACE
LESIZE,ALL,,,50 ! SET ELEMENT DIVISIONS
CSYS,0 ! CARTESIAN COORDINATE SYSTEM
LSEL,S,LOC,Y, ! SELECT LINES AT Y = 0
LESIZE,ALL,,,40 ! SET ELEMENT DIVISIONS
MSHK,2 ! MAPPED AREA MESH IF POSSIBLE
MSHA,0,2D ! USING QUADS
LSEL,ALL
ESIZE,,5 ! SET ELEMENT DIVISIONS = 5
ALLSEL
AMAP,4,10,7,5,11 ! MAP MESH SPHERE TO MAXWELL SURFACE
AMESH,ALL
K,200 ! CREATE KEYPOINTS FOR ROTATION
K,201,,R3
MSHK,0 ! FREE MESH
MSHA,1, ! USING TRIS OR TETS
TYPE,2
ASEL,ALL
ESIZE,,3 ! 3 DIVISIONS IN ROTATE DIRECTION
MAT,1
VROTAT,ALL,,,,,,200,201,ALPHA ! ROTATE ALL AREAS THROUGH 30 DEGREES
CSYS,11 ! CUSTOM SPHERICAL COORDINATE SYSTEM
NSEL,S,LOC,X,0,R1*1.03 ! NODE SELECT RADIUS 0 TO R1
ESLN,S,1 ! ELEMENT SELECT FROM NODES
EMODIF,ALL,MAT,2 ! CHANGE MATERIAL PROPERTY TO 2
CSYS,2 ! SPHERICAL COORDINATE SYSTEM
KSEL,S,LOC,X,R2 ! KEYPOINT SELECT AT RADIUS R2
LSLK,S,1 ! LINE SELECT FROM KEYPOINTS
ASLL,S,1 ! AREA SELECT FROM LINES
TYPE,3 ! NEW MESH200 ELEMENT TYPE
AMESH,ALL ! MESH AREA AT RADIUS R2
ESIZE,,8 ! EIGHT ELEMENTS IN EXTRUDE DIRECTION
TYPE,2 ! SOLID122 USED FOR EXTRUDE
VEXT,ALL,,,R3-R2 ! EXTRUDE AREAS IN RADIAL DIRECTION
KSEL,S,LOC,X,R3 ! KEYPOINT SELECT AT RADIUS R3
LSLK,S,1 ! LINE SELECT FROM KEYPOINTS
ASLL,S,1 ! AREA SELECT FROM LINES
TYPE,3 ! NEW MESH200 ELEMENT TYPE
AMESH,ALL ! MESH AREA AT RADIUS R3
ESIZE,,1 ! ONE DIVISION IN EXTRUDE DIRECTION
TYPE,4 ! INFIN122 USED FOR EXTRUDE
VEXT,ALL,,,R3 ! EXTRUDE AREA IN RADIAL DIRECTION
ALLSEL ! SELECT ALL ENTITIES
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM62
/PREP7
SMRT,OFF
/TITLE, VM62, VIBRATION OF A WEDGE
C*** VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 392, ART. 62
C*** USING SHELL63 ELEMENTS WITH BENDING STIFFNESS OPTION
ANTYPE,MODAL ! MODE-FREQUENCY ANALYSIS
MXPAND,1 ! EXPAND FIRST MODE
MODOPT,REDUC,2,,,2 ! PRINT ALL REDUCED MODE SHAPES
ET,1,SHELL63,2 ! SHELL63 WITH BENDING STIFFNESS OPTION
R,1,1 ! UNIT THICKNESS
MP,EX,1,30E6
MP,DENS,1,.000728
MP,NUXY,1,0 ! POISSON'S RATIO IS ZERO
K,1 ! DEFINE MODEL GEOMETRY
K,2,16
K,3,16,2
L,2,3
LESIZE,1,,,1
A,1,2,3,3
ARSYM,Y,1 ! SYMMETRY REFLECTION OF AREAS
NUMMRG,KPOI ! MERGE COINCIDENT KEYPOINTS
ESIZE,,4
AMESH,1,2
NSEL,S,LOC,Y,0
M,ALL,UZ
NSEL,S,LOC,X,16
D,ALL,UZ,,,,,ROTX,ROTY,UX,UY ! CONSTRAIN DISPLACEMENTS AT BASE
NSEL,ALL
OUTPR,ALL,1
OUTRES,ALL,0
FINISH
/SOLU
SOLVE
*GET,FREQ1,MODE,1,FREQ
FINISH
/PREP7
SMRT,OFF
C*** USING SHELL63 ELEMENTS WITH SHELL OPTION
ET,1,SHELL63 ! USE BENDING AND MEMBRANE STIFFNESS
FINISH
/SOLU
SOLVE
*GET,FREQ2,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE_1,,1,3
*DIM,VALUE_2,,1,3
LABEL(1,1) = ' f,'
LABEL(1,2) = ' Hz '
*VFILL,VALUE_1(1,1),DATA,259.16
*VFILL,VALUE_1(1,2),DATA,FREQ1
*VFILL,VALUE_1(1,3),DATA,ABS(FREQ1/259.16 )
*VFILL,VALUE_2(1,1),DATA,259.16
*VFILL,VALUE_2(1,2),DATA,FREQ2
*VFILL,VALUE_2(1,3),DATA,ABS(FREQ2/259.16 )
/COM
/OUT,vm62,vrt
/COM,------------------- VM62 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING PLATE ELEMENTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,
/COM,RESULTS USING SHELL ELEMENTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm62,vrt
VM63 (Static Hertz Contact Problem) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM63
/PREP7
SMRT,OFF
/TITLE, VM63, STATIC HERTZ CONTACT PROBLEM SOLVED USING CONTACT26 ELEMENTS
/COM THE PROBLEM IS SOLVED USING TWO CONTACT ELEMENTS, FIRST USING
/COM CONTACT26 (SURFACE CONTACT) ELEMENTS AND SECOND USING CONTACT178 (NODAL CONTACT)ELEMENTS
/COM THE RESULTS OBTAINED USING THESE TWO CONTACT ELEMENTS ARE COMPARED AT THE END
/COM REF: TIMOSHENKO AND GOODIER, THEORY OF ELASTICITY, 3RD ED., ART. 140.
ET,1,PLANE82,,,1 ! AXISYMMETRIC ELEMENTS
ET,2,PLANE2,,,1
ET,3,CONTAC26 ! CONTACT SURFACE
R,1 ! DEFAULT STIFFNESS OF 1E9 IS USED
MP,EX,1,1E3
MP,NUXY,1,.3
LOCAL,11,1,0,8,0 ! LOCAL CYLINDRICAL C.S. AT CENTERLINE
K,1,8,-90 ! DEFINE KEYPOINTS
K,2,8
K,3,7.5,-90
K,4,7.5
K,5
K,6,8,-82.65 ! PLACE KEYPOINT AND NODE AT EXPECTED CONTACT RADIUS
K,7,7.5,-82.65
L,1,3 ! DEFINE LINES
L,2,4
L,6,7
LESIZE,ALL,,,1 ! DEFINE ELEMENT DIVISIONS ON ALL EXISTING LINES
A,1,6,7,3 ! DEFINE AREAS
A,6,2,4,7
A,3,7,4,5
LOCAL,12,0,0,8,0
ARSYM,Y,1,3,1 ! CREATE HALF-SYMMETRY MODEL
NUMMRG,KPOI
ESIZE,,4 ! DEFINE ELEMENT DIVISIONS ON REMAINING LINES
LESIZE,4,,,5
*REPEAT,2,1
LESIZE,6,,,8,8
LESIZE,7,,,8,(1/8)
LESIZE,10,,,1
*REPEAT,2,2
LESIZE,9,,,6,.2
TYPE,1 ! CREATE NODES AND ELEMENTS
AMESH,1,2,1
AMESH,4,5,1
TYPE,2
AMESH,3,6,3
CSYS,0
N,1001,-1,1E-8 ! J AND K NODES OF CONTAC26 CONTACT SURFACE
N,1002,9,1E-8 ! USE 1E-8 TO REMOVE SYSTEM TO SYSTEM INSTABILITY
TYPE,3
REAL,1
EN,201,4,1001,1002 ! ELEMENT NUMBERS ASSIGNED TO ENABLE POSTPROCESSING
*REPEAT,4,1,2 ! MESH NODE NUMBERING SCHEME MUST BE KNOWN
EN,205,2,1001,1002 ! THIS SHOULD BE THE ELEMENT AT THE CONTACT RADIUS
EN,206,31,1001,1002 ! ADDITIONAL ELEMENT TO VERIFY POINT OF CONTACT
MODMSH,NOCHECK
TYPE,1 ! REMOVE MIDSIDE NODES ALONG CONTACT SURFACE
EMODIF,7,7,0
*REPEAT,6,1
MODMSH,CHECK
FINISH
/SOLU
NSEL,S,LOC,X,-.01,.01 ! BOUNDARY CONDITIONS AND LOADING
D,ALL,UX,0
NSEL,R,LOC,Y,0
D,ALL,UY,0
NSEL,ALL
LOAD=0
*CREATE,LOADSTEP ! MACRO TO INCREMENTALLY APPLY LOAD
FK,8,FY,ARG1
SOLVE
*END
*DO,I,1,3
LOAD=LOAD-10
*USE,LOADSTEP,LOAD*6.2831853
*ENDDO
FINISH
/POST1 ! POSTPROCESS
SET,3
ESEL,,TYPE,,3
ETABLE,RFOR,SMISC,1
NSLE
PRETAB,RFOR ! PRINT REACTION FORCE TO DETERMINE CONTACT AREA
SSUM ! SUM OF REACTION FORCE
NLIST ! LIST COORDINATES OF NODES OF CONTACT SURFACE
PRNSOL,U,COMP ! LIST DISPLACEMENTS OF NODES
/COM CALCULATE RATIO OF A - ACTUAL TO A - TARGET
PI=(4*ATAN(1))
LOAD=-(LOAD)*(2*PI)
ATAR=(0.88*((LOAD*0.008)**(1/3))) ! A - TARGET
*GET,EMAX,ELEM,,NUM,MAX
*DO,ENUM,201,EMAX ! START SEARCH FROM ELEM 201
*GET,GRFR,ELEM,ENUM,ETAB,RFOR ! FIND LAST ELEMENT IN CONTACT
*IF,GRFR,EQ,0.0,EXIT
*ENDDO
ESEL,,ELEM,,(ENUM-1) ! SELECT LAST CONTACTING ELEMENT
NSLE ! SELECT NODES ATTACHED TO SELECTED ELEMENTS
*GET,NMIN,NODE,0,NUM,MIN
NODX=NX(NMIN)
NODY=NY(NMIN)
NUX =UX(NMIN)
NUY =UY(NMIN)
AACT=NODX+NUX ! A - ACTUAL
YCHK=NODY+NUY
RATA=(AACT/ATAR) ! RATIO
*STAT
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' A,'
LABEL(1,2) = ' mm '
*VFILL,VALUE(1,1),DATA,1.010
*VFILL,VALUE(1,2),DATA,AACT
*VFILL,VALUE(1,3),DATA,ABS(AACT/1.010)
FINISH
/COM
/OUT,vm63,vrt
/COM,--------------------------------------------------------------------------
/COM,----------VM63 RESULTS COMPARISON (OBTAINED USING CONTACT26 ELEMENTS)-----
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-------------------------------------------------------------------------
/OUT
/CLEAR,NOSTART
/TITLE, VM63, STATIC HERTZ CONTACT PROBLEM SOLVED USING CONTACT178 ELEMENTS
/PREP7
SMRT,OFF
/TITLE,EV178-45S , STATIC HERTZ CONTACT PROBLEM
/COM REF: TIMOSHENKO AND GOODIER, THEORY OF ELASTICITY, 3RD ED., ART. 140.
/OUT,scratch
ET,1,PLANE82,,,1 ! AXISYMMETRIC ELEMENTS
ET,2,PLANE2,,,1
ET,3,178 ! NODAL CONTACT
R,1
RMOD,1,7,1 !CONTACT NORMAL ALONG UY
MP,EX,1,1E3
MP,NUXY,1,.3
LOCAL,11,1,0,8,0 ! LOCAL CYLINDRICAL C.S. AT CENTERLINE
K,1,8,-90 ! DEFINE KEYPOINTS
K,2,8
K,3,7.5,-90
K,4,7.5
K,5
K,6,8,-82.65 ! PLACE KEYPOINT AND NODE AT EXPECTED CONTACT RADIUS
K,7,7.5,-82.65
L,1,3 ! DEFINE LINES
L,2,4
L,6,7
LESIZE,ALL,,,1 ! DEFINE ELEMENT DIVISIONS ON ALL EXISTING LINES
A,1,6,7,3 ! DEFINE AREAS
A,6,2,4,7
A,3,7,4,5
LOCAL,12,0,0,8,0
ARSYM,Y,1,3,1 ! CREATE HALF-SYMMETRY MODEL
NUMMRG,KPOI
ESIZE,,4 ! DEFINE ELEMENT DIVISIONS ON REMAINING LINES
LESIZE,4,,,5
*REPEAT,2,1
LESIZE,6,,,8,8
LESIZE,7,,,8,(1/8)
LESIZE,10,,,1
*REPEAT,2,2
LESIZE,9,,,6,.2
TYPE,1 ! CREATE NODES AND ELEMENTS
AMESH,1,2,1
AMESH,4,5,1
TYPE,2
AMESH,3,6,3
CSYS,0
N,1001,-1,1E-8 !NODE 1001 IS THE GROUND
D,1001,ALL !X POSITION DOES NOT MATTER IN THIS CASE BECAUSE
!THE CONTACT NORMAL IS ONLY ALONG UY
TYPE,3
REAL,1
EN,205,1001,2 !USE THE SAME ELEMENT NUMBERS AS VM63 FOR POST-PROC
EN,201,1001,4
EN,202,1001,6
EN,203,1001,8
EN,204,1001,10
EN,206,1001,31
MODMSH,NOCHECK
TYPE,1 ! REMOVE MIDSIDE NODES ALONG CONTACT SURFACE
EMODIF,7,7,0
*REPEAT,6,1
MODMSH,CHECK
FINISH
/SOLU
NSEL,S,LOC,X,-.01,.01 ! BOUNDARY CONDITIONS AND LOADING
D,ALL,UX,0
NSEL,R,LOC,Y,0
D,ALL,UY,0
NSEL,ALL
LOAD=0
*CREATE,LOADSTEP ! MACRO TO INCREMENTALLY APPLY LOAD
FK,8,FY,ARG1
SOLVE
*END
*DO,I,1,3
LOAD=LOAD-10
*USE,LOADSTEP,LOAD*6.2831853
*ENDDO
FINISH
/POST1 ! POSTPROCESS
/OUT,
SET,3
ESEL,,TYPE,,3
ETABLE,RFOR,SMISC,1
NSLE
PRETAB,RFOR ! PRINT REACTION FORCE TO DETERMINE CONTACT AREA
SSUM ! SUM OF REACTION FORCE
NLIST ! LIST COORDINATES OF NODES OF CONTACT SURFACE
PRNSOL,U,COMP ! LIST DISPLACEMENTS OF NODES
/COM CALCULATE RATIO OF A - ACTUAL TO A - TARGET
PI=(4*ATAN(1))
LOAD=-(LOAD)*(2*PI)
ATAR=(0.88*((LOAD*0.008)**(1/3))) ! A - TARGET
*GET,EMAX,ELEM,,NUM,MAX
*DO,ENUM,201,EMAX ! START SEARCH FROM ELEM 201
*GET,GRFR,ELEM,ENUM,ETAB,RFOR ! FIND LAST ELEMENT IN CONTACT
*IF,GRFR,EQ,0.0,EXIT
*ENDDO
ESEL,,ELEM,,(ENUM-1) ! SELECT LAST CONTACTING ELEMENT
NSLE ! SELECT NODES ATTACHED TO SELECTED ELEMENTS
*GET,NMIN,NODE,0,NUM,MIN
NODX=NX(NMIN)
NODY=NY(NMIN)
NUX =UX(NMIN)
NUY =UY(NMIN)
AACT=NODX+NUX ! A - ACTUAL
YCHK=NODY+NUY
RATA=(AACT/ATAR) ! RATIO
*STAT
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' A,'
LABEL(1,2) = ' mm '
*VFILL,VALUE(1,1),DATA,1.010
*VFILL,VALUE(1,2),DATA,AACT
*VFILL,VALUE(1,3),DATA,ABS(AACT/1.010)
/COM
/OUT,vm63,vrt,,append
/COM,---------------------------------------------------------------------------
/COM,----------VM63 RESULTS COMPARISON (OBTAINED USING CONTACT178 ELEMENTS)-----
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,---------------------------------------------------------------------------
/OUT
FINISH
*LIST,vm63,vrt
VM64 (Thermal Expansion to Close a Gap at a Rigid Surface) Input Listing
/PREP7
/TITLE, VM68, PSD RESPONSE OF TWO DOF SPRING-MASS SYSTEM
! "VIBRATION ANALYSIS" R.K. VIERK ,2ND EDITION ,(CHAPTER 7)
ET,1,COMBIN40 ! DISPLACEMENT ALONG X AXIS, MASS AT NODE I
R,1,42832.,,0.50
R,2,32416.,,1.0
MP,EX,1,1 ! NOT USED, DUMMY PROPERTY
N,1 ! DEFINE MODEL
N,2,1
N,3,2
E,2,1
REAL,2
E,3,2
D,1,UX,0.0 ! CONSTRAINT THE BASE
OUTPR,ALL,ALL
FINISH
/SOLU
ANTYPE,MODAL ! PERFORM A MODAL ANALYSIS
MODOPT,SUBSP,2 ! SUBSPACE IERTATION METHOD
! EXTRACT 2 MODES FROM ENTIRE FREQUENCY RANGE
MXPAND,2,,,YES ! EXPAND 2 MODES, DO ELEMENT STRESS CALCULATIONS
SOLVE
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
FINISH
/SOLU
ANTYPE,SPECTR ! PERFORM SPECTRUM ANALYSIS
SPOPT,PSD,2,ON ! USE FIRST 2 MODES FROM MODAL ANALYSIS
PSDUNIT,1,ACCG ! USE G**2/HZ FOR PSD AND DIMENSION IN INCHES
D,1,UX,1.0 ! APPLY SPECTRUM AT THE SUPPORT POINT
PSDFRQ,1,1,10.0,100.0 ! FREQUENCY RANGE OF 10 TO 100 HERTZ
PSDVAL,1,.1,.1 ! WHITE NOISE PSD, VALUES IN G**2/HZ
PFACT,1,BASE ! BASE EXCITATION
DMPRAT,0.02 ! 2% DAMPING
PSDCOM ! COMBINE MODES FOR PSD, USE DEFAULT SIGNIFICANCE LEVEL
VM76 (Harmonic Response of a Guitar String) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM76
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM76, HARMONIC RESPONSE OF A GUITAR STRING
/COM, REFERENCE: BLEVINS, FORMULAS FOR NAT. FREQ. AND MODE SHAPE, TABLE 7-1.
ANTYPE,STATIC ! STATIC ANALYSIS, PRESTRESS
ET,1,LINK1 ! TWO-DIMENSIONAL SPAR
R,1,50671E-12 ! CROSS-SECTIONAL AREA OF STRING
MP,EX,1,190E9 ! MATERIAL, STAINLESS STEEL
MP,DENS,1,7920
N,1 ! DEFINE NODES
N,31,.71
FILL
E,1,2 ! DEFINE ELEMENTS
EGEN,30,1,1
D,1,ALL ! BOUNDARY CONDITIONS AND LOADING
D,2,UY,,,31
F,31,FX,84
FINISH
/SOLU
PSTRES,ON ! DEFINE AS PRESTRESSED ANALYSIS
OUTPR,BASIC,1
SOLVE
FINISH
/SOLU
ANTYPE,MODAL ! MODAL ANALYSIS
MODOPT,SUBSP,6 ! SUBSPACE ITERATION METHOD, 6 FREQ.
PSTRES,ON ! PRESTRESSED ANALYSIS
DDEL,2,UY,30
SOLVE
FINISH
/SOLU
ANTYPE,HARMIC ! HARMONIC RESPONSE ANALYSIS
HROPT,MSUP,6 ! MODE SUPERPOSITION
HROUT,OFF ! AMPLITUDE, PHASE ANGLE PRINTOUT
PSTRES,ON ! PRESTRESSED ANALYSIS
FDELE,31,FX ! DELETE STRETCH LOAD
F,8,FY,-1 ! FORCE AT X=.1657, NEAR QUARTER POINT
KBC,1 ! STEP CHANGE FORCE
HARFRQ,,2000 ! OBTAIN FREQUENCY EVERY EIGHT HERTZ
NSUBST,250
OUTPR,,NONE
OUTRES,,1
SOLVE
FINISH
/POST26 ! TIME-HISTORY POSTPROCESSOR
FILE,,rfrq ! REDUCED FREQUENCIES FILE
NSOL,2,16,U,Y,DISP ! RETRIEVE STRING MIDPOINT DISPLACEMENT RESPONSE
PRVAR,2
/AXLAB,Y,AMPL
PLCPLX,0 ! DISPLAY AMPLITUDE OF COMPLEX VARIABLE (DEFAULT)
PLVAR,2
*GET,FREQ,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' f,'
LABEL(1,2) = ' Hz '
*VFILL,VALUE(1,1),DATA,322.2
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/322.2 )
/COM
/OUT,vm76,vrt
/COM,------------------- VM76 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM76 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm76,vrt
VM77 (Transient Response to a Constant Force with a Finite Rise Time) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM77
/PREP7
MP,PRXY,,0.3
/TITLE, VM77, TRANSIENT RESPONSE TO A CONSTANT FORCE WITH A FINITE RISE TIME
C*** INTRODUCTION TO STRUCT. DYNAMICS, BIGGS, PAGE 50, EXAMPLE E
C*** DISPLACEMENT PASS USING BEAM3 AND MASS21 ELEMENTS
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC,,NODAMP ! REDUCED TRANSIENT ANALYSIS, IGNORE DAMPING
ET,1,BEAM3 ! TWO-DIMENSIONAL BEAM
ET,2,MASS21,,,4 ! TWO-DIMENSIONAL MASS
R,1,1,800.6,18 ! BEAM AREA = 1, I = 800.6, H = 18
R,2,.0259067 ! MASS
MP,EX,1,30E3
N,1
N,3,240
FILL
E,1,2 ! BEAM ELEMENTS
EGEN,2,1,1
TYPE,2
REAL,2
E,2 ! TYPE 2 ELEMENT WITH REAL CONSTANT 2
M,2,UY ! MASTER DOF IN Y DIRECTION AT MIDDLE OF BEAM
DELTIM,.004 ! INTEGRATION TIME STEP SIZE
D,1,UY
D,3,UX,,,,,UY
FINISH
/SOLU
OUTPR,BASIC,1
OUTRES,ALL,1
F,2,FY,0 ! FORCE = 0 AT TIME = 0
SOLVE
TIME,.075 ! TIME AT END OF LOAD STEP
F,2,FY,20 ! FORCE IS RAMPED (KBC,0 IS DEFAULT) TO 20
SOLVE
TIME,.1 ! CONSTANT FORCE UNTIL TIME = 0.1
SOLVE
FINISH
/SOLU
C*** EXPANSION PASS USING BEAM3 AND MASS21 ELEMENTS
EXPASS,ON ! EXPANSION PASS ON
EXPSOL,,,0.092 ! TIME OF MAXIMUM RESPONSE
SOLVE
FINISH
/POST1
ETABLE,STRS,LS,3
*GET,STRSS,ELEM,2,ETAB,STRS
FINISH
/POST26
NSOL,2,2,U,Y
STORE
*GET,TMAX,VARI,2,EXTREM,TMAX
*GET,YMAX,VARI,2,EXTREM,VMAX
*DIM,LABEL_1,CHAR,2,2
*DIM,VALUE_1,,2,3
LABEL_1(1,1) = 'T_MAX, s','Y_MAX, i'
LABEL_1(1,2) = 'ec ','n '
*VFILL,VALUE_1(1,1),DATA,.092,.331
*VFILL,VALUE_1(1,2),DATA,TMAX,YMAX
*VFILL,VALUE_1(1,3),DATA,ABS(TMAX/.092),ABS(YMAX/.331)
*DIM,LABEL_2,CHAR,1,2
*DIM,VALUE_2,,1,3
LABEL_2(1,1) = 'SIG_BEND'
LABEL_2(1,2) = ', KSI '
*VFILL,VALUE_2(1,1),DATA,-18.6
*VFILL,VALUE_2(1,2),DATA,STRSS
*VFILL,VALUE_2(1,3),DATA,ABS(STRSS/18.6)
/COM
/OUT,vm77,vrt
/COM,------------------- VM77 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,TRANSIENT:
/COM,
*VWRITE,LABEL_1(1,1),LABEL_1(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.2)
/COM,
/COM,EXPANSION PASS:
/COM,
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.2)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm77,vrt
VM78 (Transverse Shear Stresses in a Cantilever Beam) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM78
/PREP7
/TITLE, VM78: TRANSVERSE SHEAR STRESSES IN A CANTILEVER BEAM
C*** THEORY OF ELASTICITY, TIMESHENKO, PG. 35, ARTICLE 20
ANTYPE,STATIC
ET,1,SHELL99,,,,,2,4 ! 8-NODE LAYERED SHELL; STRESS & STRAIN PRINTOUT
R,1,4,1 ! FOUR SYMMETRIC LAYERS
RMORE
RMORE,1,,0.5,1,,0.5 ! EQUAL THICKNESSES
MP,EX,1,30E6
MP,NUXY,1,0
/COM --- INPUT FAILURE STRESSES FOR MATERIAL #1 ---
/COM --- COMPRESSION VALUES ARE LEFT TO DEFAULT ---
TB,FAIL,1
TBTEMP,,CRIT
TBDATA,1,0,0,1 ! USE TSAI-WU FAILURE CRITERION
TBTEMP,0
TBDATA,10,25000 ! FAILURE X TENSION
TBDATA,12,3000 ! FAILURE Y TENSION (ARBITRARY)
TBDATA,14,5000 ! FAILURE Z TENSION (ARBITRARY)
TBDATA,16,500 ! FAILURE XY DIRECTION SHEAR
N,1
N,3,,1
FILL
NGEN,11,3,1,3,1,1
E,1,7,9,3,4,8,6,2
EGEN,5,6,-1
NSEL,S,LOC,X ! SELECT NODES AT FIXED END AND CONSTRAIN
D,ALL,ALL
NSEL,S,LOC,X,10
CP,1,UZ,ALL ! COUPLE FREE END NODES
NSEL,R,LOC,Y
F,ALL,FZ,10000 ! APPLY END FORCE
NSEL,ALL
OUTPR,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,NX,SMISC,7 ! OUT-OF-PLANE ELEMENT SHEAR FORCE
ETABLE,FC,NMISC,1 ! MAXIMUM FAILURE CRITERION NUMBER
ETABLE,FCMX,NMISC,2 ! MAXIMUM FAILURE CRITERION VALUE
ETABLE,FCLN,NMISC,3 ! FAILURE LAYER
ETABLE,ILMX,NMISC,4 ! MAXIMUM INTERLAMINAR SHEAR STRESS
ETABLE,ILLN,NMISC,5 ! LOWER LAYER NUMBER FOR ILMX
PRETAB,NX,ILLN,ILMX
PRETAB,FC,FCLN,FCMX
ETABLE,SXZ,S,XZ
ETABLE,ILSXZ,SMISC,11
*GET,SIGXZ1,ELEM,4,ETAB,SXZ
*GET,SIGXZ2,ELEM,1,ETAB,ILSXZ
*GET,SIGXZ3,ELEM,1,ETAB,ILMX
*GET,FC3,ELEM,1,ETAB,FCMX
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'SIGXZ,ps','SIGXZ,ps','SIGXZ,ps','FC3MAX ('
LABEL(1,2) = 'i(Z=H/2)','i(Z=H/4)','i(Z= 0 )','FCMX) '
*VFILL,VALUE(1,1),DATA,0,5625,7500,225
*VFILL,VALUE(1,2),DATA,SIGXZ1,SIGXZ2,SIGXZ3,FC3
*VFILL,VALUE(1,3),DATA,0,ABS(SIGXZ2/5625),ABS(SIGXZ3/7500),ABS(FC3/225)
/COM
/OUT,vm78,vrt
/COM,------------------- VM78 RESULTS COMPARISON ---------------
VM79 (Transient Response of a Bilinear Spring Assembly) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM79
/PREP7
/TITLE, VM79, TRANSIENT RESPONSE OF A BI-LINEAR SPRING ASSEMBLY
C***VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 150,FIG 5.6-1
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC,,NODAMP ! REDUCED TRANSIENT ANALYSIS, IGNORE DAMPING
ET,1,COMBIN40,,,2,,,2 ! Y DOF ELEMENTS, MASS AT NODE J
R,1,200,,.5 ! K1 = 200; M = .5
N,1
N,2
E,1,2
M,2,UY ! MASTER DOF IN Y DIRECTION AT FREE END OF SPRING
GP,3,2,FY,-200,.75 ! GAP CONDITION
FINISH
/SOLU
DELTIM,25E-4 ! INTEGRATION TIME STEP
KBC,1 ! STEP BOUNDARY CONDITIONS
D,1,UY,,,3,2 ! CONSTRAIN UY DOF AT NODES 1 AND 3
F,2,FY
OUTPR,BASIC,1
SOLVE ! STATIC LOAD STEP
TIME,25E-4 ! TIME AT END OF LOAD STEP
F,2,FY,-4E3 ! APPLY 4000 LB. LOAD
SOLVE
TIME,.105
F,2,FY,0 ! REMOVE LOAD
SOLVE
FINISH
/POST26
FILE,,rdsp
NSOL,2,2,U,Y,2UY ! STORE UY DISPLACEMENTS OF APPROPRIATE NODES
PRVAR,2
*GET,Y1,VARI,2,RTIME,.09
*GET,Y2,VARI,2,RTIME,.04
*GET,Y3,VARI,2,RTIME,.07
*GET,Y4,VARI,2,RTIME,.085
*GET,Y5,VARI,2,RTIME,.105
*DIM,LABEL_1,CHAR,3,2
*DIM,VALUE_1,,3,4
LABEL_1(1,1) = 'TIME ','Y, in ','Y, in '
LABEL_1(1,2) = 'sec ','linear ','bilinear'
*VFILL,VALUE_1(1,1),DATA,.040,-.68122,Y2
*VFILL,VALUE_1(1,2),DATA,.070,-.97494,Y3
*VFILL,VALUE_1(1,3),DATA,.085,-.99604,Y4
*VFILL,VALUE_1(1,4),DATA,.105,-.88666,Y5
*DIM,LABEL_2,CHAR,1,2
*DIM,VALUE_2,,1,3
LABEL_2(1,1) = 'Y, in '
LABEL_2(1,2) = 'MAX '
*VFILL,VALUE_2(1,1),DATA,-1.0417
*VFILL,VALUE_2(1,2),DATA,Y1
*VFILL,VALUE_2(1,3),DATA,ABS(Y1/1.0417)
/COM
/OUT,vm79,vrt
/COM,------------------- VM79 RESULTS COMPARISON -----------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,TIME=.09 sec
/COM,
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,
/COM,COMPARISON OF ANSYS LINEAR (VM74) AND BILINEAR SPRING RESULTS
/COM,
*VWRITE,LABEL_1(1,1),LABEL_1(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3),VALUE_1(1,4)
(1X,A8,A8,' ',F8.5,' ',F8.5,' ',F8.5,' ',F8.5)
/COM,
/COM,-------------------------------------------------------------
/OUT
FINISH
*LIST,vm79,vrt
VM80 (Plastic Response to a Suddenly Applied Constant Force) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM80
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM80, PLASTIC RESPONSE TO A SUDDENLY APPLIED CONSTANT FORCE
C*** INTRODUCTION TO STRUCT. DYNAMICS, BIGGS, PAGE 69, ART. 2.7
ANTYPE,TRANS ! FULL TRANSIENT DYNAMIC ANALYSIS
ET,1,LINK1
ET,2,MASS21,,,4 ! TWO-DIMENSIONAL MASS
R,1,.278 ! AREA (A)
R,2,0.0259 ! MASS
MP,EX,1,30E3
TB,BKIN,1,1 ! BILINEAR KINEMATIC HARDENING STRESS-STRAIN CURVE
TBTEMP,0
TBDATA,1,162.9,0 ! YIELD STRESS AND TANGENT MODULUS
N,1
N,2,,-100
E,1,2
TYPE,2
REAL,2
E,1
FINISH
/SOLU
SOLCONTROL,0
KBC,1 ! STEP BOUNDARY CONDITIONS
TIME,4E-3 ! TIME AT THE END OF LOAD STEP 1
D,1,UX,,,2
D,2,UY
F,1,FY,30 ! APPLY F1
NSUBST,10 ! 10 SUBSTEPS FOR TIME STEP OF .0004
OUTPR,BASIC,1 ! PRINT BASIC SOLUTION FOR EACH SUBSTEP
OUTRES,NSOL,1 ! STORE NODAL SOLUTION FOR EACH SUBSTEP
SOLVE
TIME,.14 ! FINAL TIME SLIGHTLY MORE THAN 1 CYCLE OF VIBRATION
NSUBST,68 ! 68 REPEATS FOR TIME STEP OF 0.002
OUTPR,BASIC,8 ! PRINT BASIC SOLUTION FOR EVERY 8TH SUBSTEP
SOLVE
FINISH
/POST26
NSOL,2,1,U,Y,UY ! STORE UY DISPLACEMENTS OF NODE 1 AGAINST TIME
PRVAR,2 ! PRINT VARIABLE 2 (DISPLACEMENT UY OF NODE 1) V/S TIME
/GRID,1 ! TURN THE GRID ON FOR DISPLAY
/AXLAB,Y,DISPLACEMENT ! MAKE Y-AXIS LABEL AS DISP FOR DISPLAY
PLVAR,2 ! DISPLAY VARIABLE 2 (DISPLACEMENT UY OF NODE 1) V/S TIME
*GET,YMAX,VARI,2,EXTREM,VMAX
*GET,TMAX,VARI,2,EXTREM,TMAX
*GET,YMIN,VARI,2,RTIME,.122
TMIN = .122
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'Y_MAX, i','TIME, se','Y_MIN, i','TIME, se'
LABEL(1,2) = 'n ','c ','n ','c '
*VFILL,VALUE(1,1),DATA,.806,.0669,.438,.122
*VFILL,VALUE(1,2),DATA,YMAX,TMAX,YMIN,TMIN
*VFILL,VALUE(1,3),DATA,ABS(YMAX/.806),ABS(TMAX/.0669),ABS(YMIN/.438),ABS(TMIN/.122)
/COM
/OUT,vm80,vrt
/COM,------------------- VM80 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm80,vrt
VM81 (Transient Response of a Drop Container) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM81
/PREP7
/TITLE, VM81, TRANSIENT RESPONSE OF A DROP CONTAINER (NONLINEAR)
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND. PRINTING, PAGE 110,
C*** EX. 4.6-1, USING NON-LINEAR TRANSIENT DYNAMIC ANALYSIS
ET,1,COMBIN40,,,2,,,2 ! SPRING, MASS, GAP COMBINATION ELEMENT
R,1,1973.92,,.5,1 ! SPRING STIFFNESS, MASS, AND GAP
N,1 ! DEFINE NODES AND ELEMENT
N,2
E,2,1
FINISH
/SOLU
SOLCONTROL,0
ANTYPE,TRANS ! NONLINEAR TRANSIENT DYNAMIC ANALYSIS
TIME,1E-6
D,2,UY
ACEL,,386 ! BOUNDARY CONDITIONS AND LOADING
KBC,1 ! STEPPED BOUNDARY CONDITIONS
CNVTOL,F,1,0.001 ! FORCE CONVERGENCE CRITERIA
SOLVE
NSUBST,110
OUTPR,BASIC,LAST
OUTRES,NSOL,1
TIME,.11
SOLVE
FINISH
/POST26 ! TIME-HISTORY POSTPROCESSOR
NSOL,2,1,U,Y
DERIV,3,2,1,,VEL_1UY ! CALCULATE VELOCITY BY TAKING DERIVATIVE OF UY
PRVAR,2,3
*GET,Y1,VARI,2,RTIME,.072
*GET,V1,VARI,3,RTIME,.072
*GET,Y2,VARI,2,RTIME,.1
*GET,Y3,VARI,2,RTIME,.101
*DIM,LABEL1,CHAR,3,1
*DIM,VALUE1,,3,3
LABEL1(1,1) = 'TIME sec','Y, in ','V,in/sec'
*VFILL,VALUE1(1,1),DATA,.07198,-1.00,-27.79
*VFILL,VALUE1(1,2),DATA,.072,Y1,V1
*VFILL,VALUE1(1,3),DATA,ABS(.072/.07198),ABS(Y1/1),ABS(V1/27.79)
*DIM,LABEL2,CHAR,2,2
*DIM,VALUE2,,2,3
LABEL2(1,1) = 't=.1 sec','t=1.01 s'
LABEL2(1,2) = ' Y, in ','ec Y, in'
*VFILL,VALUE2(1,1),DATA,-1.5505,-1.5502
*VFILL,VALUE2(1,2),DATA,Y2,Y3
*VFILL,VALUE2(1,3),DATA,ABS(Y2/1.5505),ABS(Y3/1.5502)
SAVE,TABLE1
FINISH
/CLEAR, NOSTART ! CLEAR THE DATABASE
/PREP7
/TITLE, VM81, TRANSIENT RESPONSE OF A DROP CONTAINER (QUASI-LINEAR)
ET,1,MASS21,,,4 ! TWO-DIMENSIONAL MASS ELEMENT
R,1,.5 ! MASS
N,1 ! DEFINE NODE AND ELEMENT
E,1
FINISH
/SOLU
SOLCONTROL,0
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC,,NODAMP ! REDUCED ANALYSIS, IGNORE DAMPING
GP,2,1,FY,1973.92,1 ! GAP CONDITION
D,1,UX
M,1,UY
DELTIM,1E-3
OUTPR,NSOL,LAST
SOLVE
NSUBST,110
OUTRES,NSOL,1
TIME,.110
KBC,1 ! STEPPED BOUNDARY CONDITIONS
ACEL,,386 ! BOUNDARY CONDITIONS AND LOADING
SOLVE
FINISH
/POST26 ! TIME-HISTORY POSTPROCESSOR
FILE,,rdsp ! REDUCED DISPLACEMENTS FILE
NSOL,2,1,U,Y
DERIV,3,2,1,,VEL_1UY ! CALCULATE VELOCITY
PRVAR,2,3
*GET,Y1,VARI,2,RTIME,.072
*GET,V1,VARI,3,RTIME,.072
*GET,Y2,VARI,2,RTIME,.1
*GET,Y3,VARI,2,RTIME,.101
*DIM,LABEL1,CHAR,3,1
*DIM,VALUE1,,3,3
LABEL1(1,1) = 'TIME sec','Y, in ','V,in/sec'
*VFILL,VALUE1(1,1),DATA,.07198,-1.00,-27.79
*VFILL,VALUE1(1,2),DATA,.072,Y1,V1
*VFILL,VALUE1(1,3),DATA,ABS(.072/.07198),ABS(Y1/1),ABS(V1/27.79)
*DIM,LABEL2,CHAR,2,2
*DIM,VALUE2,,2,3
LABEL2(1,1) = 't=.1 sec','t=1.01 s'
LABEL2(1,2) = ' Y, in ','ec Y, in'
*VFILL,VALUE2(1,1),DATA,-1.5505,-1.5502
*VFILL,VALUE2(1,2),DATA,Y2,Y3
*VFILL,VALUE2(1,3),DATA,ABS(Y2/1.5505),ABS(Y3/1.5502)
SAVE,TABLE2
RESUME,TABLE1
/COM
/OUT,vm81,vrt
/COM,------------------- VM81 RESULTS COMPARISON --------------
/COM,
/COM,FULL DYNAMIC | TARGET | ANSYS | RATIO
/COM,
/COM,AT IMAPACT
*VWRITE,LABEL1(1,1),VALUE1(1,1),VALUE1(1,2),VALUE1(1,3)
(1X,A8,' ',F18.4,' ',F10.4,' ',1F5.3)
/COM,
/COM,AT ZERO VELOCITY
*VWRITE,LABEL2(1,1),LABEL2(1,2),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/NOPR
RESUME,TABLE2
/GOPR
/COM,
/COM,REDUCED DYNAMIC | TARGET | ANSYS | RATIO
/COM,
/COM,AT IMAPACT
*VWRITE,LABEL1(1,1),VALUE1(1,1),VALUE1(1,2),VALUE1(1,3)
(1X,A8,' ',F18.4,' ',F10.4,' ',1F5.3)
/COM,
/COM,AT ZERO VELOCITY
*VWRITE,LABEL2(1,1),LABEL2(1,2),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
VM83 (Impact of a Block on a Spring Scale) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM83
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM83, IMPACT OF A BLOCK ON A SPRING SCALE
C***VECTOR MECHANICS FOR ENGINEERS, BEER AND JOHNSTON, 1962, PAGE 531, PROB 14.6
C*** WITH THANKS TO ALAN GOULD
ANTYPE,TRANS ! NONLINEAR TRANSIENT DYNAMIC ANALYSIS
ET,1,COMBIN40,1,,2,,,2
ET,2,COMBIN40,,,2,,,2
R,1,100,,(25/386) ! SPRING CONSTANT = 100, MASS = (25/386)
R,2,1E4,50.899,(50/386),71.75 ! SPRING CONSTANT = 1E4, C = 50.90,M=(50/386)
N,1,,-10
N,2
N,3,,72
TYPE,2
E,1,2
TYPE,1
REAL,2
E,2,3
ACEL,,386 ! GRAVITY
FINISH
/SOLU
TIMINT,OFF ! TIME INTEGRATION TURNED OFF
KBC,1 ! STEP THE LOAD
NSUBST,2 ! TWO SUBSTEPS TO GET ZERO INITIAL VELOCITY
! AND ACCELERATION
D,1,UY,,,3,2
TIME,1E-8 ! NEAR ZERO TIME FOR FIRST LOAD STEP
SOLVE
TIMINT,ON ! TIME INTEGRATION TURNED ON
DDELE,3,UY ! REMOVE THE CONSTRAINT AT NODE 3 (RELEASE THE BLOCK)
AUTOTS,ON ! AUTO TIME STEPPING ON
NSUBST,1400 ! MAXIMUM 1400 SUBSTEPS
OUTRES,NSOL,1
TIME,.7
SOLVE
FINISH
/POST26
NSOL,2,2,U,Y,UY ! STORE DISPLACEMENTS UY OF APPROPRIATE NODES
NSOL,3,3,U,Y,UY
FILLDATA,4,,,,71.75 ! DEFINE VARIABLE 4 AS CONSTANT
ADD,5,3,4,,3OFFSET ! CALCULATE VARIABLE 5 AS 3UY + 71.75
PRTIME,.65,.7 ! LIMIT TIME INTERVAL TO BE PRINTED
PRVAR,2,3 ! PRINT VARIABLES 2 AND 3
/AXLAB,Y,INCH
PLVAR,2,5 ! DISPLAY VARIABLES 2 AND 5
*GET,DEF_N2,VARI,2,RTIME,0.68897
*GET,DEF_N3,VARI,3,RTIME,0.68897
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = ' DEF, ',' Y, '
LABEL(1,2) = 'in ','in '
*VFILL,VALUE(1,1),DATA,-7.7,-79.450
*VFILL,VALUE(1,2),DATA,DEF_N2,DEF_N3
*VFILL,VALUE(1,3),DATA,ABS(DEF_N2/7.7) ,ABS(DEF_N3/79.450)
/COM
/OUT,vm83,vrt
/COM,------------------- VM83 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm83,vrt
VM84 (Displacement Propagation Along a Bar with Free Ends) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM84
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM84, DISPLACEMENT PROPAGATION ALONG A BAR WITH FREE ENDS
C*** VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 311, PROB. 2
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC,,NODAMP ! REDUCED TRANSIENT AND IGNORE DAMPING
ET,1,LINK1
R,1,2 ! AREA = 2
MP,EX,1,3E7
MP,DENS,1,7202E-7
N,1
N,17,48E3
FILL
E,1,2
EGEN,16,1,1
M,1,UX,17
FINISH
/SOLU
DELTIM,5E-3 ! INTEGRATION TIME STEP SIZE
KBC,1 ! STEP LOADING CONDITION
OUTPR,BASIC,LAST
D,ALL,UY
F,17,FX ! DEFINE NULL FX LOAD AT NODE 17
SOLVE
OUTPR,BASIC,2
OUTRES,NSOL,1
TIME,.24 ! FINAL TIME INCLUDES 1/2 OF THE FUNDAMENTAL PERIOD
F,17,FX,6000 ! APPLY FULL LOAD TO NODE 17
SOLVE
FINISH
/POST26
FILE,,rdsp ! REDUCED DISPLACEMENTS FILE
NSOL,2,1,U,X,1UX ! STORE APPROPRIATE NODAL DISPLACEMENTS
NSOL,3,9,U,X,9UX
NSOL,4,17,U,X,17UX
DERIV,5,2,,,1VX ! COMPUTE VELOCITIES
DERIV,6,3,,,9VX
DERIV,7,4,,,17VX
/GRID,1 ! TURN GRID ON
/AXLAB,Y,DISP ! Y-AXIS LABEL DISP
PLVAR,2,3,4 ! DISPLAY VARIABLES 2, 3 AND 4
/AXLAB,Y,VELO ! Y-AXIS LABEL VELO
PLVAR,5,6,7 ! DISPLAY VARIABLES 5, 6 AND 7
PRTIME,0.230,0.240 ! APPROPRIATE TIME RANGE (.23 TO .24)
PRVAR,4 ! PRINT VARIABLE 4 (UX AT NODE 17)
*GET,DEF,VARI,4,RTIME,.240
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' DEF,'
LABEL(1,2) = 'in '
*VFILL,VALUE(1,1),DATA,4.8
*VFILL,VALUE(1,2),DATA,DEF
*VFILL,VALUE(1,3),DATA,ABS(DEF/4.8)
/COM
/OUT,vm84,vrt
/COM,------------------- VM84 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm84,vrt
VM85 (Transient Displacements in a Suddenly Stopped Moving Bar) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM85
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM85, TRANSIENT DISPLACEMENTS IN A SUDDENLY STOPPED MOVING BAR
C*** VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 305, PROB. NO. 3
ANTYPE,TRANS ! REDUCED TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC,,NODAMP ! IGNORE DAMPING
ET,1,LINK1
R,1,1 ! AREA
MP,EX,1,30E6
MP,DENS,1,.00073
N,1
N,17,10000
FILL
E,1,2
EGEN,16,1,1
M,1,UX,17
GP,1,20,FX,3E7,.64 ! GAP CONDITION
FINISH
/SOLU
SOLCONTROL,0
DELTIM,.0001 ! ITS DEFINITION
KBC,1 ! STEP BOUNDARY CONDITION
D,ALL,UY
F,1,FX,,,17 ! DEFINE NULL FORCES ON ALL BAR NODES
SOLVE
TIME,.0004
F,1,FX,57031.25,,17,16 ! FORCES REQUIRED TO ACHIEVE INITIAL VELOCITY
F,2,FX,114062.5,,16
SOLVE
TIME,.06
F,1,FX,,,17 ! REMOVE FORCES ("COAST")
SOLVE
FINISH
/POST26
FILE,,rdsp ! REDUCED DISPLACEMENTS FILE
NSOL,2,1,U,X
NSOL,3,17,U,X
NSOL,5,9,U,X
ADD,4,2,3,,REL_DISP,,,-1 ! COMPUTE RELATIVE DISPLACEMENTS
PRTIME,.053,.057
PRVAR,2,3,4,5
/AXLAB,Y,DISPLACEMENTS
PLVAR,2,3,4,5
DERIV,6,2,,,1 VX ! COMPUTE VELOCITIES
DERIV,7,3,,,17VX
DERIV,8,5,,,9 VX
/AXLAB,Y,VELOCITY
PLVAR,6,7,8
*GET,D_0544,VARI,4,RTIME,.0544
*GET,D_0557,VARI,4,RTIME,.0557
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'D,in(T=.','D,in(T=.','D,in(T=.'
LABEL(1,2) = '05573sec','0544sec)','0557sec)'
*VFILL,VALUE(1,1),DATA,4.9329,0,0
*VFILL,VALUE(1,2),DATA,0,D_0544,D_0557
*VFILL,VALUE(1,3),DATA,0,ABS(D_0544/4.9329),ABS(D_0557/4.9329)
FINISH
/SOLU
EXPASS,ON ! EXPANSION PASS
EXPSOL,,,0.0557 ! EXPAND SOLUTION AT TIME CLOSEST TO THE THEORETICAL TIME POINT
OUTPR,,1
SOLVE
FINISH
/POST1
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,1,ETAB,STRS
*DIM,LABEL_2,CHAR,2,2
*DIM,VALUE_2,,2,3
LABEL_2(1,1) = 'SIGX,PSI','SIGX,PSI'
LABEL_2(1,2) = 'T=.05573',' T=.0557'
*VFILL,VALUE_2(1,1),DATA,14799,0
*VFILL,VALUE_2(1,2),DATA,0,STRSS
*VFILL,VALUE_2(1,3),DATA,0,ABS(STRSS/14799)
/COM
/OUT,vm85,vrt
/COM,------------------- VM85 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,REDUCED TRANSIENT DYNAMIC:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,
/COM,EXPANSION PASS:
/COM,
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm85,vrt
VM86 (Harmonic Response of a Dynamic System) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM86
/PREP7
/TITLE, VM86, HARMONIC RESPONSE OF A DYNAMIC SYSTEM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 56, EX 3.1-2
C*** BY VISCOUS DAMPING APPROACH
ANTYPE,HARMIC ! HARMONIC RESPONSE ANALYSIS
HROPT,REDUC ! REDUCED HARMONIC RESPONSE
HROUT,OFF ! PRINT COMPLEX DISP. AS AMPLITUDES AND PHASE ANGLES
ET,1,COMBIN40,,,3,,,2
R,1,200,6,.5 ! SPRING STIFFNESS = 200, C = 6, M = .5
N,1
N,2
E,1,2
M,2,UZ
OUTPR,BASIC,1
HARFRQ,,3.1831 ! HARMONIC FREQUENCY RANGE
D,1,UZ
F,2,FZ,10
FINISH
/SOLU
SOLVE
FINISH
/POST26
FILE,,rfrq
NSOL,2,2,U,Z,2UX
PRVAR,2
*GET,A,VARI,2,ITIME,3.1831
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'AMPLITUD'
LABEL(1,2) = 'E, in '
*VFILL,VALUE(1,1),DATA,.0833
*VFILL,VALUE(1,2),DATA,ABS(A)
*VFILL,VALUE(1,3),DATA,ABS(A/.0833)
/COM
/OUT,vm86,vrt
/COM,------------------- VM86 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM86 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm86,vrt
VM116 (Heat Conducting Plate with Sudden Cooling) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM116
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM116, HEAT CONDUCTING PLATE WITH SUDDEN COOLING
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 161, EX. 4-11
ANTYPE,TRANS
ET,1,LINK34,,3 ! CONVECTION LINK, USE (TI-TJ) FOR HF EVALUATION
ET,2,LINK32 ! HEAT CONDUCTION BAR
R,1,1 ! UNIT AREA ASSUMED
MP,KXX,1,2 ! CONDUCTIVITY, DENSITY AND SPECIFIC HEAT
MP,DENS,1,800 ! INPUT USED BY CONDUCTION ELEMENTS
MP,C,1,0.833
MP,HF,1,2,.02 ! TEMPERATURE DEPENDENT HF (USED FOR ELEM 1)
N,1 ! NODES 1 AND 2 DEFINE THE CONVECTION LINK
N,2 ! (ARBIRARY LENGTH)
N,10,(8/12) ! CONDUCTION LENGTH IN FT.
FILL
E,1,2 ! ELEMENT 1 IS CONVECTION LINK
TYPE,2 ! ELEMENTS 2 THROUGH 9 ARE CONDUCTION BARS
E,2,3
EGEN,8,1,-1
FINISH
/SOLU
D,2,TEMP,500 ! INITIAL SURFACE TEMPERATURES
D,10,TEMP,100
OUTPR,,LAST
OUTRES,,ALL
TIMINT,OFF ! TURN OFF TIME INTEGRATION FOR
TIME,0.001 ! INITIAL STEADY-STATE CONDITION
SOLVE
TIMINT,ON ! TURN ON TIME INTEGRATION ON FOR
TIME,7 ! TRANSIENT OVER 7 HRS
DDELE,2,TEMP ! DELETE NODAL TEMPERATURE
D,1,TEMP,100 ! ENVIRONMENT TEMPERATURE IS DECREASED
KBC,1 ! SUDDENLY
AUTOTS,ON
NSUBST,20
SOLVE
FINISH
/POST26
NSOL,2,2,TEMP
PRVAR,2 ! PRINT TEMPERATURE HISTORY AT NODE 2
/AXLAB,Y,TEMP
/GRID,1
PLVAR,2
FINISH
VM118 (Centerline Temperature of a Heat-generating Wire) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM118
/PREP7
/TITLE, VM118, CENTERLINE TEMP. OF A HEAT GENERATING WIRE
C*** HEAT, MASS AND MOMENTUM TRANS., ROHSENOW AND CHOI, 2ND. PR., PAGE 106,
C*** EX. 6.5, USING PLANE55 ELEMENTS (PLANE ELEMENTS)
ANTYPE,STATIC ! THERMAL ANALYSIS
ET,1,PLANE55
MP,KXX,1,13
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM
N,1,1E-10,-5 ! USE NON-ZERO RADIUS SINCE NODE IS NOT AT THETA=0
N,6,(.375/12),-5
FILL
NGEN,2,10,1,6,1,,10
E,1,2,12,12
E,2,3,13,12
EGEN,4,1,2
CP,1,TEMP,2,12 ! COUPLING TO ENSURE CIRCUMFERENTIAL SYMMETRY
CPSGEN,5,1,1
NSEL,S,LOC,X,(0.375/12)
SF,ALL,CONV,5,70
NSEL,ALL
BFE,ALL,HGEN,,111311.7 ! ELEMENT HEAT GENERATION
OUTPR,BASIC,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
*GET,TEMP,NODE,6,TEMP ! GET TEMPERATURE AT SURFACE NODE
PI=2*ASIN(1)
AREA=36*2*(0.375/12)*SIN(PI/36) ! COMPUTE AREA OF OUTER BOUNDARY
HRATE=AREA*5.0*(TEMP-70) ! TOTAL HEAT DISSIPATION RATE
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
*STATUS ! SHOW STATUS
*GET,TCL,NODE,1,TEMP
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'T CL, ','T S, ','q, BTU'
LABEL(1,2) = 'DEGREE F','DEGREE F','/hr '
*VFILL,VALUE(1,1),DATA,419.9,417.9,341.5
*VFILL,VALUE(1,2),DATA,TCL,TEMP,HRATE
*VFILL,VALUE(1,3),DATA,ABS(TCL/419.9) ,ABS( TEMP/417.9 ),ABS(HRATE/341.5)
SAVE,TABLE1
FINISH
/PREP7
C*** USING SOLID70 ELEMENTS (SOLID ELEMENTS)
EDELE,ALL ! DELETE PLANE55 ELEMENTS
ET,1,SOLID70 ! CHANGE ELEMENT TYPE
NGEN,2,20,1,16,1,,,-1 ! GENERATE 2ND PLANE OF NODES
NUMCMP,ELEM
E,1,2,12,12,21,22,32,32
E,2,3,13,12,22,23,33,32
EGEN,4,1,2
CPDELE,1,6,1 ! REMOVE PREVIOUS COUPLING SPECIFICATIONS
CP,1,TEMP,1,21 ! COUPLING TO ENSURE AXIAL SYMMETRY
CP,2,TEMP,2,12,22,32 ! COUPLING TO ENSURE CIRCUMFERENTIAL SYMMETRY
CPSGEN,5,1,2
CSYS,1
NSEL,S,LOC,X,(0.375/12)
SF,ALL,CONV,5,70
NSEL,ALL
BFE,ALL,HGEN,1,111311.7 ! ELEMENT HEAT GENERATION
FINISH
/SOLU
SOLVE
FINISH
/POST1
*GET,TEMP,NODE,6,TEMP ! GET TEMPERATURE AT SURFACE NODE
PI=2*ASIN(1)
AREA=36*2*(0.375/12)*SIN(PI/36) ! LENGTH ALONG 10 DEG ON OUTER FACE
HRATE=AREA*5.0*(TEMP-70) ! TOTAL HEAT DISSIPATION RATE
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
*STATUS ! SHOW PARAMETER STATUS
*GET,TCL,NODE,1,TEMP
LABEL(1,1) = 'T CL, ','T S, ','q, BTU'
LABEL(1,2) = 'DEGREE F','DEGREE F','/hr '
*VFILL,VALUE(1,1),DATA,419.9,417.9,341.5
*VFILL,VALUE(1,2),DATA,TCL,TEMP,HRATE
*VFILL,VALUE(1,3),DATA,ABS(TCL/419.9) ,ABS( TEMP/417.9 ), ABS(HRATE/341.5)
SAVE,TABLE2
RESUME,TABLE1
/COM
/OUT,vm118,vrt
/COM,------------------- VM118 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,STIF55 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/NOPR
RESUME,TABLE2
/GOPR
/COM,
/COM,STIF70 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm118,vrt
VM119 (Centerline Temperature of an Electrical Wire) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM119
/PREP7
/TITLE, VM119, CENTERLINE TEMP. OF AN ELECTRICAL WIRE
C*** HEAT, MASS AND MOMENTUM TRANS., ROHSENOW AND CHOI, 2ND. PR., PAGE 106,
C*** EX. 6.5, USING PLANE67 ELEMENTS (PLANE ELEMENTS)
ANTYPE,STATIC ! THERMAL (ELECTRICAL) ANALYSIS
ET,1,PLANE67,,,1 ! AXISYMMETRIC ELEMENTS
MP,KXX,1,13 ! CONDUCTIVITY
MP,RSVX,1,8.983782E-8 ! RESISTIVITY
N,1
N,6,(.375/12)
FILL
NGEN,2,10,1,6,1,,1
E,11,1,2,12
EGEN,5,1,1
CP,1,TEMP,1,11 ! COUPLING TO INSURE AXIAL SYMMETRY
CPSGEN,6,1,1
D,1,VOLT,,,6 ! NODAL VOLTAGE
D,11,VOLT,-0.1,,16
NSEL,S,LOC,X,(0.375/12)
SF,ALL,CONV,5,70
NSEL,ALL
FINISH
/SOLU
OUTPR,ALL,1 ! USE TIME STEP OPTIMIZATION
OUTPR,VENG,NONE
KBC,1 ! STEP BOUNDARY CONDITIONS
SOLVE
FINISH
/POST1
*GET,TEMP,NODE,6,TEMP ! GET TEMPERATURE AT SURFACE NODE
PI=2*ASIN(1)
AREA=2*PI*(0.375/12) ! COMPUTE AREA OF OUTER FACE (360 DEG)
HRATE=AREA*5.0*(TEMP-70) ! TOTAL HEAT DISSIPATION RATE
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
*STATUS ! SHOW PARAMETER STATUS
*GET,TCL,NODE,1,TEMP
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'T CL, ','T S, ','q, BTU'
LABEL(1,2) = 'DEGREE F','DEGREE F','/hr '
*VFILL,VALUE(1,1),DATA,419.9,417.9,341.5
*VFILL,VALUE(1,2),DATA,TCL,TEMP,HRATE
*VFILL,VALUE(1,3),DATA,ABS(TCL/419.9) ,ABS( TEMP/417.9 ),ABS (HRATE/341.5)
SAVE,TABLE1
FINISH
/CLEAR, NOSTART ! CLEAR DATABASE FOR SOLID69 MODEL
/PREP7
/TITLE, VM119, CENTERLINE TEMP. OF AN ELECTRICAL WIRE
C*** USING SOLID69 ELEMENTS (SOLID ELEMENTS)
ANTYPE,STATIC ! THERMAL (ELECTRICAL) ANALYSIS
ET,1,SOLID69
MP,KXX,1,13 ! CONDUCTIVITY
MP,RSVX,1,8.983782E-8 ! RESISTIVITY
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM
N,1,1E-10,-5 ! USE NON-ZERO RADIUS SINCE NODE IS NOT AT THETA=0
N,6,(.375/12),-5
FILL
N,11,1E-10,5
N,16,.03125,5
FILL
NGEN,2,20,1,16,1,,,-1
E,1,2,12,12,21,22,32,32
E,2,3,13,12,22,23,33,32
EGEN,4,1,2
CP,1,TEMP,1,21 ! COUPLING TO INSURE AXIAL SYMMETRY
CP,2,TEMP,2,12,22,32 ! COUPLING TO INSURE CIRCUMFERENTIAL SYMMETRY
CPSGEN,5,1,2
D,1,VOLT,,,16
D,21,VOLT,-.1,,36
NSEL,S,LOC,X,(0.375/12)
SF,ALL,CONV,5,70
NSEL,ALL
FINISH
/SOLU
OUTPR,ALL,1
OUTPR,VENG,NONE
SOLVE
FINISH
/POST1
*GET,TEMP,NODE,6,TEMP ! GET TEMPERATURE AT SURFACE NODE
PI=2*ASIN(1)
LENG=2*(0.375/12)*SIN(PI/36) ! LENGTH ALONG 10 DEG ON OUTER FACE
AREA=LENG*36 ! COMPUTE AREA OF OUTER FACE (360 DEG)
HRATE=AREA*5.0*(TEMP-70) ! TOTAL HEAT DISSIPATION RATE
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
*STATUS ! SHOW PARAMETER STATUS
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
*GET,TCL,NODE,1,TEMP
LABEL(1,1) = 'T CL, ','T S, ','q, BTU'
LABEL(1,2) = 'DEGREE F','DEGREE F','/hr '
*VFILL,VALUE(1,1),DATA,419.9,417.9,341.5
*VFILL,VALUE(1,2),DATA,TCL,TEMP,HRATE
*VFILL,VALUE(1,3),DATA,ABS(TCL/419.9) ,ABS( TEMP/417.9 ),ABS (HRATE/341.5)
SAVE,TABLE2
RESUME,TABLE1
/COM
/OUT,vm119,vrt
/COM,------------------- VM119 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,PLANE67 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/NOPR
RESUME,TABLE2
/GOPR
/COM,
/COM,SOLID69 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm119,vrt
VM120 (Microstrip Transmission Line Capacitance) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM120
/PREP7
SMRT,OFF
/TITLE, VM120, MICROSTRIP TRANSMISSION LINE ANALYSIS
! BEREN AND KAIRES (REF. 56)
ANTYPE,STATIC ! ELECTROSTATIC ANALYSIS
ET,1,PLANE121 ! USE 2-D 8-NODE ELECTROSTATIC ELEMENT
PER=8.85E-14 ! DEFINE FREE-SPACE PERMITTIVITY
EMUNIT,EPZRO,PER
V1=1.5 ! DEFINE STRIP POTENTIAL
V0=0.5 ! DEFINE GROUND POTENTIAL
MP,PERX,1,10 ! SUBSTRATE PERMITTIVITY
MP,PERX,2,1 ! FREE SPACE PERMITTIVITY
K,1
K,2,5
K,3,,1
K,4,.5,1 ! DEFINE GEOMETRY
K,5,5,1
K,6,,10
K,7,5,10
DESIZE,8,5,30
L,1,2
L,2,5
L,5,4
L,4,3
L,3,1
L,5,7
L,7,6
L,6,3
AL,1,2,3,4,5
AL,4,3,6,7,8
ASEL,S,AREA,,2
AATT,2
ASEL,ALL ! SET AREA ATTRIBUTES FOR AIR
AMESH,ALL
NSEL,S,LOC,Y,1 ! SELECT NODES ON MICROSTRIP
NSEL,R,LOC,X,0,.5
CM,CON1,NODE
!D,ALL,VOLT,V1 ! APPLY STRIP POTENTIAL
NSEL,S,LOC,Y,0
NSEL,A,LOC,Y,10
NSEL,A,LOC,X,5 ! SELECT EXTERIOR NODES
CM,CON2,NODE
!D,ALL,VOLT,V0 ! APPLY GROUND POTENTIAL
NSEL,ALL
FINISH
/SOLUTION
CMATRIX,2,'CON',2,0 ! CALCULATE CAPACITANCE USING CMATRIX MACRO
FINISH
/POST1
SET,LAST
ETABLE,EFX,EF,X ! STORE POTENTIAL FIELD GRADIENTS
ETABLE,EFY,EF,Y
/NUMBER,1
PLNSOL,VOLT ! DISPLAY EQUIPOTENTIAL LINES
/DIST,1,2.2 ! FOCUS IN ON MICROSTRIP REGION
/FOCUS,1,2,1.5
PLVECT,EFX,EFY ! DISPLAY VECTOR ELECTRIC FIELD (VECTOR)
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'CAPACITA'
LABEL(1,2) = 'NCE,pF/m'
*VFILL,VALUE(1,1),DATA,178.1
*VFILL,VALUE(1,2),DATA,CMATRIX(1,1,1)*1E14
*VFILL,VALUE(1,3),DATA,ABS((CMATRIX(1,1,1)*1E14)/178.1)
/COM
/OUT,vm120,vrt
/COM,------------------- VM120 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm120,vrt
VM121 (Laminar Flow Through a Pipe with Uniform Heat Flux) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM121
/config,nproc,4
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE,VM121, LAMINAR FLOW THROUGH A PIPE WITH UNIFORM HEAT FLUX
! REFERENCES: 1. "FLUID MECHANICS," WHITE F., MCGRAW-HILL, 1979.
! 2. "FUNDAMENTALS OF HEAT TRANSFER," INCROPERA, F., &
! DEWITT, D., JOHN WILEY & SONS, 1981.
/PREP7
SMRT,OFF
ET,1,FLUID141,,,2 ! 2D AXISYMMETRIC XR SYSTEM
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USE QUADS
PI = ACOS(-1)
L = 0.1 ! PIPE LENGTH (M)
R = 0.0025 ! PIPE RADIUS (M)
PIN = 1.0 ! INLET PRESSURE (PA)
TIN = 300.0 ! INLET TEMPERATURE (K)
QW = 5000.0 ! WALL HEAT FLUX (W/M**2)
RHO = 13529.0 ! FLUID DENSITY (KG/M**3)
MU = 1.523E-03 ! FLUID VISCOSITY (KG/(M*SEC))
K = 8.54 ! FLUID THERMAL CONDUCTIVITY (W/(M*K))
CP = 139.3 ! FLUID SPECIFIC HEAT (J/(KG*K))
RECTNG,,L,,R
LSEL,S,,,2,4,2
LESIZE,ALL,,,12,-2 ! GRADED RADIAL LINE DIVISIONS
LSEL,INVE
LESIZE,ALL,,,100,1 ! GRADED AXIAL LINE DIVISIONS
ALLSEL
AMESH,1
/SOLU
FLDATA,ITER,EXEC,300 ! # OF GLOBAL ITERATIONS
FLDATA,ITER,CHEC,10 ! CHECKPOINT FREQUENCY
FLDATA,TEMP,NOMI,TIN ! NOMINAL TEMPERATURE
FLDATA,NOMI,DENS,RHO ! FLUID DENSITY
FLDATA,NOMI,VISC,MU ! FLUID VISCOSITY
FLDATA,NOMI,COND,K ! FLUID THERMAL CONDUCTIVITY
FLDATA,NOMI,SPHT,CP ! FLUID SPECIFIC HEAT
FLDATA,OUTP,TAUW,T ! OUTPUT WALL SHEAR STRESS
SAVE
/out,scratch
SOLVE
/out
FLDATA,ITER,EXEC,50 ! # OF GLOBAL ITERATIONS
FLDATA,SOLU,TEMP,T ! ACTIVATE ENERGY EQUATION
FLDATA,SOLU,FLOW,F ! DEACTIVATE FLOW EQUATIONS
FLDATA,RELX,TEMP,1.0 ! NO RELAXATION FOR TEMP
/out,scratch
SOLVE
/out
FINISH
/POST1
SET,LAST
/RATIO,,,10 ! EXPAND Y-DISPLAY BY FACTOR OF 10
EPLOT
/EDGE,1,1
/CONTOUR,1,27
/TITLE,CONTOURS OF AXIAL VELOCITY
PLNSOL,VX ! PLOT CONTOURS OF AXIAL VELOCITY
VXC = VX(2) ! GET CENTERLINE AXIAL VELOCITY
PATH,PIPE,2,,48 ! DEFINE PATH WITH NAME = "PIPE"
PPATH,1,,L,0,0 ! DEFINE PATH POINTS BY LOCATION
PPATH,2,,L,R,0
PDEF,VX,VX ! MAP VX TO PATH
PDEF,TEMP,TEMP ! MAP TEMP TO PATH
PCALC,MULT,PROD1,VX,S ! MULTIPLY VX TIMES R COORDINATE
PCALC,INTG,VXM,PROD1,S,2/R**2 ! INTEGRATE AXIAL VELOCITY ALONG PATH
*GET,VXM,PATH,,LAST,VXM ! GET MEAN AXIAL VELOCITY
MDOT = RHO*VXM*PI*R**2 ! DETERMINE MASS FLOW RATE
/TITLE,CONTOURS OF WALL SHEAR STRESS
PLNSOL,TAUW ! PLOT CONTOURS OF WALL SHEAR STRESS
*GET,TAU,PLNSOL,,MAX ! GET WALL SHEAR STRESS
PCALC,MULT,PROD2,VX,TEMP ! MULTIPLY VX TIMES TEMP
PCALC,MULT,PROD3,PROD2,S ! MULTIPLY ABOVE TIMES R COORDINATE
PCALC,INTG,TM,PROD3,S,2/VXM/R**2 ! INTEGRATE TEMPERATURE ALONG PATH
*GET,TM_O,PATH,,LAST,TM ! GET OUTLET MEAN TEMPERATURE
/TITLE,CONTOURS OF TEMPERATURE
PLNSOL,TEMP ! PLOT CONTOURS OF TEMPERATURE
*GET,TW_O,PLNSOL,,MAX ! GET OUTLET WALL TEMPERATURE
TC_O = TEMP(2) ! GET OUTLET CENTERLINE TEMPERATURE
*STATUS ! LIST CURRENT PARAMETER VALUES
/RATIO
/TITLE,AXIAL VELOCITY PROFILE, VX(R)
/AXLAB,X,RADIAL COORDINATE, (M)
/AXLAB,Y,VELOCITY, (M/SEC)
/DEVICE,RASTOR,ON
PLPATH,VX ! PLOT VX ALONG PATH
/TITLE,OUTLET TEMPERATURE PROFILE, T(R)
/AXLAB,Y,TEMPERATURE, (K)
PLPATH,TEMP ! PLOT TEMP ALONG PATH
VM129 (Numerical Differentiation and Integration) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM129
/TITLE, VM129, NUMERICAL DIFFERENTIATION AND INTEGRATION USING APDL COMMAND
C*** REFERENCE - ANY BASIC CALCULUS BOOK
*DIM,A,,145 ! DEFINE ARRAYS WITH DIMENSION
*DIM,B,,145
*DIM,C,,145
*DIM,D,,145
*DIM,E,,145
*DIM,F,,145
*DIM,G,,145
*DIM,H,,145
*VFILL,A(1),RAMP,0,1 ! ARRAY A(N) : TIME IN SECOND
*VFACT,0.043633 ! MULTIPLYING FACTOR : FREQUENCY = (PI/72)
*VFUN,B(1),COPY,A(1) ! RESULT ARRAY B(N)=FREQUENCY*A(N)
*VFUN,C(1),SIN,B(1) ! ARRAY C(N) : SIN(B(N))
*VFACT,1.2732 ! MULTIPLYING FACTOR : AMPLITUDE A
*VFUN,D(1),COPY,C(1) ! ARRAY D(N) : A*C(N)
*VOPER,E(1),D(1),DER1,A(1) ! ARRAY E(N) : FIRST DERIVATIVE OF D WRT TIME
*VOPER,F(1),D(1),INT1,A(1) ! ARRAY F(N) : SINGLE INTEGRAL (I1) OF D WRT TIME
*VOPER,G(1),D(1),DER2,A(1) ! ARRAY G(N) : SECOND DERIVATIVE OF D WRT TIME
*VOPER,H(1),D(1),INT2,A(1) ! ARRAY H(N) : DOUBLE INTEGRAL (I2) OF D WRT TIME
*VSCFUN,DERIV1,MAX,E(1) ! MAXIMUM VALUE OF FIRST DERIVATIVE
*VSCFUN,DERIV2,MAX,G(1) ! MAXIMUM VALUE OF SECOND DERIVATIVE
*STATUS ! LIST SCALAR PARAMETERS
*STATUS,F,37,37 ! LIST VALUE OF F(N) AT UPPER LIMIT (INTEGRAL I1)
*STATUS,H,37,37 ! LIST VALUE OF H(N) AT UPPER LIMIT (INTEGRAL I2)
*SET,INTER1,F(37,1,1)
*SET,INTER2,H(37,1,1)
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = '1ST DER ','2ND DER','1ST INT','2ND INT'
LABEL(1,2) = 'MAX','MAX','T(0-36)','T(0-36)'
*VFILL,VALUE(1,1),DATA,5.555E-2,2.424E-3,29.18,381.7
*VFILL,VALUE(1,2),DATA,DERIV1,DERIV2,INTER1,INTER2
DRV1=ABS(DERIV1/5.555E-2)
DRV2=ABS(DERIV2/2.424E-3)
INT1=ABS(INTER1/29.18)
INT2=ABS(INTER2/381.7)
*VFILL,VALUE(1,3),DATA,DRV1,DRV2,INT1,INT2
/COM
/OUT,vm129,vrt
/COM,------------------- VM129 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.6,' ',F10.6,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm129,vrt
VM130 (Fourier Series Generation for a Saw Tooth Wave) Input Listing
/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM130
/TITLE, VM130, FOURIER SERIES GENERATION FOR A SAW TOOTH WAVE
/COM VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 102, PROB. 2
*DIM,COEFF,,24
*DIM,MODE,TABLE,24
*DIM,ISYM,TABLE,24
*DIM,THETA,TABLE,121
*DIM,CURVEI,TABLE,121 ! CURVE INPUT TO PROGRAM
*DIM,CURVEO,TABLE,121 ! CURVE WHICH WILL BE DEVELOPED
! FROM GENERATED COEFFICIENTS
*VFILL,MODE(2),RAMP,1,2 ! ODD MODE NUMBERS
*VFILL,ISYM(2),RAMP,-1,0 ! ISYM = -1 (SINE)
*VFILL,THETA(1),RAMP,0,3 ! THETA VALUES INCREMENT 3 DEGREES
*VFILL,CURVEI(1),RAMP,0,1/30 ! WAVE DATA: 0 TO 90 DEG
*VFILL,CURVEI(31),RAMP,1,-1/30 ! 90 TO 270 DEG
*VFILL,CURVEI(91),RAMP,-1,1/30 ! 270 TO 360 DEG
! CALCULATE FOURIER COEFFICIENT
*MFOURI,FIT, COEFF(1),MODE(1),ISYM(1),THETA(1),CURVEI(1)
! EVALUATE SERIES BASED ON COEFFICIENTS
*MFOURI,EVAL,COEFF(1),MODE(1),ISYM(1),THETA(1),CURVEO(1)
*VWRITE ! WRITE OUTPUT IN TABULAR FORMAT
(///T14,'MODE',T24,'COEFF',T34,'ISYM',/)
*VWRITE, MODE(1),COEFF(1),ISYM(1)
(T10,F10.4,T20,F10.4,T30,F10.4,T40,F10.4)
첫댓글 vm1에서 막혀서 질문드립니다
*get,reac_2,fsum,,item,fy
이부분 get parameter에서 어디서 하는건가요? load인가여 ? ?