VM1 - 130 로그파일

[지원이 아빠^^]

VM1 (Statically Indeterminate Reaction Force Analysis) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM1
/PREP7
/TITLE, VM1, STATICALLY INDETERMINATE REACTION FORCE ANALYSIS
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 26, PROB.10
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,LINK1
R,1,1 ! CROSS SECTIONAL AREA (ARBITRARY) = 1
MP,EX,1,30E6
N,1
N,2,,4
N,3,,7
N,4,,10
E,1,2 ! DEFINE ELEMENTS
EGEN,3,1,1
D,1,ALL,,,4,3 ! BOUNDARY CONDITIONS AND LOADING
F,2,FY,-500
F,3,FY,-1000
FINISH
/SOLU
OUTPR,BASIC,1
OUTPR,NLOAD,1
SOLVE
FINISH
/POST1
NSEL,S,LOC,Y,10
FSUM
*GET,REAC_1,FSUM,,ITEM,FY
NSEL,S,LOC,Y,0
FSUM
*GET,REAC_2,FSUM,,ITEM,FY

*DIM,LABEL,CHAR,2
*DIM,VALUE,,2,3
LABEL(1) = 'R1, lb','R2, lb '
*VFILL,VALUE(1,1),DATA,900.0,600.0
*VFILL,VALUE(1,2),DATA,ABS(REAC_1),ABS(REAC_2)
*VFILL,VALUE(1,3),DATA,ABS(REAC_1 / 900) ,ABS( REAC_2 / 600)
/OUT,vm1,vrt
/COM
/COM,------------------- VM1 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vm1,vrt


VM2 (Beam Stresses and Deflections) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM2
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
MP,PRXY,,0.3
/TITLE, VM2, BEAM STRESSES AND DEFLECTIONS
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 98, PROB. 4
ANTYPE,STATIC
ET,1,BEAM3
KEYOPT,1,9,9 ! OUTPUT AT 9 INTERMEDIATE LOCATIONS
R,1,50.65,7892,30
MP,EX,1,30E6
N,1 ! DEFINE NODES AND ELEMENTS
N,5,480
FILL
E,1,2
EGEN,4,1,1
D,2,UX,,,,,UY ! BOUNDARY CONDITIONS AND LOADING
D,4,UY
SFBEAM,1,1,PRES,(10000/12)
SFBEAM,4,1,PRES,(1E4/12)
FINISH
/SOLU
OUTPR,BASIC,1
SOLVE
FINISH
/POST1
SET,1,1
PRNSOL,U,COMP
PRNSOL,ROT,COMP
PLDISP,1
MID_NODE = NODE (240,,, )
*GET,DISP,NODE,MID_NODE,U,Y
MID_ELM = ENEARN (MID_NODE)
ETABLE,STRS,LS,3
*GET,STRSS,ELEM,MID_ELM,ETAB,STRS

*DIM,LABEL,CHAR,2
*DIM,VALUE,,2,3
LABEL(1) = 'STRS_psi','DEF_in'
*VFILL,VALUE(1,1),DATA,-11400,0.182
*VFILL,VALUE(1,2),DATA,STRSS,DISP
*VFILL,VALUE(1,3),DATA,ABS(STRSS /11400 ) ,ABS( DISP /0.182 )
/OUT,vm2,vrt
/COM
/COM,-------------------VM2 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,---------------------------------------------------------------
/OUT
FINISH
*LIST,vm2,vrt




VM3 (Thermally Loaded Support Structure) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM3
/PREP7
/TITLE, VM3, THERMALLY LOADED SUPPORT STRUCTURE
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 30, PROB. 9
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,LINK1
R,1,.1
MP,EX,1,16E6
MP,ALPX,1,92E-7
MP,EX,2,30E6
MP,ALPX,2,70E-7
TREF,70 ! REFERENCE TEMPERATURE
N,1,-10 ! DEFINE NODES AND ELEMENTS
N,3,10
FILL
N,4,-10,-20
N,6,10,-20
FILL
E,1,4
E,3,6
MAT,2
E,2,5
CP,1,UY,5,4,6
D,1,ALL,,,3 ! BOUNDARY CONDITIONS AND LOADING
F,5,FY,-4000
BFUNIF,TEMP,80 ! UNIFORM TEMPERATURE (TREF+10)
FINISH
/SOLU
OUTPR,BASIC,1
OUTPR,NLOAD,1
NSUBST,1
SOLVE
FINISH
/POST1
STEEL_N = NODE (,,,)
COPPER_N = NODE (10,0,0)
STEEL_E = ENEARN (STEEL_N)
COPPER_E = ENEARN (COPPER_N)
ETABLE,STRS_ST,LS,1
ETABLE,STRS_CO,LS,1
*GET,STRSS_ST,ELEM,STEEL_E,ETAB,STRS_ST
*GET,STRSS_CO,ELEM,COPPER_E,ETAB,STRS_CO

*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'STRSS_ST','STRSS_CO'
LABEL(1,2) = ' (psi) ',' (psi) '
*VFILL,VALUE(1,1),DATA,19695,10152
*VFILL,VALUE(1,2),DATA,STRSS_ST,STRSS_CO
*VFILL,VALUE(1,3),DATA,ABS(STRSS_ST/19695 ) ,ABS( STRSS_CO/10152 )
/COM
/OUT,vm3,vrt
/COM,------------------- VM3 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vm3,vrt



VM4 (Deflection of a Hinged Support) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM4
/PREP7
/TITLE, VM4, DEFLECTION OF A HINGED SUPPORT
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 10, PROB. 2
L=15*12 ! LENGTH OF BAR IN INCHES
*AFUN,DEG ! TRIG FUNCTIONS IN DEGREES
THETA=30 ! ANGLE TO BE USED TO CALCULATE A AND B
A=2*L*COS(THETA) ! CALCULATED X LOCATION - NODE 3
B=L*SIN(THETA) ! CALCULATED Y LOCATION - NODE 2
ET,1,LINK1
R,1,.5
MP,EX,1,30E6
N,1
N,2,A/2,-B ! X LOCATION = A/2; A AND B AS ABOVE
N,3,A
E,1,2
E,2,3
D,1,ALL,,,3,2
F,2,FY,-5000
OUTPR,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
MID_NODE = NODE (A/2,-B,0 )
*GET,DISP,NODE,MID_NODE,U,Y
LEFT_EL = ENEARN (MID_NODE)
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,LEFT_EL,ETAB,STRS

*DIM,LABEL,CHAR,2
*DIM,VALUE,,2,3
LABEL(1) = 'STRS_psi','DEF_in'
*VFILL,VALUE(1,1),DATA,10000,-0.120
*VFILL,VALUE(1,2),DATA,STRSS,DISP
*VFILL,VALUE(1,3),DATA,ABS(STRSS /10000 ) ,ABS( DISP /0.120 )
/OUT,vm4,vrt
/COM
/COM,------------------- VM4 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vm4,vrt


VM5 (Laterally Loaded Tapered Support Structure) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM5
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM5, LATERALLY LOADED TAPERED SUPPORT STRUCTURE (QUAD. ELEMENTS)
C*** MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 342, PROB. 7.18
C*** USING PLANE42 ELEMENTS
ANTYPE,STATIC
ET,1,PLANE42,,,3,,,2 ! TURN ON SURFACE PRINTOUT TO GET RESULTS AT MID-LENGTH
R,1,2
MP,EX,1,30E6
MP,NUXY,1,0.0 ! POISSON'S RATIO SET TO 0.0 TO AGREE WITH BEAM THEORY
N,1,25
N,7,75
FILL
N,8,25,-3
N,14,75,-9
FILL
E,2,1,8,9
EGEN,6,1,1
NSEL,S,LOC,X,75
D,ALL,ALL ! CONSTRAIN NODES AT FIXED END
NSEL,ALL
F,1,FY,-4000
FINISH
/SOLU
OUTPR,,1
SOLVE
FINISH
/POST1
END_NODE = NODE (75,0,0)
*GET,STS_E_42,NODE,END_NODE,S,X ! STRESS AT FIXED END (END NODE )
PLDISP,2
MID_NODE = NODE (50,0,0)
*GET,STS_M_42,NODE,MID_NODE,S,EQV
FINISH
/PREP7
/TITLE, VM5, LATERALLY LOADED TAPERED SUPPORT STRUCTURE (QUAD. ELEMENTS)
C*** MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 342, PROB. 7.18
C*** USING PLANE82 ELEMENTS
C*** ! CHANGE ELEMENT TYPE TO HIGHER ORDER PLANE82
ET,1,PLANE82,,,3,,,2 ! TURN ON FACE PRINTOUT TO GET RESULTS AT MID-LENGTH
EMID ! ADD MIDSIDE NODES TO PLANE82 ELEMENTS
NSEL,R,LOC,X,75
NSEL,R,LOC,Y,-4.5 ! SELECT MIDSIDE NODE AT FIXED END
D,ALL,ALL ! CONSTRAIN MIDSIDE NODE AT FIXED END
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
END_NODE = NODE (75,0,0)
*GET,STS_E_82,NODE,END_NODE,S,X ! STRESS AT FIXED END (END NODE )
MID_NODE = NODE (50,0,0)
*GET,STS_M_82,NODE,MID_NODE,S,EQV

*DIM,LABEL,CHAR,2,2
*DIM,VALUEI,,2,3
*DIM,VALUEII,,2,3
LABEL(1,1) = 'MID_STRS','END-STRS'
LABEL(1,2) = ' (psi) ',' (psi) '
*VFILL,VALUEI(1,1),DATA,8333,7407
*VFILL,VALUEI(1,2),DATA,STS_M_42,STS_E_42
*VFILL,VALUEI(1,3),DATA,(STS_M_42/8333),(STS_E_42/7407)
*VFILL,VALUEII(1,1),DATA,8333,7407
*VFILL,VALUEII(1,2),DATA,STS_M_82,STS_E_82
*VFILL,VALUEII(1,3),DATA,(STS_M_82/8333),(STS_E_82/7407)
/COM,STS_M_42 = STRESS AT MID-LENGTH USING ELEMENT 42
/COM,STS_E_42 = STRESS AT FIXED END USING ELEMENT 42
/COM,STS_M_82 = STRESS AT MID-LENGTH USING ELEMENT 82
/COM,STS_E_82 = STRESS AT FIXED END USING ELEMENT 82
/COM,
/OUT,vm5,vrt
/COM,------------------- VM5 RESULTS COMPARISON ---------------------
/COM,
/COM,RESULTS FOR PLANE42:
/COM,
/COM, | TARGET | ANSYS | RATIO
*VWRITE,LABEL(1,1),LABEL(1,2),VALUEI(1,1),VALUEI(1,2),VALUEI(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,
/COM,RESULTS FOR PLANE82:
/COM,
/COM, | TARGET | ANSYS | RATIO
*VWRITE,LABEL(1,1),LABEL(1,2),VALUEII(1,1),VALUEII(1,2),VALUEII(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vm5,vrt


VM6 (Pinched Cylinder) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM6
/PREP7
smrt,off
/TITLE, VM6, PINCHED CYLINDER
/COM, REF: COOK, CONCEPTS AND APPL. OF FEA 2ND ED., 1981, PP. 284-287.
ANTYPE,STATIC
ET,1,SHELL93
R,,0.094
MP,EX,,10.5E6
MP,NUXY,,.3125
CSYS,1
K,1,4.953 ! DEFINE MODEL GEOMETRY
K,2,4.953,,5.175
KGEN,2,1,2,1,,90
A,1,2,4,3
ESIZE,,8
AMESH,1
CSYS,0
NSEL,S,LOC,X,0
DSYM,SYMM,X,0
NSEL,S,LOC,Y,0
DSYM,SYMM,Y,0
NSEL,S,LOC,Z,0
DSYM,SYMM,Z,0
NSEL,ALL
FK,3,FY,-25
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,LOC,Y,4.953 ! SELECT NODE AT LOAD APPLICATION
NSEL,R,LOC,Z,0
NSEL,R,LOC,X,0
PRNSOL,U,COMP ! PRINT DISPLACEMENTS AND VECTOR SUM
TOP_NODE = NODE (4.953,90,0)
*GET,DISP,NODE,TOP_NODE,U,Y

*DIM,LABEL,CHAR,1
*DIM,VALUE,,1,3
LABEL(1) = 'DEF_IN'
*VFILL,VALUE(1,1),DATA,0.1139
*VFILL,VALUE(1,2),DATA,ABS(DISP)
*VFILL,VALUE(1,3),DATA,ABS( DISP /0.1139 )
SAVE,TABLE_1
FINISH
/CLEAR,NOSTART
/PREP7
smrt,off
ANTYPE,STATIC
ET,1,SHELL150
R,,0.094
MP,EX,,10.5E6
MP,NUXY,,.3125
CSYS,1
K,1,4.953 ! DEFINE MODEL GEOMETRY
K,2,4.953,,5.175
KGEN,2,1,2,1,,90
A,1,2,4,3
ESIZE,,8
AMESH,1
CSYS,0
NSEL,S,LOC,X,0
DSYM,SYMM,X,0
NSEL,S,LOC,Y,0
DSYM,SYMM,Y,0
NSEL,S,LOC,Z,0
DSYM,SYMM,Z,0
NSEL,ALL
FK,3,FY,-25
FINISH
/SOLU
SOLVE
FINISH
/POST1
SET,1
NSEL,S,LOC,Y,4.953 ! SELECT NODE AT LOAD APPLICATION
NSEL,R,LOC,Z,0
NSEL,R,LOC,X,0
PRNSOL,U,COMP ! PRINT DISPLACEMENTS AND VECTOR SUM
TOP_NODE = NODE (4.953,90,0)
*GET,DISP,NODE,TOP_NODE,U,Y
*DIM,LABEL,CHAR,1
*DIM,VALUE,,1,3
LABEL(1) = 'DEF_in'
*VFILL,VALUE(1,1),DATA,0.1139
*VFILL,VALUE(1,2),DATA,ABS(DISP)
*VFILL,VALUE(1,3),DATA,ABS( DISP /0.1139 )
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm6,vrt
/COM,------------------- VM6 RESULTS COMPARISON ---------------------
/COM,
/COM,SHELL93 | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A10,' ',F10.4,' ',F10.4,' ',1F10.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,SHELL150
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A10,' ',F10.4,' ',F10.4,' ',1F10.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
/DEL,TABLE_1
/DEL,TABLE_2
FINISH
*LIST,vm6,vrt


VM7 (Plastic Compression of a Pipe Assembly) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM7
/PREP7
/TITLE, VM7, PLASTIC COMPRESSION OF A PIPE ASSEMBLY
C*** MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 180, EX. 5.1
C*** USING PIPE20, SOLID45 AND SHELL43 ELEMENTS
ANTYPE,STATIC
ET,1,PIPE20
ET,2,SOLID45
ET,3,SHELL43
R,1,4.9563384,0.5 ! OUTSIDE DIA. AND WALL THICKNESS FOR INSIDE TUBE (PIPE20)
R,2,8.139437,0.5 ! OUTSIDE DIA. AND WALL THICKNESS FOR OUTSIDE TUBE
R,3,0.5 ! THICKNESS (SHELL43)
MP,EX,1,26.875E6 ! STEEL
MP,NUXY,1,0.3
MP,EX,2,11E6 ! ALUMINUM
MP,NUXY,2,0.3
TB,BKIN,1,1 ! DEFINE NON-LINEAR MATERIAL PROPERTY FOR STEEL
TBTEMP,0
TBDATA,1,86000,0
TB,BKIN,2,1 ! DEFINE NON-LINEAR MATERIAL PROPERTY FOR ALUMINUM
TBTEMP,0
TBDATA,1,55000,0
N,1 ! GENERATE NODES AND ELEMENTS FOR PIPE20
N,2,,,10
MAT,1
REAL,1 ! STEEL (INSIDE) TUBE
E,1,2
MAT,2
REAL,2 ! ALUMINUM (OUTSIDE) TUBE
E,1,2
CSYS,1
N,101,1.9781692 ! GENERATE NODES AND ELEMENTS FOR SOLID45
N,102,2.4781692
N,103,3.5697185
N,104,4.0697185
N,105,1.9781692,,10
N,106,2.4781692,,10
N,107,3.5697185,,10
N,108,4.0697185,,10
NGEN,2,10,101,108,,,6 ! GENERATE 2ND SET OF NODES TO FORM A 6 DEGREE SLICE
NROTAT,101,118,1
TYPE,2
MAT,1 ! INSIDE (STEEL) TUBE
E,101,102,112,111,105,106,116,115
MAT,2 ! OUTSIDE (ALUMINUM) TUBE
E,103,104,114,113,107,108,118,117
N,201,2.2281692 ! GENERATE NODES AND ELEMENTS FOR SHELL43
N,203,2.2281692,,10
N,202,3.8197185
N,204,3.8197185,,10
NGEN,2,4,201,204,,,6 ! GENERATE NODES TO FORM A 6 DEGREE SLICE
TYPE,3
REAL,3
MAT,1 ! INSIDE (STEEL) TUBE
E,203,201,205,207
MAT,2 ! OUTSIDE (ALUMINUM) TUBE
E,204,202,206,208
C*** APPLY CONSTRAINTS TO PIPE20 MODEL
D,1,ALL ! FIX ALL DOFS FOR BOTTOM END OF PIPE20
D,2,UX,,,,,UY,ROTX,ROTY,ROTZ ! ALLOW ONLY UZ DOF AT TOP END OF PIPE20 MODEL
C*** APPLY CONSTRAINTS TO SOLID45 AND SHELL43 MODELS
CP,1,UX,101,111,105,115 ! COUPLE NODES AT BOUNDARY IN RADIAL DIR FOR SOLID45
CPSGEN,4,,1
CP,5,UX,201,205,203,20 ! COUPLE NODES AT BOUNDARY IN RADIAL DIR FOR SHELL43
CPSGEN,2,,5
CP,7,ROTY,201,205 ! COUPLE NODES AT BOUNDARY IN ROTY DIR FOR SHELL43
CPSGEN,4,,7
NSEL,S,NODE,,101,212 ! SELECT ONLY NODES IN SOLID45 AND SHELL43 MODELS
NSEL,R,LOC,Y,0 ! SELECT NODES AT THETA = 0 FROM THE SELECTED SET
DSYM,SYMM,Y,1 ! APPLY SYMMETRY BOUNDARY CONDITIONS
NSEL,S,NODE,,101,212 ! SELECT ONLY NODES IN SOLID45 AND SHELL43 MODELS
NSEL,R,LOC,Y,6 ! SELECT NODES AT THETA = 6 FROM THE SELECTED SET
DSYM,SYMM,Y,1 ! APPLY SYMMETRY BOUNDARY CONDITIONS
NSEL,ALL
NSEL,R,LOC,Z,0 ! SELECT ONLY NODES AT Z = 0
D,ALL,UZ,0 ! CONSTRAIN BOTTOM NODES IN Z DIRECTION
NSEL,ALL
FINISH
/SOLU
OUTPR,BASIC,LAST ! PRINT BASIC SOLUTION AT END OF LOAD STEP
C*** APPLY DISPLACEMENT LOADS TO ALL MODELS
*CREATE,DISP
NSEL,R,LOC,Z,10 ! SELECT NODES AT Z = 10 TO APPLY DISPLACEMENT
D,ALL,UZ,ARG1
NSEL,ALL
SOLVE
*END
*USE,DISP,-.032
*USE,DISP,-.05
*USE,DISP,-.1
FINISH
/POST1
C*** CREATE MACRO TO GET RESULTS FOR EACH MODEL
*CREATE,GETLOAD
NSEL,S,NODE,,1,2 ! SELECT NODES IN PIPE20 MODEL
NSEL,R,LOC,Z,0
FSUM ! FZ IS TOTAL LOAD FOR PIPE20 MODEL
*GET,LOAD_20,FSUM,,ITEM,FZ
NSEL,S,NODE,,101,118 ! SELECT NODES IN SOLID45 MODEL
NSEL,R,LOC,Z,0
FSUM
*GET,ZFRC,FSUM,0,ITEM,FZ
LOAD=ZFRC*60 ! MULTIPLY BY 60 FOR FULL 360 DEGREE RESULTS
*STATUS,LOAD
LOAD_45 = LOAD
NSEL,S,NODE,,201,212 ! SELECT NODES IN SHELL43 MODEL
NSEL,R,LOC,Z,0
FSUM
*GET,ZFRC,FSUM,0,ITEM,FZ
LOAD=ZFRC*60 ! MULTIPLY BY 60 FOR FULL 360 DEGREE RESULTS
*STATUS,LOAD
LOAD_43 = LOAD
*VFILL,VALUE_20(1,1),DATA,1024400,1262000,1262000
*VFILL,VALUE_20(I,2),DATA,ABS(LOAD_20)
*VFILL,VALUE_20(I,3),DATA,ABS(LOAD_20)/(VALUE_20(I,1))
*VFILL,VALUE_45(1,1),DATA,1024400,1262000,1262000
*VFILL,VALUE_45(J,2),DATA,ABS(LOAD_45)
*VFILL,VALUE_45(J,3),DATA,ABS(LOAD_45)/(VALUE_45(J,1))
*VFILL,VALUE_43(1,1),DATA,1024400,1262000,1262000
*VFILL,VALUE_43(K,2),DATA,ABS(LOAD_43)
*VFILL,VALUE_43(K,3),DATA,ABS(LOAD_43)/(VALUE_43(K,1))

*END
C*** GET TOTAL LOAD FOR DISPLACEMENT = 0.032
C*** ---------------------------------------
SET,1,1
I = 1
J = 1
K = 1
*DIM,LABEL,CHAR,3,2
*DIM,VALUE_20,,3,3
*DIM,VALUE_45,,3,3
*DIM,VALUE_43,,3,3
*USE,GETLOAD
C*** GET TOTAL LOAD FOR DISPLACEMENT = 0.05
C*** --------------------------------------
SET,2,1
I = I + 1
J = J + 1
K = K + 1
*USE,GETLOAD
C*** GET TOTAL LOAD FOR DISPLACEMENT = 0.1
C*** -------------------------------------
SET,3,1
I = I +1
J = J + 1
K = K + 1
*USE,GETLOAD

LABEL(1,1) = 'LOAD, lb','LOAD, lb','LOAD, lb'
LABEL(1,2) = ' UX=.032',' UX=0.05',' UX=0.10'
/COM
/OUT,vm7,vrt
/COM,------------------- VM7 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS FOR PIPE20:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_20(1,1),VALUE_20(1,2),VALUE_20(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,
/COM,RESULTS FOR SOLID45:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_45(1,1),VALUE_45(1,2),VALUE_45(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,
/COM,RESULTS FOR SOLID43:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_43(1,1),VALUE_43(1,2),VALUE_43(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)

/COM,-----------------------------------------------------------------
/OUT

FINISH
*LIST,vm7,vrt


VM8 (Parametric Calculation of Point-to-Point Distances) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM8
*CREATE,MAC
LENGTH ! LABEL FOR THIS BLOCK IN THE USER FILE
!
! THIS BLOCK IN THE USER FILE CALCULATES THE STRAIGHT LINE
! DISTANCE BETWEEN TWO POINTS IN SPACE DEFINED BY EITHER
! KEYPOINTS OR NODES ( CONTROLLED BY ARG1 ). OTHER INPUT
! AND OUTPUT ARGUMENTS ARE DEFINED BELOW.
!
! INPUT- ARG1 == IF ZERO, ARG2 AND ARG3 REPRESENT NODES (DEFAULT)
! == IF NONZERO, ARG2 AND ARG3 REPRESENT KEYPOINTS
! ARG2 == NUMBER OF THE FIRST NODE OR KEYPOINT
! ARG3 == NUMBER OF THE SECOND NODE OR KEYPOINT
!
! OUTPUT- PDIS == EXTERNAL PARAMETER ASSIGNED WITH THE DISTANCE VALUE
!
!
! NOTES: 1. "NORMALLY" THIS BLOCK WOULD ALREADY EXIST IN A LOCALLY
! ATTACHED USER FILE, AND WOULDN'T REQUIRE THE "*CREATE"
! OPERATION TO MAKE IT.
! 2. THE CHARACTER ":" USED IN THE FIRST COLUMN OF AN ANSYS
! INPUT LINE HAS THE EFFECT OF MAKING THE ENTIRE LINE A
! NON-ECHOING COMMENT (USUALLY USED FOR A BRANCHING LABEL).
!
/NOPR ! SUPPRESS PRINTOUT DURING MACRO EXECUTION
*GET,AR10,CSYS ! SAVE CURRENT COORDINATE SYSTEM FOR LATER RESTORATION
CSYS,0 ! CHANGE TO GLOBAL CARTESIAN SYSTEM
*IF,ARG1,EQ,0,THEN
*GET,ARG4,NX,ARG2 ! RETRIEVE COORDINATE LOCATIONS OF BOTH NODES
*GET,ARG5,NY,ARG2
*GET,ARG6,NZ,ARG2
*GET,ARG7,NX,ARG3
*GET,ARG8,NY,ARG3
*GET,ARG9,NZ,ARG3
*ELSE
*GET,ARG4,KX,ARG2 ! RETRIEVE COORDINATE LOCATIONS OF BOTH KEYPOINTS
*GET,ARG5,KY,ARG2
*GET,ARG6,KZ,ARG2
*GET,ARG7,KX,ARG3
*GET,ARG8,KY,ARG3
*GET,ARG9,KZ,ARG3
*ENDIF

! ----- NOW CALCULATE DISTANCE WITH LOCATIONS OBTAINED ABOVE -----
PDIS=((ARG7-ARG4)*(ARG7-ARG4))+((ARG8-ARG5)*(ARG8-ARG5))
PDIS=SQRT(PDIS+((ARG9-ARG6)*(ARG9-ARG6)))
CSYS,AR10 ! RESTORE ORIGINAL COORDINATE SYSTEM
*IF,ARG1,EQ,0,THEN ! BRANCH TO KEYPOINT LOGIC IF APPROPRIATE
/COM LENGTH BETWEEN NODES HAS BEEN DEFINED AS PARAMETER PDIS (FROM USERFILE)
*ELSE
/COM LENGTH BETWEEN KEYPOINTS DEFINED AS PARAMETER PDIS (FROM USERFILE)
*ENDIF
/GOPR ! TURN PRINTOUT BACK ON
*END
/PREP7
/TITLE, VM8, MACRO TO CALCULATE DISTANCES BETWEEN POINTS
C*** ANY BASIC GEOMETRY TEXT
*ULIB,MAC ! ASSIGN MACRO LIBRARY FILE
*ABBR,KLEN,*USE,LENGTH,1 ! ASSIGN ABBREVIATIONS FOR "CALLS" TO USERFILE
*ABBR,NLEN,*USE,LENGTH,0
N,1,1.5,2.5,3.5 ! DEFINE TEST NODE AND KEYPOINT LOCATIONS
N,2,-3.7,4.6,-3
K,3,100,0,30
K,4,-200,25,80
KLEN,4,3 ! USE KEYPOINT DISTANCE PART OF MACRO
LEN1=PDIS
KDIS = LEN1
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM (SHOULDN'T AFFECT CALCULATION)
NLEN,1,2 ! USE NODE DISTANCE PART OF MACRO
LEN2=PDIS
NDIS = LEN2
*STATUS

*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'N1-N2 DI','K3-K4 DI'
LABEL(1,2) = 'STANCE','STANCE'
*VFILL,VALUE(1,1),DATA,8.5849,305.16
*VFILL,VALUE(1,2),DATA,LEN2,LEN1
*VFILL,VALUE(1,3),DATA,ABS(LEN2 / 8.5849 ) , ABS( LEN1 / 305.16 )
/COM
/OUT,vm8,vrt
/COM,------------------- VM8 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.2,' ',1F5.3)
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vm8,vrt


VM9 (Large Lateral Deflection of Unequal Stiffness Springs) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM9
/PREP7
/TITLE, VM9, LARGE LATERAL DEFLECTION OF UNEQUAL STIFFNESS SPRINGS
/COM, REF: G.N. VANDERPLAATS, "NUMERICAL OPTIMIZATION TECHNIQUES FOR
/COM, ENGINEERING DESIGN", PP 72-73, MCGRAW-HILL, 1984
ET,1,COMBIN14,,,2 ! UX AND UY DOF ELEMENT
ET,3,COMBIN40,,,,,,2 ! ALL MASS IS AT NODE J, UX DOF ELEMENT
ET,4,COMBIN40,,,2,,,2 ! ALL MASS IS AT NODE J, UY DOF ELEMENT
R,1,1 ! SPRING STIFFNESS = 1
R,2,8 ! SPRING STIFFNESS = 8
/COM USE COMBIN40 MASS, K, AND DAMPING C, TO APPROX. CRITICAL DAMPING
R,3,,1.41,1 ! C = 1.41, M = 1
R,4,,2,1 ! C = 2, M = 1
N,1
N,2,,10
N,3,,20
N,4,-1,10
N,5,,9
LOCAL,11,0,0,0,0,45
NROTAT,2 ! ROTATE NODE SO LOAD CAN BE DIRECTLY APPLIED
E,1,2 ! ELEMENT 1 IS SPRING ELEMENT WITH STIFFNESS 1
REAL,2
E,2,3 ! ELEMENT 2 IS SPRING ELEMENT WITH STIFFNESS 8
TYPE,3
REAL,3
E,4,2 ! ELEMENT 3 IS COMBINATION ELEMENT WITH C = 1.41
TYPE,4
REAL,4
E,5,2 ! ELEMENT 4 IS COMBINATION ELEMENT WITH C = 2
NSEL,U,NODE,,2
D,ALL,ALL
NSEL,ALL
FINISH
/SOLU
ANTYPE,TRANS ! FULL TRANSIENT DYNAMIC ANALYSIS
NLGEOM,ON ! LARGE DEFLECTION
KBC,1 ! STEP BOUNDARY CONDITION
F,2,FX,7.071068 ! FORCE IS IN ROTATED NODAL COORDINATE SYSTEM
AUTOTS,ON
NSUBST,20
OUTPR,,20
OUTPR,VENG,20
TIME,15 ! ARBITRARY TIME FOR SLOW DYNAMICS
SOLVE
FINISH
/POST1
SET,,,,,15 ! USE ITERATION WHEN TIME = 15
ETABLE,SENE,SENE ! STORE STRAIN ENERGY
SSUM ! SUM ALL ACTIVE ENTRIES IN ELEMENT STRESS TABLE
*GET,ST_EN,SSUM,,ITEM,SENE
PRNSOL,U,COMP ! PRINT DISPLACEMENTS IN GLOBAL COORDINATE SYSTEM
*GET,DEF_X,NODE,2,U,X
*GET,DEF_Y,NODE,2,U,Y
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'STRAIN E','DEF_X (C','DEF_Y (C'
LABEL(1,2) = ', N-cm ','m) ','m) '
*VFILL,VALUE(1,1),DATA,24.01,8.631,4.533
*VFILL,VALUE(1,2),DATA,ST_EN ,DEF_X,DEF_Y
*VFILL,VALUE(1,3),DATA,ABS(ST_EN/24.01), ABS(8.631/DEF_X), ABS(DEF_Y/4.533 )
/COM
/OUT,vm9,vrt
/COM,------------------- VM9 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------------

/OUT
FINISH
*LIST,vm9,vrt


VM10 (Bending of a Tee-Shaped Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM10
/PREP7
MP,PRXY,,0.3
/TITLE, VM10, BENDING OF A TEE SHAPED BEAM
C*** MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 294, EX. 7.2
ANTYPE,STATIC
ET,1,BEAM54
R,1,60,2000,14,6 !AREA, IZ, DISTANCE TO TOP AND BOT HEIGHT
MP,EX,1,30E6
N,1
N,2,100
E,1,2
D,1,ALL
F,2,MZ,100000
FINISH
/SOLU
NSUBST,1
OUTPR,ALL,1
SOLVE
FINISH
/POST1
ETABLE,STRS_B,LS,3
ETABLE,STRS_T,LS,2
*GET,STRSS_B,ELEM,1,ETAB,STRS_B
*GET,STRSS_T,ELEM,1,ETAB,STRS_T

*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'STRSS,(B','STRSS,(T'
LABEL(1,2) = 'OT) psi ','OP) psi '
*VFILL,VALUE(1,1),DATA,300,-700
*VFILL,VALUE(1,2),DATA,STRSS_B,STRSS_T
*VFILL,VALUE(1,3),DATA,ABS(STRSS_B/300) ,ABS(STRSS_T/700 )
/COM
/OUT,vm10,vrt
/COM,------------------- VM10 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT

FINISH
*LIST,vm10,vrt


VM11 (Residual Stress Problem) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM11
/PREP7
/TITLE, VM11, RESIDUAL STRESS PROBLEM
C*** MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 234, PROB 5.31
ANTYPE,STATIC
ET,1,LINK1
R,1,1
MP,EX,1,30E6
TB,BKIN ! TABLE FOR BILINEAR KINEMATIC HARDENING
TBTEMP,100
TBDATA,1,30000 ! YIELD STRESS
C*** DEFINE MODEL GEOMETRY USING PARAMETRIC EXPRESSIONS
L=100
*AFUN,DEG ! SET ANGULAR FUNCTION ARGUMENTS AND
! RESULTS TO DEGREES
THETA=30
XLOC=L*TAN(THETA)
N,1,-XLOC
N,3,XLOC
FILL
N,4,,-L
E,1,4
E,2,4
E,3,4
OUTPR,,1
D,1,ALL,,,3
F,4,FY,-51961.5 ! APPLY LOAD F1
FINISH
/SOLU
SOLVE
FINISH
/POST1
BOT_NODE = NODE (0,-100,0)
*GET,DEF,NODE,BOT_NODE,U,Y
FINISH
/SOLU
AUTOTS,ON ! TURN ON AUTOMATIC LOAD STEPPING
NSUBST,10
OUTPR,,10
F,4,FY,-81961.5 ! APPLY LOAD F2
SOLVE
NSUBST,5
OUTPR,,5
F,4,FY ! REMOVE LOAD F2
SOLVE
FINISH
/POST1
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,2,ETAB,STRS

*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'DEF AT F','STRESS '
LABEL(1,2) = '1 (in) ','(psi) '
*VFILL,VALUE(1,1),DATA,-0.07533,-5650
*VFILL,VALUE(1,2),DATA,DEF,STRSS
*VFILL,VALUE(1,3),DATA,ABS(DEF/0.07533 ) ,ABS(STRSS/5650 )
/COM
/OUT,vm11,vrt
/COM,------------------- VM11 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.5,' ',F11.5,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST,vm11,vrt







VM12 (Combined Bending and Torsion) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM12
/PREP7
/TITLE, VM12, COMBINED BENDING AND TORSION
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 299, PROB. 2
ANTYPE,STATIC
ET,1,PIPE16
R,1,4.67017,2.33508 ! REAL CONSTANTS FOR SOLID CROSS SECTION
MP,EX,1,30E6
MP,NUXY,1,.3
N,1
N,2,,,300
E,1,2
D,1,ALL
F,2,MZ,9000
F,2,FX,-250
FINISH
/SOLU
OUTPR,BASIC,1
SOLVE
FINISH
/POST1
ETABLE,P_STRS,NMISC,86
ETABLE,SHR,NMISC,88
*GET,P_STRSS,ELEM,1,ETAB,P_STRS
*GET,SHEAR,ELEM,1,ETAB,SHR

*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'MAX PRIN','MAX SH S'
LABEL(1,2) = 'STRS psi','TRS psi '
*VFILL,VALUE(1,1),DATA,7527,3777
*VFILL,VALUE(1,2),DATA,P_STRSS,(SHEAR/2)
*VFILL,VALUE(1,3),DATA,ABS(P_STRSS/7527 ) ,ABS((SHEAR/2)/3777 )
/COM
/OUT,vm12,vrt
/COM,------------------- VM12 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST,vm12,vrt



VM13 (Cylindrical Shell Under Pressure) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM13
/PREP7
/TITLE, VM13, CYLINDRICAL SHELL UNDER PRESSURE
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 45, ART. 11
C*** AND UGURAL AND FENSTER, ADV. STRENGTH AND APPL. ELAS., 1981
ANTYPE,STATIC
ET,1,SHELL51
R,1,1
MP,EX,1,30E6
MP,NUXY,1,.3
N,1,60
N,2,60,10
E,1,2
CP,1,UX,1,2 ! COUPLE RADIAL DIRECTION
D,1,UY,,,,,UZ,ROTZ
D,2,ROTZ
F,2,FY,5654866.8 ! CAP FORCE
SFE,1,1,PRES,,500 ! INTERNAL PRESSURE
FINISH
/SOLU
OUTPR,ALL,1
SOLVE
FINISH
/POST1

ETABLE,STRS_Y,NMISC,7
ETABLE,STRS_Z,NMISC,6
*GET,STRSS_Y,ELEM,1,ETAB,STRS_Y
*GET,STRSS_Z,ELEM,1,ETAB,STRS_Z

*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'STRESS,Y ','STRESS,Z'
LABEL(1,2) = ' (psi) ',' (psi) '
*VFILL,VALUE(1,1),DATA,15000,29749
*VFILL,VALUE(1,2),DATA,STRSS_Y,STRSS_Z
*VFILL,VALUE(1,3),DATA,ABS(STRSS_Y/15000 ) ,ABS(STRSS_Z/29749 )
/COM
/OUT,vm13,vrt
/COM,------------------- VM13 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST,vm13,vrt



VM14 (Large Deflection Eccentric Compression of a Slender Column) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM14
/PREP7
/TITLE, VM14, LARGE DEFLECTION ECCENTRIC COMPRESSION OF SLENDER COLUMN
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PG. 263, PROB. 1
ANTYPE,STATIC
NLGEOM,ON ! ACTIVATE LARGE DEFLECTIONS
ET,1,BEAM54
R,1,3.36,1.3,.58,1.68 ! BEAM GEOMETRIC PROPERTIES
RMORE,,,,-.58,,-.58
MP,EX,1,30E6
MP,NUXY,1,0.3
N,1
N,5,,60
FILL
E,1,2
EGEN,4,1,1
D,1,ALL
F,5,FY,-4000
FINISH
/SOLU
CNVTOL,F,,1E-4
CNVTOL,M,,1E-4
OUTPR,,LAST
SOLVE
FINISH
/POST1
END_NODE = NODE (0,120/2,0)
*GET,DEF,NODE,END_NODE,U,X
ETABLE,TENS,NMISC,1
ETABLE,COMP,NMISC,2
*GET,STS_TENS,ELEM,1,ETAB,TENS
*GET,STS_COMP,ELEM,1,ETAB,COMP

*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFLECTI','STRSS_TE','STRSS_CO'
LABEL(1,2) = 'ON (in) ','NS (psi)','MP (psi)'
*VFILL,VALUE(1,1),DATA,.1264,2461,-2451
*VFILL,VALUE(1,2),DATA,ABS(DEF),STS_TENS,STS_COMP
*VFILL,VALUE(1,3),DATA, ABS(DEF/.1264 ),ABS(STS_TENS/2461),ABS(STS_COMP/2451)
/COM
/OUT,vm14,vrt
/COM,------------------- VM14 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST,vm14,vrt


VM15 (Bending of a Circular Plate Using Axisymmetric Shell Elements) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM15
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM15, BENDING OF A CIRCULAR PLATE USING AXISYMMETRIC SHELL ELEMENTS
C*** CASE 1 - STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 96, ART. 19
C*** CASE 2 - STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 103, ART. 21
C*** CASE 3 - STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 97, ART. 19
ANTYPE,STATIC
ET,1,SHELL51
R,1,1
MP,EX,1,30E6
MP,NUXY,1,.3
K,1
K,2,40
K,3,20
L,1,3
L,3,2
LESIZE,1,,,5,20 ! BIAS THE MESH TO ALLOW STRESS RECOVERY NEAR
LESIZE,2,,,5,.05 ! THE CENTERLINE AND EDGE CONSTRAINTS
LMESH,ALL ! MESH LINE SEGMENTS
FINISH
C*** CASE 1 - UNIFORM LOADING - CLAMPED EDGE
/SOLU
OUTPR,,1
DK,1,UX,,,,ROTZ
DK,2,ALL
SFE,ALL,1,PRES,,6 ! PRESSURE LOAD = 6 PSI ON ALL LINE SEGMENTS
SOLVE
C*** CASE 2 - CONCENTRATED CENTER LOADING - CLAMPED EDGE
FK,1,FY,-7539.82
SFE,ALL,1,PRES,,0 ! REMOVE PRESSURE
SOLVE
C*** CASE 3 - UNIFORM LOADING - SIMPLY SUPPORTED EDGE
DKDELE,2,ROTZ ! DELETE CLAMPED BOUNDARY CONDITION CONSTRAINT
FK,1,FY ! REMOVE CENTERLINE POINT LOAD
SFE,ALL,1,PRES,,1.5
SOLVE
FINISH
/POST1
/DSCALE,1,35 ! EXAGGERATE DISPLACEMENT SCALING FOR CLARITY
/WINDOW,1,-1,1,-1,-.333
SET,1,1
PLDISP,1
/WINDOW,1,OFF ! TURN-OFF WINDOW 1
/WINDOW,2,-1,1,-.333,.333,1
/NOERASE ! DON'T ERASE EXISTING DISPLAYS
MID_NODE = NODE ( 0,0,0 )
*GET,DEF_C1,NODE,MID_NODE,U,Y
ETABLE,STRS,LS,9
*GET,STRSS_C1,ELEM,10,ETAB,STRS
SET,2,1
PLDISP
/WINDOW,2,OFF ! TURN OFF WINDOW 2
/WINDOW,3,-1,1,.333,1,1
*GET,DEF_C2,NODE,MID_NODE,U,Y
ETABLE,STRS,LS,9
*GET,STRSS_C2,ELEM,10,ETAB,STRS
SET,3,1
PLDISP
*GET,DEF_C3,NODE,MID_NODE,U,Y
ETABLE,STRS,LS,9
*GET,STRSS_C3,ELEM,1,ETAB,STRS

*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C1,,2,3
*DIM,VALUE_C2,,2,3
*DIM,VALUE_C3,,2,3
LABEL(1,1) = 'DEFLECTI','MAX STRS'
LABEL(1,2) = 'ON (in) ','S (psi) '
*VFILL,VALUE_C1(1,1),DATA,-.08736,7200
*VFILL,VALUE_C1(1,2),DATA,DEF_C1,ABS(STRSS_C1)
*VFILL,VALUE_C1(1,3),DATA,ABS(DEF_C1/.08736 ),ABS(STRSS_C1/7200 )
*VFILL,VALUE_C2(1,1),DATA,-.08736,3600
*VFILL,VALUE_C2(1,2),DATA,DEF_C2,ABS(STRSS_C2)
*VFILL,VALUE_C2(1,3),DATA,ABS(DEF_C2/.08736 ),ABS(STRSS_C2/3600 )
*VFILL,VALUE_C3(1,1),DATA,-.08904,2970
*VFILL,VALUE_C3(1,2),DATA,DEF_C3,ABS(STRSS_C3)
*VFILL,VALUE_C3(1,3),DATA,ABS(DEF_C3/.08904 ),ABS(STRSS_C3/2970 )
/COM
/OUT,vm15,vrt
/COM,------------------- VM15 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS FOR CASE 1:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,
/COM,RESULTS FOR CASE 2:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,
/COM,RESULTS FOR CASE 3:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C3(1,1),VALUE_C3(1,2),VALUE_C3(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST,vm15,vrt






VM16 (Bending of a Solid Beam (Plane Elements)) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM16
/PREP7
/TITLE, VM16, BENDING OF A SOLID BEAM (PLANE ELEMENTS)
C*** FORMULAS FOR STRESS AND STRAIN, ROARK, 4TH ED.,PG. 104,106
C*** USING PLANE42 ELEMENTS
ANTYPE,STATIC
ET,1,PLANE42,,,,,,2 ! PLANE42 WITH SURFACE PRINTOUT FOR FACES 1 AND 3
MP,EX,1,30E6
MP,NUXY,1,0.0
N,1
N,6,10
FILL
NGEN,2,10,1,6,1,,2
E,1,2,12,11
EGEN,5,1,1
/COM, VM16, CASE 1 - END MOMENT, ROARK, PAGE 106, NO. 9
D,1,ALL,,,11,10
F,6,FX,1000
F,16,FX,-1000
OUTPR,NSOL,1
OUTPR,ESOL,1
FINISH
/SOLU
SOLVE
/POST1
*GET,U1,NODE,16,U,Y
FINI
/SOLU
/COM, VM16, CASE 2 - END LOAD, ROARK, PAGE 104, NO. 1
F,6,FX,,,16,10
F,6,FY,150,,16,10
SOLVE
FINISH
/POST1
*GET,U2,NODE,16,U,Y
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
*DIM,VALUE2,,1,3
LABEL(1,1) = 'DEFL'
LABEL(1,2) = ' (in) '
*VFILL,VALUE(1,1),DATA,.00500
*VFILL,VALUE(1,2),DATA,U1
*VFILL,VALUE(1,3),DATA,ABS(U1/.005)
SAVE,TABLE_1
*VFILL,VALUE2(1,1),DATA,.00500
*VFILL,VALUE2(1,2),DATA,U2
*VFILL,VALUE2(1,3),DATA,ABS(U2/.005)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm16,vrt
/COM,------------------- VM16 RESULTS COMPARISON ---------------------
/COM,
/COM,CASE 1: | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,CASE 2:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,-----------------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM16 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------------
/OUT
FINISH
/DELETE,TABLE_1
/DELETE,TABLE_2
FINISH
*LIST,vm16,vrt


VM17 (Snap-Through Buckling of a Hinged Shell) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM17
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
smrt,off
/TITLE, VM17, SNAP-THROUGH BUCKLING OF A HINGED SHELL
:COM CHANG, C.C.,"PERIODICALLY RESTARTED QUASI-NEWTON UPDATES IN
:COM IN CONSTANT ARC-LENGTH METHOD", COMPUTERS AND STRUCTURES,
:COM VOL. 41, NO. 5, PP. 963-972, 1991.
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,SHELL63,,1
R,1,6.350 ! SHELL THICKNESS
MP,EX,1,3102.75
MP,NUXY,1,0.3
:COM CREATE FINITE ELEMENT MODEL
R1 = 2540 ! SHELL MID-SURFACE RADIUS
L = 254 ! HALF THE LENGTH
PI = 4*ATAN(1) ! VALUE OF PI COMPUTED
THETA = 0.1*180/PI ! 0.1 RADIANS CONVERTED TO DEGREES
CSYS,1 ! CYLINDRICAL CO-ORDINATE SYSTEM
N,1,R1,90 ! NODES 1 AND 2 ARE CREATED AT POINTS
N,2,R1,90,L ! A AND B RESPECTIVELY.
K,1,R1,90
K,2,R1,(90-THETA)
K,3,R1,90,L
K,4,R1,(90-THETA),L
ESIZE,,2 ! TWO DIVISION ALONG THE REGION BOUNDARY
A,1,3,4,2
AMESH,1
NUMMRG,NODE
:COM APPLY BOUNDARY CONDITIONS
NSEL,S,LOC,Z,0
DSYM,SYMM,Z
NSEL,S,LOC,Y,90
DSYM,SYMM,X
NSEL,S,LOC,Y,(90-THETA)
D,ALL,UX,,,,,UY,UZ
NSEL,ALL
FINISH
:COM SOLUTION PHASE
:COM SINCE THE SOLUTION OUTPUT IS SUBSTANTIAL IT IS DIVERTED TO A
:COM SCRATCH FILE
/OUTPUT,SCRATCH
/SOLUTION
NLGEOM,ON ! LARGE DEFLECTION TURNED ON
OUTRES,,1 ! WRITE SOLUTION ON RESULTS FILE FOR EVERY SUBSTEP
F,1,FY,-250 ! 1/4 TH OF THE TOTAL LOAD APPLIED DUE TO SYMMETRY
NSUBST,30 ! BEGIN WITH 30 SUBSTEPS
ARCLEN,ON,4 ! ARC-LENGTH SOLUTION TECHNIQUE TURNED ON WITH
! MAX. ARC-LENGTH KEPT AT 4 TO COMPUTE AND STORE
! SUFFICIENT INTERMEDIATE SOLUTION INFORMATION
SOLVE
FINISH
/OUTPUT
:COM POSTPROCESSING PHASE
/POST26
NSOL,2,1,U,Y ! STORE UY DISPLACEMENT OF NODE 1
NSOL,3,2,U,Y ! STORE UY DISPLACEMENT OF NODE 2
PROD,4,1,,,LOAD,,,4*250 ! TOTAL LOAD IS 4*250 DUE TO QUARTER SYMMETRY
PROD,5,2,,,,,,-1 ! CHANGE SIGNS OF THE DISPLACEMENT VALUES
PROD,6,3,,,,,,-1
*GET,UY1,VARI,2,EXTREM,VMIN
*GET,UY2,VARI,3,EXTREM,VMIN
PRVAR,2,3,4 ! PRINT STORED INFORMATION
/AXLAB,X, DEFLECTION (MM)
/AXLAB,Y, TOTAL LOAD (N)
/GRID,1
/XRANGE,0,35
/YRANGE,-500,1050
XVAR,5
PLVAR,4 ! PLOT LOAD WITH RESPECT TO -UY OF NODE 1
/NOERASE
XVAR,6
PLVAR,4 ! PLOT LOAD WITH RESPECT TO -UY OF NODE 2
/ERASE
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'UY @A ','UY @B '
LABEL(1,2) = 'mm ','mm '
*VFILL,VALUE(1,1),DATA,-30,-26
*VFILL,VALUE(1,2),DATA,UY1,UY2
*VFILL,VALUE(1,3),DATA,ABS(UY1/30) ,ABS(UY2/26 )
/COM
/OUT,vm17,vrt
/COM,------------------- VM17 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,-------------------------------------------------------------
/OUT
FINISH
*LIST,vm17,vrt
/DELETE,SCRATCH




VM18 (Out-of-Plane Bending of a Curved Bar) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM18
/PREP7
/TITLE, VM18, OUT-OF-PLANE BENDING OF A CURVED BAR
! STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 412, EQN. 241
ANTYPE,STATIC
ET,1,PIPE18,,,,,,2 ! KEYOPT(6)=2 PRINTS MEMBER FORCES
MP,EX,1,30E6
MP,NUXY,1,.3
R,1,2,1,100 ! OD = 2, WALL THICKNESS = 1, RADIUS = 100
N,1,100 ! DEFINE NODES
N,2,,100
N,10
E,1,2,10 ! DEFINE ELEMENT
D,1,ALL ! BOUNDARY CONDITIONS + LOAD
F,2,FZ,-50
FINISH
/SOLU
OUTPR,BASIC,1
SOLVE
FINISH
/POST1
*GET,DEF,NODE,2,U,Z
ETABLE,STRS_BEN,LS,1
ETABLE,STRS_SHR,LS,4
*GET,STRSS_B,ELEM,1,ETAB,STRS_BEN
*GET,STRSS_T,ELEM,1,ETAB,STRS_SHR

*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFLECTI','STRSS BE','STRSS SH'
LABEL(1,2) = 'ON (in) ','ND psi','EAR psi'
*VFILL,VALUE(1,1),DATA,-2.648,6366,-3183
*VFILL,VALUE(1,2),DATA,DEF,ABS(STRSS_B) ,STRSS_T
*VFILL,VALUE(1,3),DATA,ABS(DEF/2.648) ,ABS(STRSS_B /6366 ),ABS(STRSS_T /3183 )
/COM
/OUT,vm18,vrt
/COM,------------------- VM18 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT

FINISH
*LIST,vm18,vrt






VM19 (Random Vibration Analysis of a Deep Simply-Supported Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM19
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM19, RANDOM VIBRATION ANALYSIS OF A DEEP SIMPLY-SUPPORTED BEAM
/COM REFERENCE: NAFEMS FORCED VIBRATION BENCHMARKS TEST 5R
ET,1,BEAM4 ! DEFINE ELEMENT TYPE
MP,EX,1,200E9 ! DEFINE MATERIAL PROPERTIES
MP,NUXY,1,0.3
MP,ALPX,1,0.1E-5
MP,DENS,1,8000
R,1,4,1.333,1.333,2,2,0 ! DEFINE REAL CONSTANTS
RMORE,0,2.2496,1.177,1.177
N,1,0
N,11,10
FILL
E,1,2
EGEN,10,1,1
FINISH

/SOLU
ANTYPE,MODAL ! DEFINE ANALYSIS TYPE
MXPAND,9,,,YES ! EXPAND 9 MODES, CALC. STRESS VALUES
MODOPT,REDUC
D,1,UX,0,0,1,1,UY,UZ,ROTX ! APPLY CONSTRAINTS
D,11,UY,0,0,11,1,UZ
M,2,UY,10,1
SOLVE
*GET,FREQ,MODE,1,FREQ
FINISH
/COPY,,tri,,mode,tri

/SOLU
ANTYPE,SPECTR ! PREFORM SPECTRUM PSD ANALYSIS
SPOPT,PSD,9,ON ! CALC. STRESS RESPONSE FOR FIRST 9 MODES
PSDUNIT,1,FORCE
DMPRAT,0.02
F,1,FY,-0.5E6 ! SCALE LOADS
F,11,FY,-0.5E6
F,2,FY,-1E6,,10,1
PSDFRQ,1,1,0.1,70.
PSDVAL,1,1,1 ! IN N**2/HZ
PFACT,1,NODE
PSDRES,DISP,REL
PSDCOM
SOLVE
FINISH

/POST26
STORE,PSD,10
NSOL,2,6,U,Y
RPSD,8,2
PRTIME,42.640.5,42.641.5
PRVAR,8
*GET,P1,VARI,8,RTIME,42.64
PM=P1*1000000
FINISH

/POST26
STORE,PSD,10
ESOL,3,5,6,LS,7
RPSD,9,3
PRTIME,42.640.5,42.641.5
PRVAR,9
*GET,P2,VARI,9,RTIME,42.64
PM2=P2/(1E12)
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'FREQ1','PEAK d','PSD(N/mm'
LABEL(1,2) = ' (Hz)',' mm^2/Hz','^2)^2/Hz'
*VFILL,VALUE(1,1),DATA,42.65,180.9,58515.6
*VFILL,VALUE(1,2),DATA,FREQ,PM,PM2
*VFILL,VALUE(1,3),DATA,ABS(FREQ/42.65) ,ABS(PM/180.9 ),ABS(PM2/58515.6 )
FINISH
/COM
/OUT,vm19.vrt
/COM,------------------- VM19 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.2)
/COM,-----------------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM19 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------------
/OUT
*LIST,vm19.vrt



VM20 (Cylindrical Membrane Under Pressure) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM20
/PREP7
/TITLE, VM20, CYLINDRICAL MEMBRANE UNDER PRESSURE
C*** STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 121, ART. 25
ANTYPE,STATIC
ET,1,SHELL41
MP,EX,1,30E6
MP,NUXY,1,0.3
R,1,1 ! THICKNESS = 1
CSYS,1 ! CYLINDRICAL C.S.
N,1,60 ! DEFINE NODES
N,2,60,,10
NGEN,2,2,1,2,1,,10
NROTAT,ALL ! ROTATE NODAL C.S. TO CYLINDRICAL C.S.
E,1,2,4,3 ! DEFINE ELEMENT
CP,1,UX,1,2,3,4 ! COUPLE RADIAL DISPLACEMENTS
CP,2,UZ,2,4 ! COUPLE UZ DISPLACEMENTS
D,1,UZ,,,3,2
D,ALL,UY
SFE,1,4,PRES,,-15000 ! AXIAL TRACTION
SFE,1,1,PRES,,-500 ! INTERNAL PRESSURE
FINISH
/SOLU
OUTPR,,1
SOLVE
FINISH
/POST1
*GET,STRS_HOP,NODE,1,S,2
*GET,STRS_AX,NODE,1,S,1
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'AXIAL ST','HOOP STR'
LABEL(1,2) = 'RSS psi ','SS psi '
*VFILL,VALUE(1,1),DATA,15000,29749
*VFILL,VALUE(1,2),DATA,STRS_HOP,STRS_AX
*VFILL,VALUE(1,3),DATA,ABS(STRS_HOP/15000),ABS(STRS_AX/29749)
/COM
/OUT,vm20,vrt
/COM,------------------- VM20 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST,vm20,vrt


VM21 (Tie Rod with Lateral Loading) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM21
/PREP7
MP,PRXY,,0.3
/TITLE, VM21, TIE ROD WITH LATERAL LOADING, NO STREES STIFFENING
C*** STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 42, ART. 6
ANTYPE,STATIC
ET,1,BEAM4,,,,,,1
R,1,6.25,3.2552,3.2552,2.5,2.5 ! AREA=6.25, IZZ=IYY=3.2552, B=H=2.5
MP,EX,1,30E6
N,1 ! DEFINE NODES
N,5,100
FILL
E,1,2 ! DEFINE ELEMENTS
EGEN,4,1,1
D,ALL,UY,,,,,ROTX,ROTZ ! BOUNDARY CONDITIONS AND LOADINGS
D,1,UZ
NSEL,S,,,5
DSYM,SYMM,X ! DEFINE SYMMETRY BOUNDARY
NSEL,ALL
F,1,FX,-21972.6 ! APPLY LOADS
SFBEAM,ALL,1,PRES,1.79253
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,,,1,5,4
PRNSOL,U,Z
PRNSOL,ROT,Y
NSEL,ALL
PRRSOL
RGHT_END = NODE (200,0,0)
LFT_END = NODE (0,0,0)
*GET,UZ_MX_C2,NODE,RGHT_END,U,Z
*GET,SLOPE_C2,NODE,LFT_END,ROT,Y
FINISH
/POST26
RFORCE,2,RGHT_END,M,Y
STORE
*GET,M_MX_C2,VARI,2,EXTREM,VMAX
FINISH
/PREP7
/TITLE, VM21, TIE ROD WITH LATERAL LOADING, STRESS STIFFENING PRESENT
SSTIF,ON ! STRESS STIFFENING ACTIVATED
NSUBST,5
AUTOTS,ON ! AUTO TIME STEPPING ACTIVATED
FINISH
/SOLU
CNVTOL,F,,.0001,,1 ! SMALLER CONVERGENCE TOLERANCE
SOLVE
FINISH
/POST1
NSEL,S,,,1,5,4
PRNSOL,U,Z
PRNSOL,ROT,Y
PRRSOL
*GET,UZ_MX_C1,NODE,RGHT_END,U,Z
*GET,SLOPE_C1,NODE,LFT_END,ROT,Y
FINISH
/POST26
RFORCE,2,RGHT_END,M,Y
STORE
*GET,M_MX_C1,VARI,2,EXTREM,VMAX
*DIM,LABEL,CHAR,3,2
*DIM,VALUE_C1,,3,3
*DIM,VALUE_C2,,3,3
LABEL(1,1) = 'UZ MAX ','SLOPE ','MOMENT M'
LABEL(1,2) = '(in) ','(rad) ','AX in-lb'
*VFILL,VALUE_C1(1,1),DATA,-.19945,.0032352,-4580.1
*VFILL,VALUE_C1(1,2),DATA,UZ_MX_C1,SLOPE_C1,M_MX_C1
*VFILL,VALUE_C1(1,3),DATA,ABS(UZ_MX_C1/.19945),ABS(SLOPE_C1/.0032352), ABS(M_MX_C1/4580.1)
*VFILL,VALUE_C2(1,1),DATA,-.38241,.0061185,-8962.7
*VFILL,VALUE_C2(1,2),DATA,UZ_MX_C2,SLOPE_C2,M_MX_C2
*VFILL,VALUE_C2(1,3),DATA,ABS(UZ_MX_C1/.19945),ABS(SLOPE_C1/.0032352), ABS(M_MX_C1/4580.1)
/COM
/OUT,vm21,vrt
/COM,------------------- VM21 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS FOR F<>0 (STIFFENED):
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F17.7,' ',F17.7,' ',1F5.3)
/COM,
/COM,RESULTS FOR F=0 (UNSTIFFENED):
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,' ',F17.7,' ',F17.7,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST,vm21,vrt






VM22 (Small Deflection of a Belleville Spring) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM22
/PREP7
/TITLE, VM22, SMALL DEFLECTION OF A BELLEVILLE SPRING
C*** STR. OF MATL., TIMOSHENKO, PART 2, 3RD ED., PAGE 143, PROB. 2
ANTYPE,STATIC
ET,1,SHELL51
R,1,.2 ! THICKNESS = .2
MP,EX,1,3E7
MP,NUXY,1,0
N,1,1,(.5*TAN(.12217)) ! DEFINE NODES
N,2,1.5
E,1,2 ! DEFINE ELEMENT
D,2,UY ! BOUNDARY CONDITIONS AND LOADS
D,2,UZ
F,1,FY,-628.31853
FINISH
/SOLU
SOLVE
FINISH
/POST1
SET,1,1
NSEL,S,NODE,,1
PRNSOL,U,COMP ! DISPLACEMENTS AT NODE 1
*GET,DEF,NODE,1,U,Y
*DIM,LABEL,CHAR,1,1
*DIM,VALUE,,1,3
LABEL(1,1) = 'UY (in)'
*VFILL,VALUE(1,1),DATA,-.0028205
*VFILL,VALUE(1,2),DATA,DEF
*VFILL,VALUE(1,3),DATA,ABS( DEF /.0028205)
/COM
/OUT,vm22,vrt
/COM,------------------- VM22 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F10.7,' ',F10.7,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT

FINISH
*LIST,vm22,vrt



VM23 (Thermal-structural Contact of Two Bodies) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM23
/PREP7
MP,PRXY,,0.3
/TITLE, VM23, THERMAL-STRUCTURAL CONTACT OF TWO BODIES
ET,1,PLANE13,4,,2 ! COUPLE-FIELD ELEMENT TYPE
ET,2,CONTAC48,1,1 ! CONTACT ELEMENT TYPE
MP,EX,1,10E6 ! YOUNG'S MODULUS
MP,KXX,1,250 ! CONDUCTIVITY
MP,ALPX,1,12E-6 ! THERMAL EXPANSION COEFFICIENT
R,2,1000,100,0.005,,0.01,100
! SET UP FINITE ELEMENT MODEL
N,1
N,2,0.4
N,3,(0.4+0.0035)
N,4,(0.9+0.0035)
NGEN,2,4,1,4,1,,0.1
E,1,2,6,5 ! PLANE13 ELEMENTS
E,3,4,8,7
NSEL,S,,,2,6,4
CM,NODES1,NODE
NSEL,S,,,3,7,4
CM,NODES2,NODE
NSEL,ALL
TYPE,2
REAL,2
MAT,2
GCGEN,NODES1,NODES2 ! CONTACT ELEMENTS
! APPLY INITIAL BOUNDARY CONDITIONS
D,ALL,AZ
D,1,UY,,,4,1
D,1,UX,,,5,4
D,4,UX,,,8,4
TREF,100
FINISH
/SOLU
NLGEOM,ON ! LARGE DEFLECTION EFFECTS TURNED ON
D,1,TEMP,500,,5,4
D,3,TEMP,100,,4
D,7,TEMP,100,,8
CNVTOL,F,1
CNVTOL,CSG,1
CNVTOL,HEAT,1
SOLVE ! FIRST LOAD STEP
OUTRES,ALL,ALL ! STORE ALL DATA
DDELE,3,TEMP,7,4
D,4,TEMP,850,,8,4
NSUBST,3
SOLVE ! SECOND LOAD STEP
D,4,TEMP,100,,8,4
SOLVE ! THIRD LOAD STEP
FINISH

/POST1
INRES,NSOL,MISC ! RETRIEVE NODAL AND MISCELLANEOUS DATA
SUBSET,2,2 ! READ LOAD STEP 2, SUBSTEP 2 DATA
ETABLE,HEAT-FLO,SMISC,4 ! STORE HEAT FLOWS FOR CONTACT ELEMENTS
ESEL,S,,,3,4
SSUM
*GET,HEAT_C1,SSUM,,ITEM,HEAT-FLO
NSEL,S,,,2,6,4
PRNSOL,TEMP
*GET,TEMP_C1,NODE,2,TEMP
APPEND,2,3 ! APPEND (OVERWRITE IN THIS CASE) BY
! LOAD STEP 2 AND SUBSTEP 3 DATA
ETABLE,REFL
SSUM
*GET,HEAT_C2,SSUM,,ITEM,HEAT-FLO
PRNSOL,TEMP
*GET,TEMP_C2,NODE,2,TEMP
SUBSET,3,3 ! READ LOAD STEP 3, SUBSTEP 3 DATA
ETABLE,REFL
PRETAB
*GET,TEMP_C3,ELEM,4,ETAB,HEAT-FLO
PRNSOL,TEMP

*DIM,LABEL,CHAR,2,2
*DIM,LABEL_C3,CHAR,1,2
*DIM,VALUE_C1,,2,3
*DIM,VALUE_C2,,2,3
*DIM,VALUE_C3,,1,2
LABEL(1,1) = 'TEMP AT ','HEAT FLO'
LABEL(1,2) = 'EA2 (C) ','W (W) '
LABEL_C3(1,1) = 'HEAT FLO'
LABEL_C3(1,2) = 'W (W) '
*VFILL,VALUE_C1(1,1),DATA,539,2439
*VFILL,VALUE_C1(1,2),DATA,TEMP_C1,HEAT_C1
*VFILL,VALUE_C1(1,3),DATA,ABS(TEMP_C1/539 ) ,ABS( HEAT_C1/2439 )
*VFILL,VALUE_C2(1,1),DATA,636.6,8536.6
*VFILL,VALUE_C2(1,2),DATA,TEMP_C2,HEAT_C2
*VFILL,VALUE_C2(1,3),DATA,ABS(TEMP_C2/636.6 ) ,ABS( HEAT_C2/8536.6)
*VFILL,VALUE_C3(1,1),DATA,0
*VFILL,VALUE_C3(1,2),DATA,TEMP_C3
/COM
/OUT,vm23,vrt
/COM,------------------- VM23 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,TEMP AT EB2 = 600 C:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,
/COM,TEMP AT EB2 = 850 C:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,
/COM,TEMP AT EB2 = 100 C:
*VWRITE,LABEL_C3(1,1),LABEL_C3(1,2),VALUE_C3(1,1),VALUE_C3(1,2)
(1X,A8,A8,' ',F10.1,' ',F10.1)
/COM,-----------------------------------------------------------------

/OUT
FINISH
*LIST,vm23,vrt



VM24 (Plastic Hinge in a Rectangular Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM24
/PREP7
/TITLE, VM24, PLASTIC HINGE IN A RECTANGULAR BEAM
C*** STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PG. 349, ART. 64
C*** USING BILINEAR KINEMATIC HARDENING PLASTICITY BEHAVIOR TO DESCRIBE
C*** THE MATERIAL NONLINEARITY
ANTYPE,STATIC
ET,1,BEAM23
R,1,2,(2/3),2 ! AREA = 2, IZZ = 2/3, H = 2
MP,EX,1,30E6
MP,NUXY,1,0.3
TB,BKIN,1,1 ! BILINEAR KINEMATIC HARDENING
TBTEMP,70
TBDATA,1,36000,0 ! YIELD POINT AND ZERO TANGENT MODULUS
N,1 ! DEFINE NODES
N,2,10
E,1,2 ! DEFINE ELEMENT
D,1,ALL ! BOUNDARY CONDITIONS AND LOADS
SAVE ! SAVE DATABASE
FINISH
/SOLU
SOLCONTROL,0
NEQIT,5 ! MAXIMUM 5 EQUILIBRIUM ITERATIONS PER STEP
NCNV,0 ! DO NOT TERMINATE THE ANALYSIS IF THE SOLUTION FAILS
! TO CONVERGE
OUTRES,EPPL,1 ! STORE PLASTIC STRAINS FOR EVERY SUBSTEP
CNVTOL,U ! CONVERGENCE CRITERION BASED UPON DISPLACEMENTS AND
CNVTOL,ROT ! ROTATIONS
*DO,I,1,4
F,2,MZ,(20000+(I*4000)) ! APPLY MOMENT LOAD
SOLVE
*ENDDO
FINISH
/POST26
NSOL,2,2,U,Y,UY2 ! NODE 2 DISPLACEMENT
ESOL,3,1,,LEPPL,1,EPPLAXL ! AXIAL PLASTIC STRAIN
PRVAR,2,3
FINISH
/CLEAR, NOSTART ! CLEAR PREVIOUS DATABASE BEFORE STARTING PART2
/PREP7
C*** USING BILINEAR ISOTROPIC HARDENING PLASTICITY BEHAVIOR TO DESCRIBE
C*** THE MATERIAL NONLINEARITY
RESUME
TBDELE,BKIN,1 ! DELETE NONLINEAR MATERIAL TABLE BKIN
TB,BISO,1,1 ! BILINEAR ISOTROPIC HARDENING
TBTEMP,70
TBDATA,1,36000,0 ! YIELD POINT AND ZERO TANGENT MODULUS
FINISH
/SOLU
SOLCONTROL,0
NEQIT,5 ! MAXIMUM 5 EQUILIBRIUM ITERATIONS PER STEP
NCNV,0 ! DO NOT TERMINATE THE ANALYSIS IF THE SOLUTION FAILS
! TO CONVERGE
OUTRES,EPPL,1 ! STORE PLASTIC STRAINS FOR EVERY SUBSTEP
CNVTOL,U ! CONVERGENCE CRITERION BASED UPON DISPLACEMENTS AND
CNVTOL,ROT ! ROTATIONS
*DO,I,1,4
F,2,MZ,(20000+(I*4000)) ! APPLY MOMENT LOAD
SOLVE
*ENDDO
FINISH
/POST26
NSOL,2,2,U,Y,UY2 ! NODE 2 DISPLACEMENT
ESOL,3,1,,LEPPL,1,EPPLAXL ! AXIAL PLASTIC STRAIN
PRVAR,2,3
/OUT,vm24,vrt
/OUT
FINISH
*LIST,vm24,vrt



VM25 (Stresses in a Long Cylinder) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM25
/PREP7
SMRT,OFF
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM25, STRESSES IN A LONG CYLINDER
C*** STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 213, PROB. 1
C*** INTERNAL PRESSURE
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,PLANE82,,,1,,2,4 ! AXISYMM, PRINT STRESSES ON NONZERO PRESS. FACES
MP,EX,1,30E6 ! MATERIAL PROPERTIES
MP,DENS,1,.00073
MP,NUXY,1,0.3 ! DEFINE KEYPOINTS, LINES, AND AREAS
K,1,4
K,2,8
KGEN,2,1,2,1,,1
L,1,2,7
ESIZE,.5
LESIZE,1,,,14
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USING QUADS
A,3,1,2,4
AMESH,1
SAVE,MODEL ! SAVE MODEL FOR SECOND LOAD CASE
NSEL,S,LOC,Y,0 ! SET UP LONG CYLINDER EFFECT
D,ALL,UY
NSEL,S,LOC,Y,1
CP,1,UY,ALL ! COUPLE AXIAL DISPLACEMENTS AT UNCONSTRAINED Y EDGE
NSEL,ALL
FINISH
/SOLU
NSEL,S,LOC,X,4
SF,,PRES,30000 ! APPLY INTERNAL PRESSURE ON CYLINDER
NSEL,S,LOC,X,8
SF,,PRES,1E-10 ! APPLY DUMMY PRESSURE FOR SURFACE PRINTOUT
NSEL,ALL
OUTPR,,ALL
SOLVE ! LOAD STEP 1 - INTERNAL PRESSURE
FINISH
/POST1
SET,1,1
LFT_NODE = NODE (4,0,0)
MID_NODE = NODE (6,0,0)
RT_NODE = NODE (8,0,0)
PRNSOL,S,COMP ! PRINT NODAL STRESS SOLUTION
PATH,STRESS,2,,48 ! DEFINE PATH WITH NAME = "STRESS"
PPATH,1,LFT_NODE ! DEFINE PATH POINTS BY NODE
PPATH,2,RT_NODE
PLSECT,S,Z,-1 ! DISPLAY SZ STRESSES
PLSECT,S,X,-1 ! DISPLAY SX STRESSES
PRSECT,-1 ! PRINT LINEARIZED STRESSES
*GET,DEF_4,NODE,LFT_NODE,U,X
*GET,RST_4_C1,NODE,LFT_NODE,S,X
*GET,RST_6_C1,NODE,MID_NODE,S,X
*GET,RST_8_C1,NODE,RT_NODE ,S,X
*GET,TST_4_C1,NODE,LFT_NODE,S,Z
*GET,TST_6_C1,NODE,MID_NODE,S,Z
*GET,TST_8_C1,NODE,RT_NODE ,S,Z
*DIM,VALUE_C1,,7,3
*VFILL,VALUE_C1(1,1),DATA,.0078666,-30000,-7778,0,50000,27778,20000
*VFILL,VALUE_C1(1,2),DATA,DEF_4,RST_4_C1,RST_6_C1,RST_8_C1,TST_4_C1,TST_6_C1,TST_8_C1
*VFILL,VALUE_C1(1,3),DATA,ABS(DEF_4/.0078666),ABS(RST_4_C1/30000),ABS(RST_6_C1/7778),0
*VFILL,VALUE_C1(5,3),DATA,ABS(TST_4_C1/50000),ABS(TST_6_C1/27778),ABS(TST_8_C1/20000)
*DIM,LABEL_C1,CHAR,7,2
LABEL_C1(1,1)='DEF (R=4','STRS_R p','STRS_R p','STRS_R p','STRS_T p'
LABEL_C1(6,1)='STRS_T p','STRS_T p'
LABEL_C1(1,2) = ') in ','si (R=4)','si (R=6)','si (R=8)','si (R=4)'
LABEL_C1(6,2) ='si (R=6)','si (R=8)'
SAVE,TABLE_1
FINISH

/SOLU
RESUME,MODEL
C*** ROTATION ABOUT AXIS
NSEL,S,LOC,Y,0 ! PREVENT RIGID BODY MOTION
NSEL,R,LOC,X,4
D,ALL,UY
NSEL,S,LOC,X,4
SF,,PRES,1E-10 ! LEAVE A SMALL PRESSURE TO ALLOW STRESS PRINTOUT
NSEL,ALL
OMEGA,,1000 ! ROTATE CYLINDER WITH ANGULAR VELOCITY OMEGA
OUTPR,,ALL
SOLVE ! LOAD STEP 2 - CENTRIFUGAL LOADING
FINISH
/POST1
LFT_NODE = NODE (4,0,0)
XI_NODE = NODE (5.43,0,0)

*GET,RST_4_C2,NODE,LFT_NODE,S,X
*GET,TST_4_C2,NODE,LFT_NODE,S,Z
*GET,RST_X_C2,NODE,XI_NODE ,S,X
*GET,TST_X_C2,NODE,XI_NODE ,S,Z
*DIM,VALUE_C2,,4,3
*VFILL,VALUE_C2(1,1),DATA,0,40588,4753,29436
*VFILL,VALUE_C2(1,2),DATA,RST_4_C2,TST_4_C2,RST_X_C2,TST_X_C2
*VFILL,VALUE_C2(1,3),DATA,0,ABS(TST_4_C2/40588 ),ABS(RST_X_C2/4753 ),ABS(TST_X_C2/29436)
*DIM,LABEL_C2,CHAR,4,2
LABEL_C2(1,1) ='STRS_R p','STRS_T p','STRS_R p','STRS_T p'
LABEL_C2(1,2) ='si (R=4)','si (R=4)','si R=5.4','si R=5.4'
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm25,vrt
/COM,------------------- VM25 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS FOR P = 30,000 PSI:
/COM,
*VWRITE,LABEL_C1(1,1),LABEL_C1(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F14.7,' ',F14.7,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS FOR w = 1000 RAD/SEC
*VWRITE,LABEL_C2(1,1),LABEL_C2(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,' ',F14.7,' ',F14.7,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST,vm25,vrt



VM26 (Large Deflection of a Cantilever) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,vm26
/FILNAM,vm26
/PREP7
/TITLE, VM26 LARGE DEFLECTION OF A CANTILEVERED PLATE
/COM REF: BATHE AND DVORKIN, " A FORMULATION OF GENERAL SHELL ELEMENTS... "
/COM IJNME, VOL 22, NO. 3 (1986) PAGE 720
/NOPR
SMRT,OFF
ANTYPE,STATIC ! STATIC ANALYSIS
NLGEOM,ON ! LARGE DEFLECTION OPTION
ET,1,SHELL43
R,1,1 ! PLATE THICKNESS = 1
MP,EX,1,1800 ! MATERIAL PROPERTIES
MP,NUXY,,0
K,1 ! DEFINE KEYPOINTS
K,2,12
K,3,12,1
K,4,,1
L,1,2 ! DEFINE LINE SEGMENTS
L,3,4
LESIZE,ALL,,,2 ! 2 DIVISIONS ALONG LENGTH
ESIZE,,1 ! ONE DIVISION ON UNSPECIFIED LINE SEGMENTS
A,1,2,3,4
AMESH,1 ! CREATE MESH
NSEL,S,LOC,X
D,ALL,ALL ! FIXED END B.C.'S
NSEL,S,LOC,X,12
CP,1,ROTY,ALL ! COUPLE ROTATIONS AT FREE END
TORQ=7.854 ! DEFINE HALF TOTAL LOAD
F,2,MY,TORQ
NSEL,ALL ! RESELECT ALL NODES
FINISH
/SOLU
AUTOTS,ON ! USE AUTOMATIC LOAD STEPPING
NSUBST,10 ! START WITH MAX OF 10 SUBSTEPS FOR EACH LOAD STEP
LNSRCH,ON ! USE LINE SEARCH METHOD
OUTPR,BASIC,LAST ! BASIC PRINTOUT IN THE LAST SUBSTEP
OUTRES,ALL,ALL ! WRITE SOLUTION TO THE RESULTS FILE FOR EACH SUBSTEP
SOLVE
FINISH

! THE FOLLOWING 4 COMMANDS ARE NOT NEEDED SINCE THE INITIAL AND THE
! RESTART ANALYSES ARE IN ONE ANSYS RUN. THE USE OF THESE COMMANDS WAS DONE
! IN ORDER TO DEMONSTRATE THE USE OF THE FILES NEEDED FOR A RESTART
/COPY,vm26,rdb,,vm26r,rdb ! COPY THE FILES NEEDED FOR RESTART TO
/COPY,vm26,ldhi,,vm26r,ldhi ! FILES NAMED VM26R.***
/COPY,vm26,r001,,vm26r,r001 !
/COPY,vm26,rst,,vm26r,rst ! NEEDED FOR POSTPROCESSOR ONLY
/CLEAR,NOSTART ! CLEAR THE DATA BASE
/FILNAM,vm26r ! CONTINUE WITH FILES NAMED VM26R.***

/SOLU
ANTYPE,,REST ! RESTART ANALYSIS
F,2,MY,TORQ*2 ! APPLY FULL LOAD
SOLVE
FINISH
/POST1
RSYS,SOLU ! CHOOSE "AS-GENERATED" COORDINATE SYSTEM
SET,2 ! USE LOAD STEP 2 (FROM RESTART ANALYSIS)
SHELL,TOP ! CHOOSE TOP SURFACE OF SHELL FOR STRESS PRINTOUT
PRNSOL,S,COMP ! PRINT NODAL STRESSES AND DISPLACEMENTS
PRNSOL,DOF
*GET,UX_N4,NODE,4,U,X
*GET,UZ_N4,NODE,4,U,Z
*GET,ROTY_N4,NODE,4,ROT,Y
*GET,STRSS_N1,NODE,1,S,X

*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'UX,NODE ','UZ,NODE ','ROTY,NOD','STS_X,N_'
LABEL(1,2) = '4 (mm) ','4 (mm) ','E 4(rad)','1 N/mm^2'
*VFILL,VALUE(1,1),DATA,-2.9,-6.5,1.26,94.25
*VFILL,VALUE(1,2),DATA,UX_N4,UZ_N4,ROTY_N4,STRSS_N1
*VFILL,VALUE(1,3),DATA,ABS(UX_N4/2.9),ABS(UZ_N4/6.5),ABS(ROTY_N4/1.26),ABS(STRSS_N1/94.25)
SAVE,TABLE_1
FINI
/DELETE,vm26r,rdb
/DELETE,vm26r,ldhi
/DELETE,vm26r,r001
/DELETE,vm26r,rst
/CLEAR,NOSTART
/PREP7
smrt,off
/NOPR
ANTYPE,STATIC ! STATIC ANALYSIS
NLGEOM,ON ! LARGE DEFLECTION OPTION
ET,1,SHELL181
R,1,1 ! PLATE THICKNESS = 1
RMORE,,,,,10.0
MP,EX,1,1800 ! MATERIAL PROPERTIES
MP,NUXY,,0
K,1 ! DEFINE KEYPOINTS
K,2,12
K,3,12,1
K,4,,1
L,1,2 ! DEFINE LINE SEGMENTS
L,3,4
LESIZE,ALL,,,2 ! 2 DIVISIONS ALONG LENGTH
ESIZE,,1 ! ONE DIVISION ON UNSPECIFIED LINE SEGMENTS
A,1,2,3,4
AMESH,1 ! CREATE MESH
NSEL,S,LOC,X
D,ALL,ALL ! FIXED END B.C.'S
NSEL,S,LOC,X,12
CP,1,ROTY,ALL ! COUPLE ROTATIONS AT FREE END
TORQ=7.854 ! DEFINE HALF TOTAL LOAD
F,2,MY,TORQ
NSEL,ALL ! RESELECT ALL NODES
FINISH
/SOLU
AUTOTS,ON ! USE AUTOMATIC LOAD STEPPING
NSUBST,10 ! START WITH MAX OF 10 SUBSTEPS FOR EACH LOAD STEP
LNSRCH,ON ! USE LINE SEARCH METHOD
OUTPR,BASIC,LAST ! BASIC PRINTOUT IN THE LAST SUBSTEP
OUTRES,ALL,ALL ! WRITE SOLUTION TO THE RESULTS FILE FOR EACH SUBSTEP
SOLVE
FINISH
/SOLU
ANTYPE,,REST ! RESTART ANALYSIS
F,2,MY,TORQ*2 ! APPLY FULL LOAD
SOLVE
FINISH
/POST1
RSYS,SOLU ! CHOOSE "AS-GENERATED" COORDINATE SYSTEM
SET,2 ! USE LOAD STEP 2 (FROM RESTART ANALYSIS)
SHELL,TOP ! CHOOSE TOP SURFACE OF SHELL FOR STRESS PRINTOUT
PRNSOL,S,COMP ! PRINT NODAL STRESSES AND DISPLACEMENTS
PRNSOL,DOF
*GET,UX_N4,NODE,4,U,X
*GET,UZ_N4,NODE,4,U,Z
*GET,ROTY_N4,NODE,4,ROT,Y
*GET,STRSS_N1,NODE,1,S,X

*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'UX,NODE ','UZ,NODE ','ROTY,NOD','STS_X,N_'
LABEL(1,2) = '4 (mm) ','4 (mm) ','E 4(rad)','1 N/mm^2'
*VFILL,VALUE(1,1),DATA,-2.9,-6.5,1.26,94.25
*VFILL,VALUE(1,2),DATA,UX_N4,UZ_N4,ROTY_N4,STRSS_N1
*VFILL,VALUE(1,3),DATA,ABS(UX_N4/2.9),ABS(UZ_N4/6.5),ABS(ROTY_N4/1.26),ABS(STRSS_N1/94.25)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/COM
/OUT,vm26,vrt
/COM,------------------- VM26 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,SHELL43:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.2)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,SHELL181:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.2)
/COM,-----------------------------------------------------------------
/OUT
FINISH
/DELETE,TABLE_1
/DELETE,TABLE_2
FINISH
*LIST,vm26,vrt


VM27 (Thermal Expansion to Close a Gap) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM27
/PREP7
/TITLE, VM27, THERMAL EXPANSION TO CLOSE A GAP
C*** INTROD. TO STRESS ANALYSIS, HARRIS, 1ST PRINTING, PAGE 58, PROB. 8
C*** CONTAC12 AND LINK1 ELEMENTS (2-D)
ET,1,LINK1
ET,2,CONTAC12,,,,1 ! KEYOPT(4) = 1 GAP SIZE BY NODE LOCATION
R,1,1 ! AREA = 1 - SPAR ELEMENT
R,2,-45,10E10 ! GAP ANGLE (GLOBAL) = -45, STIFFNESS = 10E10
MP,EX,1,10.5E6
MP,ALPX,,12.5E-6
LOCAL,11,0,,,,45 ! LOCAL COORDINATE SYSTEM
N,1 ! DEFINE NODES
N,2,3
N,3,3.002
E,1,2 ! DEFINE SPAR ELEMENT
TYPE,2
REAL,2
E,2,3 ! DEFINE GAP ELEMENT
NROTAT,ALL ! ROTATE NODES INTO LOCAL COORDINATE SYSTEM
BFUNIF,TEMP,170 ! BOUNDARY CONDITIONS AND LOADS
TREF,70
D,1,ALL,,,3,2
D,2,UY
SAVE ! SAVE DATABASE FOR SECOND ANALYSIS
FINISH
/SOLU
NSUBST,5
OUTPR,,LAST
AUTOTS,ON
SOLVE
FINISH
/POST1
ETABLE,STRS_2D,LS,1
*GET,STRSS_2D,ELEM,1,ETAB,STRS_2D
ETABLE,THST_2D,LEPTH,1
*GET,THSTR_2D,ELEM,1,ETAB,THST_2D
*DIM,VALUE_C1,,2,3
*VFILL,VALUE_C1(1,1),DATA,-6125,.00125
*VFILL,VALUE_C1(1,2),DATA,STRSS_2D,THSTR_2D
*VFILL,VALUE_C1(1,3),DATA,ABS(STRSS_2D/6125) ,ABS(THSTR_2D/.00125)
*DIM,LABEL,CHAR,2,2
LABEL(1,1) = 'STRESS ','THERMAL '
LABEL(1,2) = '(psi) ','STRAIN '
SAVE,TABLE_1
FINISH
/CLEAR, NOSTART
/PREP7
RESUME ! RESUME DATABASE
C*** USING CONTAC52 AND LINK8 ELEMENTS (3-D)
ET,1,LINK8
ET,2,CONTAC52,,,,1 ! KEYOPT(4) = 1 GAP SIZE BY NODE LOCATION
R,2,10E10 ! STIFFNESS = 10E10 - GAP ELEMENT
LOCAL,11,0,,,,45,,-45 ! LOCAL COORDINATE SYSTEM
N,2,,,3 ! REDEFINE NODES
N,3,,,3.002
NROTAT,ALL
D,1,ALL,,,3,2 ! BOUNDARY CONDITIONS AND LOADS
D,2,UY
D,2,UX
FINISH
/SOLU
NSUBST,5
OUTPR,,LAST
AUTOTS,ON
SOLVE
FINISH
/POST1
ETABLE,STRS_3D,LS,1
*GET,STRSS_3D,ELEM,1,ETAB,STRS_3D
ETABLE,THST_3D,LEPTH,1
*GET,THSTR_3D,ELEM,1,ETAB,THST_3D
*DIM,VALUE_C2,,2,3
*VFILL,VALUE_C2(1,1),DATA,-6125,.00125
*VFILL,VALUE_C2(1,2),DATA,STRSS_3D,THSTR_3D
*VFILL,VALUE_C2(1,3),DATA,ABS(STRSS_3D/6125 ) ,ABS(THSTR_3D/.00125 )
*DIM,LABEL,CHAR,2,2
LABEL(1,1) = 'STRESS ','THERMAL '
LABEL(1,2) = '(psi) ','STRAIN '
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm27,vrt
/COM,------------------- VM27 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS FOR 2-D ANALYSIS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F11.5,' ',F11.5,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS FOR 3-D ANALYSIS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,' ',F11.5,' ',F11.5,' ',1F5.3)

/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST,vm27,vrt



VM28 (Transient Heat Transfer in an Infinite Slab) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM28
/PREP7
/TITLE, VM28, TRANSIENT HEAT TRANSFER IN AN INFINITE SLAB
/COM, "HEAT TRANSFER", HOLMAN, 4TH ED., PG. 106
/NOPR
ANTYPE,TRANS
ET,1,PLANE77
MP,KXX,1,54
MP,DENS,1,7833
MP,C,1,.465
N,1
N,12,,1
FILL,,,,,,,,.1 ! BIAS MESH TOWARD SURFACE WITH 1:10 RATIO
NGEN,2,12,1,12,1,.1 ! GENERATE EDGE NODES
E,1,13,14,2
EGEN,11,1,-1 ! GENERATE ELEMENTS FROM EDGE NODES
EMID ! PLACE MIDSIDE NODES ON ELEMENTS
NSEL,S,LOC,X,0
NLIST,ALL ! LIST NODES ALONG LENGTH
NSEL,S,LOC,Y,1
SF,ALL,CONV,50,1000 ! APPLY CONVECTION TO TOP SURFACE
NSEL,ALL
TUNIF,0 ! DEFINE INITIAL TEMPERATURES, T(0)
FINISH
/SOLU
SOLCONTROL,0
KBC,1 ! STEP BOUNDARY CONDITIONS
DELTIM,0.01 ! MINIMUM TIME STEP
TIME,2.0 ! TIME AT END OF TRANSIENT
OUTRES,,ALL
AUTOTS,ON
SOLVE
FINISH
/POST26
NSOL,2,11,TEMP,,T11 ! STORE TEMPERATURES AT SELECT NODES
NSOL,3,9,TEMP,,T9
NSOL,4,7,TEMP,,T7
NSOL,5,5,TEMP,,T5
NSOL,6,1,TEMP,,T1
PRVAR,2,3,4,5,6 ! PRINT TEMPERATURE SOLUTION VS. TIME
*GET,TEMP_11,NODE,11,TEMP
*GET,TEMP_9,NODE,9,TEMP
*GET,TEMP_7,NODE,7,TEMP
*GET,TEMP_5,NODE,5,TEMP

*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'TEMP (C)','TEMP (C)','TEMP (C)','TEMP (C)'
LABEL(1,2) = ' NODE 11',' NODE 9 ',' NODE 7 ',' NODE 5 '
*VFILL,VALUE(1,1),DATA,140,98.9,51.8,14.5
*VFILL,VALUE(1,2),DATA,TEMP_11,TEMP_9,TEMP_7,TEMP_5
*VFILL,VALUE(1,3),DATA,ABS(TEMP_11/140),ABS(TEMP_9/98.9),ABS(TEMP_7/51.8),ABS(TEMP_5/14.5)
/COM
/OUT,vm28,vrt
/COM,------------------- VM28 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,-----------------------------------------------------------

/OUT
FINISH
*LIST,vm28,vrt



VM29 (Friction on a Support Block) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM29
/PREP7
/TITLE, VM29, FRICTION ON A SUPPORT BLOCK
C***VECTOR MECHANICS FOR ENGINEERS, BEER AND JOHNSTON, 1962, PAGE 283, PROB. 8.2
ANTYPE,STATIC
ET,1,CONTAC12
R,1,-20,1E6 ! THETA = -20, STIFFNESS = 1E6
MP,MU,1,.3 ! COEFFICIENT OF FRICTION
N,1 ! CREATE NODES
N,2
E,1,2 ! CREATE ELEMENT
D,1,ALL ! BOUNDARY CONDITIONS AND LOADS
F,2,FX,-5.76729 ! STICKING LOAD
F,2,FY,-100
NSUBST,1 ! LIMIT TO ONE ITERATION TO PREVENT DIVERGENCE
OUTPR,BASIC,ALL ! PRINT NODAL DOF, REACTION & ELEMENT SOLUTION
OUTPR,NLOAD,ALL ! PRINT ELEMENT NODAL LOADS
KBC,1 ! STEP CHANGE IN B.C.'S
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETAB,NOR_FC1,SMISC,1
ETAB,SLI_FC1,SMISC,2
*GET,NORM_FC1,ELEM,1,ETAB,NOR_FC1
*GET,SLID_FC1,ELEM,1,ETAB,SLI_FC1
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C1,,2,3
LABEL(1,1) = 'NORMAL F','SLIDING '
LABEL(1,2) = 'ORCE lb','FORCE lb'
*VFILL,VALUE_C1(1,1),DATA,-95.942,28.783
*VFILL,VALUE_C1(1,2),DATA,NORM_FC1,SLID_FC1
*VFILL,VALUE_C1(1,3),DATA,ABS(NORM_FC1/95.942),ABS(SLID_FC1/28.783)
SAVE,TABLE_1
FINISH
/SOLU
F,2,FX,-5.76720 ! SLIDING LOAD
SOLVE
FINISH
/POST1
ETAB,NOR_FC2,SMISC,1
ETAB,SLI_FC2,SMISC,2
*GET,NORM_FC2,ELEM,1,ETAB,NOR_FC2
*GET,SLID_FC2,ELEM,1,ETAB,SLI_FC2
*DIM,VALUE_C2,,2,3
LABEL(1,1) = 'NORMAL F','SLIDING '
LABEL(1,2) = 'ORCE lb','FORCE lb'
*VFILL,VALUE_C2(1,1),DATA,-95.942,28.783
*VFILL,VALUE_C2(1,2),DATA,NORM_FC2,SLID_FC2
*VFILL,VALUE_C2(1,3),DATA,ABS(NORM_FC2/95.942),ABS(SLID_FC2/28.783)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm29,vrt
/COM,------------------- VM29 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,FX = 5.76729 LB AND MODEL IS STICKING:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,FX = 5.76720 LB AND MODEL IS SLIDING:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm29,vrt



VM30 (Solid Model of Surface Fillet) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM30
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM30, SOLID MODEL OF SURFACE FILLET
/COM, REF: NAFEMS BENCHMARKS FOR FINITE ELEMENT PRE-PROCESSORS
/COM, D.R. HOSE, I.A. RUTHERFORD, REF R0001, ISSUED 12/2/93, PP. 23.
/COM,
ET,1,SHELL93 ! 8-NODE STRUCTURAL SHELL
L=8.0 ! BASE LENGTH
H=2.0 ! BASE HEIGHT
RECTNG,,L/2,,H, ! CREATE RECTANGULAR AREA
WPROTA,,90 ! ROTATE POSITIVE Y TOWARDS Z
PTXY,0,0,-2,2,6,2,4,0, ! DEFINE COORDINATE PAIRS FOR POLYGON
POLY ! DEFINE POLYGONAL AREA
AGLUE,1,2 ! GLUE AREAS 1 AND 2
AFILLT,1,3,1 ! CREATE AREA FILLET WITH CONSTANT RADIUS=1
/FACET,WIRE
/VIEW,1,1,2,3
/PNUM,AREA,1 ! TURN ON AREA NUMBERING
APLOT ! PLOT AREAS
ACCAT,ALL ! CONCATENATE AREAS
LSEL,S,LINE,,5 ! SELECT LINES TO CONCATENATE
LSEL,A,LINE,,21,24,3
LCCAT,ALL ! CONCATENATE LINES
LSEL,S,LINE,,20,23,3 ! SELECT LINES TO CONCATENATE
LSEL,A,LINE,,7
LCCAT,ALL ! CONCATENATE LINES
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USING QUADS
AMESH,1 ! MESH USING DEFAULT ELEMENT SIZE
EPLOT ! PLOT ELEMENTS
LOCAL,11,,,,,,,-45 ! ROTATE X TOWARDS Z
DSYS,11
NROTAT,ALL
NSEL,S,LOC,X,-.1,.1
*GET,NXMAX,NODE,,MXLOC,X ! CHECK THE POSITIVE DEVIATION FROM ZERO
*GET,NXMIN,NODE,,MNLOC,X ! CHECK THE NEGATIVE DEVIATION FROM ZERO
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'MAX LOCA','MIN LOCA'
LABEL(1,2) = 'TION ','TION '
*VFILL,VALUE(1,1),DATA,0,0
*VFILL,VALUE(1,2),DATA,NXMAX,NXMIN
*VFILL,VALUE(1,3),DATA,0,0
/COM
/OUT,vm30,vrt
/COM,------------------- VM30 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,DEVIATION:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',E10.3,' ',1F5.3)
/COM,
/COM,NOTE: THE LARGER OF THE TWO DEVIATIONS LISTED IS THE 'MAXIMUM DEVIATION'
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm30,vrt



VM31 (Cable Supporting Hanging Loads) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM31
/PREP7
/TITLE, VM31, CABLE SUPPORTING HANGING LOADS
C***VECTOR MECHANICS FOR ENGINEERS, BEER AND JOHNSTON, 1962, PAGE 260, PROB. 7.8
ANTYPE,STATIC
ET,1,LINK10
R,1,.1,1E-8 ! AREA = .1, INITIAL STRAIN = .00000001
SSTIF,ON ! STRESS STIFFENING
MP,EX,1,20E6
N,1 ! DEFINE NODES
N,2,20,-5.56
N,3,30,-5
N,4,45,5.83
N,5,60,20
E,1,2 ! DEFINE ELEMENTS
EGEN,4,1,1
NSUBST,3
OUTPR,,3
OUTPR,NLOAD,3 ! PRINT NODAL FORCES
KBC,1 ! STEP CHANGE B.C.'S
D,1,ALL,,,5,4 ! BOUNDARY CONDITIONS AND LOADS
D,2,UZ,,,4
F,2,FY,-6
F,3,FY,-12
F,4,FY,-4
FINISH
/SOLU
SOLVE
FINISH
/POST26
RFORCE,2,1,F,X
RFORCE,3,1,F,Y
STORE
*GET,AX,VARI,2,EXTREM,VMAX
*GET,AY,VARI,3,EXTREM,VMAX
FINISH
/POST1
ETABLE,MFX,SMISC,1
*GET,MX_FOR_X,ELEM,4,ETAB,MFX

*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'AX, (kip','AY, (kip','MAX TENS'
LABEL(1,2) = 's) ','s) ',' (kips) '
*VFILL,VALUE(1,1),DATA,-18.000,5.0000,24.762
*VFILL,VALUE(1,2),DATA,AX,AY,MX_FOR_X
*VFILL,VALUE(1,3),DATA,ABS(AX/18.000) ,ABS(AY/5.000),ABS(MX_FOR_X/24.762)
/COM
/OUT,vm31,vrt
/COM,------------------- VM31 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------

/OUT
FINISH
*LIST,vm31,vrt



VM32 (Thermal Stresses in a Long Cylinder) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM32
/PREP7
/TITLE, VM32, THERMAL STRESSES IN A LONG CYLINDER
! STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 234, PROB. 1
! THERMAL SOLUTION ***
ET,1,PLANE55,,,1 ! AXISYMMETRIC KEYOPT(S) OPTION
ET,2,PLANE55,,,1
MP,KXX,1,3
N,1,.1875
N,8,.625
FILL,,,,,,,,2 ! BIAS MESH DENSITY TOWARD CENTERLINE
NGEN,2,10,1,8,1,,.1
E,11,1,2,12
TYPE,2
E,12,2,3,13
EGEN,5,1,2
TYPE,1
E,8,18,17,7
FINISH
/SOLU
ANTYPE,STATIC
D,1,TEMP,-1,,11,10 ! APPLY TEMPERATURES TO INNER AND OUTER SURFACES
D,8,TEMP,,,18,10
OUTPR,BASIC,ALL
SOLVE
FINISH
/POST1
LFT_NODE = NODE (0.1875,0,0)
IN_NODE = NODE (0.2788,0,0)
RT_NODE = NODE (0.625,0,0)
*GET,LFT_TEMP,NODE,LFT_NODE,TEMP
*GET,IN_TEMP,NODE,IN_NODE,TEMP
*GET,RT_TEMP,NODE,RT_NODE,TEMP
*DIM,VALUE_C1,,3,3
*VFILL,VALUE_C1(1,1),DATA,-1,-.67037,0
*VFILL,VALUE_C1(1,2),DATA,LFT_TEMP,IN_TEMP,RT_TEMP
*VFILL,VALUE_C1(1,3),DATA,ABS(LFT_TEMP/1 ),ABS(IN_TEMP/.67037 ),0
*DIM,LABEL_1,CHAR,3,2
LABEL_1(1,1) = 'T (C) X=','T (C) X=','T (C) X='
LABEL_1(1,2) = '.1875 in','.2788 in','0.625 in'
SAVE,TABLE_1

FINISH
/PREP7
! STRESS SOLUTION, STATIC ANALYSIS ***
ETCHG,TTS ! CHANGE ELEMENT TYPE PLANE55 TO PLANE42
KEYOPT,1,3,1
KEYOPT,2,3,1
KEYOPT,1,6,1
MP,EX,1,30E6 ! DEFINE STRUCTURAL PROPERTIES
MP,ALPX,,1.435E-5
MP,NUXY,1,.3
CPNGEN,7,UY,11,18 ! COUPLE APPROPRIATE NODAL DISPLACEMENTS
CP,8,UX,1,11
CPSGEN,8,1,8
FINISH
/SOLU
ANTYPE,STATIC
D,1,UY,,,8
LDREAD,TEMP,,,,,,rth ! READ IN BODY FORCE TEMPERATURES
SOLVE
FINISH
/POST1
LFT_NODE = NODE (0.1875,0,0)
RT_NODE = NODE (0.625,0,0)
*GET,LFT_AXST,NODE,LFT_NODE,S,Y
*GET,LFT_TST,NODE,LFT_NODE ,S,Z
*GET,RT_AXST,NODE,RT_NODE,S,Y
*GET,RT_TST,NODE,RT_NODE ,S,Z
*DIM,VALUE_C2,,4,3
*VFILL,VALUE_C2(1,1),DATA,420.42,420.42,-194.58,-194.58
*VFILL,VALUE_C2(1,2),DATA,LFT_AXST,LFT_TST,RT_AXST,RT_TST
*VFILL,VALUE_C2(1,3),DATA,ABS(LFT_AXST/420.42),ABS(LFT_TST/420.42),ABS(RT_AXST/194.58)
*VFILL,VALUE_C2(4,3),DATA,ABS(RT_TST/194.58)
*DIM,LABEL_2,CHAR,4,2
LABEL_2(1,1) = 'A_STS ps','T_STS ps','A_STS ps','T_STS ps'
LABEL_2(1,2) = 'i X=.187','i X=.187','i X=.625','i X=.625'
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm32,vrt
/COM,------------------- VM32 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,THERMAL ANALYSIS:
/COM,
*VWRITE,LABEL_1(1,1),LABEL_1(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/NOPR,
RESUME,TABLE_2
/GOPR
/COM,STATIC ANALYSIS:
/COM,
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm32,vrt



VM33 (Transient Thermal Stress in a Cylinder) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM33
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM33, TRANSIENT THERMAL STRESS IN A CYLINDER
/COM, REF: ROARK AND YOUNG "FORMULAS FOR STRESS AND STRAIN",5TH
/COM, EDITION, MCGRAW-HILL, PG. 585
/COM,
ET,1,SOLID5 ! SOLID5 UX,UY,UZ,TEMP,VOLT,MAG DOF SET
MP,KXX,1,625E-6 ! DEFINE THERMAL CONDUCTIVITY
MP,EX,1,30E6 ! MODULUS OF ELASTICITY
MP,NUXY,1,.3 ! POISSON'S RATIO
MP,ALPX,1,8.4E-6 ! COEFFICIENT OF THERMAL EXPANSION
MP,DENS,1,.284 ! DENSITY (LB/IN**3)
MP,C,1,.10 ! SPECIFIC HEAT
CSYS,1
H=.20 ! MODEL HEIGHT
TH=2.5 ! MODEL HALF-ANGLE
A=1 ! INNER RADIUS
B=3 ! OUTER RADIUS
K,1,A,TH ! DEFINE KEYPOINTS
K,2,B,TH
KGEN,2,1,2,1,,,H
KGEN,2,1,4,1,,-(TH*2)
L,1,2 ! DEFINE LINE SEGMENTS
*REPEAT,4,2,2
LESIZE,ALL,,,15,5
ESIZE,,1
V,1,2,4,3,5,6,8,7 ! DEFINE VOLUME
MSHK,1 ! MAPPED VOLUME MESH
MSHA,0,3D ! USING HEX
VMESH,1 ! MESH VOLUME
NSEL,S,LOC,Y,TH
NSEL,A,LOC,Y,-TH
DSYM,SYMM,Y,1 ! DEFINE STRUCTURAL B.C.
NSEL,S,LOC,Z
DSYM,SYMM,Z,1
NSEL,S,LOC,Z,H ! SELECT NODES ON TOP SURFACE
CP,1,UZ,ALL ! COUPLE ALL NODES IN UZ
NSEL,S,LOC,X,B ! SELECT NODES AT OUTER RADIUS
D,ALL,TEMP,500 ! DEFINE FINAL SURFACE TEMPERATURE
NSEL,ALL
FINISH
/SOLU
ANTYPE,TRANS ! TRANSIENT ANALYSIS
TIMINT,OFF,STRUC ! SUPPRESS STRUCTURAL DYNAMICS
CNVTOL,HEAT ! CONVERGENCE BASED ON HEAT FLOWS
CNVTOL,F ! AND FORCES ONLY
AUTOTS,ON ! AUTOMATIC TIME STEPPING
OUTRES,,ALL ! RESULTS FOR ALL TIME POINTS
KBC,0 ! RAMP LOAD OVER LOAD STEP
TREF,70 ! SET REFERENCE TEMPERATURE
TUNIF,70 ! SET INITIAL UNIFORM TEMPERATURE
DELTIM,1,,60 ! MINIMUM TIME STEP OF 1 SEC
TIME,430 ! TIME AT END OF LOAD STEP
SOLVE
FINISH
/POST1
*GET,IN_STRS,NODE,1,S,Y
*GET,OUT_STRS,NODE,2,S,Y
FINISH
/POST26
NSOL,2,1,TEMP ! STORE TEMP AT INNER RADIUS
NSOL,3,2,TEMP ! STORE TEMP AT OUTER RADIUS
ESOL,4,1,1,S,Y,SYB ! STORE SY AT INNER RADIUS
ESOL,5,15,2,S,Y,SYC ! STORE SY AT OUTER RADIUS
ADD,6,3,2,,DELT,,,1,-1 ! CALCULATE DELTA TEMP. (OUTER-INNER)
PRVAR,2,3,4,5,6 ! PRINT VARIABLES VS. TIME
/GRID,1
/AXLAB,Y,DELT
PLVAR,6 ! DISPLAY DELTA TEMP. VS TIME
/AXLAB,Y,SY
PLVAR,4,5 ! DISPLAY SY VS. TIME

*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'STRS R=B','STRS R=A'
LABEL(1,2) = '(psi) ','(psi) '
*VFILL,VALUE(1,1),DATA,-13396,10342
*VFILL,VALUE(1,2),DATA,OUT_STRS,IN_STRS
*VFILL,VALUE(1,3),DATA,ABS(OUT_STRS/13396),ABS(IN_STRS/10342)
/COM
/OUT,vm33,vrt
/COM,------------------- VM33 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT

FINISH
*LIST,vm33,vrt



VM34 (Bending of a Tapered Plate (Beam)) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM34
/PREP7
/TITLE, VM34, BENDING OF A TAPERED PLATE (BEAM)
! INTROD. TO STRESS ANALYSIS, HARRIS, 1ST PRINTING, PAGE 114, PROB. 61
! PLATE ELEMENTS (SHELL63)
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,SHELL63,2
R,1,.5 ! THICKNESS = 0.5
MP,EX,1,30E6
MP,NUXY,1,0 ! POISSON'S RATIO IS ZERO
N,1
N,8,20,-1.5
FILL
N,11
N,18,20,1.5
FILL
E,1,2,12
E,2,3,12
E,13,12,3
E,3,4,14
E,14,13,3
EGEN,3,2,2,5
CP,1,UZ,2,12 ! COUPLE APPROPRIATE DEGREES OF FREEDOM
CP,2,ROTY,2,12
CPSGEN,6,1,1,2 ! GENERATE 6 SETS OF EQUATIONS
OUTPR,ALL,ALL
D,8,ALL,,,18,10
D, ALL,ROTX,0 ! REMOVE "TORSIONAL" DEGREES OF FREEDOM
F,1,FZ,-10
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,STRS,S,1 ! STORE S1(TOP) FOR SHELL63
ESORT,STRS ! SORT ELEMENTS BASED ON S1(TOP)
*GET,SMAX,SORT,,MAX ! GET MAXIMUM S1 AS SMAX
PRNSOL,DOF ! PRINT NODAL DISPLACEMENTS
LFT_NODE = NODE (0,0,0)
*GET,DEFL,NODE,LFT_NODE,U,Z
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C1,,2,3
LABEL(1,1) = 'DEFLECTI','MX_PRIN_'
LABEL(1,2) = 'ON (in) ','STRS psi'
*VFILL,VALUE_C1(1,1),DATA,-.042667,1600
*VFILL,VALUE_C1(1,2),DATA,DEFL,SMAX
*VFILL,VALUE_C1(1,3),DATA,ABS(DEFL/.042667 ) ,ABS( SMAX/1600 )
SAVE,TABLE_1
FINISH
/CLEAR, NOSTART
/PREP7
/TITLE, VM34, BENDING OF A TAPERED PLATE (BEAM)
! TAPERED BEAM ELEMENTS (BEAM44)
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,BEAM44
*DO,I,1,10 ! CREATE DO LOOP FOR REAL CONSTANTS
R,I, 1,1,.003125*(I-1),.25,1
RMORE,1,1,.003125* I ,.25,1
*ENDDO
RMOD,1,3,.5E-3 ! GIVE FREE END A POSITIVE MOMENT OF INERTIA
RLIST
MP,EX,1,30E6
N,1
N,11,20
FILL
N,12,,,1 ! NODE 12 FOR ALIGNING BEAM AXES
NGEN,10,1,12 ! NODES 12 TO 21 ARE COINCIDENT
E,1,2,12
EGEN,10,1,1,,,,,1 ! GENERATE ELEMENTS WITH REAL CONSTANT INCREASED BY 1
D,11,ALL
D,1,UY,,,10,,ROTX,ROTZ
F,1,FZ,-10
OUTPR,ALL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,STRS,NMISC,1 ! STORE SMAX (MAXIMUM STRESS) FOR BEAM44
ESORT,STRS ! SORT ELEMENTS BASED ON SMAX (MAXIMUM STRESS)
*GET,SMAX,SORT,,MAX ! GET MAXIMUM STRESS AS SMAX
PRNSOL,DOF ! PRINT NODAL DISPLACEMENTS
LFT_NODE = NODE (0,0,0)
*GET,DEFL,NODE,LFT_NODE,U,Z
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C2,,2,3
LABEL(1,1) = 'DEFLECTI','MX_PRIN_'
LABEL(1,2) = 'ON (in) ','STRS psi'
*VFILL,VALUE_C2(1,1),DATA,-.042667,1600
*VFILL,VALUE_C2(1,2),DATA,DEFL,SMAX
*VFILL,VALUE_C2(1,3),DATA,ABS(DEFL/.042667 ) ,ABS( SMAX/1600 )
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm34,vrt
/COM,------------------- VM34 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING SHELL63:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F12.6,' ',F12.6,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,' ',F12.6,' ',F12.6,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm34,vrt


VM35 (Bimetallic Layered Cantilever Plate with Thermal Loading) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM35
/PREP7
SMRT,OFF
/TITLE,VM35: BIMETALLIC LAYERED CANTILEVER PLATE WITH THERMAL LOADING
C*** ROARK AND YOUNG, FORMULAS FOR STRESS AND STRAIN, PP. 113-114.
ANTYPE,STATIC
ET,1,SHELL91,,1,,0,4,1,1
R,1,2
RMORE
RMORE,1,0,.05 ! LAYER 1 IS MAT'L 1, .05 THICK
RMORE,2,,.05 ! LAYER 2 IS MAT'L 2, .05 THICK
MP,EX,1,3E7 ! MATERIAL PROPERTIES
MP,EX,2,3E7
MP,ALPX,1,1E-5
MP,ALPX,2,2E-5
MP,NUXY,1,0
MP,NUXY,2,0
K,1 ! DEFINE GEOMETRY
K,2,,1
K,3,10,1
K,4,10
A,1,2,3,4
ESIZE,2 ! ELEMENT SIDE LENGTHS = 2
AMESH,1
NSEL,S,LOC,X
NSEL,R,LOC,Y,.5
D,ALL,ALL ! FIX ONE END OF CANTILEVER
NSEL,S,LOC,Y,0.5
DSYM,SYMM,Y ! SYMMETRY PLANE DOWN CENTERLINE
NSEL,ALL
TREF,70
BFUNIF,TEMP,170 ! DEFINE UNIFORM TEMPERATURE
FINISH
/SOLU
OUTPR,BASIC,1
SOLVE
FINISH
/POST1
SHELL,TOP ! SELECT TOP SURFACE FOR STRESS PRINT
PRNSOL,S,COMP
NSEL,S,LOC,X,10 ! SELECT CENTERLINE OF FREE END FOR DISPLACEMENT PRINT
NSEL,R,LOC,Y,.5
PRNSOL,U,COMP
RT_NODE = NODE (10,.5,0)
*GET,DEF_Z,NODE,RT_NODE,U,Z
*GET,DEF_X,NODE,RT_NODE,U,X
*GET,OUT_STRS,NODE,1,S,X
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'RT_END U','RT_END U','LFT_END '
LABEL(1,2) = 'Z (in) ','X (in) ','STRS psi'
*VFILL,VALUE(1,1),DATA,.750,.015,7500
*VFILL,VALUE(1,2),DATA,DEF_Z,DEF_X,OUT_STRS
*VFILL,VALUE(1,3),DATA,ABS(DEF_Z/.750) ,ABS(DEF_X/.015),ABS(OUT_STRS/7500)
/COM
/OUT,vm35,vrt
/COM,------------------- VM35 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm35,vrt



VM36 (Limit Moment Analysis) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM36
/PREP7
/TITLE, VM36, LIMIT MOMENT ANALYSIS
! MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 389, EX. 8.9
ANTYPE,STATIC
ET,1,BEAM4
ET,2,COMBIN40,,,5 ! ROTY D.O.F. SPRING
R,1,1,20,20,3.93597,3.93597 ! DEFINE THREE SETS OF REAL CONSTANTS
R,2,1E12,,,,27777.8
R,3,1,,,,1E6
MP,EX,1,30E6 ! DEFINE MATERIAL PROPERTIES
MP,NUXY,1,.3
N,1 ! BEGIN NODES DEFINITION
N,2,100
N,3,100
N,4,150
N,5,150
E,1,2 ! DEFINE BEAM ELEMENTS
E,3,4
TYPE,2 ! DEFINE BREAKAWAY HINGE ELEMENTS
REAL,2
E,2,3
E,4,5
REAL,3
E,2,3
E,4,5 ! EXTRA ELEMENTS FOR SOLUTION STABILITY
OUTPR,ALL,ALL
CNVTOL,M,27778,.001
CP,1,UX,2,3 ! COUPLE TRANSLATIONS ACROSS PLASTIC HINGE
CPLGEN,1,UZ ! GENERATE 2ND SET IN DIRECTION UZ W/ SAME NODES
CPSGEN,2,2,1,2,1 ! GENERATE TWO ADDITIONAL SETS W/ DIFFERENT NODES
DSYM,SYMM,Y ! CONSTRAIN MODEL SYMMETRICALLY IN Y DIRECTION
D,1,UZ ! CONSTRAIN SIMPLY SUPPORTED END AGAINST DISP.
D,4,UZ,,,,,UX ! CONSTRAIN RIGID END AGAINST TWO DIRECTIONAL DISP
D,5,ROTY ! CONSTRAIN RIGID END AGAINST ROTATIONAL MOVEMENT
F,2,FZ,-1000 ! APPLY ELASTIC FORCE AT HINGE B
FINISH
/SOLU
SOLCONTROL,0
SOLVE ! WRITE LOAD STEP
FINISH
/POST26
RFORCE,2,1,F,Z
RFORCE,3,5,M,Y
STORE
*GET,RA,VARI,2,EXTREM,VMAX
*GET,MC,VARI,3,EXTREM,VMAX
*GET,UB,NODE,2,U,Z
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFLECTI','REACTION','MOMENT_C'
LABEL(1,2) = 'ON (in) ','_A (lb) ',' (ib-lb)'
*VFILL,VALUE(1,1),DATA,-.02829,148.15,27778
*VFILL,VALUE(1,2),DATA,UB,RA,MC
*VFILL,VALUE(1,3),DATA,ABS(UB/.02829) ,ABS(RA/148.15 ),ABS(MC/27778)
SAVE,TABLE_1


finish
/solution

NSUBST,3 ! USE CONVERGENCE CRITERIA,3 SUBSTEPS MAX
OUTPR,ALL,LAST ! PRINT LAST ITERATION.
F,2,FZ,-1388.8 ! APPLY VALUE SLIGHTLY SMALLER THAN PL TO HINGE B
SOLVE
F,2,FZ,-1390 ! APPLY VALUE SLIGHTLY LARGER THAN PL TO HINGE B
! LARGE DISPLACEMENT VALUES INDICATE COLLAPSE
! AND PLASTIC DEFORMATION
SOLVE

finish

RESUME,TABLE_1
/COM
/OUT,vm36,vrt
/COM,------------------- VM36 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS FOR P=1000 LBS (ELSTIC):
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.5,' ',F11.5,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM36 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------

/OUT
FINISH
*LIST,vm36,vrt


VM37 (Elongation of a Solid Bar) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM37
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
smrt,off
/TITLE, VM37, ELONGATION OF A SOLID BAR
/COM INTROD. TO STRESS ANALYSIS, HARRIS, 1ST PRINTING, PAGE 237, PROB. 4
/COM USING 3-D STRUCTURAL SOLID ELEMENTS
ANTYPE,STATIC
ET,1,SOLID45
MP,EX,1,10.4E6
MP,NUXY,1,.3
K,1,1,,1 ! DEFINE KEYPOINTS
K,2,-1,,1
K,3,-1,,-1
K,4,1,,-1
K,5,.5,10,.5
K,6,-.5,10,.5
K,7,-.5,10,-.5
K,8,.5,10,-.5
V,1,2,3,4,5,6,7,8 ! DEFINE VOLUME
LSEL,S,LINE,,5,11,2 ! SELECT LINES
LESIZE,ALL,,,7 ! DEVIDE SELECTED LINES BY 7 DIVISIONS
LSEL,ALL ! SELECT ALL LINES
ESIZE,,1 ! USE 1 ELEMENT PER LINE DIVISION
/OUT,SCRATCH
VMESH,1 ! MESH THE VOLUME
/OUT
OUTPR,BASIC,ALL
NSEL,S,LOC,Y,0 ! APPLY BOUNDARY CONDITIONS AT THE BASE OF THE MODEL
D,ALL,ALL ! FIX ALL DEGREES OF FREEDOM AT SELECTED NODE SET
NSEL,ALL
NSEL,S,LOC,Y,10 ! APPLY LOAD ON FREE END OF THE MODEL
SF,,PRES,-10000
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,SIGY,S,Y ! RETRIEVE CENTROIDAL SY
/VIEW,1,1 ! CHANGE VIEW TO LOOKING DOWN X-AXIS
/VUP,1,-Y ! REORIENT MODEL ON SCREEN
!/CLABEL,1,1 ! LABEL CONTOUR LINES
!/CVAL,1,2700,3500,4300,5100,5900,6700,7500,8300 ! USER DEFINED CONTOURS
NSLE,S ! SELECT NODES ATTACHED TO ELEMENTS
PLNSOL,S,Y ! DISPLAY AXIAL STRESS
ESEL,S,ELEM,,4 ! SELECT MID-LENGTH ELEMENT
PRETAB,SIGY ! PRINT OUT STORED STRESS ITEM
PRNSOL,S,COMP ! PRINT NODAL STRESSES
ESEL,ALL ! SELECT ALL ELEMENTS
NSEL,S,LOC,Y,10 ! SELECT ALL NODES AT Y=10 (FREE END OF MODEL)
PRNSOL,DOF ! PRINT OUT DISPLACEMENTS OF NODES
NSEL,ALL
/NOPR
MID_NODE = NODE(0,5,0)
MID_ELM = ENEARN(MID_NODE)
BOT_NODE = NODE (0,10,0)
*GET,DEF,NODE,BOT_NODE,U,Y
*GET,STRSS,ELEM,MID_ELM,ETAB,SIGY
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C1,,2,3
LABEL(1,1) = 'MAX DEF ','SIGY MID'
LABEL(1,2) = '(in) ','_ELM psi'
*VFILL,VALUE_C1(1,1),DATA,.0048077,4444
*VFILL,VALUE_C1(1,2),DATA,DEF,STRSS
*VFILL,VALUE_C1(1,3),DATA,ABS(DEF/.0048077) ,ABS(STRSS/4444)
/GOPR
FINISH
/COM
/OUT,vm37,vrt
/COM,------------------- VM37 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS FOR SOLID45:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F12.7,' ',F12.7,' ',1F5.3)
/NOPR
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm37,vrt
/DELETE,SCRATCH
FINISH


VM38 (Plastic Loading of a Thick-Walled Cylinder Under Pressure) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM38
/PREP7
/TITLE, VM38, PLASTIC LOADING OF A THICK-WALLED CYLINDER UNDER PRESSURE
C*** STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 388, ART. 70
ET,1,PLANE42,,1,1 ! AXISYMMETRIC SOLID, SUPPRESS EXTRA SHAPES
ET,2,SURF153,,,1,1 ! AXISYMMETRIC 2-D SURFACE EFFECT ELEMENT WITHOUT
! MIDSIDE NODES
MP,EX,1,30E6
MP,NUXY,1,.3
TB,BKIN,1,1 ! BILINEAR KINEMATIC HARDENING
TBTEMP,70
TBDATA,1,30000,0 ! YIELD STRESS AND ZERO TANGENT MODULUS
N,1,4 ! DEFINE NODES
N,6,8
FILL
NGEN,2,10,1,6,1,,1
E,11,1,2,12 ! DEFINE ELEMENTS
EGEN,5,1,1
CPNGEN,1,UY,11,16 ! COUPLE NODES
TYPE,2 ! CREATE SURF153 TO APPLY SURFACE PRESSURE LOADING
NSEL,S,LOC,X,4
ESURF
NSEL,ALL
TREF,70 ! BOUNDARY CONDITIONS AND LOADING
D,1,UY,,,6
FINISH
/SOLU
ESEL,S,TYPE,,2 ! SELECT SURF153 ELEMENTS TO APPLY SURFACE PRESSURE
! LOADING FOR ELASTIC ANALYSIS
SFE,ALL,1,PRES,,12990
ESEL,ALL
OUTPR,BASIC,1
SOLVE
FINISH
/POST1
ETABLE,STRS_R,S,X
ETABLE,STRS_T,S,Z
*GET,SIGR_I,ELEM,1,ETAB,STRS_R
*GET,SIGT_I,ELEM,1,ETAB,STRS_T
*GET,SIGR_O,ELEM,5,ETAB,STRS_R
*GET,SIGT_O,ELEM,5,ETAB,STRS_T

*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'SIGR LFT','SIGT LFT','SIGR RT_','SIGT RT_'
LABEL(1,2) = '_END psi','_END psi','END psi ','END psi '
*VFILL,VALUE(1,1),DATA,-9984,18645,-468,9128
*VFILL,VALUE(1,2),DATA,SIGR_I,SIGT_I,SIGR_O,SIGT_O
*VFILL,VALUE(1,3),DATA,ABS(SIGR_I/9984),ABS(SIGT_I/18645)
*VFILL,VALUE(3,3),DATA,ABS(SIGR_O/468),ABS(SIGT_O/9128)
SAVE,TABLE_1


FINISH
/SOLU
ESEL,S,TYPE,,2 ! SELECT SURF153 ELEMENTS TO APPLY SURFACE PRESSURE
! LOADING FOR PLASTIC ANALYSIS
SFE,ALL,1,PRES,,24012
ESEL,ALL
SOLVE
FINISH

/PREP7
EDELE,ALL
NDELE,ALL ! REMOVE PREVIOUS MODEL GEOMETRY
ET,1,SOLID45,1 ! 3-D SOLID ELEMENT, SUPPRESS EXTRA SHAPES
ET,2,SURF154,,,,1 ! 3-D SURFACE EFFECT ELEMENT WITHOUT
! MIDSIDE NODES
CSYS,1
N,1,4,-2.5 ! DEFINE NODES
N,6,8,-2.5
FILL
NGEN,2,6,1,6,1,,5
NGEN,2,12,1,12,1,,,1
NUMCMP,ELEM
NUMSTR,ELEM,1
TYPE,1
MAT,1
E,1,2,8,7,13,14,20,19 ! DEFINE ELEMENTS
EGEN,5,1,-1
TYPE,2 ! CREATE SURF154 TO APPLY SURFACE PRESSURE LOADING
NSEL,S,NODE,,1,7,6
NSEL,A,NODE,,13,19,6
ESURF
NSEL,ALL
NROTAT,ALL ! ROTATE ALL NODES INTO CYLINDRICAL COORDINATES
CPDELE,1,1,1 ! REMOVE NODAL COUPLING
SFDELE,ALL,PRES ! REMOVE NODAL PRESSURES
D,ALL,UY,0.0 ! CONSTRAIN ALL NODES IN TANGENTIAL DIRECTION
NSEL,S,LOC,Z,1 ! SELECT NODES AT Z = 1
CP,1,UZ,ALL ! COUPLE SELECTED NODES IN UZ DIRECTION TO
! SIMULATE GENERALIZED 3-D PLANE STRAIN BEHAVIOR
NSEL,S,LOC,Z,0 ! CONSTRAIN NODES AT Z = 0 IN UZ DIRECTION
D,ALL,UZ
NSEL,ALL
FINISH
/SOLU
ESEL,S,TYPE,,2 ! SELECT SURF154 ELEMENTS TO APPLY SURFACE PRESSURE
! LOADING FOR ELASTIC ANALYSIS
SFE,ALL,1,PRES,,12990
ESEL,ALL
OUTPR,BASIC,1
SOLVE

finish

/POST1
ETABLE,STRS_R,S,X
ETABLE,STRS_T,S,Y
*GET,SIGR_I,ELEM,1,ETAB,STRS_R
*GET,SIGT_I,ELEM,1,ETAB,STRS_T
*GET,SIGR_O,ELEM,5,ETAB,STRS_R
*GET,SIGT_O,ELEM,5,ETAB,STRS_T

LABEL(1,1) = 'SIGR LFT','SIGT LFT','SIGR RT_','SIGT RT_'
LABEL(1,2) = '_END psi','_END psi','END psi ','END psi '
*VFILL,VALUE(1,1),DATA,-9984,18645,-468,9128
*VFILL,VALUE(1,2),DATA,SIGR_I,SIGT_I,SIGR_O,SIGT_O
*VFILL,VALUE(1,3),DATA,ABS(SIGR_I/9984),ABS(SIGT_I/18645)
*VFILL,VALUE(3,3),DATA,ABS(SIGR_O/468),ABS(SIGT_O/9128)
SAVE,TABLE_3
FINISH

/solu

ESEL,S,TYPE,,2 ! SELECT SURF154 ELEMENTS TO APPLY SURFACE PRESSURE
! LOADING FOR PLASTIC ANALYSIS
SFE,ALL,1,PRES,,24012
ESEL,ALL
SOLVE
FINISH
/POST1
RESUME,TABLE_1
/COM
/OUT,vm38,vrt
/COM,------------------- VM38 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,FULLY ELASTIC, PLANE42 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM,FULLY ELASTIC, PLANE45 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM38 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm38,vrt



VM39 (Bending of a Circular Plate with a Center Hole) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM39
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM39, BENDING OF A CIRCULAR PLATE WITH A CENTER HOLE
C*** STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 111, EQNS. (E,F)
ANTYPE,STATIC
ET,1,SHELL63
R,1,.25 ! DEFINE PLATE THICKNESS = .25
MP,EX,1,30.E6
MP,NUXY,1,.3
CSYS,1 ! DEFINE CYLINDRICAL C.S.
N,1,10 ! BEGIN NODE DEFINITION
N,7,30
FILL,,,,,,,,3 ! USE 3:1 SPACING RATIO FOR FILLING IN NODES
NGEN,2,10,1,7,1,,10
NROTAT,1,17,1
E,1,2,12,11 ! DEFINE FIRST ELEMENT
EGEN,6,1,1 ! GENERATE NEXT 5 ELEMENTS
D,1,ALL,,,11,10 ! CONSTRAIN INNER EDGE IN ALL D.O.F.
D,2,UY,,,7,,ROTX,ROTZ ! CONSTRAIN LOWER EDGE AGAINST ROTATIONS IN X & Z
D,12,UY,,,17,,ROTX,ROTZ ! CONSTRAIN UPPER EDGE AGAINST ROTATIONS IN X & Z
F,7,MY,-26.18,,17,10 ! APPLY MOMENT LOAD AT OUTER EDGE
OUTPR,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
/WINDOW,1,TOP ! SET UP WINDOW 1 FOR DISPLACEMENT CONTOUR DISPLAY
/PLOPTS,MINM,OFF ! TURN OFF MN AND MX DUE TO INSTABILITY
PLNSOL,U,Z ! DISPLAY PERPENDICULAR DISPLACEMENTS AS CONTOURS
/WINDOW,1,OFF ! TURN OFF WINDOW 1
/NOERASE ! TURN OFF AUTOMATIC ERASE BETWEEN DISPLAYS
/WINDOW,2,BOT ! SET UP WINDOW 2 FOR EDGE DISPLACEMENT DISPLAY
/VIEW,2,,-1 ! CHANGE VIEW FOR WINDOW 2
PLDISP,1 ! DISPLAY UNDISPLACED & DISPLACED SHAPES
SHELL,TOP
ESEL,,,,1 ! SELECT INNER ELEMENT(ELEM #1)
ETABLE,MOMX,SMISC,4 ! RETRIEVE MOMENT(X) AND SX AT TOP
ETABLE,SIGX,S,X
PRETAB,GRP1 ! PRINT STORED VALUES
*GET,M1,ETAB,1,ELEM,1
*GET,P1,ETAB,2,ELEM,1
ESEL,,,,6 ! SELECT OUTER ELEMENT(ELEM#6)
ETABLE,REFL
PRETAB,GRP1 ! PRINT STORED VALUES
*GET,M2,ETAB,1,ELEM,6
*GET,P2,ETAB,2,ELEM,6
ESEL,ALL
RSYS,1
PRNSOL,S,COMP ! PRINT NODAL STRESSES
NSEL,S,LOC,X,30 ! SELECT NODES AT R=A
PRNSOL,DOF ! PRINT DISPLACEMENTS
*GET,DEF,NODE,7,U,Z
*GET,ROT,NODE,7,ROT,Y
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'DEFLECTI','MX_SLOPE'
LABEL(1,2) = 'ON (in) ','(rad) '
*VFILL,VALUE(1,1),DATA,.049064,-.0045089
*VFILL,VALUE(1,2),DATA,DEF,ROT
*VFILL,VALUE(1,3),DATA,ABS(DEF/.049064 ) ,ABS( ROT/.0045089)
/COM
/OUT,vm39,vrt
/COM,------------------- VM39 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.7,' ',F10.7,' ',1F5.3)
/COM,----------------------------------------------------------
/NOPR
LABEL(1,1) = 'MOMENT ','PRESSURE'
LABEL(1,2) = 'in-lb/in',' psi '
*VFILL,VALUE(1,1),DATA,-13.783,-1323.2
*VFILL,VALUE(1,2),DATA,M1,P1
*VFILL,VALUE(1,3),DATA,ABS(M1/13.783),ABS(P1/1323.2)
/GOPR
/COM,----------------------------------------------------------
/COM,
/COM,X=10.81 in | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/NOPR
LABEL(1,1) = 'MOMENT ','PRESSURE'
LABEL(1,2) = 'in-lb/in',' psi '
*VFILL,VALUE(1,1),DATA,-10.127,-972.22
*VFILL,VALUE(1,2),DATA,M2,P2
*VFILL,VALUE(1,3),DATA,ABS(M2/10.127),ABS(P2/972.22)
/GOPR
/COM,----------------------------------------------------------
/COM,
/COM,X=27.1 in | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm39,vrt



VM40 (Large Deflection and Rotation of a Beam Pinned at One End) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM40
/PREP7
MP,PRXY,,0.3
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM40, LARGE DEFLECTION AND ROTATION OF A BEAM PINNED AT ONE END
C*** REFERENCE - ANY BASIC MATHEMATICS BOOK
PI=(4.0)*ATAN(1.0) ! ANALYST FORGETS VALUE OF PI - LETS ANSYS CALCULATE IT
ANTYPE,TRANS ! NONLINEAR TRANSIENT DYNAMIC ANALYSES
NLGEOM,ON ! LARGE DEFLECTIONS
ET,1,BEAM3
R,1,1,1,1 ! ARBITRARY GEOMETRIC PROPERTIES
MP,EX,1,30E6 ! DEFINE MATERIAL PROPERTIES
MP,DENS,1,1E-10 ! DEFINE DENSITY OF ALMOST ZERO
N,1 ! BEGIN NODAL DEFINITION
N,2,10
E,1,2 ! DEFINE ELEMENT
FINISH
/SOLU
SOLCONTROL,0
D,1,ROTZ,PI*2 ! ONE COMPLETE REVOLUTION
D,1,UX,,,,,UY ! CONSTRAIN NODE 1 (PINNED END OF BEAM)
NSUBST,24
TIME,.15 ! TIME STEP OF 0.00625 SEC. (.15/24)
OUTRES,NSOL,1 ! SAVE NODAL DOF SOLUTION FOR EVERY SUBSTEP
OUTRES,ESOL,1 ! SAVE ELEMENT SOLUTION FOR EVERY SUBSTEP
CNVTOL,F,1,0.00001 ! CONVERGENCE CRITERION BASED UPON FORCES
CNVTOL,M,1,0.00001 ! CONVERGENCE CRITERION BASED UPON MOMENTS
SOLVE
FINISH
/POST26
NSOL,2,2,U,X,UX ! DEFINE NODE 2 UX DISP AS VARIABLE 2
NSOL,3,2,U,Y,UY ! DEFINE NODE 2 UY DISP AS VARIABLE 3
NSOL,4,1,ROT,Z,ROTZ ! DEFINE NODE 1 ROTZ AS VARIABLE 4
ESOL,6,1,,LS,4,SDIR ! GET AXIAL STRESS OF ELEMENT AT NODE 2
DERIV,5,4,,,INPUT_W ! CALCULATE DERIVATIVE OF VAR. 4 WRT VARIABLE 1 (TIME)
PRVAR,2,3,4,5,6 ! PRINT VARIABLES 1 THRU 6
PLVAR,2,3 ! DISPLAY VARIABLES 2 AND 3 AS A FUNCTION OF TIME
STORE
*GET,MX_STRS,VARI,6,EXTREM,VMAX
*GET,DEFX_60,VARI,2,RSET,4
*GET,DEFY_90,VARI,3,RSET,6
*GET,DEFX_180,VARI,2,RSET,12
*GET,DEFY_210,VARI,3,RSET,14
*GET,DEFX_315,VARI,2,RSET,21
*GET,DEFY_360,VARI,3,RSET,24
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
*DIM,STRSS,,1,1
*VFILL,STRSS(1,1),DATA,MX_STRS
LABEL(1,1) = '60 DEG, ','90 DEG, ','180 DEG,','180 DEG,','180 DEG,','180 DEG,'
LABEL(1,2) = ' UX (in)',' UY (in)',' UX (in)',' UX (in)',' UX (in)',' UX (in)'
*VFILL,VALUE(1,1),DATA,-5,10,-20,-5,2.93,0
*VFILL,VALUE(1,2),DATA,DEFX_60,DEFY_90,DEFX_180,DEFY_210,DEFX_315,DEFY_360
*VFILL,VALUE(1,3),DATA,ABS(DEFX_60/5),ABS(DEFY_90/10),ABS(DEFX_180/20),ABS(DEFY_210/5)
*VFILL,VALUE(5,3),DATA,ABS(DEFX_315/2.93),0
/COM
/OUT,vm40,vrt
/COM,------------------- VM40 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,
/COM,THE MAXIMUM AXIAL STRESS IS:
*VWRITE,STRSS(1,1)
(1X,F4.2)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm40,vrt



VM41 (Small Deflection of a Rigid Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM41
/PREP7
MP,PRXY,,0.3
/TITLE, VM41, SMALL DEFLECTION OF A RIGID BEAM
!COM REFERENCE - ANY BASIC STRENGTH OF MATERIAL BOOK
!COM USING THICK BEAM GEOMETRY
ET,1,MATRIX27,,,4 ! KEYOPT(3)=4, INPUT DATA AS 12 X 12 STIFFNESS MATRIX
ET,2,BEAM3
R,1 ! TABLE 1 REAL CONSTANTS FOR MATRIX27 STIFFNESS MATRIX
RMODIF,1,51,10000 ! MODIFY POSITIONS 51, 57 AND 78 IN TABLE 1
RMODIF,1,78,10000 ! RMODIF USED, RATHER THAN RMORE, FOR EASIER INPUT
RMODIF,1,57,-10000
R,2,100,1000,10 ! RIGID BEAM PROPERTIES
MP,EX,1,30E6
N,1
N,2
N,3,10
E,1,2 ! STIFFNESS MATRIX ELEMENT
TYPE,2
REAL,2
E,2,3 ! BEAM ELEMENT
OUTPR,ALL,1 ! PRINT ALL ITEMS
D,1,ROTZ
D,2,UX,,,,,UY
F,3,FY,-10
FINISH
/SOLU
SOLVE
FINISH
/POST26
ESOL,2,2,,LS,2,SBEN
STORE
*GET,STRS_BEN,VARI,2,EXTREM,VMAX
FINISH
/POST1
*GET,DEF_X,NODE,3,U,X
*GET,DEF_Y,NODE,3,U,Y
*GET,ROT_Z,NODE,3,ROT,Z
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'DEFLECTI','DEFLECTI','ROTATION','SIG_BEND'
LABEL(1,2) = 'ON_X(in)','ON_Y(in)',' (rad)',' (psi)'
*VFILL,VALUE(1,1),DATA,0,-.1,-.01,0
*VFILL,VALUE(1,2),DATA,DEF_X,DEF_Y,ROT_Z,STRS_BEN
*VFILL,VALUE(1,3),DATA,0,ABS(DEF_Y/.1 ),ABS(ROT_Z/.01),0
SAVE,TABLE_1
FINISH
/PREP7
!COM USING CONSTRAINT EQUATIONS
R,2,.0625,.00032552,.25 ! BEAM PROPERTIES
CE,1,,3,UY,1,2,ROTZ,-10 ! CONSTRAINT EQUATION
FINISH
/SOLU
SOLVE
FINISH
/POST26
ESOL,2,2,,LS,2,SBEN
STORE
*GET,STRS_BEN,VARI,2,EXTREM,VMAX
FINISH
/POST1
*GET,DEF_X,NODE,3,U,X
*GET,DEF_Y,NODE,3,U,Y
*GET,ROT_Z,NODE,3,ROT,Z
LABEL(1,1) = 'DEFLECTI','DEFLECTI','ROTATION','SIG_BEND'
LABEL(1,2) = 'ON_X(in)','ON_Y(in)',' (rad)',' (psi)'
*VFILL,VALUE(1,1),DATA,0,-.1,-.01,0
*VFILL,VALUE(1,2),DATA,DEF_X,DEF_Y,ROT_Z,STRS_BEN
*VFILL,VALUE(1,3),DATA,0,ABS(DEF_Y/.1 ),ABS(ROT_Z/.01),0
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm41,vrt
/COM,------------------- VM41 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS FOR THICK BEAM:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS WITH CONSTRAINT EQUATION:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm41,vrt



VM42 (Barrel Vault Roof Under Self Weight) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM42
/PREP7
smrt,off
/TITLE, VM42, BARREL VAULT ROOF UNDER SELF WEIGHT
/COM, REF: COOK, CONCEPTS AND APPL. OF F.E.A., 2ND ED., 1981, PP. 284-287.
ANTYPE,STATIC
ET,1,SHELL93
R,1,0.25
MP,EX,1,4.32E8 ! MATERIAL PROPERTIES
MP,NUXY,1,0.0
MP,DENS,1,36.7347
CSYS,1
K,1,25,50
K,2,25,50,25 ! DEFINE KEYPOINTS AND AREA
KGEN,2,1,2,1,,40
A,1,3,4,2
ESIZE,,4
AMESH,1
CSYS,0 ! SWITCH BACK TO GLOBAL CARTESIAN C.S.
NSEL,S,LOC,X
DSYM,SYMM,X ! CONSTRAIN SYMMETRY PLANES
NSEL,S,LOC,Z
DSYM,SYMM,Z
NSEL,S,LOC,Z,25
D,ALL,UX,0,,,,UY,ROTZ ! CONSTRAIN END OF ROOF
NSEL,ALL
ACEL,,9.8
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,NODE,,1,2,1 ! SELECT NODES AT POINTS A AND B
ESLN,S ! SELECT ELEMENTS CONTAINING NODES
PRNSOL,U,COMP
*GET,UYA,NODE,1,U,Y
*GET,UXA,NODE,1,U,X
RSYS,1 ! DISPLAY RESULTS IN CYLINDRICAL SYSTEM
SHELL,TOP
PRNSOL,S,COMP
*GET,SIGZ_TOP,NODE,1,S,Z
*GET,SIGY_TOP,NODE,2,S,Y
SHELL,BOT
PRNSOL,S,COMP
*GET,SIGZ_BOT,NODE,1,S,Z
*GET,SIGY_BOT,NODE,2,S,Y
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
LABEL(1,1) = 'UYA ','UXA ','SIGZ, TO','SIGZ, BO','SIGTH,TO','SIGTH,BO'
LABEL(1,2) = ' (m)',' (m)','P_A (PA)','T_A (PA)','P_B (PA)','T_B (PA)'
*VFILL,VALUE(1,1),DATA,-.3019,-.1593,215570,340700,191230,-218740
*VFILL,VALUE(1,2),DATA,UYA,UXA,SIGZ_TOP,SIGZ_BOT,SIGY_TOP,SIGY_BOT
*VFILL,VALUE(1,3),DATA,ABS(UYA/.3019 ),ABS(UXA/.1593 ),ABS(SIGZ_TOP/215570 )
*VFILL,VALUE(4,3),DATA,ABS(SIGZ_BOT/340700),ABS(SIGY_TOP/191230),ABS(SIGY_BOT/218740)
/COM
/OUT,vm42,vrt
/COM,------------------- VM42 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F12.4,' ',F12.4,' ',1F5.3)
/COM,-----------------------------------------------------------

/OUT
FINISH
*LIST,vm42,vrt



VM43 (Bending of an Axisymmetric Thick Pipe Under Gravity Loading) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM43
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM43, BENDING OF AN AXISYMMETRIC THICK PIPE UNDER GRAVITY LOADING
C*** FORMULAS FOR STRESS AND STRAIN, ROARK, 4TH ED., PAGE 112, NO. 33
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,PLANE25,,,,,,2 ! PLANE25
MP,EX,1,30.E6 ! DEFINE MATERIAL PROPERTIES
MP,DENS,1,.00073
MP,NUXY,1,0 ! DEFINE NUXY AS 0.0
K,1,.5 ! DEFINE KEYPOINTS
K,2,.5,100
KGEN,2,1,2,1,.5 ! GENERATE 2 ADDITIONAL KEYPOINTS IN X DIRECTION
L,1,2 ! DEFINE LINES AND NUMBER OF DIVISIONS
LESIZE,1,,,12
L,2,4
LESIZE,2,,,1
L,3,4
LESIZE,3,,,12
L,1,3
LESIZE,4,,,1
A,3,1,2,4 ! DEFINE AREA
AMESH,1 ! MESH AREA 1
ACEL,386,,-386 ! GRAVITY AS THE SUM OF TWO HARMONICALLY VARYING LOADS
MODE,1,1 ! SYMMETRIC HARMONIC LOAD
NSEL,S,LOC,Y,0 ! SELECT NODES AT Y=0
D,ALL,ALL ! CONSTRAIN IN ALL DOF
NSEL,S,LOC,Y,100 ! SELECT NODES AT Y=100
D,ALL,UY ! CONSTRAIN IN Y DISPLACEMENT DOF (SYMMETRY PLANE)
NSEL,ALL
FINISH
/SOLU
OUTPR,BASIC,LAST ! PRINT BASIC SOLUTION
SOLVE
FINISH
/POST1
SET,1,1,,,,0.0 ! READ IN RESULTS AT ANGLE=0.0
/VUP,1,X ! DEFINE X AXIS AS VERTICAL AXIS FOR DISPLAYS
/WINDOW,1,-1,1,0,1 ! DEFINE AND TURN ON WINDOW 1
PLDISP,1 ! DISPLAY UNDISPLACED AND DISPLACED SHAPE OF PIPE
PRNSOL,U,COMP ! PRINT DISPLACEMENTS
*GET,DEF_X,NODE,3,U,X
SET,1,1,,,,90.0 ! READ IN RESULTS AT ANGLE=90.0
/WINDOW,1,OFF ! TURN OFF WINDOW 1
/NOERASE ! DON'T ERASE EXISTING DISPLAY
/WINDOW,2,-1,1,-1,0 ! DEFINE AND TURN ON WINDOW 2
/VUP,2,X ! DEFINE X AXIS AS VERTICAL AXIS FOR DISPLAYS
PLDISP,1 ! DISPLAY UNDIS. AND DISP. SHAPE AT NEW ANGLE
PRNSOL,U,COMP ! PRINT DISPLACEMENTS
*GET,DEF_Z,NODE,3,U,Z
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'UX, IN ','UZ, IN ('
LABEL(1,2) = '(ANG=0) ','ANG=90) '
*VFILL,VALUE(1,1),DATA,-.12524,.12524
*VFILL,VALUE(1,2),DATA,DEF_X,DEF_Z
*VFILL,VALUE(1,3),DATA,ABS(DEF_X/.12524 ) ,ABS( DEF_Z/.12524)
/COM
/OUT,vm43,vrt
/COM,------------------- VM43 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM43 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm43,vrt



VM44 (Bending of an Axisymmetric Thin Pipe Under Gravity Loading) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM44
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM44, BENDING OF AN AXISYMMETRIC THIN PIPE UNDER GRAVITY LOADING
C*** FORMULAS FOR STRESS AND STRAIN, ROARK, 4TH ED., PAGE 112, NO. 33
ANTYPE,STATIC
ET,1,SHELL61,,,,,,1 ! PRINT DISP. AT ELEMENT ENDS AS WELL AS MIDPOINT
R,1,.1 ! DEFINE WALL THICKNESS
MP,EX,1,30.E6 ! DEFINE MATERIAL PROPERTIES
MP,DENS,1,.00073 ! DEFINE DENSITY
MP,NUXY,1,0 ! DEFINE NUXY AS 0.0
N,1,1 ! BEGIN NODE DEFINITION
N,8,1,125
FILL ! PLACE NODES 2 THRU 7 BETWEEN NODES 1 & 8
E,1,2 ! BEGIN ELEMENT DEFINITION
EGEN,7,1,1 ! GENERATE NEXT 6 ELEMENTS
CE,1,,2,UY,1,2,ROTZ,-1 ! DEFINE FIRST CONSTRAINT EQN. (UY(2) = ROTZ(2))
*REPEAT,6,1,,1,,,1 ! REPEAT FOR NODES 3 TO 7
CE,7,,2,UX,1,2,UZ,1 ! UX(2) = -UZ(2) AND FOR 6 INTERIOR NODES
*REPEAT,6,1,,1,,,1
OUTPR,ALL,ALL
ACEL,386,,-386 ! GRAVITY AS THE SUM OF TWO HARMONICALLY VARYING LOADS
MODE,1,1 ! MODE NUMBER 1, SYMMETRIC LOADING
D,1,ALL ! FIXED END
NSEL,S,LOC,Y,125
DSYM,SYMM,Y ! CENTER PLANE END
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
SET,1,1,,,,0.0 ! GET RESULTS AT 0 DEGREES
/VUP,1,X ! DEFINE X AXIS AS VERTICAL FOR VIEWING
/WINDOW,1,TOP ! DEFINE WINDOW 1 AS TOP HALF OF SCREEN
PLDISP,1 ! DISPLAY BOTH DISTORTED AND UNDISTORTED GEOMETRY
PRNSOL,DOF ! PRINT DEGREE OF FREEDOM VALUES
LCOPER,LPRIN ! CALCULATE PRINCIPAL STRESSES
PRESOL,ELEM ! PRINT ELEMENT SOLUTION RESULTS
ETABLE,STRS,NMISC,11
*GET,STRSS,ELEM,1,ETAB,STRS
*GET,DEF_X,NODE,8,U,X
SET,1,1,,,,90.0 ! STUDY RESULTS AT 90.0 DEGREES
/WINDOW,1,OFF ! TURN-OFF WINDOW 1
/WINDOW,2,BOT ! DEFINE WINDOW 2 AS BOTTOM HALF OF SCREEN
/NOERASE ! OVERLAY NEXT DISPLAY (DON'T ERASE WINDOW 1)
/VUP,2,X
PLDISP ! DISPLAY ONLY DISTORTED GEOMETRY
PRNSOL,U,COMP ! PRINT DISPLACEMENTS
*GET,DEF_Z,NODE,8,U,Z
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'UX, in ','UZ, in ','SIGMX,ps'
LABEL(1,2) = ' (ANG=0)','(ANG=90)','i(ANG=90'
*VFILL,VALUE(1,1),DATA,-.19062,.19062,3074.3
*VFILL,VALUE(1,2),DATA,DEF_X,DEF_Z,STRSS
*VFILL,VALUE(1,3),DATA,ABS(DEF_X/.19062),ABS(DEF_Z/.19062),ABS(STRSS/3074.3)
/COM
/OUT,vm44,vrt
/COM,------------------- VM44 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,-----------------------------------------------------------

/OUT
FINISH
*LIST,vm44,vrt



VM45 (Natural Frequency of a Spring-mass System) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM45
/PREP7
/TITLE, VM45, NATURAL FREQUENCY OF A SPRING-MASS SYSTEM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 6, EX. 1.2-2
ANTYPE,MODAL
MODOPT,REDUC,1,,,1 ! PRINT ALL REDUCED MODE SHAPES
ET,1,COMBIN14,,,2 ! TWO-DIMENSIONAL LONGITUDINAL SPRING
ET,2,MASS21,,,4 ! TWO-DIMENSIONAL MASS
R,1,48
R,2,.006477
N,1
N,2,,1
E,1,2
TYPE,2
REAL,2
E,2
M,2,UY ! MASTER DOF IN Y DIRECTION AT FREE END OF SPRING
OUTPR,ALL,1
OUTRES,ALL,0
D,1,ALL
D,2,UX
FINISH
/SOLU
SOLVE
*GET,FREQ,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' F,'
LABEL(1,2) = ' (Hz) '
*VFILL,VALUE(1,1),DATA,13.701
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/13.701)
/COM
/OUT,vm45,vrt
/COM,------------------- VM45 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------

/OUT
FINISH
*LIST,vm45,vrt



VM46 (Flow Between Rotating Concentric Cylinders) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM46
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM46, FLOW BETWEEN ROTATING CONCENTRIC CYLINDERS
! VISCOUS FLUID FLOW, WHITE, P. 110
!
! -- PARAMETERS --
R1 = 1.0 ! RADIUS OF INNER CYLINDER
R2 = 2.0 ! RADIUS OF OUTER CYLINDER
NX = 30 ! NUMBER OF X DIVISIONS
THETA = 10.0 ! CYLINDER ENDING ANGLE
NY = 2 ! NUMBER OF Y DIVISIONS
LZ = 1.0 ! LENGTH IN Z DIRECTION
NZ = 2 ! NUMBER OF Z DIVISIONS
OMEGA = 1.0 ! ANGULAR VELOCITY
RHO = 1.0 ! FLUID DENSITY
MU = 1.0 ! FLUID VISCOSITY
! -- MODEL --
/PREP7
smrt,off
ET,1,FLUID142,,,3 ! 3D RTZ SYSTEM
MSHK,1 ! MAPPED VOLUME MESH
MSHA,0,3D ! USING HEX
CYLIND,R1,R2,,LZ,,THETA
LSEL,S,,,1,8,7
LSEL,A,,,3,6,3
LESIZE,ALL,,,NX,-20
LSEL,S,,,2,7,5
LSEL,A,,,4,5
LESIZE,ALL,,,NY
LSEL,S,,,9,12
LESIZE,ALL,,,NZ
ALLSEL
VMESH,1
ASEL,S,,,4 ! INNER CYLINDER BOUNDARY CONDITIONS
NSLA,S,1
D,ALL,VX
D,ALL,VY
D,ALL,VZ
ASEL,S,,,3 ! OUTER CYLINDER BOUNDARY CONDITIONS
NSLA,S,1
D,ALL,VX
D,ALL,VY,-R2*OMEGA
D,ALL,VZ
D,ALL,PRES
D,ALL,ENKE,-1
ASEL,S,,,5 ! PERIODIC BOUNDARY CONDITIONS
NSLA,S,1
D,ALL,VX
D,ALL,VX
PERI,,THETA ! PERIODIC BC MACRO
ASEL,S,,,1,2 ! SYMMETRY BOUNDARY CONDITIONS
NSLA,S,1
D,ALL,VX
D,ALL,VZ
ALLSEL
FINISH
! -- SOLUTION --
/SOLU
FLDATA,ITER,EXEC,200 ! NUMBER OF GLOBAL ITERATIONS
FLDATA,NOMI,DENS,RHO ! NOMINAL DENSITY
FLDATA,NOMI,VISC,MU ! NOMINAL VISCOSITY
FLDATA,OUTP,TAUW,T ! OUTPUT WALL SHEAR STRESS
CGOMGA,,,OMEGA ! ANGULAR VELOCITY OF ROTATING CS
SAVE
/OUTPUT,SCRATCH ! DIVERT OUTPUT
SOLVE
/OUTPUT
FINISH
!
! -- POST PROCESSING --
/POST1
SET,LAST
CSYS,1 ! GLOBAL CYLINDRICAL CS
RSYS,1 ! CYLINDRICAL RESULTS CS
*DIM,RES1,,NX+1,6 ! DIMENSION RESULTS ARRAY #1
NSEL,S,LOC,Y,THETA/2 ! RESULTS ACROSS FLOW SECTION
NSEL,R,LOC,Z,LZ/2
*DO,I,1,NX+1
*GET,XMAX,NODE,,MXLOC,X
N = NODE(XMAX,THETA/2,LZ/2)
RES1(I,1) = N ! NODE NUMBER
RES1(I,2) = NX(N) ! X-COORDINATE
RES1(I,3) = VY(N) ! VY (FLOTRAN)
RES1(I,4) = R1**2*OMEGA*(R2**2/NX(N) - NX(N))/(R2**2 - R1**2)
RES1(I,4) = RES1(I,4) - OMEGA*NX(N) ! VY (EXACT)
NSEL,U,,,N
*ENDDO
/COM
/COM
/COM
/COM CIRCUMFERENTIAL VELOCITY BETWEEN CYLINDERS AT (X,THETA/2,LZ/2):
/COM
*VWRITE
(4X,'NODE',12X,'X',9X,'VY (FLOTRAN)',7X,'VY (EXACT)')
*VWRITE,RES1(1,1),RES1(1,2),RES1(1,3),RES1(1,4)
(3X,F5.0,3(1PE17.5))
/COM
/COM
ALLSEL
PATH,CYLS,2,,48 ! DEFINE PATH WITH NAME = "CYLS"
PPATH,1,,R1,0,0 ! DEFINE PATH POINTS BY LOCATION
PPATH,2,,R2,0,0
PDEF,VY,VY
/AXLAB,X,RADIAL PATH COORDINATE
/AXLAB,Y,CIRCUMFERENTIAL VELOCITY
PLPATH,VY ! VELOCITY DISTRIBUTION
/DEVICE,VECTOR,ON
/PLOPTS,MINM,OFF
PLNSOL,PRES ! PRESSURE CONTOURS
FINISH
CSYS,1
VY_R = NODE(1.5,0,0)
*GET,VELY,NODE,VY_R,V,Y
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'VY (R=1.'
LABEL(1,2) = '5) '
*VFILL,VALUE(1,1),DATA,-1.111
*VFILL,VALUE(1,2),DATA,VELY
*VFILL,VALUE(1,3),DATA,ABS(VELY /1.111 )
/COM
/OUT,vm46,vrt
/COM,------------------- VM46 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
/DELETE,SCRATCH
/DELETE,vm46,pfl
/DELETE,vm46,rsw

FINISH
*LIST,vm46,vrt



VM47 (Torsional Frequency of a Suspended Disk) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM47
/PREP7
/TITLE, VM47, TORSIONAL FREQUENCY OF A SUSPENDED DISK
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 10, EX 1.3-2
ANTYPE,MODAL
MODOPT,REDUC,,,,1 ! PRINT REDUCED MODE SHAPE
ET,1,COMBIN14,,,1 ! THREE-DIMENSIONAL TORSIONAL SPRING
ET,2,MASS21,,,3 ! TWO-DIMENSIONAL MASS WITH ROTARY INERTIA
R,1,4.8 ! REAL CONSTANT SET #1 SPRING CONSTANT
R,2,1,.30312 ! REAL CONSTANT SET #2 MASS & IZZ(J)
N,1 ! BEGIN NODE DEFINITION
N,2,,,-1
E,1,2 ! DEFINE BEAM ELEMENT
TYPE,2 ! DEFINE ACTIVE ELEMENT TYPE AS SET 2
REAL,2 ! DEFINE ACTIVE REAL CONSTANT TYPE AS SET 2
E,2 ! DEFINE MASS AT END OF WIRE
M,2,ROTZ ! MASTER DOF IN ROTZ DIRECTION AT FREE END OF SPRING
OUTPR,BASIC,1
D,1,ALL ! CONSTRAIN END OF WIRE IN ALL DOF
D,2,UX,,, ,,UY,UX ! PREVENT TRANSLATION OF THE MASS
FINISH
/SOLU
SOLVE
*GET,FREQ,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' F,'
LABEL(1,2) = ' (Hz) '
*VFILL,VALUE(1,1),DATA,.63333
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/.63333 )
/COM
/OUT,vm47,vrt
/COM,------------------- VM47 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT

FINISH
*LIST,vm47,vrt



VM48 (Natural Frequency of a Motor-Generator) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM48
/PREP7
MP,PRXY,,0.3
/TITLE, VM48, NATURAL FREQUENCY OF A MOTOR-GENERATOR
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 10, EX 1.3-3
ANTYPE,MODAL
MODOPT,REDUC,1,,,1 ! PRINT ALL REDUCED MODE SHAPES
ET,1,PIPE16 ! ELASTIC STRAIGHT PIPE
ET,2,MASS21 ! GENERALIZED MASS
R,1,.375,.1875 ! REAL CONSTANT SET 1 O.D. OF PIPE AND WALL THICKNESS
R,2,,,,31E-3 ! REAL CONSTANT SET 2 IXX
MP,EX,1,31.2E6 ! DEFINE MODULUS OF ELASTICITY
N,1 ! BEGIN NODE DEFINITION
N,2,8
E,1,2 ! DEFINE PIPE ELEMENT
TYPE,2 ! DEFINE ACTIVE ELEMENT TYPE AS SET #2
REAL,2 ! DEFINE ACTIVE REAL CONSTANT TYPE AS SET #2
E,2 ! DEFINE MASS AT END OF PIPE
M,2,ROTX ! MASTER DOF IN ROTX DIRECTION AT FREE END OF PIPE
OUTPR,BASIC,1
D,ALL,ALL ! CONSTRAIN ALL DOF'S
DDELE,2,ROTX ! RELEASE TORSIONAL DOF AT NODE 2
FINISH
/SOLU
SOLVE
*GET,FREQ,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' F,'
LABEL(1,2) = ' (Hz) '
*VFILL,VALUE(1,1),DATA,48.781
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/48.781)
/COM
/OUT,vm48,vrt
/COM,------------------- VM48 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------

/OUT
FINISH
*LIST,vm48,vrt



VM49 (Electrostatic Field Analysis of Quadpole Wires in Open Air) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM49
/PREP7
SMRT,OFF
/TITLE, VM49, ELECTROSTATIC FIELD ANALYSIS OF QUADPOLE WIRES IN OPEN AIR
C*** ANY BASIC STATIC AND DYNAMIC ELECTRICITY BOOK
ANTYPE,STATIC
ET,1,PLANE121 ! 2-D 8-NODE ELECTROSTATIC ELEMENT
ET,2,INFIN110,1 ! 2-D 4-NODE INFINITE ELEMENT WITH VOLT DOF
EMUNIT,MKS ! MKS UNIT
MP,PERX,1,1 ! ELECTRICAL PERMITTIVITY
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM
PCIRC,25.4/1000,0,90 ! QUARTER CIRCULAR AREA
PCIRC,50.8/1000,0,90
PCIRC,470/1000,0,90
AOVLAP,1,2,3 ! OVERLAP AREAS
KPSCALE,7,8,1,2 ! SCALE KEYPOINTS 7 & 8 TO DOUBLE
L,7,6
L,6,9
L,8,9
AL,7,5,6,8
LSEL,S,LINE,,1,4,1 ! SELECT LINES
LSEL,A,LINE,,6,7
LSEL,A,LINE,,10,11
LESIZE,ALL,,,10 ! DIVIDE THE SELECTED LINES INTO TEN
! DIVISION
LSEL,ALL
LSEL,S,LINE,,12,13
LESIZE,ALL,,,30,10
LSEL,ALL
LSEL,S,LINE,,5,8,3
LESIZE,ALL,,,1
LSEL,ALL
TYPE,2 ! USE ELEMENT TYPE 2
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USING QUADS
ESIZE,,1 ! CREATE 1 ELEMENT PER LINE DIVISION
ASEL,S,AREA,,2
AMESH,ALL ! MESH THE AREA 2
ASEL,ALL
ESIZE,,10 ! CREATE 10 ELEMENTS PER LINE DIVISION
TYPE,1 ! USE ELEMENT TYPE 1
ASEL,S,AREA,,1,4,3 ! SELECT AREAS
ASEL,A,AREA,,5
AMESH,ALL
NSEL,S,LOC,X,25.4/1000 ! SELECT NODES
NSEL,R,LOC,Y,0
F,ALL,CHRG,.5E-6 ! APPLY CHARGE AS POINT LOAD
NSEL,S,LOC,X,25.4/1000
NSEL,R,LOC,Y,90
F,ALL,CHRG,-.5E-6
NSEL,ALL
NSEL,S,LOC,X,940/1000
SF,ALL,INF ! FLAG THE EXTERIOR FACE OF INFIN110 AT
! INFINITE DISTANCE
NSEL,ALL
FINISH
/SOLU
OUTRES,ALL,ALL
OUTPR,,NONE
SOLVE
FINISH
/POST1
/COM SELECT THE NODES AT ANGLES FROM 0 TO 90 DEGREE WITH 10
/COM DIVISION ON SURFACE OF RADIUS 470 MM AND RETRIEVE THE
/COM ELECTRIC POTENTIAL, V
DSYS,1
*DIM,ANG,,11,2
*VFILL,ANG(1,1),RAMP,0,9
*DO,J,1,11
NSEL,S,LOC,X,470/1000
NSEL,R,LOC,Y,ANG(J,1)
*GET,NOD,NODE,,NUM,MAX
*GET,ANG(J,2),NODE,NOD,VOLT
NSEL,ALL
*ENDDO
*DIM,VLT,,11
*VFUN,VLT(1),COPY,ANG(1,2)
*DIM,VALUE,,11,2
*VFILL,VALUE(1,1),DATA,105.05,99.9,84.98,61.74,32.46,0,-32.46,-61.74,-84.98
*VFILL,VALUE(10,1),DATA,-99.98,-105.05
*VFILL,VALUE(1,2),DATA,ABS(VLT(1,1)/105.05 ),ABS(VLT(2,1)/99.9),ABS(VLT(3,1)/84.98)
*VFILL,VALUE(4,2),DATA,ABS(VLT(4,1)/61.74),ABS(VLT(5,1)/32.46),0
*VFILL,VALUE(7,2),DATA,ABS(VLT(7,1)/32.46),ABS(VLT(8,1)/61.74),ABS(VLT(9,1)/84.98)
*VFILL,VALUE(10,2),DATA,ABS(VLT(10,1)/99.98),ABS(VLT(11,1)/105.05 )
*DIM,LABEL,CHAR,11,2
*DO,I,1,11,1
LABEL(I,1) = 'V(VOLT) '
LABEL(I,2) = 'AT ANGLE'
*ENDDO
! WRITE DESIRED ANGLE AND POTENTIAL VALUES
/COM
/OUT,vm49,vrt
/COM,------------------- VM49 RESULTS COMPARISON ---------------
/COM,
/COM, |TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),ANG(1,1),VALUE(1,1),VLT(1),VALUE(1,2)
(1X,A8,A8,': ',F4.1,' ',F7.2,' ',F7.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm49,vrt



VM50 (Fundamental Frequency of a Simply Supported Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM50
/PREP7
/TITLE, VM50, FUNDAMENTAL FREQUENCY OF A SIMPLY SUPPORTED BEAM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 18, EX 1.5-1
ET,1,BEAM3 ! TWO DIMENSIONAL ELASTIC BEAM
MP,EX,1,30E6 ! DEFINE MATERIAL PROPERTIES
MP,DENS,1,728E-6
R,1,4,(4/3),2 ! DEFINE REAL CONSTANT SET FOR BEAM-AREA,IZZ & HEIGHT
K,1 ! BEGIN DEFINING KEYPOINTS
K,2,80
L,1,2 ! DEFINE LINE WITH
LESIZE,ALL,,,4 ! 4 DIVISIONS
LMESH,1 ! MESH LINE
FINISH
/SOLU
ANTYPE,MODAL
MODOPT,REDUC,3,,,3 ! PRINT ALL REDUCED MODE SHAPES
MXPAND,1 ! EXPAND FIRST MODE
M,3,UY,5 ! MASTER DOF IN Y DIRECTION AT NODES 3 THROUGH 5
OUTPR,ALL,1
DK,ALL,UX ! CONSTRAIN ENDS OF BEAM IN DISP. X DOF
DK,ALL,UY ! CONSTRAIN ENDS OF BEAM IN DISP. Y DOF
PSOLVE,ELFORM ! CREATE THE ELEMENT MATRICES
PSOLVE,TRIANG ! TRIANGULARIZE THE MATRICES
PSOLVE,EIGREDUC ! CALCULATE THE EIGENVALUES AND EIGENVECTORS USING HOUSEHOLDER
PSOLVE,EIGEXP ! EXPAND THE EIGENVECTOR SOLUTION
FINISH
/POST26
*GET,FREQ,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' f'
LABEL(1,2) = ', (Hz) '
*VFILL,VALUE(1,1),DATA,28.766
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/28.766)
/COM
/OUT,vm50,vrt
/COM,------------------- VM50 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm50,vrt



VM51 (Electrostatic Forces Between Charged Spheres) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM51
/config,nproc,4
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE,VM51, FORCE BETWEEN CHARGED SPHERES
! THE ELECTROMAGNETIC FIELD, SHADOWITZ, PAGE 61
/PREP7
smrt,off $ shpp,warn
mopt,amesh,alte
mopt,qmesh,alte
R1 = 1 ! SPHERE RADIUS
R2 = 3 ! DISTANCE BETWEEN SPHERES
R3 = 6 ! RADIUS OF FINITE ELEMENT DOMAIN
R4 = 1.25 ! MAXWELL SURFACE RADIUS
PER=8.854E-12 ! FREE SPACE PERMITIVITY
PI=3.14159265359
Q = 4*PI*PER ! TOTAL CHARGE
ALPHA = 30 ! SLICE ANGLE
AREA = 4*PI*(R1**2) ! TOTAL SPHERE AREA
CHRGS = Q/AREA ! SURFACE CHARGE
/NOPR
PCIRC,,R2,0,90 ! CIRCLE RADIUS R2, 0 TO 90 DEGREES
WPOFFS,,R2/2 ! WORKING PLANE OFFSET Y = R2/2
PCIRC,,R1,0,90 ! CIRCLE RADIUS R1, 0 TO 90 DEGREES
PCIRC,,R1,-90,0 ! CIRCLE RADIUS R1, 0 TO -90 DEGREES
PCIRC,,R4,-90,90 ! CIRCLE RADIUS R4, -90 TO 90 DEGREES
AOVLAP,ALL
NUMCMP,AREA
ET,1,PLANE121 ! 2-D 8-NODE ELECTROSTATIC SOLID
ET,2,SOLID122 ! 3-D 20-NODE ELECTROSTATIC SOLID
ET,3,MESH200,7 ! NEW MESH200 2-D 8-NODE ELEMENT TYPE
ET,4,INFIN111,2,1 ! 3-D INFINITE SOLID ELEMENT
MP,PERX,1,1
MP,PERX,2,1
CSYS,2 ! SPHERICAL COORDINATE SYSTEM
LSEL,S,LOC,X,R2
LESIZE,ALL,,,30 ! SET ELEMENT DIVISIONS = 20
ESIZE,,25 ! SET ELEMENT DIVISIONS FOR EXTRUDE REGION
TYPE,1
LOCAL,11,2,,R2/2 ! DEFINE COORDINATE SYSTEM AT SPHERE CENTER
LSEL,S,LOC,X,R1 ! SELECT LINES ON SPHERE SURFACE
LESIZE,ALL,,,25 ! SET ELEMENT DIVISIONS
LSEL,A,LOC,X,R4 ! SELECT LINES FOR MAXWELL SURFACE
LESIZE,ALL,,,50 ! SET ELEMENT DIVISIONS
CSYS,0 ! CARTESIAN COORDINATE SYSTEM
LSEL,S,LOC,Y, ! SELECT LINES AT Y = 0
LESIZE,ALL,,,40 ! SET ELEMENT DIVISIONS
MSHK,2 ! MAPPED AREA MESH IF POSSIBLE
MSHA,0,2D ! USING QUADS
LSEL,ALL
ESIZE,,5 ! SET ELEMENT DIVISIONS = 5
ALLSEL
AMAP,4,10,7,5,11 ! MAP MESH SPHERE TO MAXWELL SURFACE
AMESH,ALL
K,200 ! CREATE KEYPOINTS FOR ROTATION
K,201,,R3
MSHK,0 ! FREE MESH
MSHA,1, ! USING TRIS OR TETS
TYPE,2
ASEL,ALL
ESIZE,,3 ! 3 DIVISIONS IN ROTATE DIRECTION
MAT,1
VROTAT,ALL,,,,,,200,201,ALPHA ! ROTATE ALL AREAS THROUGH 30 DEGREES
CSYS,11 ! CUSTOM SPHERICAL COORDINATE SYSTEM
NSEL,S,LOC,X,0,R1*1.03 ! NODE SELECT RADIUS 0 TO R1
ESLN,S,1 ! ELEMENT SELECT FROM NODES
EMODIF,ALL,MAT,2 ! CHANGE MATERIAL PROPERTY TO 2
CSYS,2 ! SPHERICAL COORDINATE SYSTEM
KSEL,S,LOC,X,R2 ! KEYPOINT SELECT AT RADIUS R2
LSLK,S,1 ! LINE SELECT FROM KEYPOINTS
ASLL,S,1 ! AREA SELECT FROM LINES
TYPE,3 ! NEW MESH200 ELEMENT TYPE
AMESH,ALL ! MESH AREA AT RADIUS R2
ESIZE,,8 ! EIGHT ELEMENTS IN EXTRUDE DIRECTION
TYPE,2 ! SOLID122 USED FOR EXTRUDE
VEXT,ALL,,,R3-R2 ! EXTRUDE AREAS IN RADIAL DIRECTION
KSEL,S,LOC,X,R3 ! KEYPOINT SELECT AT RADIUS R3
LSLK,S,1 ! LINE SELECT FROM KEYPOINTS
ASLL,S,1 ! AREA SELECT FROM LINES
TYPE,3 ! NEW MESH200 ELEMENT TYPE
AMESH,ALL ! MESH AREA AT RADIUS R3
ESIZE,,1 ! ONE DIVISION IN EXTRUDE DIRECTION
TYPE,4 ! INFIN122 USED FOR EXTRUDE
VEXT,ALL,,,R3 ! EXTRUDE AREA IN RADIAL DIRECTION
ALLSEL ! SELECT ALL ENTITIES

/OUTPUT,SCRATCH
NUMMRG,NODE
NUMMRG,ELEM
NUMMRG,KP
/OUTPUT

CSYS,0
NSEL,S,LOC,Y,0 ! SELECT SYMMETRY BOUNDARY
D,ALL,VOLT,0 ! CONSTRAIN BOUNDARY VOLT DOF
CSYS,2 ! SPHERICAL COORDINATE SYSTEM
NSEL,S,LOC,X,10,12 ! SELECT OUTER NODES OF INFINITE DOMAIN
ESLN,S
SF,ALL,INF ! SET INFINITE FLAG
NSEL,ALL
CSYS,11 ! CUSTOM SPHERICAL COORDINATE SYSTEM
NSEL,S,LOC,X,0.97*R4,1.2*R4 ! SELECT INTERFACE ELEMENTS
ESLN,S,1
SF,ALL,MXWF ! SET MAXWELL FORCE FLAG
OUTRES,ALL,ALL
FINISH
/SOLU
ALLSEL
ESEL,U,TYPE,,1, ! UNSELECT DUMMY MESHING ELEMENT 122
ESEL,S,MAT,,2 ! SELECT SPHERE ELEMENTS
NSLE
CSYS,11 ! CUSTOM SPHERICAL COORDINATE SYSTEM
NSEL,S,LOC,X,0.98*R1,1.02*R1 ! SELECT NODES ON SPHERE SURFACE
ESLN
ESEL,U,MAT,,1
SF,ALL,CHRG,CHRGS ! APPLY SURFACE CHARGE
ALLSEL
ESEL,U,TYPE,,1 ! UNSELECT DUMMY MESHING ELEMENT 122
/TYPE,,6
/DEVICE,VECTOR,ON
/DIST,,3.661
/FOCUS,,3.08,2.884,-.148327
/COM *** THE FOLLOWING ANNOTATION COMMANDS ARE ***
/COM *** TYPICALLY GENERATED INTERACTIVELY ***
/AUTO, 1
/ANUM ,0, 1,-0.12607 , 0.38512 ! ANNOTATION NUMBER, TYPE AND HOT SPOT
/TLAB,-0.546, 0.385,Infinite Element Domain
/ANUM ,0, 1, 0.16752 ,-0.72533E-01
/TLAB,-0.217,-0.073,Finite Element Domain
/ANUM ,0, 12, 0.77714E-01,-0.24523
/LINE, 0.259,-0.124,-0.104,-0.366
/LSYM,-0.104,-0.366, 213, 1, 1.000
/ANUM ,0, 1,-0.32640 ,-0.34885
/TLAB,-0.571,-0.349,Sphere Surface
/ANUM ,0, 12,-0.44556 ,-0.45247
/LINE,-0.373,-0.366,-0.518,-0.539
/LSYM,-0.518,-0.539, 229, 1, 1.000
/ANUM ,0, 1,-0.41447E-01,-0.78577
/TSPEC, 15, 1.000, 1, 1, 0
/TLAB,-0.321,-0.791,Maxwell Surface
/ANUM ,0, 12,-0.31258 ,-0.72015
/LINE,-0.235,-0.746,-0.390,-0.694
/LSYM,-0.390,-0.694, 161, 1, 1.000
/ANUM ,0, 1,-0.39893 ,-0.93257
/TSPEC, 15, 1.000, 1, 0, 0
/TLAB,-0.434,-0.933,R3
/ANUM ,0, 12,-0.25214 ,-0.92566
/LINE,-0.373,-0.926,-0.131,-0.926
/LSYM,-0.131,-0.926, 0, 1, 1.000
/ANUM ,0, 12,-0.51118 ,-0.92566
/LINE,-0.442,-0.926,-0.580,-0.926
/LSYM,-0.580,-0.926, 180, 1, 1.000
APLOT
/ANNOT,ON
/USER ! RESET GRAPHICS DISPLAY SETTINGS
/VIEW,1,.5274,.2492,.8123
/ANGLE,1,3.621
/DIST,,7.735
/FOCUS,,6,6,-3
/DEVICE,VECTOR,OFF
/ANNOT,OFF
/PNUM,TYPE,1
/NUMBER,1
VPLOT
EPLOT
SOLVE
FINISH
/POST1 ! ENTER GENERAL POSTPROCESSOR
RSYS,11 ! USE CUSTOM SPHERICAL RESULTS COORDINATE SYSTEM
ESEL,S,TYPE,,2 ! SELECT SOLID122 ELEMENTS
ESEL,U,MAT,,2 ! UNSELECT SPHERE
NSLE
/AUTO
PLNSOL,EF,X ! PLOT NODAL RESULTS, RADIAL ELECTRIC FIELD
PLNSOL,VOLT ! PLOT NODAL RESULTS, VOLTAGE DOF
RSYS,0
CSYS,11
NSEL,S,LOC,X,R4
ESLN,S
ETABLE,FY,FMAG,Y ! PUT FORCES INTO ETABLE
SSUM ! FORCE SUMNATION
*GET,FYSUM,SSUM,0,ITEM,FY
YFORCE=FYSUM*12 ! MULTIPLY TO ACCOUNT FOR 30 DEGREE SLICE
*STATUS,YFORCE
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' YFORC'
LABEL(1,2) = 'E (N) '
*VFILL,VALUE(1,1),DATA,-1.236E-11
*VFILL,VALUE(1,2),DATA,YFORCE
*VFILL,VALUE(1,3),DATA,ABS(YFORCE/1.236E-11)
/COM
/OUT,vm51,vrt
/COM,------------------- VM51 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',E11.4,' ',E11.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
/DELETE,SCRATCH
*LIST,vm51,vrt



VM52 (Automobile Suspension System Vibration) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM52
/PREP7
MP,PRXY,,0.3
/TITLE, VM52, AUTOMOBILE SUSPENSION SYSTEM VIBRATIONS
C***VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 181, EX 6.7-1
ANTYPE,MODAL ! MODE-FREQUENCY ANALYSIS
MXPAND,1 ! EXPAND FIRST MODE
MODOPT,REDUC,,,,2 ! PRINT TWO REDUCED MODE SHAPES
ET,1,BEAM3 ! BEAM ELEMENT
ET,2,COMBIN14,,,2 ! SPRING ELEMENT
ET,3,MASS21,,,3 ! MASS ELEMENT
R,1,2400 ! SPRING STIFFNESS (K1) = 2400
R,2,1,1,1 ! BEAM PROPERTIES
R,3,100,1600 ! MASS = 100 (FROM 3220/32.2), I = 1600
R,4,1,1,1 ! BEAM PROPERTIES (ARBITRARY)
R,5,2600 ! SPRING STIFFNESS (K2) = 2600
MP,EX,1,4E9
N,1
N,2,,1
N,3,4.5,1
N,4,10,1
N,5,10
TYPE,2
E,1,2 ! SPRING ELEMENT
TYPE,1
REAL,2
E,2,3 ! BEAM ELEMENT
TYPE,3
REAL,3
E,3 ! MASS ELEMENT
TYPE,1
REAL,4
E,3,4 ! BEAM ELEMENT
TYPE,2
REAL,5
E,4,5 ! SPRING ELEMENT
M,3,UY,,,ROTZ ! UY AND ROTZ OF NODE 3 ARE SELECTED AS MDOF
D,1,UX,,,5,4,UY ! BOUNDARY CONDITIONS
D,3,UX
OUTPR,NSOL,1
FINISH
/SOLU
SOLVE
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = ' f1, ',' f2, '
LABEL(1,2) = 'Hz ','Hz '
*VFILL,VALUE(1,1),DATA,1.0981,1.4406
*VFILL,VALUE(1,2),DATA,FREQ1,FREQ2
*VFILL,VALUE(1,3),DATA,ABS(FREQ1/1.0981 ) ,ABS( FREQ2/1.4406)
/COM
/OUT,vm52,vrt
/COM,------------------- VM52 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm52,vrt




VM53 (Vibration of a String Under Tension) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM53
/PREP7
/TITLE, VM53, VIBRATION OF A STRING UNDER TENSION
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND. PRINTING,
C*** PAGE 264, ART. 8.2,
ANTYPE,STATIC ! STATIC ANALYSIS
PSTRES,ON ! INCLUDE PRESTRESS EFFECTS (THIS OPTION IS NEEDED
! FOR PRESTRESSED MODAL ANALYSIS PERFORMED LATER)
ET,1,LINK10
R,1,306796E-8,543248E-8 ! AREA AND INITIAL STRAIN
MP,EX,1,30E6
MP,DENS,1,73E-5
N,1 ! DEFINE NODES
N,14,100
FILL
E,1,2 ! DEFINE ELEMENTS
EGEN,13,1,1
OUTPR,BASIC,1
D,ALL,ALL ! FIX ALL MOTIONS FOR STATIC STRESSES
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,13,ETAB,STRS
FINISH
/POST26
RFORCE,2,1,F,X
STORE
*GET,FORCE,VARI,2,EXTREM,VMAX
/SOLU
ANTYPE,MODAL ! PERFORM MODAL ANALYSIS
MODOPT,SUBSP,3 ! EXTRACT 3 MODES USING SUBSPACE ITERATION METHOD
MXPAND,3 ! EXPAND FIRST THREE MODES
PSTRES,ON ! INCLUDE PRESTRESS EFFECTS
DDELE,2,UX,13 ! RELEASE INTERIOR DOFS
DDELE,2,UY,13
SOLVE
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*GET,FREQ3,MODE,3,FREQ
*DIM,LABEL,CHAR,5,2
*DIM,VALUE,,5,3
LABEL(1,1) = ' F,',' SI',' f1',' f2',' f3'
LABEL(1,2) = ' lb ','GMA,psi ',', Hz ',', Hz ',', Hz '
*VFILL,VALUE(1,1),DATA,500,162974,74.708,149.42,224.12
*VFILL,VALUE(1,2),DATA,ABS(FORCE),STRSS,FREQ1,FREQ2,FREQ3
*VFILL,VALUE(1,3),DATA,ABS(FORCE/500),ABS(STRSS/162974),ABS(FREQ1/74.708)
*VFILL,VALUE(4,3),DATA,ABS(FREQ2/149.42),ABS(FREQ3/224.12)
/COM
/OUT,vm53,vrt
/COM,------------------- VM53 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm53,vrt



VM54 (Vibration of a Rotating Cantilever Blade) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM54
/PREP7
/TITLE, VM54, VIBRATION OF A ROTATING CANTILEVER BLADE
C*** CARNEGIE,W., VIBRATIONS OF ROTATING CANTILEVER BLADING,
C*** JOURNAL OF MECHANICAL ENGINEERING SCIENCE,PG. 239,VOL.1,NO.3,1959.
ET,1,SHELL63,,,,,,,1 ! FOUR NODE SHELL, SUPPRESS STRESS PRINTOUT
R,1,3E-3 ! THICKNESS OF SHELL
MP,EX,1,217E9 ! MATERIAL, STEEL
MP,NUXY,1,0.3
MP,DENS,1,7850
N,1,-.014,,.150 ! DEFINE NODES
N,9,-.014,,.478
FILL
NGEN,2,9,1,9,1,.028
E,1,2,11,10 ! DEFINE ELEMENTS
EGEN,8,1,-1
FINISH
/SOLU
ANTYPE,STATIC ! STATIC ANALYSIS, PRESTRESS
PSTRES,ON ! PRESTRESS ANALYSIS
D,1,ALL,,,10,9 ! BOUNDARY CONDITIONS AND LOADING
OMEGA,314.159265 ! SPINNING LOAD
OUTPR,,1
SOLVE
FINISH
/SOLU
ANTYPE,MODAL ! MODAL ANALYSIS
MODOPT,SUBSP,5 ! FULL SUBSPACE, EXTRACT 5 MODES
PSTRES,ON ! PRESTRESS ANALYSIS
OMEGA,314.159265,,,1 ! INCLUDE SPIN SOFTENING
SOLVE
*GET,FREQ,MODE,1,FREQ

*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' f, '
LABEL(1,2) = 'Hz '
*VFILL,VALUE(1,1),DATA,52.75
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ /52.75)
/COM
/OUT,vm54,vrt
/COM,------------------- VM54 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm54,vrt


VM55 (Vibration of a Stretched Circular Membrane) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM55
/PREP7
MP,PRXY,,0.3
/TITLE, VM55, VIBRATION OF A STRETCHED CIRCULAR MEMBRANE
C*** VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 439, EQN. 182
ANTYPE,STATIC ! STATIC ANALYSIS
PSTRES,ON ! INCLUDE PRESTRESS EFFECTS (THIS OPTION IS NEEDED FOR
! PRESTRESSED MODAL ANALYSIS PERFORMED LATER)
ET,1,SHELL51
MP,EX,1,30E6
MP,DENS,1,73E-5
R,1,.01 ! THICKNESS = 0.01
N,1
N,10,15
FILL
E,1,2
EGEN,9,1,1
D,1,UX,,,,,ROTZ
D,10,UY,,,,,UZ
F,10,FX,9424.778
FINISH
/SOLU
OUTPR,BASIC,1
SOLVE
FINISH
/POST1
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,9,ETAB,STRS
FINI
/SOLU
ANTYPE,MODAL ! MODAL ANALYSIS
PSTRES,ON ! INCLUDE PRESTRESS EFFECTS
MXPAND,3 ! EXPAND FIRST 3 MODES
MODOPT,REDUC,,,,9 ! PRINT FIRST 9 REDUCED MODES
M,1,UY,9
SOLVE
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*GET,FREQ3,MODE,3,FREQ

*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'SIG,R p','f1, ','f2, ','f3, '
LABEL(1,2) = 'si ','Hz ','Hz ','Hz '
*VFILL,VALUE(1,1),DATA,10000,94.406,216.77,339.85
*VFILL,VALUE(1,2),DATA,STRSS,FREQ1,FREQ2,FREQ3
*VFILL,VALUE(1,3),DATA,(STRSS/10000),(FREQ1/94.406),(FREQ2/216.77),(FREQ3/339.85)
/COM
/OUT,vm55,vrt
/COM,------------------- VM55 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm55,vrt



VM56 (Hyperelastic Thick Cylinder Under Internal Pressure) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM56
/PREP7
SMRT,OFF
/TITLE, VM56, HYPERELASTIC THICK CYLINDER UNDER INTERNAL PRESSURE
/COM REF: ODEN, J.T., "FINITE ELEMENTS OF NONLINEAR CONTINUA"
/COM MCGRAW-HILL, 1972, PP 325-331
ANTYPE,STATIC
NLGEOM,ON ! LARGE DEFLECTION
ET,1,HYPER84,1,,1,,,1,1 ! 8 NODE AXISYM. W/REDUCED INTEGRATION,NO PRINT
ET,2,HYPER84,1,,1,,,1 ! 8 NODE AXISYM. W/REDUCED INTEGRATION
MP,NUXY,1,0.49 ! POISSON'S RATIO (APPROXIMATELY INCOMPRESSIBLE)
TB,MOONEY,1,2 ! HYPERELASTIC MATERIAL PROPERTY TABLE
TBTEMP,20 ! MOONEY COEFFICIENTS AT TEMP = 20
TBDATA,1,40
TBDATA,2,10
TBTEMP,40 ! MOONEY COEFFICIENTS AT TEMP = 40
TBDATA,1,120
TBDATA,2,30
K,1,7 ! DEFINE KEYPOINTS
K,3,7,2.5
K,2,18.625
K,4,18.625,2.5
A,1,2,4,3 ! DEFINE AREA
ESIZE,2.5
AMESH,1 ! CREATE NODES AND ELEMENTS
TYPE,2
EMODIF,1 ! PRINT ONLY INNERMOST ELEMENT RESULTS
BFUNIF,TEMP,30 ! UNIFORM TEMPERATURES
D,ALL,UY,0 ! FIX ALL NODES AXIALLY
D,ALL,UZ,0 ! FIX ALL NODES TANGENTIALLY
FINISH
/SOLU
SOLCONTROL,0
/TITLE, PRESSURE = 90 PSI
NEQIT,20 ! MAXIMUM 20 EQUILIBRIUM ITERATIONS
NSEL,S,LOC,X,7.0
SF,ALL,PRES,90 ! APPLY INTERNAL PRESSURE OF 90 PSI
NSEL,ALL
SOLVE
/TITLE, PRESSURE = 150 PSI
NSEL,S,LOC,X,7.0
SF,ALL,PRES,150 ! APPLY INTERNAL PRESSURE OF 150 PSI
NSEL,ALL
SOLVE
FINISH
/POST1 ! POSTPROCESS
SET,2
ETABLE,SX1,S,X
AVPRIN,0,0,
ELM=0
NSEL,S,LOC,X,6.5,8.5
ESLN
ELM=ELNEXT(ELM)
*GET,SIGX,ELEM,ELM,ETABLE,SX1
ELM=0
ESEL,ALL
NSEL,ALL
*GET,DEF,NODE,1,U,X
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'UR(INNER'
LABEL(1,2) = ' RAD),in'
LABEL(2,1) = 'SIGX: EL'
LABEL(2,2) = ' 1 CENT '
VALUE(1,1) = 7.180
VALUE(1,2) = DEF
VALUE(1,3) = ABS(DEF/7.180)
VALUE(2,1) = -122.0
VALUE(2,2) = SIGX
VALUE(2,3) = ABS(SIGX/(-122.0))
SAVE,TABLE_1
FINISH
/CLEAR,NOSTART ! CLEAR THE PREVIOUS DATABASE
/PREP7
SMRT,OFF
/TITLE, VM56: HYPERELASTIC THICK CYLINDER UNDER INTERNAL PRESSURE
ANTYPE,STATIC
NLGEOM,ON
ET,1,HYPER86,,,,,,1,1 ! 3-D SOLID W/REDUCED INTEGRATION, NO PRINTOUT
ET,2,HYPER86,,,,,,1 ! 3-D SOLID W/REDUCED INTEGRATION
MP,NUXY,1,0.49 ! POISSON'S RATIO (APPROX. INCOMPRESSIBLE)
TB,MOONEY,1 ! NO TEMPERATURE DEPENDENCY OF MOONEY PROPERTIES
TBDATA,1,80 ! MOONEY COEFFICIENT A
TBDATA,2,20 ! MOONEY COEFFICIENT B
CSYS,1
K,1,7,3.16 ! DEFINE KEYPOINTS
K,2,7,3.16,.775
K,3,7,-3.16,.775
K,4,7,-3.16
KGEN,2,ALL,,,11.625
V,1,2,3,4,5,6,7,8 ! DEFINE VOLUME
LSEL,S,LINE,,5
LSEL,A,LINE,,7
LSEL,A,LINE,,11
LSEL,A,LINE,,9
LESIZE,ALL,,,5
LSEL,ALL
ESIZE,,1
VMESH,ALL ! CREATE NODES AND ELEMENTS
TYPE,2
EMODIF,1
NROTAT,ALL ! ROTATE ALL NODES INTO CYLINDRICAL COORDINATES
D,ALL,UZ,0.0 ! CONSTRAIN ALL NODES AXIALLY
D,ALL,UY,0.0 ! CONSTRAIN ALL NODES TANGENTIALLY
FINISH
/SOLU
SOLCONTROL,0
/TITLE, PRESSURE = 90 PSI
NEQIT,30 ! MAXIMUM 30 EQUILIBRIUM ITERATIONS
NSEL,S,LOC,X,7
SF,ALL,PRES,90 ! INTERNAL PRESSURE OF 90 PSI
NSEL,ALL
SOLVE
/TITLE, PRESSURE = 150 PSI
NSEL,S,LOC,X,7
SF,ALL,PRES,150 ! INTERNAL PRESSURE OF 150 PSI
NSEL,ALL
SOLVE
FINISH
/POST1 ! POSTPROCESS
SET,2
ETABLE,SX1,S,X
AVPRIN,0,0,
ELM=0
NSEL,S,LOC,X,6.5,8.5
ESLN
ELM=ELNEXT(ELM)
*GET,SIGX,ELEM,ELM,ETABLE,SX1
ELM=0
ESEL,ALL
NSEL,ALL
*GET,DEF,NODE,1,U,X
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'UR(INNER'
LABEL(1,2) = ' RAD),in'
LABEL(2,1) = 'SIGX: EL'
LABEL(2,2) = ' 1 CENT '
VALUE(1,1) = 7.180
VALUE(1,2) = DEF
VALUE(1,3) = ABS(DEF/7.180)
VALUE(2,1) = -122.0
VALUE(2,2) = SIGX
VALUE(2,3) = ABS(SIGX/(-122.0))
SAVE,TABLE_2
FINISH
/CLEAR,NOSTART ! CLEAR THE PREVIOUS DATABASE
/PREP7
SMRT,OFF
/TITLE, VM56: HYPERELASTIC THICK CYLINDER UNDER INTERNAL PRESSURE
ANTYPE,STATIC
NLGEOM,ON
ET,1,HYPER158,,,,,,,,1
ET,2,HYPER158
MP,NUXY,1,0.49 ! POISSON'S RATIO (APPROX. INCOMPRESSIBLE)
TB,MOONEY,1 ! NO TEMPERATURE DEPENDENCY OF MOONEY PROPERTIES
TBDATA,1,80 ! MOONEY COEFFICIENT A
TBDATA,2,20 ! MOONEY COEFFICIENT B
CSYS,1
K,1,7,3.16 ! DEFINE KEYPOINTS
K,2,7,3.16,.775
K,3,7,-3.16,.775
K,4,7,-3.16
KGEN,2,ALL,,,11.625
V,1,2,3,4,5,6,7,8 ! DEFINE VOLUME
LSEL,S,LINE,,5
LSEL,A,LINE,,7
LSEL,A,LINE,,11
LSEL,A,LINE,,9
LESIZE,ALL,,,5
LSEL,ALL
ESIZE,,1
VMESH,ALL ! CREATE NODES AND ELEMENTS
TYPE,2
EMODIF,1
NROTAT,ALL ! ROTATE ALL NODES INTO CYLINDRICAL COORDINATES
D,ALL,UZ,0.0 ! CONSTRAIN ALL NODES AXIALLY
D,ALL,UY,0.0 ! CONSTRAIN ALL NODES TANGENTIALLY
FINISH
/SOLU
SOLCONTROL,0
/TITLE, PRESSURE = 90 PSI
NEQIT,30 ! MAXIMUM 30 EQUILIBRIUM ITERATIONS
NSEL,S,LOC,X,7
SF,ALL,PRES,90 ! INTERNAL PRESSURE OF 90 PSI
NSEL,ALL
SOLVE
/TITLE, PRESSURE = 150 PSI
NSEL,S,LOC,X,7
SF,ALL,PRES,150 ! INTERNAL PRESSURE OF 150 PSI
NSEL,ALL
SOLVE
FINISH
/POST1 ! POSTPROCESS
SET,2
*GET,DEF,NODE,1,U,X
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'UR(INNER'
LABEL(1,2) = ' RAD),in'
VALUE(1,1) = 7.180
VALUE(1,2) = DEF
VALUE(1,3) = ABS(DEF/7.180)
SAVE,TABLE_3
RESUME,TABLE_1
/COM
/OUT,vm56,vrt
/COM,------------------- VM56 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING HYPER84:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING HYPER86:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM,RESULTS USING HYPER158:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/OUT
FINISH
*LIST,vm56,vrt

/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,TABLE_3
FINISH


VM57 (Torsional Frequencies of a Drill Pipe) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM57
/PREP7
/TITLE, VM57, TORSIONAL FREQUENCIES OF A DRILL PIPE
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND. PRINTING, PAGE 272, EX. 8.4-5
C*** USING PIPE16 ELEMENTS
ET,1,PIPE16
ET,2,MASS21
R,1,(4.5/12),(.335/12) ! GEOMETRIC PROPERTIES FOR PIPE ELEMENTS
R,2,,,,,,29.3 ! GEOMETRIC PROPERTY FOR MASS ELEMENT
MP,EX,1,4.4928E9
MP,DENS,1,15.2174
MP,NUXY,1,.3
N,1
N,13,,,-5000
FILL
E,1,2
EGEN,12,1,1 ! PIPE ELEMENTS
TYPE,2
REAL,2
E,13 ! MASS ELEMENT
FINISH
/SOLU
ANTYPE,MODAL ! MODE-FREQUENCY ANALYSIS
MODOPT,SUBSP,2 ! EXTRACT FIRST TWO MODES
D,1,UX,,,13,,UY,UZ,ROTX,ROTY
D,1,ROTZ
OUTPR,,1
SOLVE
FINISH
/POST1
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = ' f1',' f2'
LABEL(1,2) = ', Hz ',', Hz '
*VFILL,VALUE(1,1),DATA,.3833,1.260
*VFILL,VALUE(1,2),DATA,FREQ1,FREQ2
*VFILL,VALUE(1,3),DATA,ABS(FREQ1/.3833),ABS(FREQ2/1.260)
SAVE,TABLE_1
FINISH
/PREP7
C**** USING BEAM ELEMENTS (BEAM4)
ET,1,BEAM4
R,1,304401E-7,4613E-7,4613E-7,4.5,4.5
RMORE,,9226E-7 ! GEOMETRIC PROPERTIES FOR BEAM ELEMENTS
FINISH
/SOLU
MODOPT,REDUC,2,,,2 ! USE HOUSEHOLDER, EXTRACT AND PRINT 2 REDUCED MODE SHAPES
M,2,ROTZ,13
SOLVE
FINISH
/POST1
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
LABEL(1,1) = 'UR(INNER'
LABEL(1,2) = ' RAD),in'
*VFILL,VALUE(1,1),DATA,.3833,1.26
*VFILL,VALUE(1,2),DATA,FREQ1,FREQ2
*VFILL,VALUE(1,3),DATA,ABS(FREQ1/.3833),ABS(FREQ2/1.26)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm57,vrt
/COM,------------------- VM57 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING PIPE ELEMENTS:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING BEAM ELEMENTS:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm57,vrt



VM58 (Centerline Temperature of a Heat Generating Wire) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM58
/PREP7
SMRT,OFF
/TITLE, VM58, CENTERLINE TEMP. OF A HEAT GENERATING WIRE
C*** HEAT, MASS AND MOMENTUM TRANS., ROHSENOW AND CHOI, 2ND. PR., P. 106,EX 6.5
ANTYPE,STATIC
ET,1,PLANE35 ! 2-D 6 NODE TRIANGULAR THERMAL SOLID
ET,2,SURF151 ! 2-D THERMAL SURFACE EFFECT ELEMENT
KEYOPT,2,8,2
MP,KXX,1,13
CSYS,1
K,1 ! DEFINE MODEL
K,2,.03125,-15
K,3,.03125,15
L,2,3
CSYS
A,1,2,3
ESIZE,,4
AMESH,1
CSYS,1
NSEL,S,LOC,X,.03125
CP,1,TEMP,ALL ! COUPLE NODAL TEMPERATURES ON EXTERIOR
TYPE,2 ! SELECT SURF151 TYPE
ESURF ! GENERATE SURF151 ELEMENTS ON OUTER RADIUS
NSEL,ALL
ESEL,S,TYPE,,2
SFE,ALL,,CONV,,5
SFE,ALL,,CONV,2,70
ESEL,ALL
BFA,1,HGEN,111311.7 ! HEAT GENERATION
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,LOC,X
PRNSOL,TEMP
NSEL,S,LOC,X,.03125
PRNSOL,TEMP
ESLN,S,1 ! SELECT SURFACE ELEMENTS ON OUTER RADIUS
ETABLE,Q1,SMISC,2 ! HEAT RATE OVER EACH SURFACE ELEMENT
SSUM
*GET,HFLW,SSUM,,ITEM,Q1
HFLW=HFLW*12 ! CALCULATE TOTAL HEAT DISSIPATION RATE
*STATUS
ALLSEL
*GET,T_AT_CL,NODE,1,TEMP
*GET,T_AT_S,NODE,2,TEMP
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'T CL, ','T S, ','Q, (BTU/'
LABEL(1,2) = '(F) ','(F) ','HR) '
*VFILL,VALUE(1,1),DATA,419.9,417.9,341.5
*VFILL,VALUE(1,2),DATA,T_AT_CL,T_AT_S,HFLW
*VFILL,VALUE(1,3),DATA,ABS(T_AT_CL/419.9),ABS(T_AT_S/417.9),ABS(HFLW/341.5)
/COM
/OUT,vm58,vrt
/COM,------------------- VM58 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm58,vrt


VM59 (Lateral Vibration of an Axially-loaded Bar) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM59
/PREP7
MP,PRXY,,0.3
/TITLE, VM59, LATERAL VIBRATION OF AN AXIALLY LOADED BAR
C*** VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 374, ART. 59
ANTYPE,STATIC ! STATIC ANALYSIS
PSTRES,ON ! INCLUDE PRESTRESS EFFECTS (THIS OPTION IS NEEDED
! FOR PRESTRESSED MODAL ANALYSIS PERFORMED LATER)
ET,1,BEAM4
R,1,4,(4/3),(4/3),2,2 ! GEOMETRIC PROPERTIES OF THE BAR
MP,EX,1,30E6
MP,DENS,1,727973E-9
N,1
N,14,80
FILL
E,1,2
EGEN,13,1,1
D,1,UY,,,14,,ROTX,ROTZ ! B.C.'S AND LOADING
D,1,UX,,,,,UZ
D,14,UZ
F,14,FX,-40E3
M,2,UZ,13 ! SELECT UZ OF NODES 2 TO 13 AS MDOF
FINISH
/SOLU
OUTPR,BASIC,1
SOLVE
FINISH
/POST1
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,13,ETAB,STRS
*GET,DEF,NODE,14,U,X
/SOLU
ANTYPE,MODAL ! MODAL ANALYSIS
PSTRES,ON ! INCLUDE PRESTRESS EFFECTS
MXPAND,3 ! EXPAND FIRST 3 MODES
MODOPT,LANB,3 ! SELECT THE BLOCK LANCZOS EIGENSOLVER
SOLVE
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*GET,FREQ3,MODE,3,FREQ

*DIM,LABEL,CHAR,5,2
*DIM,VALUE,,5,3
LABEL(1,1) = 'DEFLECTI','SIGMA, ','f1, ','f2, ','f3, '
LABEL(1,2) = 'ON, (in)',' (psi)',' (Hz)',' (Hz)',' (Hz)'
*VFILL,VALUE(1,1),DATA,-.026667,-10000,17.055,105.32,249.39
*VFILL,VALUE(1,2),DATA,DEF,STRSS,FREQ1,FREQ2,FREQ3
*VFILL,VALUE(1,3),DATA,ABS(DEF/.026667),ABS(STRSS/10000),ABS(FREQ1/17.055)
*VFILL,VALUE(4,3),DATA,ABS(FREQ2/105.32),ABS(FREQ3/249.39)
/COM
/OUT,vm59,vrt
/COM,------------------- VM59 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F14.6,' ',F14.6,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM59 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm59,vrt


VM60 (Natural Frequency of a Cross-ply Laminated Spherical Shell) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM60
/PREP7
SMRT,OFF
/TITLE,VM60: NATURAL FREQUENCY OF A CROSS-PLY LAMINATED SPHERICAL SHELL
C*** THEORETICAL SOLUTION IS FROM J.N. REDDY
C*** ASCE JOURNAL OF ENGINEERING MECHANICS VOL 110 #5 MAY,1984 PP794-809
ET,1,SHELL99,,,,,,,1 ! SUPPRESS SHELL99 PRINTOUT
R,1,2,,1,1 ! TWO LAYERS
RMORE
RMORE,1,,.5,1,90,.5 ! LAYER 1, 0 DEG; #2, 90 DEG (BOTH LAYERS .5 THICK)
MP,EX,1,25E6
MP,EY,1,1E6
MP,EZ,1,25E6
MP,NUXY,1,.01
MP,NUYZ,1,.01
MP,NUXZ,1,.01
MP,GXY,1,.5E6
MP,GYZ,1,.2E6
MP,GXZ,1,.5E6
MP,DENS,1,1
CSYS,2 ! SPHERICAL COORDINATES
K,1,300
K,2,300,19.0986
K,3,300,19.0986,19.0986
K,4,300,,19.0986
ESIZE,,4
A,1,2,3,4
AMESH,ALL
NROTAT,ALL
FINISH
/SOLU
ANTYPE,MODAL
MODOPT,SUBSP,5 ! EXTRACT 1ST 5 MODES
EQSLVE,PCG ! USE POWERDYNAMICS
NSEL,R,LOC,Y,0
NSEL,A,LOC,Y,19,20
D,ALL,UX,,,,,ROTX,UZ,ROTY
NSEL,S,LOC,Z,0
NSEL,A,LOC,Z,19,20
D,ALL,UX,,,,,ROTX,UY,ROTZ
NSEL,ALL
SOLVE
*GET,FREQ,MODE,1,FREQ

*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' f,'
LABEL(1,2) = ' (Hz) '
*VFILL,VALUE(1,1),DATA,.73215
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/.73215)
/COM
/OUT,vm60,vrt
/COM,------------------- VM60 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm60,vrt


VM61 (Longitudinal Vibration of a Free-free Rod) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM61
/PREP7
MP,PRXY,,0.3
/TITLE, VM61, LONGITUDINAL VIBRATION OF A FREE-FREE ROD
C***VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 269, EX 8.3-1
ANTYPE,MODAL ! MODE-FREQUENCY ANALYSIS
ET,1,BEAM3
R,1,1,1,1 ! AREA=1, IZZ=1, HEIGHT=1
MODOPT,LANB,3 ! SELECT THE BLOCK LANCZOS EIGENSOLVER
MP,EX,1,3E7
MP,DENS,1,73E-5
K,1
K,2,800
L,1,2
ESIZE,,11
LMESH,1
OUTPR,BASIC,1
D,ALL,UY,,,,,ROTZ ! ALLOW UX DOF'S ONLY
FINISH
/SOLU
SOLVE
FINISH
/SOLU
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*GET,FREQ3,MODE,3,FREQ
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = ' f1',' f2',' f3'
LABEL(1,2) = ', (Hz) ',', (Hz) ',', (Hz) '
*VFILL,VALUE(1,1),DATA,0,126.70,253.40
*VFILL,VALUE(1,2),DATA,FREQ1,FREQ2,FREQ3
*VFILL,VALUE(1,3),DATA,0,ABS(FREQ2/126.70 ),ABS(FREQ3/253.40 )
/COM
/OUT,vm61,vrt
/COM,------------------- VM61 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,----------------------------------------------------------

/OUT
FINISH
*LIST,vm61,vrt


VM62 (Vibration of a Wedge) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM62
/PREP7
SMRT,OFF
/TITLE, VM62, VIBRATION OF A WEDGE
C*** VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 392, ART. 62
C*** USING SHELL63 ELEMENTS WITH BENDING STIFFNESS OPTION
ANTYPE,MODAL ! MODE-FREQUENCY ANALYSIS
MXPAND,1 ! EXPAND FIRST MODE
MODOPT,REDUC,2,,,2 ! PRINT ALL REDUCED MODE SHAPES
ET,1,SHELL63,2 ! SHELL63 WITH BENDING STIFFNESS OPTION
R,1,1 ! UNIT THICKNESS
MP,EX,1,30E6
MP,DENS,1,.000728
MP,NUXY,1,0 ! POISSON'S RATIO IS ZERO
K,1 ! DEFINE MODEL GEOMETRY
K,2,16
K,3,16,2
L,2,3
LESIZE,1,,,1
A,1,2,3,3
ARSYM,Y,1 ! SYMMETRY REFLECTION OF AREAS
NUMMRG,KPOI ! MERGE COINCIDENT KEYPOINTS
ESIZE,,4
AMESH,1,2
NSEL,S,LOC,Y,0
M,ALL,UZ
NSEL,S,LOC,X,16
D,ALL,UZ,,,,,ROTX,ROTY,UX,UY ! CONSTRAIN DISPLACEMENTS AT BASE
NSEL,ALL
OUTPR,ALL,1
OUTRES,ALL,0
FINISH
/SOLU
SOLVE
*GET,FREQ1,MODE,1,FREQ
FINISH
/PREP7
SMRT,OFF
C*** USING SHELL63 ELEMENTS WITH SHELL OPTION
ET,1,SHELL63 ! USE BENDING AND MEMBRANE STIFFNESS
FINISH
/SOLU
SOLVE
*GET,FREQ2,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE_1,,1,3
*DIM,VALUE_2,,1,3
LABEL(1,1) = ' f,'
LABEL(1,2) = ' Hz '
*VFILL,VALUE_1(1,1),DATA,259.16
*VFILL,VALUE_1(1,2),DATA,FREQ1
*VFILL,VALUE_1(1,3),DATA,ABS(FREQ1/259.16 )
*VFILL,VALUE_2(1,1),DATA,259.16
*VFILL,VALUE_2(1,2),DATA,FREQ2
*VFILL,VALUE_2(1,3),DATA,ABS(FREQ2/259.16 )
/COM
/OUT,vm62,vrt
/COM,------------------- VM62 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING PLATE ELEMENTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,
/COM,RESULTS USING SHELL ELEMENTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm62,vrt


VM63 (Static Hertz Contact Problem) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM63
/PREP7
SMRT,OFF
/TITLE, VM63, STATIC HERTZ CONTACT PROBLEM SOLVED USING CONTACT26 ELEMENTS
/COM THE PROBLEM IS SOLVED USING TWO CONTACT ELEMENTS, FIRST USING
/COM CONTACT26 (SURFACE CONTACT) ELEMENTS AND SECOND USING CONTACT178 (NODAL CONTACT)ELEMENTS
/COM THE RESULTS OBTAINED USING THESE TWO CONTACT ELEMENTS ARE COMPARED AT THE END
/COM REF: TIMOSHENKO AND GOODIER, THEORY OF ELASTICITY, 3RD ED., ART. 140.
ET,1,PLANE82,,,1 ! AXISYMMETRIC ELEMENTS
ET,2,PLANE2,,,1
ET,3,CONTAC26 ! CONTACT SURFACE
R,1 ! DEFAULT STIFFNESS OF 1E9 IS USED
MP,EX,1,1E3
MP,NUXY,1,.3
LOCAL,11,1,0,8,0 ! LOCAL CYLINDRICAL C.S. AT CENTERLINE
K,1,8,-90 ! DEFINE KEYPOINTS
K,2,8
K,3,7.5,-90
K,4,7.5
K,5
K,6,8,-82.65 ! PLACE KEYPOINT AND NODE AT EXPECTED CONTACT RADIUS
K,7,7.5,-82.65
L,1,3 ! DEFINE LINES
L,2,4
L,6,7
LESIZE,ALL,,,1 ! DEFINE ELEMENT DIVISIONS ON ALL EXISTING LINES
A,1,6,7,3 ! DEFINE AREAS
A,6,2,4,7
A,3,7,4,5
LOCAL,12,0,0,8,0
ARSYM,Y,1,3,1 ! CREATE HALF-SYMMETRY MODEL
NUMMRG,KPOI
ESIZE,,4 ! DEFINE ELEMENT DIVISIONS ON REMAINING LINES
LESIZE,4,,,5
*REPEAT,2,1
LESIZE,6,,,8,8
LESIZE,7,,,8,(1/8)
LESIZE,10,,,1
*REPEAT,2,2
LESIZE,9,,,6,.2
TYPE,1 ! CREATE NODES AND ELEMENTS
AMESH,1,2,1
AMESH,4,5,1
TYPE,2
AMESH,3,6,3
CSYS,0
N,1001,-1,1E-8 ! J AND K NODES OF CONTAC26 CONTACT SURFACE
N,1002,9,1E-8 ! USE 1E-8 TO REMOVE SYSTEM TO SYSTEM INSTABILITY
TYPE,3
REAL,1
EN,201,4,1001,1002 ! ELEMENT NUMBERS ASSIGNED TO ENABLE POSTPROCESSING
*REPEAT,4,1,2 ! MESH NODE NUMBERING SCHEME MUST BE KNOWN
EN,205,2,1001,1002 ! THIS SHOULD BE THE ELEMENT AT THE CONTACT RADIUS
EN,206,31,1001,1002 ! ADDITIONAL ELEMENT TO VERIFY POINT OF CONTACT
MODMSH,NOCHECK
TYPE,1 ! REMOVE MIDSIDE NODES ALONG CONTACT SURFACE
EMODIF,7,7,0
*REPEAT,6,1
MODMSH,CHECK
FINISH
/SOLU
NSEL,S,LOC,X,-.01,.01 ! BOUNDARY CONDITIONS AND LOADING
D,ALL,UX,0
NSEL,R,LOC,Y,0
D,ALL,UY,0
NSEL,ALL
LOAD=0
*CREATE,LOADSTEP ! MACRO TO INCREMENTALLY APPLY LOAD
FK,8,FY,ARG1
SOLVE
*END
*DO,I,1,3
LOAD=LOAD-10
*USE,LOADSTEP,LOAD*6.2831853
*ENDDO
FINISH
/POST1 ! POSTPROCESS
SET,3
ESEL,,TYPE,,3
ETABLE,RFOR,SMISC,1
NSLE
PRETAB,RFOR ! PRINT REACTION FORCE TO DETERMINE CONTACT AREA
SSUM ! SUM OF REACTION FORCE
NLIST ! LIST COORDINATES OF NODES OF CONTACT SURFACE
PRNSOL,U,COMP ! LIST DISPLACEMENTS OF NODES
/COM CALCULATE RATIO OF A - ACTUAL TO A - TARGET
PI=(4*ATAN(1))
LOAD=-(LOAD)*(2*PI)
ATAR=(0.88*((LOAD*0.008)**(1/3))) ! A - TARGET
*GET,EMAX,ELEM,,NUM,MAX
*DO,ENUM,201,EMAX ! START SEARCH FROM ELEM 201
*GET,GRFR,ELEM,ENUM,ETAB,RFOR ! FIND LAST ELEMENT IN CONTACT
*IF,GRFR,EQ,0.0,EXIT
*ENDDO
ESEL,,ELEM,,(ENUM-1) ! SELECT LAST CONTACTING ELEMENT
NSLE ! SELECT NODES ATTACHED TO SELECTED ELEMENTS
*GET,NMIN,NODE,0,NUM,MIN
NODX=NX(NMIN)
NODY=NY(NMIN)
NUX =UX(NMIN)
NUY =UY(NMIN)
AACT=NODX+NUX ! A - ACTUAL
YCHK=NODY+NUY
RATA=(AACT/ATAR) ! RATIO
*STAT
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' A,'
LABEL(1,2) = ' mm '
*VFILL,VALUE(1,1),DATA,1.010
*VFILL,VALUE(1,2),DATA,AACT
*VFILL,VALUE(1,3),DATA,ABS(AACT/1.010)
FINISH
/COM
/OUT,vm63,vrt
/COM,--------------------------------------------------------------------------
/COM,----------VM63 RESULTS COMPARISON (OBTAINED USING CONTACT26 ELEMENTS)-----
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-------------------------------------------------------------------------
/OUT
/CLEAR,NOSTART
/TITLE, VM63, STATIC HERTZ CONTACT PROBLEM SOLVED USING CONTACT178 ELEMENTS
/PREP7
SMRT,OFF
/TITLE,EV178-45S , STATIC HERTZ CONTACT PROBLEM
/COM REF: TIMOSHENKO AND GOODIER, THEORY OF ELASTICITY, 3RD ED., ART. 140.
/OUT,scratch
ET,1,PLANE82,,,1 ! AXISYMMETRIC ELEMENTS
ET,2,PLANE2,,,1
ET,3,178 ! NODAL CONTACT
R,1
RMOD,1,7,1 !CONTACT NORMAL ALONG UY
MP,EX,1,1E3
MP,NUXY,1,.3
LOCAL,11,1,0,8,0 ! LOCAL CYLINDRICAL C.S. AT CENTERLINE
K,1,8,-90 ! DEFINE KEYPOINTS
K,2,8
K,3,7.5,-90
K,4,7.5
K,5
K,6,8,-82.65 ! PLACE KEYPOINT AND NODE AT EXPECTED CONTACT RADIUS
K,7,7.5,-82.65
L,1,3 ! DEFINE LINES
L,2,4
L,6,7
LESIZE,ALL,,,1 ! DEFINE ELEMENT DIVISIONS ON ALL EXISTING LINES
A,1,6,7,3 ! DEFINE AREAS
A,6,2,4,7
A,3,7,4,5
LOCAL,12,0,0,8,0
ARSYM,Y,1,3,1 ! CREATE HALF-SYMMETRY MODEL
NUMMRG,KPOI
ESIZE,,4 ! DEFINE ELEMENT DIVISIONS ON REMAINING LINES
LESIZE,4,,,5
*REPEAT,2,1
LESIZE,6,,,8,8
LESIZE,7,,,8,(1/8)
LESIZE,10,,,1
*REPEAT,2,2
LESIZE,9,,,6,.2
TYPE,1 ! CREATE NODES AND ELEMENTS
AMESH,1,2,1
AMESH,4,5,1
TYPE,2
AMESH,3,6,3
CSYS,0
N,1001,-1,1E-8 !NODE 1001 IS THE GROUND
D,1001,ALL !X POSITION DOES NOT MATTER IN THIS CASE BECAUSE
!THE CONTACT NORMAL IS ONLY ALONG UY
TYPE,3
REAL,1
EN,205,1001,2 !USE THE SAME ELEMENT NUMBERS AS VM63 FOR POST-PROC
EN,201,1001,4
EN,202,1001,6
EN,203,1001,8
EN,204,1001,10
EN,206,1001,31

MODMSH,NOCHECK
TYPE,1 ! REMOVE MIDSIDE NODES ALONG CONTACT SURFACE
EMODIF,7,7,0
*REPEAT,6,1
MODMSH,CHECK
FINISH
/SOLU
NSEL,S,LOC,X,-.01,.01 ! BOUNDARY CONDITIONS AND LOADING
D,ALL,UX,0
NSEL,R,LOC,Y,0
D,ALL,UY,0
NSEL,ALL
LOAD=0
*CREATE,LOADSTEP ! MACRO TO INCREMENTALLY APPLY LOAD
FK,8,FY,ARG1
SOLVE
*END
*DO,I,1,3
LOAD=LOAD-10
*USE,LOADSTEP,LOAD*6.2831853
*ENDDO
FINISH
/POST1 ! POSTPROCESS
/OUT,
SET,3
ESEL,,TYPE,,3
ETABLE,RFOR,SMISC,1
NSLE
PRETAB,RFOR ! PRINT REACTION FORCE TO DETERMINE CONTACT AREA
SSUM ! SUM OF REACTION FORCE
NLIST ! LIST COORDINATES OF NODES OF CONTACT SURFACE
PRNSOL,U,COMP ! LIST DISPLACEMENTS OF NODES
/COM CALCULATE RATIO OF A - ACTUAL TO A - TARGET
PI=(4*ATAN(1))
LOAD=-(LOAD)*(2*PI)
ATAR=(0.88*((LOAD*0.008)**(1/3))) ! A - TARGET
*GET,EMAX,ELEM,,NUM,MAX
*DO,ENUM,201,EMAX ! START SEARCH FROM ELEM 201
*GET,GRFR,ELEM,ENUM,ETAB,RFOR ! FIND LAST ELEMENT IN CONTACT
*IF,GRFR,EQ,0.0,EXIT
*ENDDO
ESEL,,ELEM,,(ENUM-1) ! SELECT LAST CONTACTING ELEMENT
NSLE ! SELECT NODES ATTACHED TO SELECTED ELEMENTS
*GET,NMIN,NODE,0,NUM,MIN
NODX=NX(NMIN)
NODY=NY(NMIN)
NUX =UX(NMIN)
NUY =UY(NMIN)
AACT=NODX+NUX ! A - ACTUAL
YCHK=NODY+NUY
RATA=(AACT/ATAR) ! RATIO
*STAT
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' A,'
LABEL(1,2) = ' mm '
*VFILL,VALUE(1,1),DATA,1.010
*VFILL,VALUE(1,2),DATA,AACT
*VFILL,VALUE(1,3),DATA,ABS(AACT/1.010)
/COM
/OUT,vm63,vrt,,append
/COM,---------------------------------------------------------------------------
/COM,----------VM63 RESULTS COMPARISON (OBTAINED USING CONTACT178 ELEMENTS)-----
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,---------------------------------------------------------------------------
/OUT
FINISH
*LIST,vm63,vrt







VM64 (Thermal Expansion to Close a Gap at a Rigid Surface) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM64
/PREP7
/TITLE, VM64, THERMAL EXPANSION TO CLOSE A GAP AT A RIGID SURFACE
C*** INTRO. TO STRESS ANALYSIS, HARRIS, 1ST PRINTING, PAGE 58, PROB. 8
C*** USING CONTAC26 AND PLANE42 ELEMENTS
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,CONTAC26
R,1,2.625E15 ! SURFACE STIFFNESS (K) = 2.625E15
ET,2,PLANE42,,,3
R,2,1 ! THICKNESS = 1
MP,EX,1,10.5E6
MP,ALPX,1,12.5E-6
MP,NUXY,1,0
N,1,2,1
N,2,3,1
N,3,3,4
N,4,2,4
N,11,1,0.998
N,12,4,0.998
E,1,11,12 ! CONTACT ELEMENTS
E,2,11,12
TYPE,2
REAL,2
E,1,2,3,4
TREF,70
BFUNIF,TEMP,170
D,3,ALL,,,4
D,1,UX,,,2,1
OUTPR,BASIC,LAST
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,STRSX,S,X
ETABLE,STRSY,S,Y
*GET,STRSSX,ELEM,3,ETAB,STRSX
*GET,STRSSY,ELEM,3,ETAB,STRSY
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'SIGX, (p','SIGY, (p'
LABEL(1,2) = 'si) ','si) '
*VFILL,VALUE(1,1),DATA,-13125,-6125
*VFILL,VALUE(1,2),DATA,STRSSX,STRSSY
*VFILL,VALUE(1,3),DATA,ABS(STRSSX/13125) ,ABS(STRSSY/6125)
/COM
/OUT,vm64,vrt
/COM,------------------- VM64 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm64,vrt


VM65 (Transient Response of a Ball Impacting a Flexible Surface) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM65
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM65, TRANSIENT RESPONSE OF A BALL IMPACTING A FLEXIBLE SURFACE
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND. PRINTING, PAGE 110,
C*** EX. 4.6-1, USING NON-LINEAR TRANSIENT DYNAMIC ANALYSIS
ANTYPE,TRANS ! NONLINEAR TRANSIENT DYNAMIC ANALYSIS
ET,1,CONTAC26
R,1,1973.92088 ! CONTACT SURFACE WITH STIFFNESS = 1973.92088
ET,2,MASS21,,,4 ! 2-D MASS WITHOUT ROTARY INERTIA
R,2,.5
N,1,,1
N,2,-1
N,3,1
E,1,2,3
TYPE,2
REAL,2
E,1
FINISH
/SOLU
SOLCONTROL,0
NSUBST,10
ACEL,,386
KBC,1 ! STEP ACCELERATION CHANGE
CNVTOL,F,1,1E-5 ! FORCE CONVERGENCE CRITERIA
TIME,1E-3 ! RELEASE MASS USING SMALL TIME STEP
SOLVE
OUTRES,,1
NSUBST,109 ! INTEGRATION TIME STEP OF 0.001 IN SECOND LOAD STEP
TIME,.11 ! TIME TO ALLOW THE MASS TO REACH ITS LARGEST DEFLECTION
SOLVE
FINISH
/POST26
NSOL,2,1,U,Y,UY
DERIV,3,2,1,,VEL1UY
PROD,4,3,3,,K.E.,,,.5,.5 ! CALCULATE K.E. BY 1/2(MV**2)
PLVAR,2,3,4
PRVAR,2,3,4 ! PRINT DISP., VELOCITY AND KINETIC ENERGY
*GET,DISP,VARI,2,RTIME,.072
*GET,VELO,VARI,3,RTIME,.072
*GET,KENG,VARI,4,RTIME,.072
*GET,MAXY,VARI,2,EXTREM,VMIN
*GET,TMAX,VARI,2,EXTREM,TMIN
FINISH
/POST1
SET,,,,,0.072 ! DEFINE DATA SET AT TIME = 0.072
ETABLE,KENE,KENE ! RETRIEVE KINETIC ENERGY
PRETAB,KENE ! PRINT KINETIC ENERGY
*DIM,LABEL2,CHAR,4,2
*DIM,VALUE2,,4,3
LABEL2(1,1) = 'TIME, s','Y DISP, ','Y VEL, i','K ENRG, '
LABEL2(1,2) = 'ec ','in ','n/sec ','lb-in '
*VFILL,VALUE2(1,1),DATA,.07198,-1,-27.79,193
*VFILL,VALUE2(1,2),DATA,.072,DISP,VELO,KENG
*VFILL,VALUE2(1,3),DATA,ABS(.072/.07198),ABS(DISP/1),ABS(VELO/27.79),ABS(KENG/193)
/COM
/OUT,vm65,vrt
/COM,------------------- VM65 RESULTS COMPARISON --------------
/COM,
/COM,AT IMPACT | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL2(1,1),LABEL2(1,2),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/COM,
/NOPR
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'TIME, s','MAXY DISP, '
LABEL(1,2) = 'ec ',' in '
*VFILL,VALUE(1,1),DATA,.10037,-1.5506
*VFILL,VALUE(1,2),DATA,TMAX,MAXY
*VFILL,VALUE(1,3),DATA,ABS(TMAX/.10037),ABS(MAXY/1.5506)
/GOPR
/COM
/COM,----------------------------------------------------------
/COM,
/COM,AT "ZERO" VELOCITY | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm65,vrt


VM66 (Vibration of a Flat Plate) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM66
/PREP7
SMRT,OFF
/TITLE, VM66, VIBRATION OF A FLAT PLATE
C*** VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 338, ART. 53
C*** USING SHELL63 ELEMENTS WITH SHELL OPTION
ANTYPE,MODAL ! MODE-FREQUENCY ANALYSIS
ET,1,SHELL63
R,1,1 ! THICKNESS = 1
MXPAND,1 ! EXPAND FIRST MODE
MODOPT,REDUC,2,,,2 ! PRINT ALL REDUCED MODE SHAPES
MP,EX,1,30E6
MP,DENS,1,728E-6
MP,NUXY,1,0
K,1,,-2
K,2,16,-2
KGEN,2,1,2,1,,4
L,1,3
L,2,4
LESIZE,ALL,,,2
A,1,2,4,3
ESIZE,,4
AMESH,1
NSEL,S,LOC,Y,0
M,ALL,UZ
NSEL,S,LOC,X,16
D,ALL,ALL
NSEL,ALL
OUTPR,ALL,1
FINISH
/SOLU
SOLVE
*GET,FREQ,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' f, '
LABEL(1,2) = 'Hz '
*VFILL,VALUE(1,1),DATA,128.09
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/128.09)
/COM
/OUT,vm66,vrt
/COM,------------------- VM66 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm66,vrt


VM67 (Radial Vibrations of a Circular Ring from an Axisymmetric Model) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM67
/PREP7
/TITLE, VM67, RADIAL VIBRATIONS OF A CIRCULAR RING FROM AN AXISYMMETRIC MODEL
C*** VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 425, ART. 68
C*** (AXISYMMETRIC) AND 2
ANTYPE,MODAL ! MODE-FREQUENCY ANALYSIS
ET,1,PLANE25
MXPAND,1 ! EXPAND FIRST MODE
MP,EX,1,30E6
MP,DENS,1,73E-5
MP,NUXY,1,0 ! POISSON'S RATIO IS ZERO
LOCAL,11,,9.975 ! DEFINE LOCAL C.S. AT INSIDE SURFACE OF THE RING
N,1
N,2,,.05
NGEN,2,2,1,2,1,.05
E,1,3,4,2
CP,1,UX,1,2 ! COUPLE RADIAL DOF'S
M,1,UX
FINISH
/SOLU
OUTPR,ALL,1
D,ALL,UZ,0
D,1,UY,0
MODE,0,1
MODOPT,REDUC
SOLVE
*GET,FREQ0,MODE,1,FREQ
FINISH
/SOLU
OUTPR,ALL,1
DDELE,ALL ! DELETE DISPLACEMENT CONSTRAINTS
M,1,UX,,,UZ
D,1,UY
MODE,2,1 ! SYMMETRIC LOADING FOR MODE 2
MXPAND,1,0,100 ! RANGE OF FREQUENCIES OF INTEREST
SOLVE
*GET,FREQ2,MODE,1,FREQ
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = ' f0,',' f2,'
LABEL(1,2) = ' Hz ',' Hz '
*VFILL,VALUE(1,1),DATA,3226.4,12.496
*VFILL,VALUE(1,2),DATA,FREQ0,FREQ2
*VFILL,VALUE(1,3),DATA,ABS(FREQ0/3226.4 ) ,ABS( FREQ2/12.496)
/COM
/OUT,vm67,vrt
/COM,------------------- VM67 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm67,vrt


VM68 (PSD Response of a Two DOF Spring-mass System) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM68

/PREP7
/TITLE, VM68, PSD RESPONSE OF TWO DOF SPRING-MASS SYSTEM
! "VIBRATION ANALYSIS" R.K. VIERK ,2ND EDITION ,(CHAPTER 7)
ET,1,COMBIN40 ! DISPLACEMENT ALONG X AXIS, MASS AT NODE I
R,1,42832.,,0.50
R,2,32416.,,1.0
MP,EX,1,1 ! NOT USED, DUMMY PROPERTY
N,1 ! DEFINE MODEL
N,2,1
N,3,2
E,2,1
REAL,2
E,3,2
D,1,UX,0.0 ! CONSTRAINT THE BASE
OUTPR,ALL,ALL
FINISH

/SOLU
ANTYPE,MODAL ! PERFORM A MODAL ANALYSIS
MODOPT,SUBSP,2 ! SUBSPACE IERTATION METHOD
! EXTRACT 2 MODES FROM ENTIRE FREQUENCY RANGE
MXPAND,2,,,YES ! EXPAND 2 MODES, DO ELEMENT STRESS CALCULATIONS
SOLVE
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
FINISH

/SOLU
ANTYPE,SPECTR ! PERFORM SPECTRUM ANALYSIS
SPOPT,PSD,2,ON ! USE FIRST 2 MODES FROM MODAL ANALYSIS

PSDUNIT,1,ACCG ! USE G**2/HZ FOR PSD AND DIMENSION IN INCHES
D,1,UX,1.0 ! APPLY SPECTRUM AT THE SUPPORT POINT
PSDFRQ,1,1,10.0,100.0 ! FREQUENCY RANGE OF 10 TO 100 HERTZ
PSDVAL,1,.1,.1 ! WHITE NOISE PSD, VALUES IN G**2/HZ
PFACT,1,BASE ! BASE EXCITATION

DMPRAT,0.02 ! 2% DAMPING
PSDCOM ! COMBINE MODES FOR PSD, USE DEFAULT SIGNIFICANCE LEVEL

PSDRES,ACEL,REL ! CALCULATE RELATIVE ACCELERATION SOLUTIONS
SOLVE
FINISH

/POST1
LCDEF,6,5,1 ! DEFINE LOAD STEP AND SUBSTEP FOR LOAD FACTOR OPERATION
LCFACT,ALL,(1/386.4) ! CONVERT ACCEL. RESULT TO G
LCASE,6
PRNSOL,U,COMP ! PRINT NODAL SOLUTION RESULTS
*GET,M1STD,NODE,2,U,X
*GET,M2STD,NODE,3,U,X
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'f1, ','f2, ','MASS1,1S','MASS2,1S'
LABEL(1,2) = ' Hz',' Hz','IG.STDEV','IG.STDEV'
*VFILL,VALUE(1,1),DATA,20.57,64.88,9.059,10.63
*VFILL,VALUE(1,2),DATA,FREQ1,FREQ2,M1STD,M2STD
*VFILL,VALUE(1,3),DATA,ABS(FREQ1/20.57),ABS(FREQ2/64.88),ABS(M1STD/9.059),ABS(M2STD/10.63)
/COM
/OUT,vm68,vrt
/COM,------------------- VM68 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm68,vrt


VM69 (Seismic Response) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM69
/PREP7
/TITLE, VM69, SEISMIC RESPONSE
C***VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 78, EX 3.11-1
ET,1,COMBIN40,,,,,,2
R,1,9.8696,,1 ! SPRING CONSTANT = 9.8696, MASS = 1
N,1
N,2
E,1,2
M,2,UX
FINISH
/SOLU
ANTYPE,MODAL ! MODE-FREQUENCY SEISMIC RESPONSE
MXPAND,1,,,YES ! EXPAND MODES; ELEM STRESS
! ONLY ONE MODE WILL BE USED IN SPECTRUM ANALYSIS
MODOPT,LANB,1 ! USE BLOCK LANCZOS EIGENVALUE EXTRACTION METHOD
D,1,UX
OUTPR,NSOL,LAST
OUTRES,ALL,ALL
SOLVE
*GET,FREQ,MODE,1,FREQ
FINISH
/SOLU
ANTYPE,SPECTR ! SPECTRUM ANALYSIS
SPOPT,SPRS,,ON ! STRESS ON
SED,1 ! GLOBAL X-AXIS AS SPECTRUM DIRECTION
SVTYP,3 ! SEISMIC DISPLACEMENT SPECTRUM
FREQ,.4,.5,.6 ! FREQUENCY POINTS FOR SV V/S FREQ TABLE
SV,,1.01270849,1.02,1.02905569 ! SPECT. VALUES ASSOCIATED WITH FREQ. POINTS
OUTPR,NSOL,ALL
OUTRES,ALL,ALL
SOLVE
*GET,MC1,MODE,1,MCOEF ! OBTAIN MODE COEFF. FOR THIS SPECTRUM & MODE 1
FINISH
/POST1
SET,1,1,MC1 ! MULTIPY DATABASE FOR MODE1 BY MODE COEFFICIENT
PRNSOL,U,X
*GET,AMP,NODE,2,U,X
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = ' f, ',' AE,'
LABEL(1,2) = ' Hz',' in'
*VFILL,VALUE(1,1),DATA,.5,1.02
*VFILL,VALUE(1,2),DATA,FREQ,AMP
*VFILL,VALUE(1,3),DATA,ABS(FREQ/.5),ABS(AMP/1.02)
/COM
/OUT,vm69,vrt
/COM,------------------- VM69 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm69,vrt


VM70 (Seismic Response of a Beam Structure) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM70
/PREP7
MP,PRXY,,0.3
/TITLE, VM70, SEISMIC RESPONSE OF A BEAM STRUCTURE
C*** INTRODUCTION TO STRUCT. DYNAMICS, BIGGS, PAGE 262, ART. 6.4
ET,1,BEAM3
R,1,273.9726,(1000/3),14 ! A = 273.9726, I = (1000/3), H = 14
MP,EX,1,30E6
MP,DENS,1,73E-5
K,1
K,2,240
L,1,2
ESIZE,,8
LMESH,1
NSEL,S,LOC,X,0
D,ALL,UY
NSEL,S,LOC,X,240
D,ALL,UX,,,,,UY
NSEL,ALL
FINISH
/SOLU
ANTYPE,MODAL ! MODE-FREQUENCY ANALYSIS
MODOPT,REDUC,,,,3 ! HOUSEHOLDER, PRINT FIRST 3 REDUCED MODE SHAPES
MXPAND,1,,,YES ! EXPAND FIRST MODE SHAPE, CALCULATE ELEMENT STRESSES
M,ALL,UY
OUTPR,BASIC,1
SOLVE
*GET,FREQ,MODE,1,FREQ
FINISH
/SOLU
ANTYPE,SPECTR ! SPECTRUM ANALYSIS
SPOPT,SPRS ! SINGLE POINT SPECTRUM
SED,,1 ! GLOBAL Y-AXIS AS SPECTRUM DIRECTION
SVTYP,3 ! SEISMIC DISPLACEMENT SPECTRUM
FREQ,.1,10 ! FREQUENCY POINTS FOR SV VS. FREQ TABLE
SV,,.44,.44 ! SPECTRUM VALUES ASSOCIATED WITH FREQUENCY POINTS
SOLVE
*GET,MCOEF,MODE,1,MCOEF ! GET MODE COEFFICIENT FOR FIRST FREQUENCY
FINISH
/POST1
SET,1,1,MCOEF ! SCALE VALUES OF FIRST LOAD STEP
PRNSOL,DOF ! PRINT NODAL SOLUTION
PRESOL,ELEM ! PRINT ELEMENT SOLUTION IN ELEMENT FORMAT
PRRSOL,F ! PRINT REACTION SOLUTION
ETABLE,STRS,LS,3
*GET,STRSS,ELEM,5,ETAB,STRS
*GET,DEF,NODE,6,U,Y
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'f, ','DEF. ','SIG MAX,'
LABEL(1,2) = ' Hz',' in',' psi'
*VFILL,VALUE(1,1),DATA,6.0979,.56,20158
*VFILL,VALUE(1,2),DATA,FREQ,DEF,ABS(STRSS)
*VFILL,VALUE(1,3),DATA,ABS(FREQ/6.0979) ,ABS(DEF/.56), ABS(STRSS/20158)
/COM
/OUT,vm70,vrt
/COM,------------------- VM70 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F12.5,' ',F12.5,' ',1F5.3)
/COM,----------------------------------------------------------

/OUT
FINISH
*LIST,vm70,vrt


VM71 (Transient Response of a Spring-Mass-Damper System) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM71
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM71, TRANSIENT RESPONSE OF A SPRING, MASS, DAMPING SYSTEM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 41, EX 2.2-1
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC ! REDUCED TRANSIENT DYNAMIC ANALYSIS
ET,1,COMBIN40,,,2 ! Y-DOF ELEMENT
R,1,30,3.52636,.02590673 ! VARIOUS SPRING CONST., DAMPING COEFFICIENTS, MASS
R,2,30,1.76318,.02590673
R,3,30,.352636,.02590673
R,4,30,0,.02590673
N,1
N,8
FILL
E,1,2
EGEN,4,2,1,1,1,,,1 ! GENERATE ELEMENTS WITH INCREMENTING REAL CONSTANT SET
M,1,UY,7,2 ! MASTER DOF IN Y DIRECTION AT FREE END OF SPRING
FINISH
/SOLU
DELTIM,1E-3 ! INTEGRATION TIME STEP SIZE
KBC,1 ! STEP CHANGE B.C.'S
OUTPR,NSOL,1
OUTRES,NSOL,1
D,2,UY,,,8,2
F,1,FY,30,,7,2
SOLVE
TIME,95E-3 ! TIME TO COVER ABOUT 1/2 THE PERIOD
F,1,FY,,,7,2 ! REMOVE FORCE
SOLVE
FINISH
/POST26
FILE,,rdsp
NSOL,2,1,U,Y,1UY ! STORE UY DISPLACEMENTS OF APPROPRIATE NODES
NSOL,3,3,U,Y,3UY
NSOL,4,5,U,Y,5UY
NSOL,5,7,U,Y,7UY
NPRINT,10 ! PRINT EVERY 10 POINTS
PRVAR,2,3,4,5 ! PRINT VARIABLES 2,3,4,5
/GRID,1 ! TURN GRID ON
/AXLAB,Y,DISP ! Y-AXIS LABEL DISP
PLVAR,2,3,4,5 ! DISPLAY VARIABLES 2,3,4,5
*GET,U_DAMP2,VARI,2,RTIME,.09
*GET,U_DAMP1,VARI,3,RTIME,.09
*GET,U_DAMP02,VARI,4,RTIME,.09
*GET,U_DAMP0,VARI,5,RTIME,.09
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'U,in DA','U,in DA','U,in DA','U,in DA'
LABEL(1,2) = 'MPRAT=2 ','MPRAT=1 ','MPRAT=.2','MPRAT=0 '
*VFILL,VALUE(1,1),DATA,.4742,.18998,-.52108,-.99688
*VFILL,VALUE(1,2),DATA,U_DAMP2,U_DAMP1,U_DAMP02,U_DAMP0
*VFILL,VALUE(1,3),DATA,U_DAMP2/.4742,U_DAMP1/.18998,ABS(U_DAMP02/.52108)
*VFILL,VALUE(4,3),DATA,ABS(U_DAMP0/.99688)
/COM
/OUT,vm71,vrt
/COM,------------------- VM71 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm71,vrt


VM72 (Logarithmic Decrement) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM72
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM72, LOGARITHMIC DECREMENT
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 45, EX 2.3-1
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC ! LINEAR TRANSIENT
ET,1,COMBIN40,,,2 ! Y DOF ELEMENT
R,1,30,.12,.02590673 ! SPRING CONSTANT = 30, C=.12, MASS=.02590673
N,1
N,2
E,1,2
M,1,UY ! MASTER DOF IN Y DIRECTION AT FREE END OF SPRING
FINISH
/SOLU
DELTIM,.003 ! INTEGRATION TIME STEP SIZE
KBC,1 ! STEP BOUNDARY CONDITIONS
D,2,UY
F,1,FY,30
OUTPR,BASIC,1
OUTRES,NSOL,1
SOLVE ! STATIC SOLUTION AT FIRST LOAD STEP
TIME,.69 ! TIME TO INCLUDE ALMOST FOUR CYCLES
F,1,FY
SOLVE
FINISH
/POST26
FILE,,rdsp
NSOL,2,1,U,Y,UY ! STORE UY DISPLACEMENTS OF NODE 1 AS UY
NPRINT,20 ! PRINT EVERY 20 POINTS
/GRID,1 ! TURN GRID ON
/AXLAB,Y,DISP ! Y-AXIS LABEL AS DISP
PLVAR,2 ! DISPLAY VARIABLE 2 V/S TIME
*GET,AMP1,VARI,2,RTIME,0
*GET,AMP2,VARI,2,RTIME,.186
*GET,AMP3,VARI,2,RTIME,.372
*GET,AMP4,VARI,2,RTIME,.558
R1_2 = AMP1/AMP2
R2_3 = AMP2/AMP3
R3_4 = AMP3/AMP4
TD1_2 = .186 - 0
TD2_3 = .372 - .186
TD3_4 = .558 - .372
*DIM,LABEL_1,CHAR,3,2
*DIM,VALUE_1,,3,4
LABEL_1(1,1) = 'PEAK NUM','MAX. AMP','TIME, '
LABEL_1(1,2) = 'BER ',', in ',' sec '
*VFILL,VALUE_1(1,1),DATA,1,AMP1,0
*VFILL,VALUE_1(1,2),DATA,2,AMP2,.186
*VFILL,VALUE_1(1,3),DATA,3,AMP3,.372
*VFILL,VALUE_1(1,4),DATA,4,AMP4,.558
*DIM,LABEL_2,CHAR,6,2
*DIM,VALUE_2,,6,3
LABEL_2(1,1) = ' R',' R',' R',' (',' (',' ('
LABEL_2(1,2) = ',1_2 ',',2_3 ',',3_4 ','TD)1_2 ','TD)2_3 ','TD)3_4 '
*VFILL,VALUE_2(1,1),DATA,1.5350,1.5350,1.5350,.18507,.18507,.18507
*VFILL,VALUE_2(1,2),DATA,R1_2,R2_3,R3_4,TD1_2,TD2_3,TD3_4
*VFILL,VALUE_2(1,3),DATA,ABS(R1_2/1.535),ABS(R2_3/1.5350),ABS(R3_4/1.535)
*VFILL,VALUE_2(4,3),DATA,ABS(TD1_2/.18507),ABS(TD2_3/.18507),ABS(TD3_4/.18507)
/COM
/OUT,vm72,vrt
/COM,------------------- VM72 RESULTS COMPARISON --------------
/COM,
*VWRITE,LABEL_1(1,1),LABEL_1(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3),VALUE_1(1,4)
(1X,A8,A8,' ',F7.5,' ',F7.5,' ',F7.5,' ',F7.5)
/COM,
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm72,vrt


VM73 (Free Vibration with Coulomb Damping) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM73
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM73, FREE VIBRATION WITH COULOMB DAMPING
C*** MECHANICAL VIBRATIONS, TSE, MORSE, AND HINKLE, PAGE 175, CASE 1
ET,1,COMBIN40,,,,,,2 ! MASS AT NODE J OF ELEMENT
R,1,1E4,,(10/386),,1.875,30
N,1
N,2
E,1,2
FINISH
/SOLU
SOLCONTROL,0
ANTYPE,TRANS ! NONLINEAR TRANSIENT DYNAMIC ANALYSIS
D,1,UX
IC,2,UX,-1,0 ! STRETCH SPRING
KBC,1 ! STEP BOUNDARY CONDITION
CNVTOL,F,1,0.001 ! FORCE CONVERGENCE CRITERIA
TIME,.2025
NSUBST,404 ! TO COMPLETE CIRCLE
OUTRES,,1
SOLVE
FINISH
/POST26
NSOL,2,2,U,X,UX ! STORE UX DISPLACEMENT OF NODE 2
ESOL,3,1,,SMISC,1,F1 ! STORE FORCE F1 OF ELEMENT 1 AS VARIABLE 3
PRVAR,2,3 ! PRINT VARIABLES 2 AND 3
/GRID,1 ! TURN GRID ON
/AXLAB,Y,DISP ! Y AXIS LABEL AS DISP
/GTHK,CURVE,2 ! CURVE LINES THICKNESS RATIO OF 2
PLVAR,2 ! DISPLAY VARIABLE 2
/AXLAB,Y,FORCE ! Y AXIS LABEL AS FORCE
PLVAR,3 ! DISPLAY VARIABLE 3
*GET,U1,VARI,2,RTIME,.09
*GET,U2,VARI,2,RTIME,.102
*GET,U3,VARI,2,RTIME,.183
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'U,IN(T=0','U,IN(T=0','U,IN(T=0'
LABEL(1,2) = '.09sec) ','.102sec)','.183sec)'
*VFILL,VALUE(1,1),DATA,.87208,.83132,-.74874
*VFILL,VALUE(1,2),DATA,U1,U2,U3
*VFILL,VALUE(1,3),DATA,ABS(U1/.87208 ),ABS(U2/.83132 ),ABS(U1/.87208 )
/COM
/OUT,vm73,vrt
/COM,------------------- VM73 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm73,vrt


VM74 (Transient Response to an Impulsive Excitation) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM74
/PREP7
/TITLE, VM74, TRANSIENT RESPONSE TO AN IMPULSIVE EXCITATION
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 99, ART. 4.1
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC ! REDUCED TRANSIENT
ET,1,COMBIN40,,,2,,,2 ! Y DOF ELEMENTS, MASS AT NODE J
R,1,200,,.5 ! TWO DAMPING RATIOS
R,2,200,14,.5
N,1
N,4
FILL
E,1,2
REAL,2
E,3,4
D,1,UY,,,3,2
F,2,FY,,,4,2
M,2,UY,4,2 ! MASTER DOF IN Y DIRECTION AT FREE END OF SPRING
FINISH
/SOLU
DELTIM,25E-4 ! INTEGRATION TIME STEP
KBC,1 ! STEP BOUNDARY CONDITIONS
OUTPR,BASIC,1
SOLVE
TIME,25E-4 ! TIME AT END OF LOAD STEP
F,2,FY,4000,,4,2
SOLVE
TIME,.105 ! TIME TO ALLOW THE MASSES TO REACH LARGEST DEFLECTIONS
F,2,FY,,,4,2
SOLVE
FINISH
/POST26
FILE,,rdsp
NSOL,2,2,U,Y,2UY ! STORE UY DISPLACEMENTS OF APPROPRIATE NODES
NSOL,4,4,U,Y,4UY
NPRINT,.25
PRVAR,2,4
*GET,Y1,VARI,2,RTIME,.08
*GET,Y2,VARI,2,RTIME,.1
*GET,Y3,VARI,4,RTIME,.1
*DIM,LABEL_1,CHAR,1,2
*DIM,VALUE_1,,1,3
LABEL_1(1,1) = 'Y,MAX in'
LABEL_1(1,2) = ' NODE=2 '
*VFILL,VALUE_1(1,1),DATA,.99957
*VFILL,VALUE_1(1,2),DATA,Y1
*VFILL,VALUE_1(1,3),DATA,ABS(Y1/.99957)
*DIM,LABEL_2,CHAR,2,2
*DIM,VALUE_2,,2,3
LABEL_2(1,1) = 'Y, in ','Y, in '
LABEL_2(1,2) = 'node=2 ','node=4 '
*VFILL,VALUE_2(1,1),DATA,.90930,.34180
*VFILL,VALUE_2(1,2),DATA,Y2,Y3
*VFILL,VALUE_2(1,3),DATA,ABS(Y2/.90930),ABS(Y3/.34180)
/COM
/OUT,vm74,vrt
/COM,------------------- VM74 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,TIME=.08 sec
/COM,
*VWRITE,LABEL_1(1,1),LABEL_1(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,
/COM,TIME=.1 sec
/COM,
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm74,vrt


VM75 (Transient Response to a Step Excitation) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM75
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM75, TRANSIENT RESPONSE TO A STEP EXCITATION
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 102, ART 4.3
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC ! REDUCED TRANSIENT
ET,1,COMBIN40,,,2,,,2 ! Y DOF ELEMENTS, MASS AT NODE J
R,1,200,,.5 ! TWO DAMPING RATIOS
R,2,200,10,.5
N,1
N,4
FILL
E,1,2
REAL,2
E,3,4
M,2,UY,4,2 ! MASTER DOF IN Y DIRECTION AT FREE END OF SPRING
DELTIM,25E-4 ! INTEGRATION TIME STEP SIZE
KBC,1 ! STEP BOUNDARY CONDITIONS
D,1,UY,,,3,2
FINISH
/SOLU
OUTPR,BASIC,1
OUTRES,NSOL,1
F,2,FY,,,4,2
SOLVE
TIME,.205 ! TIME AT END OF LOAD STEP
F,2,FY,200,,4,2
SOLVE
FINISH
/POST26
FILE,,rdsp
NSOL,2,2,U,Y,2UY ! STORE UY DISPLACEMENTS OF APPROPRIATE NODES
NSOL,3,4,U,Y,4UY
NPRINT,10 ! PRINT EVERY 10 POINTS
PRVAR,2,3 ! PRINT VARIABLES 2 AND 3
/GRID,1 ! TURN GRID ON
/AXLAB,Y,DISP ! Y-AXIS LABEL AS DISP
PLVAR,2,3 ! DISPLAY VARIABLES 2 AND 3
*GET,UMAX,VARI,2,RTIME,.1575
*GET,U0,VARI,2,RTIME,.2
*GET,U5,VARI,3,RTIME,.2
*DIM,LABEL_1,CHAR,1,2
*DIM,VALUE_1,,1,3
LABEL_1(1,1) = 'UMAX, '
LABEL_1(1,2) = 'in '
*VFILL,VALUE_1(1,1),DATA,2
*VFILL,VALUE_1(1,2),DATA,UMAX
*VFILL,VALUE_1(1,3),DATA,ABS(UMAX/2)
*DIM,LABEL_2,CHAR,2,2
*DIM,VALUE_2,,2,3
LABEL_2(1,1) = 'U,in(DAM','U,in(DAM'
LABEL_2(1,2) = 'PING=0) ','PING=.5)'
*VFILL,VALUE_2(1,1),DATA,1.6536,1.1531
*VFILL,VALUE_2(1,2),DATA,U0,U5
*VFILL,VALUE_2(1,3),DATA,ABS(U0/1.6536),ABS(U5/1.1531)
/COM
/OUT,vm75,vrt
/COM,------------------- VM75 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,TIME = 0.1575 SEC:
*VWRITE,LABEL_1(1,1),LABEL_1(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,
/COM,TIME = 0.20 SEC:
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)

/COM,----------------------------------------------------------

/OUT
FINISH
*LIST,vm75,vrt


VM76 (Harmonic Response of a Guitar String) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM76
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM76, HARMONIC RESPONSE OF A GUITAR STRING
/COM, REFERENCE: BLEVINS, FORMULAS FOR NAT. FREQ. AND MODE SHAPE, TABLE 7-1.
ANTYPE,STATIC ! STATIC ANALYSIS, PRESTRESS
ET,1,LINK1 ! TWO-DIMENSIONAL SPAR
R,1,50671E-12 ! CROSS-SECTIONAL AREA OF STRING
MP,EX,1,190E9 ! MATERIAL, STAINLESS STEEL
MP,DENS,1,7920
N,1 ! DEFINE NODES
N,31,.71
FILL
E,1,2 ! DEFINE ELEMENTS
EGEN,30,1,1
D,1,ALL ! BOUNDARY CONDITIONS AND LOADING
D,2,UY,,,31
F,31,FX,84
FINISH
/SOLU
PSTRES,ON ! DEFINE AS PRESTRESSED ANALYSIS
OUTPR,BASIC,1
SOLVE
FINISH
/SOLU
ANTYPE,MODAL ! MODAL ANALYSIS
MODOPT,SUBSP,6 ! SUBSPACE ITERATION METHOD, 6 FREQ.
PSTRES,ON ! PRESTRESSED ANALYSIS
DDEL,2,UY,30
SOLVE
FINISH
/SOLU
ANTYPE,HARMIC ! HARMONIC RESPONSE ANALYSIS
HROPT,MSUP,6 ! MODE SUPERPOSITION
HROUT,OFF ! AMPLITUDE, PHASE ANGLE PRINTOUT
PSTRES,ON ! PRESTRESSED ANALYSIS
FDELE,31,FX ! DELETE STRETCH LOAD
F,8,FY,-1 ! FORCE AT X=.1657, NEAR QUARTER POINT
KBC,1 ! STEP CHANGE FORCE
HARFRQ,,2000 ! OBTAIN FREQUENCY EVERY EIGHT HERTZ
NSUBST,250
OUTPR,,NONE
OUTRES,,1
SOLVE
FINISH
/POST26 ! TIME-HISTORY POSTPROCESSOR
FILE,,rfrq ! REDUCED FREQUENCIES FILE
NSOL,2,16,U,Y,DISP ! RETRIEVE STRING MIDPOINT DISPLACEMENT RESPONSE
PRVAR,2
/AXLAB,Y,AMPL
PLCPLX,0 ! DISPLAY AMPLITUDE OF COMPLEX VARIABLE (DEFAULT)
PLVAR,2
*GET,FREQ,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' f,'
LABEL(1,2) = ' Hz '
*VFILL,VALUE(1,1),DATA,322.2
*VFILL,VALUE(1,2),DATA,FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/322.2 )
/COM
/OUT,vm76,vrt
/COM,------------------- VM76 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM76 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm76,vrt


VM77 (Transient Response to a Constant Force with a Finite Rise Time) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM77
/PREP7
MP,PRXY,,0.3
/TITLE, VM77, TRANSIENT RESPONSE TO A CONSTANT FORCE WITH A FINITE RISE TIME
C*** INTRODUCTION TO STRUCT. DYNAMICS, BIGGS, PAGE 50, EXAMPLE E
C*** DISPLACEMENT PASS USING BEAM3 AND MASS21 ELEMENTS
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC,,NODAMP ! REDUCED TRANSIENT ANALYSIS, IGNORE DAMPING
ET,1,BEAM3 ! TWO-DIMENSIONAL BEAM
ET,2,MASS21,,,4 ! TWO-DIMENSIONAL MASS
R,1,1,800.6,18 ! BEAM AREA = 1, I = 800.6, H = 18
R,2,.0259067 ! MASS
MP,EX,1,30E3
N,1
N,3,240
FILL
E,1,2 ! BEAM ELEMENTS
EGEN,2,1,1
TYPE,2
REAL,2
E,2 ! TYPE 2 ELEMENT WITH REAL CONSTANT 2
M,2,UY ! MASTER DOF IN Y DIRECTION AT MIDDLE OF BEAM
DELTIM,.004 ! INTEGRATION TIME STEP SIZE
D,1,UY
D,3,UX,,,,,UY
FINISH
/SOLU
OUTPR,BASIC,1
OUTRES,ALL,1
F,2,FY,0 ! FORCE = 0 AT TIME = 0
SOLVE
TIME,.075 ! TIME AT END OF LOAD STEP
F,2,FY,20 ! FORCE IS RAMPED (KBC,0 IS DEFAULT) TO 20
SOLVE
TIME,.1 ! CONSTANT FORCE UNTIL TIME = 0.1
SOLVE
FINISH
/SOLU
C*** EXPANSION PASS USING BEAM3 AND MASS21 ELEMENTS
EXPASS,ON ! EXPANSION PASS ON
EXPSOL,,,0.092 ! TIME OF MAXIMUM RESPONSE
SOLVE
FINISH
/POST1
ETABLE,STRS,LS,3
*GET,STRSS,ELEM,2,ETAB,STRS
FINISH
/POST26
NSOL,2,2,U,Y
STORE
*GET,TMAX,VARI,2,EXTREM,TMAX
*GET,YMAX,VARI,2,EXTREM,VMAX
*DIM,LABEL_1,CHAR,2,2
*DIM,VALUE_1,,2,3
LABEL_1(1,1) = 'T_MAX, s','Y_MAX, i'
LABEL_1(1,2) = 'ec ','n '
*VFILL,VALUE_1(1,1),DATA,.092,.331
*VFILL,VALUE_1(1,2),DATA,TMAX,YMAX
*VFILL,VALUE_1(1,3),DATA,ABS(TMAX/.092),ABS(YMAX/.331)
*DIM,LABEL_2,CHAR,1,2
*DIM,VALUE_2,,1,3
LABEL_2(1,1) = 'SIG_BEND'
LABEL_2(1,2) = ', KSI '
*VFILL,VALUE_2(1,1),DATA,-18.6
*VFILL,VALUE_2(1,2),DATA,STRSS
*VFILL,VALUE_2(1,3),DATA,ABS(STRSS/18.6)
/COM
/OUT,vm77,vrt
/COM,------------------- VM77 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,TRANSIENT:
/COM,
*VWRITE,LABEL_1(1,1),LABEL_1(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.2)
/COM,
/COM,EXPANSION PASS:
/COM,
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.2)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm77,vrt


VM78 (Transverse Shear Stresses in a Cantilever Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM78
/PREP7
/TITLE, VM78: TRANSVERSE SHEAR STRESSES IN A CANTILEVER BEAM
C*** THEORY OF ELASTICITY, TIMESHENKO, PG. 35, ARTICLE 20
ANTYPE,STATIC
ET,1,SHELL99,,,,,2,4 ! 8-NODE LAYERED SHELL; STRESS & STRAIN PRINTOUT
R,1,4,1 ! FOUR SYMMETRIC LAYERS
RMORE
RMORE,1,,0.5,1,,0.5 ! EQUAL THICKNESSES
MP,EX,1,30E6
MP,NUXY,1,0
/COM --- INPUT FAILURE STRESSES FOR MATERIAL #1 ---
/COM --- COMPRESSION VALUES ARE LEFT TO DEFAULT ---
TB,FAIL,1
TBTEMP,,CRIT
TBDATA,1,0,0,1 ! USE TSAI-WU FAILURE CRITERION
TBTEMP,0
TBDATA,10,25000 ! FAILURE X TENSION
TBDATA,12,3000 ! FAILURE Y TENSION (ARBITRARY)
TBDATA,14,5000 ! FAILURE Z TENSION (ARBITRARY)
TBDATA,16,500 ! FAILURE XY DIRECTION SHEAR
N,1
N,3,,1
FILL
NGEN,11,3,1,3,1,1
E,1,7,9,3,4,8,6,2
EGEN,5,6,-1
NSEL,S,LOC,X ! SELECT NODES AT FIXED END AND CONSTRAIN
D,ALL,ALL
NSEL,S,LOC,X,10
CP,1,UZ,ALL ! COUPLE FREE END NODES
NSEL,R,LOC,Y
F,ALL,FZ,10000 ! APPLY END FORCE
NSEL,ALL
OUTPR,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,NX,SMISC,7 ! OUT-OF-PLANE ELEMENT SHEAR FORCE
ETABLE,FC,NMISC,1 ! MAXIMUM FAILURE CRITERION NUMBER
ETABLE,FCMX,NMISC,2 ! MAXIMUM FAILURE CRITERION VALUE
ETABLE,FCLN,NMISC,3 ! FAILURE LAYER
ETABLE,ILMX,NMISC,4 ! MAXIMUM INTERLAMINAR SHEAR STRESS
ETABLE,ILLN,NMISC,5 ! LOWER LAYER NUMBER FOR ILMX
PRETAB,NX,ILLN,ILMX
PRETAB,FC,FCLN,FCMX
ETABLE,SXZ,S,XZ
ETABLE,ILSXZ,SMISC,11
*GET,SIGXZ1,ELEM,4,ETAB,SXZ
*GET,SIGXZ2,ELEM,1,ETAB,ILSXZ
*GET,SIGXZ3,ELEM,1,ETAB,ILMX
*GET,FC3,ELEM,1,ETAB,FCMX
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'SIGXZ,ps','SIGXZ,ps','SIGXZ,ps','FC3MAX ('
LABEL(1,2) = 'i(Z=H/2)','i(Z=H/4)','i(Z= 0 )','FCMX) '
*VFILL,VALUE(1,1),DATA,0,5625,7500,225
*VFILL,VALUE(1,2),DATA,SIGXZ1,SIGXZ2,SIGXZ3,FC3
*VFILL,VALUE(1,3),DATA,0,ABS(SIGXZ2/5625),ABS(SIGXZ3/7500),ABS(FC3/225)
/COM
/OUT,vm78,vrt
/COM,------------------- VM78 RESULTS COMPARISON ---------------

/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm78,vrt


VM79 (Transient Response of a Bilinear Spring Assembly) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM79
/PREP7
/TITLE, VM79, TRANSIENT RESPONSE OF A BI-LINEAR SPRING ASSEMBLY
C***VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 150,FIG 5.6-1
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC,,NODAMP ! REDUCED TRANSIENT ANALYSIS, IGNORE DAMPING
ET,1,COMBIN40,,,2,,,2 ! Y DOF ELEMENTS, MASS AT NODE J
R,1,200,,.5 ! K1 = 200; M = .5
N,1
N,2
E,1,2
M,2,UY ! MASTER DOF IN Y DIRECTION AT FREE END OF SPRING
GP,3,2,FY,-200,.75 ! GAP CONDITION
FINISH
/SOLU
DELTIM,25E-4 ! INTEGRATION TIME STEP
KBC,1 ! STEP BOUNDARY CONDITIONS
D,1,UY,,,3,2 ! CONSTRAIN UY DOF AT NODES 1 AND 3
F,2,FY
OUTPR,BASIC,1
SOLVE ! STATIC LOAD STEP
TIME,25E-4 ! TIME AT END OF LOAD STEP
F,2,FY,-4E3 ! APPLY 4000 LB. LOAD
SOLVE
TIME,.105
F,2,FY,0 ! REMOVE LOAD
SOLVE
FINISH
/POST26
FILE,,rdsp
NSOL,2,2,U,Y,2UY ! STORE UY DISPLACEMENTS OF APPROPRIATE NODES
PRVAR,2
*GET,Y1,VARI,2,RTIME,.09
*GET,Y2,VARI,2,RTIME,.04
*GET,Y3,VARI,2,RTIME,.07
*GET,Y4,VARI,2,RTIME,.085
*GET,Y5,VARI,2,RTIME,.105
*DIM,LABEL_1,CHAR,3,2
*DIM,VALUE_1,,3,4
LABEL_1(1,1) = 'TIME ','Y, in ','Y, in '
LABEL_1(1,2) = 'sec ','linear ','bilinear'
*VFILL,VALUE_1(1,1),DATA,.040,-.68122,Y2
*VFILL,VALUE_1(1,2),DATA,.070,-.97494,Y3
*VFILL,VALUE_1(1,3),DATA,.085,-.99604,Y4
*VFILL,VALUE_1(1,4),DATA,.105,-.88666,Y5
*DIM,LABEL_2,CHAR,1,2
*DIM,VALUE_2,,1,3
LABEL_2(1,1) = 'Y, in '
LABEL_2(1,2) = 'MAX '
*VFILL,VALUE_2(1,1),DATA,-1.0417
*VFILL,VALUE_2(1,2),DATA,Y1
*VFILL,VALUE_2(1,3),DATA,ABS(Y1/1.0417)
/COM
/OUT,vm79,vrt
/COM,------------------- VM79 RESULTS COMPARISON -----------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,TIME=.09 sec
/COM,
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,
/COM,COMPARISON OF ANSYS LINEAR (VM74) AND BILINEAR SPRING RESULTS
/COM,
*VWRITE,LABEL_1(1,1),LABEL_1(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3),VALUE_1(1,4)
(1X,A8,A8,' ',F8.5,' ',F8.5,' ',F8.5,' ',F8.5)
/COM,
/COM,-------------------------------------------------------------
/OUT
FINISH
*LIST,vm79,vrt


VM80 (Plastic Response to a Suddenly Applied Constant Force) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM80
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM80, PLASTIC RESPONSE TO A SUDDENLY APPLIED CONSTANT FORCE
C*** INTRODUCTION TO STRUCT. DYNAMICS, BIGGS, PAGE 69, ART. 2.7
ANTYPE,TRANS ! FULL TRANSIENT DYNAMIC ANALYSIS
ET,1,LINK1
ET,2,MASS21,,,4 ! TWO-DIMENSIONAL MASS
R,1,.278 ! AREA (A)
R,2,0.0259 ! MASS
MP,EX,1,30E3
TB,BKIN,1,1 ! BILINEAR KINEMATIC HARDENING STRESS-STRAIN CURVE
TBTEMP,0
TBDATA,1,162.9,0 ! YIELD STRESS AND TANGENT MODULUS
N,1
N,2,,-100
E,1,2
TYPE,2
REAL,2
E,1
FINISH
/SOLU
SOLCONTROL,0
KBC,1 ! STEP BOUNDARY CONDITIONS
TIME,4E-3 ! TIME AT THE END OF LOAD STEP 1
D,1,UX,,,2
D,2,UY
F,1,FY,30 ! APPLY F1
NSUBST,10 ! 10 SUBSTEPS FOR TIME STEP OF .0004
OUTPR,BASIC,1 ! PRINT BASIC SOLUTION FOR EACH SUBSTEP
OUTRES,NSOL,1 ! STORE NODAL SOLUTION FOR EACH SUBSTEP
SOLVE
TIME,.14 ! FINAL TIME SLIGHTLY MORE THAN 1 CYCLE OF VIBRATION
NSUBST,68 ! 68 REPEATS FOR TIME STEP OF 0.002
OUTPR,BASIC,8 ! PRINT BASIC SOLUTION FOR EVERY 8TH SUBSTEP
SOLVE
FINISH
/POST26
NSOL,2,1,U,Y,UY ! STORE UY DISPLACEMENTS OF NODE 1 AGAINST TIME
PRVAR,2 ! PRINT VARIABLE 2 (DISPLACEMENT UY OF NODE 1) V/S TIME
/GRID,1 ! TURN THE GRID ON FOR DISPLAY
/AXLAB,Y,DISPLACEMENT ! MAKE Y-AXIS LABEL AS DISP FOR DISPLAY
PLVAR,2 ! DISPLAY VARIABLE 2 (DISPLACEMENT UY OF NODE 1) V/S TIME
*GET,YMAX,VARI,2,EXTREM,VMAX
*GET,TMAX,VARI,2,EXTREM,TMAX
*GET,YMIN,VARI,2,RTIME,.122
TMIN = .122
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'Y_MAX, i','TIME, se','Y_MIN, i','TIME, se'
LABEL(1,2) = 'n ','c ','n ','c '
*VFILL,VALUE(1,1),DATA,.806,.0669,.438,.122
*VFILL,VALUE(1,2),DATA,YMAX,TMAX,YMIN,TMIN
*VFILL,VALUE(1,3),DATA,ABS(YMAX/.806),ABS(TMAX/.0669),ABS(YMIN/.438),ABS(TMIN/.122)
/COM
/OUT,vm80,vrt
/COM,------------------- VM80 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm80,vrt


VM81 (Transient Response of a Drop Container) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM81
/PREP7
/TITLE, VM81, TRANSIENT RESPONSE OF A DROP CONTAINER (NONLINEAR)
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND. PRINTING, PAGE 110,
C*** EX. 4.6-1, USING NON-LINEAR TRANSIENT DYNAMIC ANALYSIS
ET,1,COMBIN40,,,2,,,2 ! SPRING, MASS, GAP COMBINATION ELEMENT
R,1,1973.92,,.5,1 ! SPRING STIFFNESS, MASS, AND GAP
N,1 ! DEFINE NODES AND ELEMENT
N,2
E,2,1
FINISH
/SOLU
SOLCONTROL,0
ANTYPE,TRANS ! NONLINEAR TRANSIENT DYNAMIC ANALYSIS
TIME,1E-6
D,2,UY
ACEL,,386 ! BOUNDARY CONDITIONS AND LOADING
KBC,1 ! STEPPED BOUNDARY CONDITIONS
CNVTOL,F,1,0.001 ! FORCE CONVERGENCE CRITERIA
SOLVE
NSUBST,110
OUTPR,BASIC,LAST
OUTRES,NSOL,1
TIME,.11
SOLVE
FINISH
/POST26 ! TIME-HISTORY POSTPROCESSOR
NSOL,2,1,U,Y
DERIV,3,2,1,,VEL_1UY ! CALCULATE VELOCITY BY TAKING DERIVATIVE OF UY
PRVAR,2,3
*GET,Y1,VARI,2,RTIME,.072
*GET,V1,VARI,3,RTIME,.072
*GET,Y2,VARI,2,RTIME,.1
*GET,Y3,VARI,2,RTIME,.101
*DIM,LABEL1,CHAR,3,1
*DIM,VALUE1,,3,3
LABEL1(1,1) = 'TIME sec','Y, in ','V,in/sec'
*VFILL,VALUE1(1,1),DATA,.07198,-1.00,-27.79
*VFILL,VALUE1(1,2),DATA,.072,Y1,V1
*VFILL,VALUE1(1,3),DATA,ABS(.072/.07198),ABS(Y1/1),ABS(V1/27.79)
*DIM,LABEL2,CHAR,2,2
*DIM,VALUE2,,2,3
LABEL2(1,1) = 't=.1 sec','t=1.01 s'
LABEL2(1,2) = ' Y, in ','ec Y, in'
*VFILL,VALUE2(1,1),DATA,-1.5505,-1.5502
*VFILL,VALUE2(1,2),DATA,Y2,Y3
*VFILL,VALUE2(1,3),DATA,ABS(Y2/1.5505),ABS(Y3/1.5502)
SAVE,TABLE1
FINISH
/CLEAR, NOSTART ! CLEAR THE DATABASE
/PREP7
/TITLE, VM81, TRANSIENT RESPONSE OF A DROP CONTAINER (QUASI-LINEAR)
ET,1,MASS21,,,4 ! TWO-DIMENSIONAL MASS ELEMENT
R,1,.5 ! MASS
N,1 ! DEFINE NODE AND ELEMENT
E,1
FINISH
/SOLU
SOLCONTROL,0
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC,,NODAMP ! REDUCED ANALYSIS, IGNORE DAMPING
GP,2,1,FY,1973.92,1 ! GAP CONDITION
D,1,UX
M,1,UY
DELTIM,1E-3
OUTPR,NSOL,LAST
SOLVE
NSUBST,110
OUTRES,NSOL,1
TIME,.110
KBC,1 ! STEPPED BOUNDARY CONDITIONS
ACEL,,386 ! BOUNDARY CONDITIONS AND LOADING
SOLVE
FINISH
/POST26 ! TIME-HISTORY POSTPROCESSOR
FILE,,rdsp ! REDUCED DISPLACEMENTS FILE
NSOL,2,1,U,Y
DERIV,3,2,1,,VEL_1UY ! CALCULATE VELOCITY
PRVAR,2,3
*GET,Y1,VARI,2,RTIME,.072
*GET,V1,VARI,3,RTIME,.072
*GET,Y2,VARI,2,RTIME,.1
*GET,Y3,VARI,2,RTIME,.101
*DIM,LABEL1,CHAR,3,1
*DIM,VALUE1,,3,3
LABEL1(1,1) = 'TIME sec','Y, in ','V,in/sec'
*VFILL,VALUE1(1,1),DATA,.07198,-1.00,-27.79
*VFILL,VALUE1(1,2),DATA,.072,Y1,V1
*VFILL,VALUE1(1,3),DATA,ABS(.072/.07198),ABS(Y1/1),ABS(V1/27.79)
*DIM,LABEL2,CHAR,2,2
*DIM,VALUE2,,2,3
LABEL2(1,1) = 't=.1 sec','t=1.01 s'
LABEL2(1,2) = ' Y, in ','ec Y, in'
*VFILL,VALUE2(1,1),DATA,-1.5505,-1.5502
*VFILL,VALUE2(1,2),DATA,Y2,Y3
*VFILL,VALUE2(1,3),DATA,ABS(Y2/1.5505),ABS(Y3/1.5502)
SAVE,TABLE2
RESUME,TABLE1
/COM
/OUT,vm81,vrt
/COM,------------------- VM81 RESULTS COMPARISON --------------
/COM,
/COM,FULL DYNAMIC | TARGET | ANSYS | RATIO
/COM,
/COM,AT IMAPACT
*VWRITE,LABEL1(1,1),VALUE1(1,1),VALUE1(1,2),VALUE1(1,3)
(1X,A8,' ',F18.4,' ',F10.4,' ',1F5.3)
/COM,
/COM,AT ZERO VELOCITY
*VWRITE,LABEL2(1,1),LABEL2(1,2),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/NOPR
RESUME,TABLE2
/GOPR
/COM,
/COM,REDUCED DYNAMIC | TARGET | ANSYS | RATIO
/COM,
/COM,AT IMAPACT
*VWRITE,LABEL1(1,1),VALUE1(1,1),VALUE1(1,2),VALUE1(1,3)
(1X,A8,' ',F18.4,' ',F10.4,' ',1F5.3)
/COM,
/COM,AT ZERO VELOCITY
*VWRITE,LABEL2(1,1),LABEL2(1,2),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)

/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm81,vrt


VM82 (Simply Supported Laminated Plate Under Pressure) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM82
/PREP7
SMRT,OFF
/TITLE, VM82, SIMPLY SUPPORTED LAMINATED PLATE UNDER PRESSURE
C*** EXACT SOLUTIONS OF MODERATELY THICK LAMINATED SHELLS,
C*** J.N. REDDY, JNL. OF ENGR. MECHANICS, VOL 110, NO.5, MAY'84.
ANTYPE,STATIC
ET,1,SHELL99,,,,,,,1 ! 8 NODE LAYERED SHELL
R,1,4,1 ! 4 LAYERS; SYMMETRIC STACKING
RMORE
RMORE,1,0,.025,1,90,.025 ! LAYER 1 AND 2 OF (0/90/90/0)
MP,EX,1,25E6 ! ORTHOTROPIC MATERIAL PROPERTIES
MP,EY,1,1E6
MP,EZ,1,1E6 ! EZ=EY ASSUMED
MP,GXY,1,5E5
MP,GYZ,1,2E5
MP,GXZ,1,5E5
MP,PRXY,1,0.01 ! MAJOR POISSONS RATIO
MP,PRYZ,1,0.25 ! MAJOR POISSONS RATIO
MP,PRXZ,1,0.01 ! MAJOR POISSONS RATIO
K,1 ! CORNER KEYPOINTS OF QUADRANT (AREA)
K,2,5
K,3,5,5
K,4,,5
A,1,2,3,4
ESIZE,,3 ! 3X3 MESH USING QUARTER SYMMETRY
AMESH,1
NSEL,S,LOC,X,0
DSYM,SYMM,X
NSEL,S,LOC,Y,0
DSYM,SYMM,Y
NSEL,S,LOC,X,5 ! APPLY FREELY SUPPORTED B.C.
D,ALL,UZ,,,,,UY
NSEL,S,LOC,Y,5
D,ALL,UZ,,,,,UX
NSEL,ALL
SFE,ALL,2,PRES,,1 ! APPLY UNIFORM PRESSURE
OUTPR,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,LOC,X ! SELECT CENTER NODE
NSEL,R,LOC,Y
PRNSOL,U,Z ! PRINT CENTER DEFLECTION
*GET,DEF99,NODE,1,U,Z
*DIM,LABEL_1,CHAR,1,2
*DIM,VALUE_1,,1,3
LABEL_1(1,1) = 'DEF,m (S'
LABEL_1(1,2) = 'ELL99) '
*VFILL,VALUE_1(1,1),DATA,.0683
*VFILL,VALUE_1(1,2),DATA,ABS(DEF99)
*VFILL,VALUE_1(1,3),DATA,ABS(DEF99/.0683)
SAVE,INF1
FINISH
/CLEAR, NOSTART
/PREP7
SMRT,OFF
/TITLE, VM82, SIMPLY SUPPORTED LAMINATED PLATE UNDER PRESSURE
C*** EXACT SOLUTIONS OF MODERATELY THICK LAMINATED SHELLS,
C*** J.N. REDDY, JNL. OF ENGR. MECHANICS, VOL 110, NO.5, MAY'84.
ANTYPE,STATIC
ET,1,SOLID46,,,,,,,1 ! 8 NODE LAYERED SOLID
R,1,4,1 ! 4 LAYERS; SYMMETRIC STACKING
RMORE
RMORE,1,0,.25,1,90,.25 ! LAYERS 1 AND 2 OF (0/90/90/0)
MP,EX,1,25E6 ! ORTHOTROPIC MATERIAL PROPERTIES
MP,EY,1,1E6
MP,EZ,1,1E6 ! EZ=EY ASSUMED
MP,GXY,1,5E5
MP,GYZ,1,2E5
MP,GXZ,1,5E5
MP,PRXY,1,0.25 ! MAJOR POISSONS RATIO
MP,PRYZ,1,0.25
MP,PRXZ,1,0.01
K,1 ! CORNER KEYPOINTS OF QUADRANT (VOLUME)
K,2,5
K,3,5,5
K,4,,5
KGEN,2,1,4,1,,,0.1
L,1,5
*REPEAT,4,1,1
LESIZE,ALL,,,1
V,1,2,3,4,5,6,7,8
ESIZE,,6 ! 6X6 MESH USING QUARTER SYMMETRY
VMESH,1
NSEL,S,LOC,X,0
DSYM,SYMM,X
NSEL,S,LOC,Y,0
DSYM,SYMM,Y
NSEL,S,LOC,X,5 ! FREELY SUPPORTED B.C.
D,ALL,UZ,,,,,UY
NSEL,S,LOC,Y,5
D,ALL,UZ,,,,,UX
NSEL,ALL
SFE,ALL,6,PRES,,1 ! APPLY UNIFORM PRESSURE ON TOP SURFACE
OUTPR,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,LOC,X ! SELECT CENTER NODES
NSEL,R,LOC,Y
PRNSOL,U,Z ! PRINT CENTER DEFLECTION
*GET,DEF46,NODE,1,U,Z
*DIM,LABEL_2,CHAR,1,2
*DIM,VALUE_2,,1,3
LABEL_2(1,1) = 'DEF,m (S'
LABEL_2(1,2) = 'ELL46) '
*VFILL,VALUE_2(1,1),DATA,.0683
*VFILL,VALUE_2(1,2),DATA,ABS(DEF46)
*VFILL,VALUE_2(1,3),DATA,ABS(DEF46/.0683)
SAVE, INF2
FINISH
/CLEAR,NOSTART
/PREP7
SMRT,OFF
/TITLE, VM82, SIMPLY SUPPORTED LAMINATED PLATE UNDER PRESSURE
C*** EXACT SOLUTIONS OF MODERATELY THICK LAMINATED SHELLS,
C*** J.N. REDDY, JNL. OF ENGR. MECHANICS, VOL 110, NO.5, MAY'84.
ANTYPE,STATIC
ET,1,SOLID191,,,,,,,1 ! 8 NODE LAYERED SOLID
R,1,4,1 ! 4 LAYERS; SYMMETRIC STACKING
RMORE
RMORE,1,0,.25,1,90,.25 ! LAYERS 1 AND 2 OF (0/90/90/0)
MP,EX,1,25E6 ! ORTHOTROPIC MATERIAL PROPERTIES
MP,EY,1,1E6
MP,EZ,1,1E6 ! EZ=EY ASSUMED
MP,GXY,1,5E5
MP,GYZ,1,2E5
MP,GXZ,1,5E5
MP,PRXY,1,0.25 ! MAJOR POISSONS RATIO
MP,PRYZ,1,0.25
MP,PRXZ,1,0.01
K,1 ! CORNER KEYPOINTS OF QUADRANT (VOLUME)
K,2,5
K,3,5,5
K,4,,5
KGEN,2,1,4,1,,,0.1
L,1,5
*REPEAT,4,1,1
LESIZE,ALL,,,1
V,1,2,3,4,5,6,7,8
ESIZE,,6 ! 6X6 MESH USING QUARTER SYMMETRY
VMESH,1
NSEL,S,LOC,X,0
DSYM,SYMM,X
NSEL,S,LOC,Y,0
DSYM,SYMM,Y
NSEL,S,LOC,X,5 ! FREELY SUPPORTED B.C.
D,ALL,UZ,,,,,UY
NSEL,S,LOC,Y,5
D,ALL,UZ,,,,,UX
NSEL,ALL
SFE,ALL,6,PRES,,1 ! APPLY UNIFORM PRESSURE ON TOP SURFACE
OUTPR,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,LOC,X ! SELECT CENTER NODES
NSEL,R,LOC,Y
PRNSOL,U,Z ! PRINT CENTER DEFLECTION
*GET,DEF191,NODE,1,U,Z
*DIM,LABEL_2,CHAR,1,2
*DIM,VALUE_2,,1,3
LABEL_2(1,1) = 'DEF,m (S'
LABEL_2(1,2) = 'ELL191) '
*VFILL,VALUE_2(1,1),DATA,.0683
*VFILL,VALUE_2(1,2),DATA,ABS(DEF191)
*VFILL,VALUE_2(1,3),DATA,ABS(DEF191/.0683)
SAVE, INF3
RESUME,INF1
/COM
/OUT,vm82,vrt
/COM,------------------- VM82 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL_1(1,1),LABEL_1(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/NOPR
RESUME,INF2
/GOPR
/NOPR
/COM.
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
RESUME, INF3
/GOPR
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm82,vrt


VM83 (Impact of a Block on a Spring Scale) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM83
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM83, IMPACT OF A BLOCK ON A SPRING SCALE
C***VECTOR MECHANICS FOR ENGINEERS, BEER AND JOHNSTON, 1962, PAGE 531, PROB 14.6
C*** WITH THANKS TO ALAN GOULD
ANTYPE,TRANS ! NONLINEAR TRANSIENT DYNAMIC ANALYSIS
ET,1,COMBIN40,1,,2,,,2
ET,2,COMBIN40,,,2,,,2
R,1,100,,(25/386) ! SPRING CONSTANT = 100, MASS = (25/386)
R,2,1E4,50.899,(50/386),71.75 ! SPRING CONSTANT = 1E4, C = 50.90,M=(50/386)
N,1,,-10
N,2
N,3,,72
TYPE,2
E,1,2
TYPE,1
REAL,2
E,2,3
ACEL,,386 ! GRAVITY
FINISH
/SOLU
TIMINT,OFF ! TIME INTEGRATION TURNED OFF
KBC,1 ! STEP THE LOAD
NSUBST,2 ! TWO SUBSTEPS TO GET ZERO INITIAL VELOCITY
! AND ACCELERATION
D,1,UY,,,3,2
TIME,1E-8 ! NEAR ZERO TIME FOR FIRST LOAD STEP
SOLVE
TIMINT,ON ! TIME INTEGRATION TURNED ON
DDELE,3,UY ! REMOVE THE CONSTRAINT AT NODE 3 (RELEASE THE BLOCK)
AUTOTS,ON ! AUTO TIME STEPPING ON
NSUBST,1400 ! MAXIMUM 1400 SUBSTEPS
OUTRES,NSOL,1
TIME,.7
SOLVE
FINISH
/POST26
NSOL,2,2,U,Y,UY ! STORE DISPLACEMENTS UY OF APPROPRIATE NODES
NSOL,3,3,U,Y,UY
FILLDATA,4,,,,71.75 ! DEFINE VARIABLE 4 AS CONSTANT
ADD,5,3,4,,3OFFSET ! CALCULATE VARIABLE 5 AS 3UY + 71.75
PRTIME,.65,.7 ! LIMIT TIME INTERVAL TO BE PRINTED
PRVAR,2,3 ! PRINT VARIABLES 2 AND 3
/AXLAB,Y,INCH
PLVAR,2,5 ! DISPLAY VARIABLES 2 AND 5
*GET,DEF_N2,VARI,2,RTIME,0.68897
*GET,DEF_N3,VARI,3,RTIME,0.68897
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = ' DEF, ',' Y, '
LABEL(1,2) = 'in ','in '
*VFILL,VALUE(1,1),DATA,-7.7,-79.450
*VFILL,VALUE(1,2),DATA,DEF_N2,DEF_N3
*VFILL,VALUE(1,3),DATA,ABS(DEF_N2/7.7) ,ABS(DEF_N3/79.450)
/COM
/OUT,vm83,vrt
/COM,------------------- VM83 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm83,vrt


VM84 (Displacement Propagation Along a Bar with Free Ends) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM84
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM84, DISPLACEMENT PROPAGATION ALONG A BAR WITH FREE ENDS
C*** VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 311, PROB. 2
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC,,NODAMP ! REDUCED TRANSIENT AND IGNORE DAMPING
ET,1,LINK1
R,1,2 ! AREA = 2
MP,EX,1,3E7
MP,DENS,1,7202E-7
N,1
N,17,48E3
FILL
E,1,2
EGEN,16,1,1
M,1,UX,17
FINISH
/SOLU
DELTIM,5E-3 ! INTEGRATION TIME STEP SIZE
KBC,1 ! STEP LOADING CONDITION
OUTPR,BASIC,LAST
D,ALL,UY
F,17,FX ! DEFINE NULL FX LOAD AT NODE 17
SOLVE
OUTPR,BASIC,2
OUTRES,NSOL,1
TIME,.24 ! FINAL TIME INCLUDES 1/2 OF THE FUNDAMENTAL PERIOD
F,17,FX,6000 ! APPLY FULL LOAD TO NODE 17
SOLVE
FINISH
/POST26
FILE,,rdsp ! REDUCED DISPLACEMENTS FILE
NSOL,2,1,U,X,1UX ! STORE APPROPRIATE NODAL DISPLACEMENTS
NSOL,3,9,U,X,9UX
NSOL,4,17,U,X,17UX
DERIV,5,2,,,1VX ! COMPUTE VELOCITIES
DERIV,6,3,,,9VX
DERIV,7,4,,,17VX
/GRID,1 ! TURN GRID ON
/AXLAB,Y,DISP ! Y-AXIS LABEL DISP
PLVAR,2,3,4 ! DISPLAY VARIABLES 2, 3 AND 4
/AXLAB,Y,VELO ! Y-AXIS LABEL VELO
PLVAR,5,6,7 ! DISPLAY VARIABLES 5, 6 AND 7
PRTIME,0.230,0.240 ! APPROPRIATE TIME RANGE (.23 TO .24)
PRVAR,4 ! PRINT VARIABLE 4 (UX AT NODE 17)
*GET,DEF,VARI,4,RTIME,.240
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' DEF,'
LABEL(1,2) = 'in '
*VFILL,VALUE(1,1),DATA,4.8
*VFILL,VALUE(1,2),DATA,DEF
*VFILL,VALUE(1,3),DATA,ABS(DEF/4.8)
/COM
/OUT,vm84,vrt
/COM,------------------- VM84 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm84,vrt


VM85 (Transient Displacements in a Suddenly Stopped Moving Bar) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM85
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM85, TRANSIENT DISPLACEMENTS IN A SUDDENLY STOPPED MOVING BAR
C*** VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 305, PROB. NO. 3
ANTYPE,TRANS ! REDUCED TRANSIENT DYNAMIC ANALYSIS
TRNOPT,REDUC,,NODAMP ! IGNORE DAMPING
ET,1,LINK1
R,1,1 ! AREA
MP,EX,1,30E6
MP,DENS,1,.00073
N,1
N,17,10000
FILL
E,1,2
EGEN,16,1,1
M,1,UX,17
GP,1,20,FX,3E7,.64 ! GAP CONDITION
FINISH
/SOLU
SOLCONTROL,0
DELTIM,.0001 ! ITS DEFINITION
KBC,1 ! STEP BOUNDARY CONDITION
D,ALL,UY
F,1,FX,,,17 ! DEFINE NULL FORCES ON ALL BAR NODES
SOLVE
TIME,.0004
F,1,FX,57031.25,,17,16 ! FORCES REQUIRED TO ACHIEVE INITIAL VELOCITY
F,2,FX,114062.5,,16
SOLVE
TIME,.06
F,1,FX,,,17 ! REMOVE FORCES ("COAST")
SOLVE
FINISH
/POST26
FILE,,rdsp ! REDUCED DISPLACEMENTS FILE
NSOL,2,1,U,X
NSOL,3,17,U,X
NSOL,5,9,U,X
ADD,4,2,3,,REL_DISP,,,-1 ! COMPUTE RELATIVE DISPLACEMENTS
PRTIME,.053,.057
PRVAR,2,3,4,5
/AXLAB,Y,DISPLACEMENTS
PLVAR,2,3,4,5
DERIV,6,2,,,1 VX ! COMPUTE VELOCITIES
DERIV,7,3,,,17VX
DERIV,8,5,,,9 VX
/AXLAB,Y,VELOCITY
PLVAR,6,7,8
*GET,D_0544,VARI,4,RTIME,.0544
*GET,D_0557,VARI,4,RTIME,.0557
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'D,in(T=.','D,in(T=.','D,in(T=.'
LABEL(1,2) = '05573sec','0544sec)','0557sec)'
*VFILL,VALUE(1,1),DATA,4.9329,0,0
*VFILL,VALUE(1,2),DATA,0,D_0544,D_0557
*VFILL,VALUE(1,3),DATA,0,ABS(D_0544/4.9329),ABS(D_0557/4.9329)
FINISH
/SOLU
EXPASS,ON ! EXPANSION PASS
EXPSOL,,,0.0557 ! EXPAND SOLUTION AT TIME CLOSEST TO THE THEORETICAL TIME POINT
OUTPR,,1
SOLVE
FINISH
/POST1
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,1,ETAB,STRS
*DIM,LABEL_2,CHAR,2,2
*DIM,VALUE_2,,2,3
LABEL_2(1,1) = 'SIGX,PSI','SIGX,PSI'
LABEL_2(1,2) = 'T=.05573',' T=.0557'
*VFILL,VALUE_2(1,1),DATA,14799,0
*VFILL,VALUE_2(1,2),DATA,0,STRSS
*VFILL,VALUE_2(1,3),DATA,0,ABS(STRSS/14799)
/COM
/OUT,vm85,vrt
/COM,------------------- VM85 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,REDUCED TRANSIENT DYNAMIC:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,
/COM,EXPANSION PASS:
/COM,
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm85,vrt


VM86 (Harmonic Response of a Dynamic System) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM86
/PREP7
/TITLE, VM86, HARMONIC RESPONSE OF A DYNAMIC SYSTEM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 56, EX 3.1-2
C*** BY VISCOUS DAMPING APPROACH
ANTYPE,HARMIC ! HARMONIC RESPONSE ANALYSIS
HROPT,REDUC ! REDUCED HARMONIC RESPONSE
HROUT,OFF ! PRINT COMPLEX DISP. AS AMPLITUDES AND PHASE ANGLES
ET,1,COMBIN40,,,3,,,2
R,1,200,6,.5 ! SPRING STIFFNESS = 200, C = 6, M = .5
N,1
N,2
E,1,2
M,2,UZ
OUTPR,BASIC,1
HARFRQ,,3.1831 ! HARMONIC FREQUENCY RANGE
D,1,UZ
F,2,FZ,10
FINISH
/SOLU
SOLVE
FINISH
/POST26
FILE,,rfrq
NSOL,2,2,U,Z,2UX
PRVAR,2
*GET,A,VARI,2,ITIME,3.1831
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'AMPLITUD'
LABEL(1,2) = 'E, in '
*VFILL,VALUE(1,1),DATA,.0833
*VFILL,VALUE(1,2),DATA,ABS(A)
*VFILL,VALUE(1,3),DATA,ABS(A/.0833)
/COM
/OUT,vm86,vrt
/COM,------------------- VM86 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM86 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm86,vrt


VM87 (Equivalent Structural Damping) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM87
/PREP7
/TITLE, VM87, EQUIVALENT STRUCTURAL DAMPING
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND. PRINTING, PAGE 72,
C*** ART. 3.9, AND PAGE 56, EX. 3.1-2
ANTYPE,HARMIC ! HARMONIC RESPONSE ANALYSIS
HROPT,REDUC ! REDUCED HARMONIC RESPONSE
HROUT,OFF ! PRINT COMPLEX DISP. AS AMPLITUDES AND PHASE ANGLES
ET,1,COMBIN40,,,3,,,2
BETAD,.03 ! EQUIVALENT STRUCTURAL DAMPING
R,1,200,,.5 ! SPRING STIFFNESS = 200, C = 0, M = 0.5
N,1
N,2
E,1,2
M,2,UZ
OUTPR,BASIC,1
HARFRQ,,3.1831 ! HARMONIC FREQUENCY RANGE
D,1,UZ
F,2,FZ,10
FINISH
/SOLU
SOLVE
FINISH
/POST26
FILE,,rfrq
NSOL,2,2,U,Z,2UX
PRVAR,2
*GET,A,VARI,2,ITIME,3.1831
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'AMPLITUD'
LABEL(1,2) = 'E, in '
*VFILL,VALUE(1,1),DATA,.0833
*VFILL,VALUE(1,2),DATA,ABS(A)
*VFILL,VALUE(1,3),DATA,ABS(A/.0833)
/COM
/OUT,vm87,vrt
/COM,------------------- VM87 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM87 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm87,vrt


VM88 (Response of an Eccentric Weight Exciter) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM88
/PREP7
/TITLE, VM88, RESPONSE OF AN ECCENTRIC WEIGHT EXCITER
! VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 60, EX 3.3-1
ANTYPE,HARMIC ! HARMONIC RESPONSE ANALYSIS
HROPT,REDUC ! REDUCED HARMONIC RESPONSE
HROUT,OFF ! PRINT COMPLEX DISP. AS AMPLITUDES AND PHASE ANGLES
ET,1,COMBIN40
R,1,30,.11754533,.02590673 ! K = 30, C = .11754533, M = .02590673
N,1
N,2
E,2,1
M,2,UX
FINISH
/SOLU
OUTPR,BASIC,1
HARFRQ,,5.415947 ! FREQUENCY RANGE FROM 0 TO 5.415947 HZ.
D,1,UX
F,2,FX,2.4
SOLVE
HARFRQ,,541.5947 ! FREQUENCY RANGE FROM 0 TO 541.5947 HZ.
F,2,FX,24000
SOLVE
FINISH
/POST26
FILE,,rfrq
NSOL,2,2,U,X,2UX
PRVAR,2
*GET,A1,VARI,2,ITIME,5.4159
*GET,A2,VARI,2,RTIME,541.59
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'AMP f=fn','AMP f=10'
LABEL(1,2) = ', in ','0fn, in '
*VFILL,VALUE(1,1),DATA,.6,.08
*VFILL,VALUE(1,2),DATA,ABS(A1),ABS(A2)
*VFILL,VALUE(1,3),DATA,ABS(A1/.6),ABS(A2/.08)
/COM
/OUT,vm88,vrt
/COM,------------------- VM88 RESULTS COMPARISON ---------------

/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM88 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm88,vrt


VM89 (Natural Frequencies of a Two-mass-spring System) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM89
/PREP7
/TITLE, VM89, NATURAL FREQUENCIES OF A TWO-MASS-SPRING SYSTEM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 163,EX 6.2-2
ANTYPE,MODAL ! MODE-FREQUENCY ANALYSIS
MODOPT,REDUC,,,,2 ! PRINT ALL REDUCED MODE SHAPES (TOTAL 2)
ET,1,COMBIN14,,,2
ET,2,MASS21,,,4
R,1,200 ! SPRING CONSTANT = 200
R,2,800 ! SPRING CONSTANT = 800
R,3,.5 ! MASS = .5
R,4,1 ! MASS = 1
N,1
N,4,1
FILL
E,1,2 ! SPRING ELEMENT (TYPE,1) AND K = 200 (REAL,1)
TYPE,2
REAL,3
E,2 ! MASS ELEMENT (TYPE,2) AND MASS = .5 (REAL,3)
TYPE,1
REAL,2
E,2,3 ! SPRING ELEMENT (TYPE,1) AND K = 800 (REAL,2)
TYPE,2
REAL,4
E,3 ! MASS ELEMENT (TYPE,2) AND MASS = 1 (REAL,4)
TYPE,1
REAL,1
E,3,4 ! SPRING ELEMENT (TYPE,1) AND K = 200 (REAL,1)
M,2,UX,3
OUTPR,BASIC,1
D,1,UY,,,4
D,1,UX,,,4,3
FINISH
/SOLU
SOLVE
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = ' f1',' f2'
LABEL(1,2) = ', Hz ',', Hz '
*VFILL,VALUE(1,1),DATA,2.5814,8.3263
*VFILL,VALUE(1,2),DATA,FREQ1,FREQ2
*VFILL,VALUE(1,3),DATA,ABS(FREQ1/2.5814 ) ,ABS( FREQ2/8.3263)
/COM
/OUT,vm89,vrt
/COM,------------------- VM89 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM89 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm89,vrt


VM90 (Harmonic Response of a Two-Mass-Spring System) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM90
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM90, HARMONIC RESPONSE OF A TWO-MASS-SPRING SYSTEM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 178,EX 6.6-1
ANTYPE,HARMIC ! HARMONIC RESPONSE ANALYSIS
HROPT,REDUC ! REDUCED HARMONIC RESPONSE
HROUT,OFF ! PRINT RESULTS AS AMPLITUDES AND PHASE ANGLES
ET,1,COMBIN14,,,2
ET,2,MASS21,,,4
R,1,200 ! SPRING CONSTANT = 200
R,2,.5 ! MASS = 0.5
N,1
N,4,1
FILL
E,1,2
TYPE,2
REAL,2
E,2 ! MASS ELEMENT
TYPE,1
REAL,1
E,2,3 ! SPRING ELEMENT
TYPE,2
REAL,2
E,3 ! MASS ELEMENT
TYPE,1
REAL,1
E,3,4 ! SPRING ELEMENT
M,2,UX,3
OUTPR,BASIC,1
NSUBST,30 ! 30 INTERVALS WITHIN FREQ. RANGE
HARFRQ,,7.5 ! FREQUENCY RANGE FROM 0 TO 7.5 HZ
KBC,1 ! STEP BOUNDARY CONDITION
D,1,UY,,,4
D,1,UX,,,4,3
F,2,FX,200
FINISH
/SOLU
SOLVE
FINISH
/POST26
FILE,,rfrq
NSOL,2,2,U,X,2UX ! STORE UX DISPLACEMENTS
NSOL,3,3,U,X,3UX
PRVAR,2,3
*GET,X1,VARI,2,RTIME,1.5
*GET,X2,VARI,3,RTIME,1.5
*GET,X3,VARI,2,RTIME,4
*GET,X4,VARI,3,RTIME,4
*GET,X5,VARI,2,RTIME,6.5
*GET,X6,VARI,3,RTIME,6.5
/GRID,1 ! TURN GRID ON
/AXLAB,Y,DISP ! Y-AXIS LABEL DISP
PLVAR,2,3 ! DISPLAY VARIABLES 2 AND 3
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
LABEL(1,1) = 'X1, in ','X2, in ','X1, in ','X2, in ','X1, in ','X2, in '
LABEL(1,2) = 'f=1.5 Hz','f=1.5 Hz','f=4 Hz ','f=4 Hz ','f=6.5 Hz','f=6.5 Hz'
*VFILL,VALUE(1,1),DATA,.82272,.46274,.51145,1.2153,.58513,.26966
*VFILL,VALUE(1,2),DATA,ABS(X1),ABS(X2),ABS(X3),ABS(X4),ABS(X5),ABS(X6)
V1 = ABS(X1/.82272)
V2 = ABS(X2/.46274)
V3 = ABS(X3/.51145)
V4 = ABS(X4/1.2153)
V5 = ABS(X5/.58513)
V6 = ABS(X6/.26965)
*VFILL,VALUE(1,3),DATA,V1,V2,V3,V4,V5,V6
/COM
/OUT,vm90,vrt
/COM,------------------- VM90 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM90 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm90,vrt


VM91 (Large Rotation of a Swinging Pendulum) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM91
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM91, LARGE ROTATION OF A SWINGING PENDULUM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 138,EX 5.4-1
/NOPR
ANTYPE,TRANS ! NONLINEAR TRANSIENT DYNAMIC ANALYSIS
NLGEOM,ON ! LARGE DEFLECTION OPTION
ET,1,LINK8
ET,2,MASS21,,,2
R,1,.1 ! AREA = .1
R,2,.5 ! MASS = 0.5
MP,EX,1,3E7
N,1
N,2,60,-80
E,1,2 ! ROD
TYPE,2
REAL,2
E,2 ! MASS
SAVE
FINISH
*CREATE,SLV
/SOLU
ACEL,,386
KBC,1 ! STEP BOUNDARY CONDITION
D,1,UZ,,,2
D,1,UX,,,,,UY
TIME,.01 ! INITIAL L.S. TO ATTAIN FINAL ACCELERATION
NSUBST,5
OUTRES,,1
LSWRITE,1 ! WRITE LOAD STEP FILE 1
TIME,.82071 ! SUCCEEDING LOAD STEPS AT T/4 INCREMENTS
NSUBST,8
OUTRES,,1
LSWRITE,2 ! WRITE LOAD STEP FILE 2
TIME,1.64142
LSWRITE,3 ! WRITE LOAD STEP FILE 3
TIME,2.46213
LSWRITE,4 ! WRITE LOAD STEP FILE 4
TIME,3.28284
LSWRITE,5 ! WRITE LOAD STEP FILE 5
LSSOLVE,1,5,1 ! READ IN LOAD STEP FILES 1 THROUGH 5 AND SOLVE
FINISH
*END
*USE,SLV
*CREATE,P26
/POST26
NSOL,2,2,U,X,UX2 ! STORE NODE 2 DISPLACEMENTS
NSOL,3,2,U,Y,UY2
PRVAR,2,3 ! PRINT DISPLACEMENTS VS. TIME
/AXLAB,Y,DISPLACEMENTS ! Y-AXIS LABEL
PLVAR,2,3 ! DISPLAY DISPLACEMENTS VS. TIME.
T = 3.28284
*GET,DEFX_Q,VARI,2,RTIME,T/4
*GET,DEFY_Q,VARI,3,RTIME,T/4
*GET,DEFX_H,VARI,2,RTIME,T/2
*GET,DEFY_H,VARI,3,RTIME,T/2
*GET,DEFX_3Q,VARI,2,RTIME,3*T/4
*GET,DEFY_3Q,VARI,3,RTIME,3*T/4
*GET,DEFX_F,VARI,2,RTIME,T
*GET,DEFY_F,VARI,3,RTIME,T
*DIM,LABEL,CHAR,8,2
*DIM,VALUE,,8,3
LABEL(1,1) = 'DEFX,in ','DEFY,in ','DEFX,in ','DEFY,in ','DEFX,in ','DEFY,in '
LABEL(7,1) = 'DEFX,in ','DEFY,in '
LABEL(1,2) = 'TIME=T/4','TIME=T/4','TIME=T/2','TIME=T/2','TIM=3T/4','TIM=3T/4'
LABEL(7,2) = 'TIME= T ','TIME= T '
*END
*USE,P26
*VFILL,VALUE(1,1),DATA,-60,-20,-120,0,-60,-20,0,0
*VFILL,VALUE(1,2),DATA,DEFX_Q,DEFY_Q,DEFX_H,DEFY_H,DEFX_3Q,DEFY_3Q,DEFX_F,DEFY_F
*VFILL,VALUE(1,3),DATA,ABS(DEFX_Q/60),ABS(DEFY_Q/20),ABS(DEFX_H/120),0,ABS(DEFX_3Q/60)
*VFILL,VALUE(6,3),DATA,ABS(DEFY_3Q/20),0,0
SAVE,TABLE1
FINISH
/CLEAR,NOSTART
/SHOW,vm91,grph
/COM, Switch to 3-Link Element, LINK180
/COM
/PREP7
RESUME
ET,1,LINK180
FINISH
*USE,SLV
*USE,P26
*VFILL,VALUE(1,1),DATA,-60,-20,-120,0,-60,-20,0,0
*VFILL,VALUE(1,2),DATA,DEFX_Q,DEFY_Q,DEFX_H,DEFY_H,DEFX_3Q,DEFY_3Q,DEFX_F,DEFY_F
*VFILL,VALUE(1,3),DATA,ABS(DEFX_Q/60),ABS(DEFY_Q/20),ABS(DEFX_H/120),0,ABS(DEFX_3Q/60)
*VFILL,VALUE(6,3),DATA,ABS(DEFY_3Q/20),0,0
SAVE,TABLE2
RESUME,TABLE1
/OUT,vm91,vrt
/COM,
/COM,------------------- VM91 RESULTS COMPARISON---------------
/COM,
/COM, LINK8 Results | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
RESUME,TABLE2
/COM,
/COM, LINK180 Results | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
/DELETE,vm91,s01
/DELETE,vm91,s02
/DELETE,vm91,s03
/DELETE,vm91,s04
/DELETE,vm91,s05
FINISH
*LIST,vm91,vrt


VM92 (Insulated Wall Temperature) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM92
/PREP7
/TITLE, VM92, INSULATED WALL TEMPERATURE
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 32, EX. 2-5
ANTYPE,STATIC ! THERMAL ANALYSIS
ET,1,LINK34
ET,2,LINK32
R,1,1 ! AREA = 1
MP,KXX,1,.8
MP,HF,1,12
MP,KXX,2,.1
MP,HF,2,2
N,1
N,2
N,3,.75
N,4,(14/12) ! 14 INCHES TO FEET
N,5,(14/12)
E,1,2
TYPE,2
E,2,3
MAT,2
E,3,4
TYPE,1
E,4,5
D,1,TEMP,3000
D,5,TEMP,80
FINISH
/SOLU
SOLVE
FINISH
/POST1
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
PRNLD,HEAT ! PRINT HEAT FLOW RATES
*GET,TI,NODE,2,TEMP
*GET,TO,NODE,4,TEMP
FINISH
/POST26
ESOL,2,4,5,HEAT,,HEAT
STORE
*GET,HEAT,VARI,2,EXTREM,VMAX
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'Q, BTU/h','TI, ','TO, '
LABEL(1,2) = 'r ','F ','F '
*VFILL,VALUE(1,1),DATA,513,2957,336
*VFILL,VALUE(1,2),DATA,HEAT,TI,TO
*VFILL,VALUE(1,3),DATA,ABS(HEAT/513) ,ABS(TI/2957),ABS(TO/336)
/COM
/OUT,vm92,vrt
/COM,------------------- VM92 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm92,vrt


VM93 (Temperature Dependent Conductivity) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM93
/PREP7
/TITLE, VM93, TEMPERATURE DEPENDENT CONDUCTIVITY
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 25, EX. 2-2
ANTYPE,STATIC
ET,1,LINK32
MP,KXX,1,.031,31E-6 ! TEMPERATURE-DEPENDENT CONDUCTIVITY
R,1,1 ! AREA = 1
N,1
N,2,.25
E,1,2
OUTPR,ALL,1
OUTPR,VENG,NONE
KBC,1 ! STEP BOUNDARY CONDITIONS
D,1,TEMP,300
D,2,TEMP,100
FINISH
/SOLU
SOLVE
FINISH
/POST26
ESOL,2,1,2,HEAT,,HEAT
STORE
*GET,HEAT,VARI,2,EXTREM,VMAX
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Q, BTU/h'
LABEL(1,2) = 'r '
*VFILL,VALUE(1,1),DATA,29.760
*VFILL,VALUE(1,2),DATA,HEAT
*VFILL,VALUE(1,3),DATA,ABS(HEAT/29.760 )
/COM
/OUT,vm93,vrt
/COM,------------------- VM93 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm93,vrt


VM94 (Heat-generating Plate) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM94
/PREP7
/TITLE, VM94, HEAT GENERATING PLATE
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 42, EX. 2-9
ANTYPE,STATIC
ET,1,LINK32
ET,2,LINK34
R,1,1 ! AREA = 1
MP,KXX,1,25 ! CONDUCTIVITY
MP,HF,1,13.969738 ! CONVECTION COEFFICIENT
N,1
N,5,((.5/12)*.5)
FILL
N,6,((.5/12)*.5)
E,1,2 ! LINK32 ELEMENTS (CONDUCTION)
EGEN,4,1,1
TYPE,2
E,5,6 ! LINK34 ELEMENT (CONVECTION)
D,6,TEMP,150 ! SPECIFY "FLUID" TEMPERATURES
ESEL,S,ELEM,,1,4
BFE,ALL,HGEN,,1E5 ! HEAT GENERATION
ESEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
PRNLD,HEAT ! PRINT NODAL HEAT FLOW RATES
FINISH
/POST1
*GET,TC,NODE,1,TEMP
FINISH
/POST26
ESOL,2,5,6,HEAT,,HEAT
STORE
*GET,HEAT,VARI,2,EXTREM,VMAX
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'Qf, BTU/','Tc, '
LABEL(1,2) = 'hr ',' F '
*VFILL,VALUE(1,1),DATA,2083.3,299.1
*VFILL,VALUE(1,2),DATA,HEAT,TC
*VFILL,VALUE(1,3),DATA,ABS(HEAT/2083.3) ,ABS(TC/299.1)
/COM
/OUT,vm94,vrt
/COM,------------------- VM94 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm94,vrt


VM95 (Heat Transfer from a Cooling Spine) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM95
/PREP7
/TITLE, VM95, HEAT TRANSFER FROM A COOLING SPINE
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 48, EQNS. 2-44,45
C*** USING LINK33 AND LINK34 ELEMENTS
ANTYPE,STATIC
ET,1,LINK33
ET,2,LINK34
R,1,(1/144) ! CONVERT AREAS INTO SQUARE FT. UNITS
R,2,(1/72)
R,3,(4/144)
MP,KXX,1,25
MP,HF,1,1
N,1
N,9,(8/12)
FILL
N,11
N,19
FILL
E,1,2 ! DEFINE ELEMENTS
TYPE,2
REAL,2
E,1,11
TYPE,1
REAL,1
E,2,3
TYPE,2
REAL,3
E,2,12
EGEN,7,1,3,4
REAL,2
E,9,19
D,1,TEMP,100 ! DEFINE WALL AND TIP TEMPERATURES
D,11,TEMP,,,19
FINISH
/SOLU
SOLVE
FINISH
/POST1
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
NSEL,S,NODE,,1 ! SELECT NODE 1
PRNLD,HEAT ! PRINT NODAL HEAT FLOWS
FSUM ! PRINT HEAT FLOW SUMMATION
ALLSEL
*GET,TL,NODE,9,TEMP
/POST26
ESOL,2,2,1,HEAT,,HEAT
ESOL,3,1,1,HEAT,,HEAT
STORE
*GET,HEAT,VARI,2,EXTREM,VMAX
*GET,HEAT2,VARI,3,EXTREM,VMAX
HTTOT=(ABS(HEAT+HEAT2))
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = ' TL','Q, BTU/'
LABEL(1,2) = ', F ','hr '
*VFILL,VALUE(1,1),DATA,68.594,17.504
*VFILL,VALUE(1,2),DATA,TL,HTTOT
*VFILL,VALUE(1,3),DATA,ABS(TL/68.594),ABS(HTTOT/17.504)
SAVE,TABLE1
FINISH

/CLEAR, NOSTART ! CLEAR DATABASE BEFORE STARTING PART 2
/PREP7
C*** USING SOLID70 ELEMENTS
ANTYPE,STATIC
ET,1,SOLID70
MP,KXX,1,25
LOCAL,11,0,,(-.5/12),(-.5/12)
N,1
N,9,(8/12)
FILL
NGEN,2,10,1,9,1,,,(1/12)
NGEN,2,20,1,19,1,,(1/12)
E,1,2,22,21,11,12,32,31
EGEN,8,1,1
CP,1,TEMP,2,12,22,32 ! COUPLE APPROPRIATE NODAL TEMPERATURES
CPSGEN,8,1,1 ! GENERATE 8 COUPLED SETS
NSEL,S,LOC,X,0
D,ALL,TEMP,100
NSEL,ALL
SFE,ALL,1,CONV,,1
SFE,ALL,2,CONV,,1
SFE,ALL,4,CONV,,1
SFE,ALL,6,CONV,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,LOC,X,(8/12) ! SELECT NODES AT X=L
PRNSOL,TEMP
NSEL,ALL ! PRINT NODAL TEMPERATURES
PRNLD,HEAT ! PRINT NODAL HEAT FLOWS AT WALL
NSEL,S,LOC,X,0 ! SELECT NODES AT X=0
FSUM ! PRINT HEAT FLOW SUMMATION
ALLSEL
*GET,TL,NODE,9,TEMP
/POST26
ESOL,2,1,11,HEAT,,HEAT
ESOL,3,1,1,HEAT,,HEAT
ESOL,4,1,21,HEAT,,HEAT
ESOL,5,1,31,HEAT,,HEAT
STORE
*GET,HEAT,VARI,2,EXTREM,VMAX
*GET,HEAT2,VARI,3,EXTREM,VMAX
*GET,HEAT3,VARI,4,EXTREM,VMAX
*GET,HEAT4,VARI,5,EXTREM,VMAX
HTTOT=(ABS(HEAT+HEAT2+HEAT3+HEAT4))
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = ' TL','Q, BTU/'
LABEL(1,2) = ', F ','hr '
*VFILL,VALUE(1,1),DATA,68.594,17.504
*VFILL,VALUE(1,2),DATA,TL,HTTOT
*VFILL,VALUE(1,3),DATA,ABS(TL/68.594),ABS(HTTOT/17.504)
SAVE,TABLE2
RESUME,TABLE1
/COM
/OUT,vm95,vrt
/COM,------------------- VM95 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,LINK33&LINK34:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/NOPR
RESUME,TABLE2
/GOPR
/COM,
/COM,SOLID70:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm95,vrt


VM96 (Temperature Distribution in a Short, Solid Cylinder) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM96
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
smrt,off
MOPT,VMESH,MAIN
/TITLE, VM96, TEMPERATURE DISTRIBUTION IN A SHORT SOLID CYLINDER
C*** CONDUCTION HEAT TRANSFER, SCHNEIDER, 2ND. PRINTING, PAGE 134, FIG. 6-7
ANTYPE,STATIC
ET,1,SOLID87
MP,KXX,1,1
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM
K,1
K,2,.5,-22.5
K,3,.5,22.5
KGEN,2,ALL,,,,,.5
L,1,4
LESIZE,ALL,,,4 ! SET LINE SEGMENT DIVISIONS TO FOUR
V,1,2,3,1,4,5,6,4 ! DEFINE VOLUME
ESIZE,,6
MSHK,0
MSHA,1
VMESH,1
NSEL,S,LOC,Z
NSEL,A,LOC,X,.5 ! SELECT BOTTOM AND WALL NODES
D,ALL,TEMP
NSEL,S,LOC,Z,.5 ! SELECT NODES AT TOP OF CYLINDER
D,ALL,TEMP,40
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
/VIEW,1,.2,-1,.4
/ANGLE,1,-29,ZS
/CTYPE,1
/EDGE,1,1
/COM *** THE FOLLOWING ANNOTATION COMMANDS ARE ***
/COM *** TYPICALLY GENERATED INTERACTIVELY ***
/ANUM,1,1,-.78943,-.82532 ! ANNOTATION NUMBER, TYPE AND HOT SPOT
/TSPEC,15,1.000,2,0,0 ! TEXT ATTRIBUTES
/TLABEL,-.911,-.826,THERMAL ! ANNOTATION LOCATION AND TEXT
/ANUM,2,1,-.72083,-.89575
/TLABEL,-.913,-.896,ISOSURFACES
/ANUM,3,4,-.54504,-.60828
/LSPEC,15,0,1.000 ! LINE ATTRIBUTES
/LINE,-.599,-.667,-.491,-.550 ! ANNOTATION LINE DEFINITION
/ANUM,4,4,-.55957,-.76672
/LINE,-.520,-.723,-.599,-.811
/ANUM,5,4,-.56409,-.69934
/LINE,-.541,-.697,-.587,-.703
/ANUM,6,8,-.53174,-.71106
/LARC,-.532,-.711,.016,315,468 ! ANNOTATION ARC DEFINITION
/ANUM,7,8,-.59338,-.68469
/LARC,-.593,-.685,.016,111,281
/ANUM,8,11,-.49353,-.55261
/LSYMBOL,-.494,-.553,48,1,1.000 ! ANNOTATION SYMBOL DEFINITION - ARROW
PLNSOL,TEMP ! PLOT NODAL TEMPERATURES AS ISOSURFACES
CSYS,1
NSEL,S,LOC,X ! SELECT CENTERLINE NODES
NSEL,U,LOC,Z,.0625 ! UNSELECT MIDSIDE NODES
NSEL,U,LOC,Z,.1875
NSEL,U,LOC,Z,.3125
NSEL,U,LOC,Z,.4375
NSORT,Z ! SORT RESULTS BASED ON Z COORDINATES
NLIST,ALL
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES FOR CENTERLINE NODES (R=0)
N0 = node(0,0,0.000)
N1 = node(0,0,0.125)
N2 = node(0,0,0.250)
N3 = node(0,0,0.375)
N4 = node(0,0,0.500)
*GET,TA,NODE,N0,TEMP
*GET,TB,NODE,N1,TEMP
*GET,TC,NODE,N2,TEMP
*GET,TD,NODE,N3,TEMP
*GET,TE,NODE,N4,TEMP
*DIM,LABEL,CHAR,5,2
*DIM,VALUE,,5,3
LABEL(1,1) = 'Z=0.0 ft','Z=.125ft','Z=.25 ft','Z=.375ft','Z=0.5 ft'
LABEL(1,2) = ' T, F ',' T, F ',' T, F ',' T, F ',' T, F '
*VFILL,VALUE(1,1),DATA,0,6.8,15.6,26.8,40.0
*VFILL,VALUE(1,2),DATA,TA,TB,TC,TD,TE
*VFILL,VALUE(1,3),DATA,0,ABS(TB/6.8),ABS(TC/15.6),ABS(TD/26.8),ABS(TE/40.0)
/COM
/OUT,vm96,vrt
/COM,------------------- VM96 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm96,vrt


VM97 (Temperature Distribution Along a Straight Fin) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM97
/PREP7
/TITLE, VM97, TEMPERATURE DISTRIBUTION ALONG A STRAIGHT FIN
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 57, EX. 2-13
ANTYPE,STATIC
ET,1,SHELL57 ! CONDUCTING SHELL ELEMENTS
ET,2,LINK34 ! CONVECTION ELEMENTS
L=(4/12) ! FIN LENGTH
B=(1/12) ! FIN WIDTH
R,1,B ! THICKNESS OF CONDUCTING SHELL ELEMENTS
R,2,B/2 ! CROSS-SECTIONAL AREA OF CONVECTION ELEMENTS
MP,KXX,1,15 ! CONDUCTIVITY
MP,HF,1,15 ! CONVECTION COEFFICIENT
N,1
N,11,L
FILL
N,12,L
NGEN,2,20,1,12,1,,1
E,1,2,22,21
EGEN,10,1,1
TYPE,2
REAL,2
E,11,12 ! CONVECTION ELEMENTS AT THE TIP OF THE FIN
EGEN,2,20,11
D,12,TEMP,100,,32,20 ! DEFINE TEMPERATURE FOR CONVECTION ELEMENTS
NSEL,S,LOC,X,0
D,ALL,TEMP,1100 ! APPLY WALL TEMPERATURE
NSEL,ALL
ESEL,S,TYPE,,1
SFE,ALL,1,CONV,,15 ! H = 15 AND TBULK = 100
SFE,ALL,1,CONV,2,100
SFE,ALL,2,CONV,,15
SFE,ALL,2,CONV,2,100
ESEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST26
ESOL,2,1,1,HEAT,,HEAT
ESOL,3,1,21,HEAT,,HEAT
STORE
*GET,HEAT,VARI,2,EXTREM,VMAX
*GET,HEAT2,VARI,3,EXTREM,VMAX
HTTOT=(ABS(HEAT+HEAT2))
/POST1
*DIM,VALUE,,12,3
*VFILL,VALUE(1,1),DATA,1100,955,835,740,660,595,535,490,460,430
*VFILL,VALUE(11,1),DATA,416,5820
*DO,I,0,1,0.1 ! PRINT NODAL TEMPERATURES FOR NODES
NSEL,S,LOC,X,(I*L) ! ALONG INCREMENTS OF 0.1*L
PRNSOL,TEMP
NNUM = NODE (I*L,0,0)
*GET,VAL,NODE,NNUM,TEMP
*VFILL,VALUE(I*10+1,2),DATA,VAL
*VFILL,VALUE(I*10+1,3),DATA,ABS(VALUE(I*10+1,2) / VALUE(I*10+1,1) )
*ENDDO
*VFILL,VALUE(12,2),DATA,HTTOT
*VFILL,VALUE(12,3),DATA,ABS(HTTOT/5820)
NSEL,S,LOC,X,0 ! SELECT NODES TO GET HEAT DISSIPATION RATE (Q)
PRRSOL,HEAT ! PRINT NODAL HEAT FLOW REACTIONS
*DIM,LABEL,CHAR,12,2
LABEL(1,1) = 'T,F(AT X','T,F(AT X','T,F(AT X','T,F(AT X','T,F(AT X','T,F(AT X','T,F(AT X'
LABEL(8,1) = 'T,F(AT X','T,F(AT X','T,F(AT X','T,F(AT X','q, BTU'
LABEL(1,2) = '/L = 0.0','/L = 0.1','/L = 0.2','/L = 0.3','/L = 0.4','/L = 0.5','/L = 0.6'
LABEL(8,2) = '/L = 0.7','/L = 0.8','/L = 0.9','/L = 1.0','/hr '
/COM
/OUT,vm97,vrt
/COM,------------------- VM97 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm97,vrt


VM98 (Temperature Distribution Along a Tapered Fin) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM98
/PREP7
/TITLE, VM98, TEMPERATURE DISTRIBUTION ALONG A TAPERED FIN
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 57, EX. 2-13
C*** USING PLANE55 ELEMENTS
ANTYPE,STATIC
ET,1,PLANE55
MP,KXX,1,15
L=(4/12) ! FIN LENGTH
B=(1/12) ! FIN HEIGHT AT WALL
N,1,,-(B/2)
N,11,L
FILL
N,21,,(B/2)
N,31,L
FILL
E,21,1,2,22
EGEN,9,1,1
E,30,10,11,11
NSEL,S,LOC,X,0
D,ALL,TEMP,1100
NSEL,S,NODE,,1,11
SF,ALL,CONV,15,100
NSEL,S,NODE,,21,30
NSEL,A,NODE,,11
SF,ALL,CONV,15,100
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST26
ESOL,2,1,1,HEAT,,HEAT
ESOL,3,1,21,HEAT,,HEAT
STORE
*GET,HEAT,VARI,2,EXTREM,VMAX
*GET,HEAT2,VARI,3,EXTREM,VMAX
HTTOT=(ABS(HEAT+HEAT2))
/POST1
*DIM,VALUE,,12,3
*VFILL,VALUE(1,1),DATA,1100,970,850,750,655,575,495,430,370,315
*VFILL,VALUE(11,1),DATA,265,5050
*DO,I,0,1,.1 ! CREATE DO LOOP TO PRINT TEMPS IN
NSEL,S,LOC,X,(I*L) ! INCREMENTS OF 0.1*L
PRNSOL,TEMP
NNUM = NODE (I*L,(-(B/2)),0)
*GET,VAL,NODE,NNUM,TEMP
*VFILL,VALUE(I*10+1,2),DATA,VAL
*VFILL,VALUE(I*10+1,3),DATA,ABS(VALUE(I*10+1,2) / VALUE(I*10+1,1) )
*ENDDO
*VFILL,VALUE(12,2),DATA,HTTOT
*VFILL,VALUE(12,3),DATA,ABS(HTTOT/5050)
NSEL,ALL
PRNLD,HEAT ! PRINT NODAL HEAT FLOW RATES
*DIM,LABEL,CHAR,12,2
LABEL(1,1) = 'T,F(AT X','T,F(AT X','T,F(AT X','T,F(AT X','T,F(AT X','T,F(AT X','T,F(AT X'
LABEL(8,1) = 'T,F(AT X','T,F(AT X','T,F(AT X','T,F(AT X','q, BTU'
LABEL(1,2) = '/L = 0.0','/L = 0.1','/L = 0.2','/L = 0.3','/L = 0.4','/L = 0.5','/L = 0.6'
LABEL(8,2) = '/L = 0.7','/L = 0.8','/L = 0.9','/L = 1.0','/hr '
/COM
/OUT,vm98,vrt
/COM,------------------- VM98 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm98,vrt


VM99 (Temperature Distribution in a Trapezoidal Fin) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM99
/PREP7
/TITLE, VM99, TEMPERATURE DISTRIBUTION IN A TRAPEZOIDAL FIN
C*** CONDUCTION HEAT TRANSFER, SCHNEIDER, 2ND. PRINTING, PAGE 164, ART. 7-8
ANTYPE,STATIC
ET,1,PLANE55
MP,KXX,1,18
W=(.96/12) ! FIN LENGTH
N,7
N,8,(W/2)
N,3,W
N,1,W,-((2*W)/6)
FILL,1,3
N,6,,-(W/6)
FILL,2,7,1,5
FILL,1,6,1,4
E,6,4,5
E,7,6,5
E,7,5,8
E,5,3,8
E,5,2,3
E,4,2,5
E,4,1,2
NSEL,S,LOC,X,W
D,ALL,TEMP,100 ! DEFINE WALL TEMPERATURE
NSEL,S,NODE,,1,4,3
NSEL,A,NODE,,6,7
SF,ALL,CONV,500
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
PRNLD,HEAT ! PRINT HEAT FLOW RATES
*GET,TN4,NODE,4,TEMP
*GET,TN5,NODE,5,TEMP
*GET,TN6,NODE,6,TEMP
*GET,TN7,NODE,7,TEMP
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT '
LABEL(1,2) = 'NODE 4) ','NODE 5) ','NODE 6) ','NODE 7) '
*VFILL,VALUE(1,1),DATA,27.6,32.7,9.5,10.7
*VFILL,VALUE(1,2),DATA,TN4,TN5,TN6,TN7
*VFILL,VALUE(1,3),DATA,ABS(TN4/27.6),ABS(TN5/32.7),ABS(TN6/9.5),ABS(TN7/10.7)
/COM
/OUT,vm99,vrt
/COM,------------------- VM99 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM99 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm99,vrt


VM100 (Heat Conduction Across a Chimney Section) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/SHOW,JPEG
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/VERIFY,VM100
/PREP7
/TITLE, VM100, HEAT CONDUCTION ACROSS A CHIMNEY SECTION
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 102, EX. 3-4
ANTYPE,STATIC ! THERMAL ANALYSIS
ET,1,PLANE55
MP,KXX,1,1
N,1
N,3,1
FILL
NGEN,5,3,1,5,1,,.5
E,4,1,2,5
E,3,6,5,2
EGEN,2,3,1,2,1
E,11,7,8,8
E,9,12,11,8
E,12,15,11,11
OUTPR,ALL,1
OUTPR,VENG,NONE
NSEL,S,LOC,X
SF,ALL,CONV,12,100 ! INNER CONVECTION SURFACE
NSEL,S,LOC,X,1
SF,ALL,CONV,3,0 ! OUTER CONVECTION SURFACE
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
ESEL,S,ELEM,,1,3,2 ! SELECT ELEMENTS 1 AND 3
FSUM ! PERFORM FORCE AND MOMENT SUMMATIONS
*GET,HT13,FSUM,,ITEM,HEAT ! ADD HEAT FLOW RATES OF ELEMENTS 1 AND 3
HEAT=HT13*8 ! COMPUTE TOTAL HEAT FLOW RATE
ESEL,ALL
/CLABEL,,1 ! LABEL CONTOUR LINES
/CONTOUR,,20 ! USE 20 CONTOUR LINES
PLNSOL,TEMP ! DISPLAY TEMPERATURE CONTOURS
*DIM,VALUE,,13,3
*VFILL,VALUE(1,1),DATA,93.7,56.3,22.2,93.2,54.6,21.4,87.6,47.5,18.3
*VFILL,VALUE(10,1),DATA,29.6,11.7,4.7,775.2
*DO,I,1,9,1
*GET,TN,NODE,I,TEMP
*VFILL,VALUE(I,2),DATA,TN
*VFILL,VALUE(I,3),DATA,ABS(VALUE(I,2)/VALUE(I,1))
*ENDDO
*VFILL,VALUE(13,2),DATA,HEAT
*VFILL,VALUE(13,3),DATA,ABS(HEAT/775.2)
*GET,TN11,NODE,11,TEMP
*GET,TN12,NODE,12,TEMP
*GET,TN15,NODE,15,TEMP
*VFILL,VALUE(10,2),DATA,TN11,TN12,TN15
*VFILL,VALUE(10,3),DATA,ABS(TN11/29.6),ABS(TN12/11.7),ABS(TN15/4.7)
*DIM,LABEL,CHAR,13,2
LABEL(1,1) = 'T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT '
LABEL(8,1) = 'T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT ','q, BTU'
LABEL(1,2) = 'NODE 1) ','NODE 2) ','NODE 3) ','NODE 4) ','NODE 5) ','NODE 6) ','NODE 7) '
LABEL(8,2) = 'NODE 8) ','NODE 9) ','NODE 11)','NODE 12)','NODE 15)','/hr '
/COM
/OUT,vm100,vrt
/COM,------------------- VM100 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.2)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm100,vrt



VM101 (Temperature Distribution in a Short Solid Cylinder) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM101
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM101, TEMPERATURE DISTRIBUTION IN A SHORT SOLID CYLINDER
C*** CONDUCTION HEAT TRANSFER, SCHNEIDER, 2ND. PRINTING, PAGE 134, FIG. 6-7
ANTYPE,STATIC
ET,1,SOLID70
MP,KXX,1,1
CSYS,1
N,1,1E-10,-5 ! ZERO RADIUS WITH NON-ZERO THETA IS NOT PERMITTED
N,5,.5,-5
FILL
N,6,1E-10,5 ! ZERO RADIUS WITH NON-ZERO THETA IS NOT PERMITTED
N,10,.5,5
FILL
NGEN,5,10,1,10,1,,,.125
E,1,2,7,7,11,12,17,17
E,2,3,8,7,12,13,18,17
EGEN,3,1,2
EGEN,4,10,1,4
OUTPR,,1
D,1,TEMP,,,10 ! APPLY TEMPERATURES
D,15,TEMP,,,40,5
D,41,TEMP,40,,50
NUMMRG,NODE ! MERGE COINCIDENT NODE NUMBERS
FINISH
/SOLU
SOLVE
FINISH
/POST1
/VIEW,,,-1
!/DEVICE,VECTOR,ON
PLNSOL,TEMP
CSYS,1
NSEL,S,LOC,X,0
PRNSOL,TEMP ! TEMPERATURES ALONG AXIS (R=0)
NSEL,S,LOC,X,0.25
NSEL,R,LOC,Y,-5
PRNSOL,TEMP ! TEMPERATURES ALONG R=0.25 FT
ALLSEL
*GET,TN11,NODE,11,TEMP
*GET,TN21,NODE,21,TEMP
*GET,TN31,NODE,31,TEMP
*GET,TN13,NODE,13,TEMP
*GET,TN23,NODE,23,TEMP
*GET,TN33,NODE,33,TEMP
*DIM,LABEL_1,CHAR,3,2
*DIM,VALUE_1,,3,3
LABEL_1(1,1) = ' NODE ',' NODE ',' NODE '
LABEL_1(1,2) = '11 ','21 ','31 '
*VFILL,VALUE_1(1,1),DATA,6.8,15.6,26.8
*VFILL,VALUE_1(1,2),DATA,TN11,TN21,TN31
*VFILL,VALUE_1(1,3),DATA,ABS(TN11/6.8),ABS(TN21/15.6),ABS(TN31/26.8)
*DIM,LABEL_2,CHAR,3,2
*DIM,VALUE_2,,3,3
LABEL_2(1,1) = ' NODE ',' NODE ',' NODE '
LABEL_2(1,2) = '13 ','23 ','33 '
*VFILL,VALUE_2(1,1),DATA,5.2,12.8,24
*VFILL,VALUE_2(1,2),DATA,TN13,TN23,TN33
*VFILL,VALUE_2(1,3),DATA,ABS(TN13/5.2),ABS(TN23/12.8),ABS(TN33/24)
/COM
/OUT,vm101,vrt
/COM,------------------- VM101 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,T, F (CENTERLINE):
/COM,
*VWRITE,LABEL_1(1,1),LABEL_1(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.2)
/COM,
/COM,T, F (MID-RADIUS):
/COM,
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.2)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm101,vrt



VM102 (Cylinder with Temperature Dependent Conductivity) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM102
/PREP7
/TITLE, VM102, CYLINDER WITH TEMPERATURE DEPENDENT CONDUCTIVITY
C*** CONDUCTION HEAT TRANSFER, SCHNEIDER, 2ND. PRINTING, PAGE 166, ART. 7-9
ANTYPE,STATIC
ET,1,PLANE55,,,1 ! AXISYMMETRIC OPTION
MP,KXX,1,50 ! CONSTANT CONDUCTIVITY
N,1,(1/24)
N,6,(1/12)
FILL
NGEN,2,10,1,6,1,,.01
E,1,2,12,11
EGEN,5,1,1
OUTPR,,1
KBC,1 ! STEP BOUNDARY CONDITIONS
D,1,TEMP,100,,11,10
D,6,TEMP,,,16,10
FINISH
/SOLU
SOLVE
FINISH
/POST1
SET,1
NSEL,S,LOC,Y
PRNSOL,TEMP ! RADIAL TEMPERATURES FOR CONSTANT K
*GET,TN2,NODE,2,TEMP
*GET,TN3,NODE,3,TEMP
*GET,TN4,NODE,4,TEMP
*GET,TN5,NODE,5,TEMP
*DIM,LABEL_1,CHAR,4,2
*DIM,VALUE_1,,4,3
LABEL_1(1,1) = ' NODE ',' NODE ',' NODE ',' NODE '
LABEL_1(1,2) = '2 ','3 ','4 ','5 '
*VFILL,VALUE_1(1,1),DATA,73.8,51.5,32.2,15.3
*VFILL,VALUE_1(1,2),DATA,TN2,TN3,TN4,TN5
*VFILL,VALUE_1(1,3),DATA,ABS(TN2/73.8),ABS(TN3/51.5),ABS(TN4/32.2),ABS(TN5/15.3)
NSEL,ALL
FINISH

/PREP7
MP,KXX,1,50,0.5 ! TEMPERATURE-DEPENDENT CONDUCTIVITY
FINISH
/SOLU
SOLVE
FINISH
/POST1
SET,1
NSEL,S,LOC,Y
PRNSOL,TEMP ! RADIAL TEMPERATURES FOR K(T)
*GET,TN2,NODE,2,TEMP
*GET,TN3,NODE,3,TEMP
*GET,TN4,NODE,4,TEMP
*GET,TN5,NODE,5,TEMP
*DIM,LABEL_2,CHAR,4,2
*DIM,VALUE_2,,4,3
LABEL_2(1,1) = ' NODE ',' NODE ',' NODE ',' NODE '
LABEL_2(1,2) = '2 ','3 ','4 ','5 '
*VFILL,VALUE_2(1,1),DATA,79.2,59.6,40.2,20.8
*VFILL,VALUE_2(1,2),DATA,TN2,TN3,TN4,TN5
*VFILL,VALUE_2(1,3),DATA,ABS(TN2/79.2),ABS(TN3/59.6),ABS(TN4/40.2),ABS(TN5/20.8)
/COM
/OUT,vm102,vrt
/COM,------------------- VM102 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,T, F (K=CONSTANT);FIRST LOAD STEP:
/COM,
*VWRITE,LABEL_1(1,1),LABEL_1(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.2)
/COM,
/COM,T, F (K=K(T);SECOND LOAD STEP:
/COM,
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.2)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm102,vrt


VM103 (Thin Plate with Central Heat Source) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM103
/PREP7
/TITLE, VM103, THIN PLATE WITH CENTRAL HEAT SOURCE
C*** CONDUCTION HEAT TRANSFER, SCHNEIDER, 2ND. PRINTING, PAGE 173, ART. 8-1
C*** USING SHELL57 ELEMENTS
ANTYPE,STATIC ! THERMAL ANALYSIS
ET,1,SHELL57
R,1,.1 ! THICKNESS
MP,KXX,1,5
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM
N,1,.1,-5
N,8,.8,-5
FILL
NGEN,2,10,1,8,1,,10
N,21
N,9,(2/15),-5
N,10,(1/6),-5
NGEN,2,10,9,10,1,,10
E,21,1,11 ! 7 TRIANGULAR ELEMENTS
E,1,9,11
E,19,11,9
E,9,10,20
E,20,19,9
E,10,2,20
E,12,20,2
E,12,2,3,13 ! 6 QUADRILATERAL ELEMENTS
EGEN,6,1,8
CP,1,TEMP,1,11 ! COUPLE NODAL TEMPS TANGENTIALLY
CPSGEN,10,1,1
OUTPR,BASIC,1
ESEL,S,ELEM,,2,13,1
SFE,ALL,1,CONV,,30
SFE,ALL,1,CONV,2,100
SFE,ALL,2,CONV,,20
SFE,ALL,2,CONV,2,0
ESEL,ALL
BFE,1,HGEN,,250E3 ! HEAT SOURCE
FINISH
/SOLU
SOLVE
*DIM,VALUE,,10,3
*VFILL,VALUE(1,1),DATA,226.3,103.2,73.8,65.8,62.8,60.8,60.2,60,173.1
*VFILL,VALUE(10,1),DATA,130.7
*DO,I,1,10,1
*GET,TN,NODE,I,TEMP
*VFILL,VALUE(I,2),DATA,TN
*VFILL,VALUE(I,3),DATA,ABS(VALUE(I,2)/VALUE(I,1))
*ENDDO
*DIM,LABEL,CHAR,10,2
LABEL(1,1) = 'T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT '
LABEL(8,1) = 'T,F (AT ','T,F (AT ','T,F (AT '
LABEL(1,2) = 'NODE 1) ','NODE 2) ','NODE 3) ','NODE 4) ','NODE 5) ','NODE 6) ','NODE 7) '
LABEL(8,2) = 'NODE 8) ','NODE 9) ','NODE 10)'
/COM
/OUT,vm103,vrt
/COM,------------------- VM103 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.2)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm103,vrt



VM104 (Liquid-Solid Phase Change) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM104
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM104, LIQUID-SOLID PHASE CHANGE
C*** DANTZIG,J.A., IJNME, VOL 28, 1989, PAGE 1773-1775.
ANTYPE,TRANS
ET,1,PLANE55
MP,DENS,1,1000
MP,KXX,1,0.6
MPTEMP,1,-10,-1,0,10
MPDATA,ENTH,1,1,0,37.8E6,79.8E6,121.8E6 ! ENTHALPY
K,1
K,2,0.01
K,3,0.01,0.001
K,4,,0.001
L,2,3
L,1,4
LESIZE,ALL,,,1
A,1,2,3,4
ESIZE,,15
AMESH,1
FINISH
/SOLU
OUTRES,,ALL
BFUNIF,TEMP ! INITIAL TEMPERATURE
NSEL,S,LOC,X
D,ALL,TEMP,-5.0 ! SURFACE TEMPERATURE
NSEL,ALL
KBC,1 ! STEP LOAD
AUTOTS,ON
DELTIM,3,3,10
TIME,900 ! FINAL TIME
SOLVE
FINISH
/POST1
SET,,,,,500
*GET,T1,NODE,5,TEMP
*GET,T2,NODE,8,TEMP
PATH,TPATH,2,,48 ! DEFINE PATH WITH NAME = "TPATH"
PPATH,1,1 ! DEFINE PATH POINTS BY NODE
PPATH,2,2
PDEF,TEMP,TEMP
PLPATH,TEMP
NSEL,S,LOC,Y
PRNSOL,TEMP ! NODAL TEMPERATURES
FINISH
/POST26
NSOL,2,2,TEMP,,T2
NSOL,3,3,TEMP,,T3
NSOL,4,4,TEMP,,T4
NSOL,5,5,TEMP,,T5
NSOL,6,6,TEMP,,T6
NSOL,7,7,TEMP,,T7
PLVAR,2,3,4,5,6,7 ! DISPLAY TEMPERATURE HISTORY
PRTIME,700,900
PRVAR,2,3,4,5,6,7
FINISH
*DIM,VALUE,,2,3
*DIM,LABEL,CHAR,2,2
*VFILL,VALUE(1,1),DATA,-3.64,-2.32
*VFILL,VALUE(1,2),DATA,T1,T2
*VFILL,VALUE(1,3),DATA,ABS(T1/3.64),ABS(T2/2.32)
LABEL(1,1) = 'T,C (X=0','T,C (X=0'
LABEL(1,2) = '.002 m) ','004 m) '
/OUT,vm104,vrt
/COM,------------------- VM104 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM104 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm104,vrt



VM105 (Heat Generating Coil with Temperature Dependent Conductivity) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM105
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM105, HEAT GENERATING COIL WITH TEMP. DEPENDENT CONDUCTIVITY
C*** CONDUCTION HEAT TRANSFER, SCHNEIDER, 2ND. PRINTING, PAGE 193, ART. 8-8
ANTYPE,STATIC
ET,1,PLANE55 ! THERMAL SOLID
MP,KXX,1,10,.075
CSYS,1
N,1,(1/48),-5 ! RADIAL SECTOR ONE-ELEMENT WIDE
N,10,(1/12),-5
FILL
NGEN,2,10,1,10,1,,10
E,1,2,12,11
EGEN,9,1,1
OUTPR,BASIC,1
KBC,1 ! STEP LOAD
D,1,TEMP,0,,11,10 ! INNER WALL TEMPERATURE
D,10,TEMP,0,,20,10 ! OUTER WALL TEMPERATURE
BFE,ALL,HGEN,,1E6 ! APPLY HEAT GENERATION RATES
FINISH
/SOLU
SOLVE
FINISH
/POST1
CSYS,1
NSEL,S,LOC,Y,-5 ! SELECT NODES ALONG RADIUS AT THETA=-5
PRNSOL,TEMP ! PRINT TEMPERATURE DISTRIBUTION
NSEL,S,NODE,,ALL
PATH,TPATH,2,,48 ! DEFINE PATH WITH NAME = "TPATH"
PPATH,1,1 ! DEFINE PATH POINTS BY NODE
PPATH,2,10
PDEF,TEMP,TEMP
PLPATH,TEMP
*DIM,VALUE,,8,3
*VFILL,VALUE(1,1),DATA,23.3,35.9,42.2,44,42.2,37,28.6,16.5
*DO,I,2,9,1
*GET,TN,NODE,I,TEMP
*VFILL,VALUE(I-1,2),DATA,TN
*VFILL,VALUE(I-1,3),DATA,ABS(VALUE(I-1,2)/VALUE(I-1,1))
*ENDDO
*DIM,LABEL,CHAR,8,2
LABEL(1,1) = 'T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT ','T,F (AT '
LABEL(7,1) = 'T,F (AT ','T,F (AT '
LABEL(1,2) = 'NODE 2) ','NODE 3) ','NODE 4) ','NODE 5) ','NODE 6) ','NODE 7) '
LABEL(7,2) = 'NODE 8) ','NODE 9) '
/COM
/OUT,vm105,vrt
/COM,------------------- VM105 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm105,vrt




VM106 (Radiant Energy Emission) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM106
/PREP7
/TITLE, VM106, RADIANT ENERGY EMISSION
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 22, PROB. 1-8(B)
ANTYPE,STATIC ! THERMAL ANALYSIS
ET,1,LINK31
R,1,144,1,1
N,1 ! TWO COINCIDENT NODES
N,2
E,1,2
OUTPR,ALL,1
OUTPR,VENG,NONE
KBC,1
TOFFST,460 ! OFFSET TEMPERATURE
D,1,TEMP,3000 ! DEFINE NODAL TEMPERATURES
D,2,TEMP,0
FINISH
/SOLU
SOLVE
FINISH
/POST26
ESOL,2,1,1,HEAT,,HEAT
STORE
*GET,HEAT,VARI,2,EXTREM,VMAX
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'q, BTU/h'
LABEL(1,2) = 'r '
*VFILL,VALUE(1,1),DATA,2.4559E5
*VFILL,VALUE(1,2),DATA,ABS(HEAT)
*VFILL,VALUE(1,3),DATA,ABS(HEAT/245590)
/COM,
/OUT,vm106,vrt
/COM,------------------ VM106 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',E11.4,' ',E11.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm106,vrt



VM107 (Thermocouple Radiation) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM107
/PREP7
/TITLE, VM107, THERMOCOUPLE RADIATION
C*** HEAT TRANSFER, CHAPMAN, 1ST. PRINTING, PAGE 396, ART. 13.5
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,LINK34
ET,2,LINK31
R,1,1
R,2,1,1,.5, 0.174E-8
MP,HF,1,11.85 ! FILM COEFFICIENT
N,1
N,3
FILL
E,1,2
TYPE,2
REAL,2
E,2,3
OUTPR,BASIC,1
OUTPR,NLOAD,1 ! PRINT NODAL HEAT FLOWS
KBC,1 ! STEP CHANGE LOADS
TOFFST,460 ! OFFSET TEMPERATURE
D,1,TEMP,1309
D,3,TEMP,300
FINISH
/SOLU
SOLVE
FINISH
/POST1
*GET,TN2,NODE,2,TEMP
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' TT,'
LABEL(1,2) = ' F '
*VFILL,VALUE(1,1),DATA,1000
*VFILL,VALUE(1,2),DATA,TN2
*VFILL,VALUE(1,3),DATA,ABS(TN2/1000 )
/COM
/OUT,vm107,vrt
/COM,------------------- VM107 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM107 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm107,vrt



VM108 (Temperature Gradient Across a Solid Cylinder) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM108
/PREP7
/TITLE, VM108, TEMPERATURE GRADIENT ACROSS A SOLID CYLINDER
C*** HILDEBRAND, ADVANCED CALCULUS, PAGE 447, EQUATIONS 38-44
ANTYPE,STATIC
ET,1,PLANE75 ! AXISYMMETRIC HARMONIC THERMAL SOLID
MP,KXX,1,1
N,1
N,5,20
FILL
NGEN,2,5,1,5,1,,5 ! AXIAL LENGTH IS ARBITRARY
E,1,2,7,6 ! FOUR ELEMENTS ALONG RADIUS AT THETA=0
EGEN,4,1,1
OUTPR,BASIC,1
MODE,1,1 ! ANTISYMMETRIC MODE (ISYM=1)
D,5,TEMP,80,,10,5 ! DEFINE PEAK TEMPERATURE
FINISH
/SOLU
SOLVE
FINISH
/POST1
*GET,TN1,NODE,1,TEMP
*GET,TN2,NODE,2,TEMP
*GET,TN3,NODE,3,TEMP
*GET,TN4,NODE,4,TEMP
*DIM,VALUE,,4,3
*DIM,LABEL,CHAR,4,2
*VFILL,VALUE(1,1),DATA,0,20,40,60
*VFILL,VALUE(1,2),DATA,TN1,TN2,TN3,TN4
*VFILL,VALUE(1,3),DATA,0,ABS(TN2/20),ABS(TN3/40),ABS(TN4/60)
LABEL(1,1) = 'NODE 1 T','NODE 2 T','NODE 3 T','NODE 4 T'
LABEL(1,2) = ', F ',', F ',', F ',', F '
/COM
/OUT,vm108,vrt
/COM,------------------- VM108 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.2)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm108,vrt



VM109 (Temperature Response of a Suddenly Cooled Wire) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM109
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM109, TEMPERATURE RESPONSE OF A SUDDENLY COOLED WIRE
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 120, EX. 4-1
ANTYPE,TRANS ! THERMAL ANALYSIS
ET,1,MASS71,,,1
ET,2,LINK34
R,1,2.7046E-4 ! THERMAL CAPACITANCE PER UNIT LENGTH
R,2,0.0081812 ! SURFACE AREA PER UNIT LENGTH
MP,HF,1,2 ! FILM COEFFICIENT
N,1 ! COINCIDENT NODES AT ORIGIN
N,2
E,1
TYPE,2
REAL,2
E,1,2
FINISH
/SOLU
OUTRES,,ALL
AUTOTS,ON
OUTPR,BASIC,LAST
DELTIM,0.00125
TIME,.0125
BFUNIF,TEMP,300 ! UNIFORM INITIAL TEMPERATURE
KBC,1
D,2,TEMP,100 ! AIR TEMPERATURE
SOLVE
TIME,.0325
SOLVE
TIME,0.05
SOLVE
FINISH
/POST26
NSOL,2,1,TEMP
PRVAR,2 ! PRINT TEMPERATURE
/GRID,1
/AXLAB,Y,TEMP
PLVAR,2 ! DISPLAY TEMP OF NODE 1 VS. TIME
*GET,T1,VARI,2,RTIME,.0125
*GET,T2,VARI,2,RTIME,.0325
*GET,T3,VARI,2,RTIME,.05
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'T,F AT 0','T,F AT 0','T,F AT 0'
LABEL(1,2) = '.0125 hr','.0325 hr','.05 hr'
*VFILL,VALUE(1,1),DATA,193.89,128,109.71
*VFILL,VALUE(1,2),DATA,T1,T2,T3
*VFILL,VALUE(1,3),DATA,ABS(T1/193.89),ABS(T2/128),ABS(T3/109.71)
/COM
/OUT,vm109,vrt
/COM,------------------- VM109 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm109,vrt



VM110 (Transient Temperature Distribution in a Sla) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM110
/PREP7
/TITLE, VM110, TRANSIENT TEMPERATURE DISTRIBUTION IN A SLAB
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 140, EX. 4-4
ANTYPE,TRANS ! TRANSIENT ANALYSIS
ET,1,LINK32 ! HEAT CONDUCTING BAR
ET,2,LINK34 ! CONVECTION LINK
R,1,1 ! UNIT AREA
MP,KXX,1,.54 ! PROPERTIES OF WALL
MP,DENS,1,144
MP,C,1,.20
MP,HF,1,5 ! CONVECTION COEFFICIENT
N,1
N,11,1
FILL
N,12,1
E,1,2
EGEN,10,1,1 ! TEN BAR ELEMENTS ACROSS WALL THICKNESS
TYPE,2
E,11,12 ! ONE CONVECTION LINK AT GAS END
FINISH
/SOLU
OUTRES,,ALL
TIME,14.5 ! TIME AT END OF LOAD STEP
NSUBST,80
BFUNIF,TEMP,100
D,12,TEMP,1600
KBC,1 ! STEP BOUNDARY CONDITION
AUTOTS,ON
OUTPR,BASIC,LAST
TINTPAR,,,,0.5 ! USE CENTRAL DIFFERENCE
SOLVE
FINISH
/POST26
ESOL,2,11,,SMISC,1,HEAT ! HEAT RATE FOR ELEMENT 11
INT1,3,2,1,,TOTAL_HT ! INTEGRATE HEAT RATE OVER TIME SPAN
PRVAR,2,3
*GET,QTOT,VARI,3,RTIME,14.5
FINISH
/POST1
*GET,T1,NODE,1,TEMP
*GET,T3,NODE,3,TEMP
*GET,T5,NODE,5,TEMP
*GET,T7,NODE,7,TEMP
*GET,T9,NODE,9,TEMP
*GET,T11,NODE,11,TEMP
*DIM,LABEL,CHAR,7,2
*DIM,VALUE,,7,3
LABEL(1,1) = 'T, F (NO','T, F (NO','T, F (NO','T, F (NO','T, F (NO','T, F (NO','Q, BTU/f'
LABEL(1,2) = 'DE 1 ) ','DE 3 ) ','DE 5 ) ','DE 7 ) ','DE 9 ) ','DE 11) ','t^2 '
*VFILL,VALUE(1,1),DATA,505,550,670,865,1135,1435,-20736
*VFILL,VALUE(1,2),DATA,T1,T3,T5,T7,T9,T11,QTOT
*VFILL,VALUE(1,3),DATA,ABS(T1/505),ABS(T3/550),ABS(T5/670),ABS(T7/865),ABS(T9/1135)
*VFILL,VALUE(6,3),DATA,ABS(T11/1435),ABS(QTOT/20736)
/COM
/OUT,vm110,vrt
/COM,------------------- VM110 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.2)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm110,vrt



VM111 (Cooling of a Spherical Body) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM111
/PREP7
/TITLE, VM111, COOLING OF A SPHERICAL BODY
! PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 143, EX. 4-5
! USING PLANE55 ELEMENTS (QUAD. ELEMENTS)
ANTYPE,TRANS
ET,1,PLANE55,,,1 ! AXISYMMETRIC ELEMENTS
MP,KXX,1,(1/3)
MP,DENS,1,62
MP,C,1,1.0752677
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM
N,1
N,2,(1/18),-7.5
N,4,(1/6),-7.5
FILL
NGEN,2,20,1,4,1,,15
E,2,22,1,1
E,3,23,22,2
EGEN,2,1,2
CP,1,TEMP,2,22 ! COUPLING TO ENSURE CIRCUMFERENTIAL SYMMETRY
CPSGEN,3,1,1
AUTOTS,ON ! USE AUTOMATIC TIME STEPPING
DELTIM,.01 ! MIN TIME STEP SIZE
OUTPR,BASIC,LAST ! PRINT LAST SUBSTEP
TIME,6
TUNIF,65
KBC,1 ! STEP BOUNDARY CONDITIONS
NSEL,S,LOC,X,(1/6)
SF,ALL,CONV,2,25 ! CONVECTION ON ELEMENT SURFACE
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
*GET,TEMP,NODE,1,TEMP
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' T'
LABEL(1,2) = ', F '
*VFILL,VALUE(1,1),DATA,28
*VFILL,VALUE(1,2),DATA,TEMP
*VFILL,VALUE(1,3),DATA,ABS(TEMP/28)
/COM
/OUT,vm111,vrt
/COM,------------------- VM111 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm111,vrt



VM112 (Cooling of a Spherical Body) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM112
/PREP7
/TITLE, VM112, COOLING OF A SPHERICAL BODY
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 143, EX. 4-5
C*** USING PLANE77 ELEMENTS (MULTI-NODE ELEMENTS)
ANTYPE,TRANS ! THERMAL ANALYSIS
ET,1,PLANE77,,,1 ! AXISYMMETRIC ELEMENTS
MP,KXX,1,(1/3)
MP,DENS,1,62
MP,C,1,1.0752677
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM
N,1
N,2,(1/18),-7.5
N,4,(1/6),-7.5
FILL
NGEN,2,20,1,4,1,,15
N,14,(1/6)
E,2,22,1,1
E,3,23,22,2
E,4,24,23,3,14
CP,1,TEMP,2,22 ! COUPLING TO INSURE CIRCUMFERENTIAL SYMMETRY
CPSGEN,2,1,1
CP,3,TEMP,4,14,24
AUTOTS,ON ! USE AUTOMATIC TIME STEPPING
OUTPR,BASIC,LAST
TIME,6
DELTIM,0.15
BFUNIF,TEMP,65
KBC,1 ! STEP BOUNDARY CONDITIONS
NSEL,S,LOC,X,(1/6)
SF,ALL,CONV,2,25 ! CONVECTION ON ELEMENT SURFACE
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
*GET,TEMP,NODE,1,TEMP
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' T'
LABEL(1,2) = ', F '
*VFILL,VALUE(1,1),DATA,28
*VFILL,VALUE(1,2),DATA,TEMP
*VFILL,VALUE(1,3),DATA,ABS(TEMP/28)
/COM
/OUT,vm112,vrt
/COM,------------------- VM112 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm112,vrt



VM113 (Transient Temperature Distribution in an Orthotropic Metal Bar) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM113
/PREP7
smrt,off
/TITLE, VM113, TRANSIENT TEMP. DISTRIBUTION IN AN ORTHOTROPIC METAL BAR
C*** CONDUCTION HEAT TRANSFER, SCHNEIDER, 2ND. PRINTING, PAGE 261, EX. 10-7
ANTYPE,TRANS
ET,1,PLANE55 ! THERMAL SOLID
MP,KXX,1,20 ! ORTHOTROPIC CONDUCTIVITIES
MP,KYY,1,3.6036
MP,DENS,1,400
MP,C,1,.009009
K,1 ! USE SOLID MODEL
K,2,(2/12)
KGEN,2,1,2,1,,(1/12)
L,1,2
*REPEAT,2,2,2
LESIZE,ALL,,,6,(1/3)
L,1,3
*REPEAT,2,1,1
LESIZE,3,,,5,(1/3)
LESIZE,4,,,5,(1/3)
A,1,3,4,2
AMESH,1
TIME,(3/3600)
NSUBST,40
AUTOTS,ON ! USE AUTOMATIC TIME STEPPING
OUTPR,,LAST
BFUNIF,TEMP,500
KBC,1 ! STEP BOUNDARY CONDITIONS
NSEL,S,LOC,X,(2/12)
NSEL,A,LOC,Y,(1/12)
SF,ALL,CONV,240,100 ! CONVECTION SURFACE
NSEL,ALL
FINISH
/SOLU
EQSLV,JCG ! USE JACOBI CONJUGATE GRADIENT SOLVER
SOLVE
FINISH
/POST1
NSEL,S,LOC,X
NSEL,A,LOC,X,(2/12) ! SELECT NODES OF INTEREST
NSEL,U,LOC,Y,.01,(.99/12)
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
*get,tn1,node,1,temp
*get,tn7,node,7,temp
*get,tn13,node,13,temp
*get,tn2,node,2,temp
*dim,label,char,4,2
*dim,value,,4,3
label(1,1) = 'T,F (nod','T,F (nod','T,F (nod','T,F (nod'
label(1,2) = 'e 1) ','e 7) ','e 13) ','e 2) '
*vfill,value(1,1),data,459,151,279,202
*vfill,value(1,2),data,tn1,tn7,tn13,tn2
*vfill,value(1,3),data,abs(tn1/459),abs(tn7/151),abs(tn13/279),abs(tn2/202)
/com

/OUT,vm113,vrt
/com,-------------------(VM113)RESULTS COMPARISON---------------
/com,
/com, | TARGET | ANSYS | RATIO
/com,
*vwrite,label(1,1),label(1,2),value(1,1),value(1,2),value(1,3)
(1x,a8,a8,' ',f10.0,' ',f10.0,' ',1f5.2)
/com,----------------------------------------------------------
/OUT
FINISH
*LIST,vm113,vrt




VM114 (Temperature Response to a Linearly-rising Surface Temperature) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM114
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM114, TEMPERATURE RESPONSE TO A LINEARLY RISING SURFACE TEMPERATURE
C*** CONDUCTION HEAT TRANSFER, SCHNEIDER, 2ND. PRINTING, PAGE 274, ART 11-2
ANTYPE,TRANS
ET,1,LINK33 ! HEAT CONDUCTING BAR
R,1,1 ! UNIT AREA ASSUMED
MP,KXX,1,10
MP,DENS,1,500
MP,C,1,0.2
K,1
K,2,.3 ! LENGTH OF MODEL FROM SURFACE
L,1,2
LESIZE,1,,,8,3 ! NON-UNIFORM MESH WITH 8 DIVISIONS
LMESH,1
FINISH
/SOLU
SOLCONTROL,0
AUTOTS,ON
OUTPR,,LAST
OUTRES,,ALL
TIME,(2/60) ! TIME PERIOD OF 2 MIN. CONVERTED TO HR.
NSUBST,20
DK,1,TEMP,120 ! TEMPERATURE SPECIFICATION AT KEY POINT 1
SOLVE
FINISH
/POST26
NSOL,2,1,TEMP ! TEMPERATURE HISTORY AT NODES NEAR SURFACE
NSOL,3,3,TEMP
NSOL,4,4,TEMP
NSOL,5,5,TEMP
NSOL,6,6,TEMP
PRVAR,2,3,4,5,6 ! PRINT NODAL TEMPERATURE VARIATION WITH TIME
/GRID,1
/AXLAB,Y,TEMP
PLVAR,2,4,5,6,3 ! DISPLAY NODAL TEMPERATURE HISTORIES
FINISH
/POST1
SET,1
NSORT,TEMP ! SORT NODES BY DESCENDING TEMPERATURE VALUES
NLIST ! LIST NODES TO VERIFY X-COORDINATE LOCATION
PRNSOL,TEMP ! PRINT NODAL TEMPERATURE DISTRIBUTION
*GET,TN1,NODE,1,TEMP
*GET,TN3,NODE,3,TEMP
*GET,TN4,NODE,4,TEMP
*GET,TN5,NODE,5,TEMP
*GET,TN6,NODE,6,TEMP
*GET,TN2,NODE,2,TEMP
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
LABEL(1,1) = 'T,F (NOD','T,F (NOD','T,F (NOD','T,F (NOD','T,F (NOD','T,F (NOD'
LABEL(1,2) = 'E 1) ','E 3) ','E 4) ','E 5) ','E 6) ','E 2) '
*VFILL,VALUE(1,1),DATA,120,79.32,46.62,23.44,9.51,0
*VFILL,VALUE(1,2),DATA,TN1,TN3,TN4,TN5,TN6,TN2
*VFILL,VALUE(1,3),DATA,ABS(TN1/120),ABS(TN3/79.32),ABS(TN4/46.62),ABS(TN5/23.44)
*VFILL,VALUE(5,3),DATA,ABS(TN6/9.51),0
/COM
/OUT,vm114,vrt
/COM,------------------- VM114 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm114,vrt



VM115 (Thermal Response of a Heat-generating Slab) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM115
/PREP7
/TITLE, VM115, THERMAL RESPONSE OF A HEAT GENERATING SLAB
C*** CONDUCTION HEAT TRANSFER, SCHNEIDER, 2ND. PRINTING, PAGE 283, EQN 11-21
ANTYPE,TRANS
ET,1,LINK32 ! HEAT CONDUCTING BAR
R,1,1
MP,KXX,1,20
MP,DENS,1,500
MP,C,1,.2
K,1 ! SURFACE KEYPOINT
K,2,.5 ! CENTERLINE KEYPOINT
L,1,2 ! UNIFORM MESH
LESIZE,1,,,5
LMESH,1
AUTOTS,ON
OUTPR,,LAST
TIME,(12/60) ! CONVERT 12 MIN TO HRS
DELTIM,0.01
BFUNIF,TEMP,60 ! INITIAL UNIFORM TEMPERATURE
KBC,1 ! APPLY STEP LOADS
DK,1,TEMP,32 ! SURFACE TEMPERATURE APPLIED TO KEYPOINT 1
BFK,ALL,HGEN,4E4 ! HEAT GENERATION SPECIFIED AT KEYPOINTS 1 & 2
FINISH
/SOLU
SOLVE
/POST1
*GET,TN1,NODE,1,TEMP
*GET,TN3,NODE,3,TEMP
*GET,TN4,NODE,4,TEMP
*GET,TN5,NODE,5,TEMP
*GET,TN6,NODE,6,TEMP
*GET,TN2,NODE,2,TEMP
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
LABEL(1,1) = 'T,F (NOD','T,F (NOD','T,F (NOD','T,F (NOD','T,F (NOD','T,F (NOD'
LABEL(1,2) = 'E 1) ','E 3) ','E 4) ','E 5) ','E 6) ','E 2) '
*VFILL,VALUE(1,1),DATA,32,75.75,103.99,120.80,129.46,132.1
*VFILL,VALUE(1,2),DATA,TN1,TN3,TN4,TN5,TN6,TN2
*VFILL,VALUE(1,3),DATA,ABS(TN1/32 ),ABS(TN3/75.75),ABS(TN4/103.99),ABS(TN5/120.80)
*VFILL,VALUE(5,3),DATA,ABS(TN6/129.46),ABS(TN2/132.1)
/COM
/OUT,vm115,vrt
/COM,------------------- VM115 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm115,vrt



VM116 (Heat Conducting Plate with Sudden Cooling) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM116
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM116, HEAT CONDUCTING PLATE WITH SUDDEN COOLING
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 161, EX. 4-11
ANTYPE,TRANS
ET,1,LINK34,,3 ! CONVECTION LINK, USE (TI-TJ) FOR HF EVAL‎UATION
ET,2,LINK32 ! HEAT CONDUCTION BAR
R,1,1 ! UNIT AREA ASSUMED
MP,KXX,1,2 ! CONDUCTIVITY, DENSITY AND SPECIFIC HEAT
MP,DENS,1,800 ! INPUT USED BY CONDUCTION ELEMENTS
MP,C,1,0.833
MP,HF,1,2,.02 ! TEMPERATURE DEPENDENT HF (USED FOR ELEM 1)
N,1 ! NODES 1 AND 2 DEFINE THE CONVECTION LINK
N,2 ! (ARBIRARY LENGTH)
N,10,(8/12) ! CONDUCTION LENGTH IN FT.
FILL
E,1,2 ! ELEMENT 1 IS CONVECTION LINK
TYPE,2 ! ELEMENTS 2 THROUGH 9 ARE CONDUCTION BARS
E,2,3
EGEN,8,1,-1
FINISH
/SOLU
D,2,TEMP,500 ! INITIAL SURFACE TEMPERATURES
D,10,TEMP,100
OUTPR,,LAST
OUTRES,,ALL
TIMINT,OFF ! TURN OFF TIME INTEGRATION FOR
TIME,0.001 ! INITIAL STEADY-STATE CONDITION
SOLVE
TIMINT,ON ! TURN ON TIME INTEGRATION ON FOR
TIME,7 ! TRANSIENT OVER 7 HRS
DDELE,2,TEMP ! DELETE NODAL TEMPERATURE
D,1,TEMP,100 ! ENVIRONMENT TEMPERATURE IS DECREASED
KBC,1 ! SUDDENLY
AUTOTS,ON
NSUBST,20
SOLVE
FINISH

/POST26
NSOL,2,2,TEMP
PRVAR,2 ! PRINT TEMPERATURE HISTORY AT NODE 2
/AXLAB,Y,TEMP
/GRID,1
PLVAR,2
FINISH

/POST1
ETABLE,TI,SMISC,2 ! NODAL TEMPERATURES FOR CONDUCTION ELEMENTS
ETABLE,TJ,SMISC,3
PLLS,TI,TJ ! DISPLAY TEMPERATURE VARIATION ACROSS PLATE (AT 7 HRS)
PRNSOL,TEMP
*GET,TN2,NODE,2,TEMP
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'T,F(AT X'
LABEL(1,2) = '=0.0 in)'
*VFILL,VALUE(1,1),DATA,285
*VFILL,VALUE(1,2),DATA,TN2
*VFILL,VALUE(1,3),DATA,ABS(TN2/285)
/COM
/OUT,vm116,vrt
/COM,------------------- VM116 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.2)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm116,vrt



VM117 (Electric Current Flowing in a Network) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM117
/PREP7
/TITLE, VM117, ELECTRIC CURRENT FLOWING IN A NETWORK
C*** BASIC ELECTRICAL ENGR, FITZGERALD AND HIGGIN BOTHAM, 2ND ED, P. 22, EX. 1-11
ANTYPE,STATIC
ET,1,LINK68 ! THERMAL-ELECTRICAL LINE ELEMENT
MP,RSVX,1,1 ! UNIT RESISTIVITY
R,1,(1/20) ! AREAS INPUT TO GIVE REQUIRED RESISTANCE
R,2,(1/10) ! AS PER RESISTANCE=RSVX*L/AREA
R,3,(SQRT(2)/9)
R,4,(1/30)
R,5,(1/90)
N,1
N,2,,1
NGEN,2,2,1,2,1,1
E,1,2 ! BRANCH 1-2, 20 OHM
REAL,2 ! BRANCH 1-3, 10 OHM
E,1,3
REAL,3 ! BRANCH 2-3, 9 OHM
E,2,3
REAL,4 ! BRANCH 2-4, 30 OHM
E,2,4
REAL,5 ! BRANCH 3-4, 90 OHM
E,3,4
KBC,1 ! STEP BOUNDARY CONDITIONS
D,4,VOLT,100 ! NODAL VOLTAGE
D,1,VOLT,0 ! GROUND NODE
OUTPR,ALL,1
OUTPR,VENG,NONE
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,CUR,NMISC,5
PRETAB,CUR ! PRINT CURRENT FOR ALL BRANCHES
*GET,I42,ELEM,4,ETAB,CUR ! CURRENT IN BRANCH 4-2
*GET,I43,ELEM,5,ETAB,CUR ! CURRENT IN BRANCH 4-3
I14=I42+I43 ! CURRENT THROUGH BATTERY (BRANCH 1-4)
*GET,I21,ELEM,1,ETAB,CUR
*GET,I31,ELEM,2,ETAB,CUR
*GET,I23,ELEM,3,ETAB,CUR
*GET,V1,NODE,1,VOLT
*GET,V2,NODE,2,VOLT
*GET,V3,NODE,3,VOLT
*GET,V4,NODE,4,VOLT
*DIM,LABEL,CHAR,10,2
*DIM,VALUE,,10,3
LABEL(1,1) = 'V1, VOLT','V2, VOLT','V3, VOLT','V4, VOLT','I2_1, AM'
LABEL(1,2) = 'S ','S ','S ','S ','PS '
LABEL(6,1) = 'I3_1, AM','I2_3, AM','I4_2, AM','I4_3, AM','I1_4, AM'
LABEL(6,2) = 'PS ','PS ','PS ','PS ','PS '
*VFILL,VALUE(1,1),DATA,0,28,19,100,1.4,1.9,1,2.4,.9,3.3
*VFILL,VALUE(1,2),DATA,V1,V2,V3,V4,ABS(I21),ABS(I31),ABS(I23),ABS(I42),ABS(I43),ABS(I14)
*VFILL,VALUE(1,3),DATA,0,ABS(V2/28),ABS(V3/19),ABS(V4/100),ABS(I21/1.4),ABS(I31/1.9)
*VFILL,VALUE(7,3),DATA,ABS(I23/1),ABS(I42/2.4 ),ABS(I43/.9),ABS(I14/3.3)
SAVE,TABLE_1
FINISH
/CLEAR,NOSTART
/PREP7
ANTYPE,STATIC
ET,1,CIRCU124,0
ET,2,CIRCU124,4
MP,RSVX,1,1 ! UNIT RESISTIVITY
R,1,20
R,2,10
R,3,9
R,4,30
R,5,90
R,6,100
N,1
N,2,,1
NGEN,2,2,1,2,1,1
N,5,2,.5
E,1,2 ! BRANCH 1-2, 20 OHM
REAL,2 ! BRANCH 1-3, 10 OHM
E,1,3
REAL,3 ! BRANCH 2-3, 9 OHM
E,2,3
REAL,4 ! BRANCH 2-4, 30 OHM
E,2,4
REAL,5 ! BRANCH 3-4, 90 OHM
E,3,4
TYPE,2
REAL,6
E,4,1,5
KBC,1 ! STEP BOUNDARY CONDITIONS
D,1,VOLT,0 ! GROUND NODE
OUTPR,ALL,1
OUTPR,VENG,NONE
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,CUR,SMISC,2
PRETAB,CUR ! PRINT CURRENT FOR ALL BRANCHES
*GET,I42,ELEM,4,ETAB,CUR ! CURRENT IN BRANCH 4-2
*GET,I43,ELEM,5,ETAB,CUR ! CURRENT IN BRANCH 4-3
I14=I42+I43 ! CURRENT THROUGH BATTERY (BRANCH 1-4)
*GET,I21,ELEM,1,ETAB,CUR
*GET,I31,ELEM,2,ETAB,CUR
*GET,I23,ELEM,3,ETAB,CUR
*GET,V1,NODE,1,VOLT
*GET,V2,NODE,2,VOLT
*GET,V3,NODE,3,VOLT
*GET,V4,NODE,4,VOLT
*DIM,LABEL,CHAR,10,2
*DIM,VALUE,,10,3
LABEL(1,1) = 'V1, VOLT','V2, VOLT','V3, VOLT','V4, VOLT','I2_1, AM'
LABEL(1,2) = 'S ','S ','S ','S ','PS '
LABEL(6,1) = 'I3_1, AM','I2_3, AM','I4_2, AM','I4_3, AM','I1_4, AM'
LABEL(6,2) = 'PS ','PS ','PS ','PS ','PS '
*VFILL,VALUE(1,1),DATA,0,28,19,100,1.4,1.9,1,2.4,.9,3.3
*VFILL,VALUE(1,2),DATA,V1,V2,V3,V4,ABS(I21),ABS(I31),ABS(I23),ABS(I42),ABS(I43),ABS(I14)
*VFILL,VALUE(1,3),DATA,0,ABS(V2/28),ABS(V3/19),ABS(V4/100),ABS(I21/1.4),ABS(I31/1.9)
*VFILL,VALUE(7,3),DATA,ABS(I23/1),ABS(I42/2.4 ),ABS(I43/.9),ABS(I14/3.3)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm117,vrt
/COM,------------------- VM117 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,LINK68:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,CIRCU124:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
/DELETE,TABLE_1
/DELETE,TABLE_2
FINISH
*LIST,vm117,vrt



VM118 (Centerline Temperature of a Heat-generating Wire) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM118
/PREP7
/TITLE, VM118, CENTERLINE TEMP. OF A HEAT GENERATING WIRE
C*** HEAT, MASS AND MOMENTUM TRANS., ROHSENOW AND CHOI, 2ND. PR., PAGE 106,
C*** EX. 6.5, USING PLANE55 ELEMENTS (PLANE ELEMENTS)
ANTYPE,STATIC ! THERMAL ANALYSIS
ET,1,PLANE55
MP,KXX,1,13
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM
N,1,1E-10,-5 ! USE NON-ZERO RADIUS SINCE NODE IS NOT AT THETA=0
N,6,(.375/12),-5
FILL
NGEN,2,10,1,6,1,,10
E,1,2,12,12
E,2,3,13,12
EGEN,4,1,2
CP,1,TEMP,2,12 ! COUPLING TO ENSURE CIRCUMFERENTIAL SYMMETRY
CPSGEN,5,1,1
NSEL,S,LOC,X,(0.375/12)
SF,ALL,CONV,5,70
NSEL,ALL
BFE,ALL,HGEN,,111311.7 ! ELEMENT HEAT GENERATION
OUTPR,BASIC,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
*GET,TEMP,NODE,6,TEMP ! GET TEMPERATURE AT SURFACE NODE
PI=2*ASIN(1)
AREA=36*2*(0.375/12)*SIN(PI/36) ! COMPUTE AREA OF OUTER BOUNDARY
HRATE=AREA*5.0*(TEMP-70) ! TOTAL HEAT DISSIPATION RATE
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
*STATUS ! SHOW STATUS
*GET,TCL,NODE,1,TEMP
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'T CL, ','T S, ','q, BTU'
LABEL(1,2) = 'DEGREE F','DEGREE F','/hr '
*VFILL,VALUE(1,1),DATA,419.9,417.9,341.5
*VFILL,VALUE(1,2),DATA,TCL,TEMP,HRATE
*VFILL,VALUE(1,3),DATA,ABS(TCL/419.9) ,ABS( TEMP/417.9 ),ABS(HRATE/341.5)
SAVE,TABLE1
FINISH

/PREP7
C*** USING SOLID70 ELEMENTS (SOLID ELEMENTS)
EDELE,ALL ! DELETE PLANE55 ELEMENTS
ET,1,SOLID70 ! CHANGE ELEMENT TYPE
NGEN,2,20,1,16,1,,,-1 ! GENERATE 2ND PLANE OF NODES
NUMCMP,ELEM
E,1,2,12,12,21,22,32,32
E,2,3,13,12,22,23,33,32
EGEN,4,1,2
CPDELE,1,6,1 ! REMOVE PREVIOUS COUPLING SPECIFICATIONS
CP,1,TEMP,1,21 ! COUPLING TO ENSURE AXIAL SYMMETRY
CP,2,TEMP,2,12,22,32 ! COUPLING TO ENSURE CIRCUMFERENTIAL SYMMETRY
CPSGEN,5,1,2
CSYS,1
NSEL,S,LOC,X,(0.375/12)
SF,ALL,CONV,5,70
NSEL,ALL
BFE,ALL,HGEN,1,111311.7 ! ELEMENT HEAT GENERATION
FINISH
/SOLU
SOLVE
FINISH
/POST1
*GET,TEMP,NODE,6,TEMP ! GET TEMPERATURE AT SURFACE NODE
PI=2*ASIN(1)
AREA=36*2*(0.375/12)*SIN(PI/36) ! LENGTH ALONG 10 DEG ON OUTER FACE
HRATE=AREA*5.0*(TEMP-70) ! TOTAL HEAT DISSIPATION RATE
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
*STATUS ! SHOW PARAMETER STATUS
*GET,TCL,NODE,1,TEMP
LABEL(1,1) = 'T CL, ','T S, ','q, BTU'
LABEL(1,2) = 'DEGREE F','DEGREE F','/hr '
*VFILL,VALUE(1,1),DATA,419.9,417.9,341.5
*VFILL,VALUE(1,2),DATA,TCL,TEMP,HRATE
*VFILL,VALUE(1,3),DATA,ABS(TCL/419.9) ,ABS( TEMP/417.9 ), ABS(HRATE/341.5)
SAVE,TABLE2
RESUME,TABLE1
/COM
/OUT,vm118,vrt
/COM,------------------- VM118 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,STIF55 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/NOPR
RESUME,TABLE2
/GOPR
/COM,
/COM,STIF70 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm118,vrt



VM119 (Centerline Temperature of an Electrical Wire) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM119
/PREP7
/TITLE, VM119, CENTERLINE TEMP. OF AN ELECTRICAL WIRE
C*** HEAT, MASS AND MOMENTUM TRANS., ROHSENOW AND CHOI, 2ND. PR., PAGE 106,
C*** EX. 6.5, USING PLANE67 ELEMENTS (PLANE ELEMENTS)
ANTYPE,STATIC ! THERMAL (ELECTRICAL) ANALYSIS
ET,1,PLANE67,,,1 ! AXISYMMETRIC ELEMENTS
MP,KXX,1,13 ! CONDUCTIVITY
MP,RSVX,1,8.983782E-8 ! RESISTIVITY
N,1
N,6,(.375/12)
FILL
NGEN,2,10,1,6,1,,1
E,11,1,2,12
EGEN,5,1,1
CP,1,TEMP,1,11 ! COUPLING TO INSURE AXIAL SYMMETRY
CPSGEN,6,1,1
D,1,VOLT,,,6 ! NODAL VOLTAGE
D,11,VOLT,-0.1,,16
NSEL,S,LOC,X,(0.375/12)
SF,ALL,CONV,5,70
NSEL,ALL
FINISH
/SOLU
OUTPR,ALL,1 ! USE TIME STEP OPTIMIZATION
OUTPR,VENG,NONE
KBC,1 ! STEP BOUNDARY CONDITIONS
SOLVE
FINISH
/POST1
*GET,TEMP,NODE,6,TEMP ! GET TEMPERATURE AT SURFACE NODE
PI=2*ASIN(1)
AREA=2*PI*(0.375/12) ! COMPUTE AREA OF OUTER FACE (360 DEG)
HRATE=AREA*5.0*(TEMP-70) ! TOTAL HEAT DISSIPATION RATE
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
*STATUS ! SHOW PARAMETER STATUS
*GET,TCL,NODE,1,TEMP
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'T CL, ','T S, ','q, BTU'
LABEL(1,2) = 'DEGREE F','DEGREE F','/hr '
*VFILL,VALUE(1,1),DATA,419.9,417.9,341.5
*VFILL,VALUE(1,2),DATA,TCL,TEMP,HRATE
*VFILL,VALUE(1,3),DATA,ABS(TCL/419.9) ,ABS( TEMP/417.9 ),ABS (HRATE/341.5)
SAVE,TABLE1
FINISH

/CLEAR, NOSTART ! CLEAR DATABASE FOR SOLID69 MODEL
/PREP7
/TITLE, VM119, CENTERLINE TEMP. OF AN ELECTRICAL WIRE
C*** USING SOLID69 ELEMENTS (SOLID ELEMENTS)
ANTYPE,STATIC ! THERMAL (ELECTRICAL) ANALYSIS
ET,1,SOLID69
MP,KXX,1,13 ! CONDUCTIVITY
MP,RSVX,1,8.983782E-8 ! RESISTIVITY
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM
N,1,1E-10,-5 ! USE NON-ZERO RADIUS SINCE NODE IS NOT AT THETA=0
N,6,(.375/12),-5
FILL
N,11,1E-10,5
N,16,.03125,5
FILL
NGEN,2,20,1,16,1,,,-1
E,1,2,12,12,21,22,32,32
E,2,3,13,12,22,23,33,32
EGEN,4,1,2
CP,1,TEMP,1,21 ! COUPLING TO INSURE AXIAL SYMMETRY
CP,2,TEMP,2,12,22,32 ! COUPLING TO INSURE CIRCUMFERENTIAL SYMMETRY
CPSGEN,5,1,2
D,1,VOLT,,,16
D,21,VOLT,-.1,,36
NSEL,S,LOC,X,(0.375/12)
SF,ALL,CONV,5,70
NSEL,ALL
FINISH
/SOLU
OUTPR,ALL,1
OUTPR,VENG,NONE
SOLVE
FINISH
/POST1
*GET,TEMP,NODE,6,TEMP ! GET TEMPERATURE AT SURFACE NODE
PI=2*ASIN(1)
LENG=2*(0.375/12)*SIN(PI/36) ! LENGTH ALONG 10 DEG ON OUTER FACE
AREA=LENG*36 ! COMPUTE AREA OF OUTER FACE (360 DEG)
HRATE=AREA*5.0*(TEMP-70) ! TOTAL HEAT DISSIPATION RATE
PRNSOL,TEMP ! PRINT NODAL TEMPERATURES
*STATUS ! SHOW PARAMETER STATUS
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
*GET,TCL,NODE,1,TEMP
LABEL(1,1) = 'T CL, ','T S, ','q, BTU'
LABEL(1,2) = 'DEGREE F','DEGREE F','/hr '
*VFILL,VALUE(1,1),DATA,419.9,417.9,341.5
*VFILL,VALUE(1,2),DATA,TCL,TEMP,HRATE
*VFILL,VALUE(1,3),DATA,ABS(TCL/419.9) ,ABS( TEMP/417.9 ),ABS (HRATE/341.5)
SAVE,TABLE2
RESUME,TABLE1
/COM
/OUT,vm119,vrt
/COM,------------------- VM119 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,PLANE67 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/NOPR
RESUME,TABLE2
/GOPR
/COM,
/COM,SOLID69 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm119,vrt



VM120 (Microstrip Transmission Line Capacitance) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM120
/PREP7
SMRT,OFF
/TITLE, VM120, MICROSTRIP TRANSMISSION LINE ANALYSIS
! BEREN AND KAIRES (REF. 56)
ANTYPE,STATIC ! ELECTROSTATIC ANALYSIS
ET,1,PLANE121 ! USE 2-D 8-NODE ELECTROSTATIC ELEMENT
PER=8.85E-14 ! DEFINE FREE-SPACE PERMITTIVITY
EMUNIT,EPZRO,PER
V1=1.5 ! DEFINE STRIP POTENTIAL
V0=0.5 ! DEFINE GROUND POTENTIAL
MP,PERX,1,10 ! SUBSTRATE PERMITTIVITY
MP,PERX,2,1 ! FREE SPACE PERMITTIVITY
K,1
K,2,5
K,3,,1
K,4,.5,1 ! DEFINE GEOMETRY
K,5,5,1
K,6,,10
K,7,5,10
DESIZE,8,5,30
L,1,2
L,2,5
L,5,4
L,4,3
L,3,1
L,5,7
L,7,6
L,6,3
AL,1,2,3,4,5
AL,4,3,6,7,8
ASEL,S,AREA,,2
AATT,2
ASEL,ALL ! SET AREA ATTRIBUTES FOR AIR
AMESH,ALL
NSEL,S,LOC,Y,1 ! SELECT NODES ON MICROSTRIP
NSEL,R,LOC,X,0,.5
CM,CON1,NODE
!D,ALL,VOLT,V1 ! APPLY STRIP POTENTIAL
NSEL,S,LOC,Y,0
NSEL,A,LOC,Y,10
NSEL,A,LOC,X,5 ! SELECT EXTERIOR NODES
CM,CON2,NODE
!D,ALL,VOLT,V0 ! APPLY GROUND POTENTIAL
NSEL,ALL
FINISH
/SOLUTION
CMATRIX,2,'CON',2,0 ! CALCULATE CAPACITANCE USING CMATRIX MACRO
FINISH
/POST1
SET,LAST
ETABLE,EFX,EF,X ! STORE POTENTIAL FIELD GRADIENTS
ETABLE,EFY,EF,Y
/NUMBER,1
PLNSOL,VOLT ! DISPLAY EQUIPOTENTIAL LINES
/DIST,1,2.2 ! FOCUS IN ON MICROSTRIP REGION
/FOCUS,1,2,1.5
PLVECT,EFX,EFY ! DISPLAY VECTOR ELECTRIC FIELD (VECTOR)
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'CAPACITA'
LABEL(1,2) = 'NCE,pF/m'
*VFILL,VALUE(1,1),DATA,178.1
*VFILL,VALUE(1,2),DATA,CMATRIX(1,1,1)*1E14
*VFILL,VALUE(1,3),DATA,ABS((CMATRIX(1,1,1)*1E14)/178.1)
/COM
/OUT,vm120,vrt
/COM,------------------- VM120 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm120,vrt


VM121 (Laminar Flow Through a Pipe with Uniform Heat Flux) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM121
/config,nproc,4
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE,VM121, LAMINAR FLOW THROUGH A PIPE WITH UNIFORM HEAT FLUX

! REFERENCES: 1. "FLUID MECHANICS," WHITE F., MCGRAW-HILL, 1979.
! 2. "FUNDAMENTALS OF HEAT TRANSFER," INCROPERA, F., &
! DEWITT, D., JOHN WILEY & SONS, 1981.

/PREP7
SMRT,OFF
ET,1,FLUID141,,,2 ! 2D AXISYMMETRIC XR SYSTEM

MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USE QUADS

PI = ACOS(-1)
L = 0.1 ! PIPE LENGTH (M)
R = 0.0025 ! PIPE RADIUS (M)
PIN = 1.0 ! INLET PRESSURE (PA)
TIN = 300.0 ! INLET TEMPERATURE (K)
QW = 5000.0 ! WALL HEAT FLUX (W/M**2)
RHO = 13529.0 ! FLUID DENSITY (KG/M**3)
MU = 1.523E-03 ! FLUID VISCOSITY (KG/(M*SEC))
K = 8.54 ! FLUID THERMAL CONDUCTIVITY (W/(M*K))
CP = 139.3 ! FLUID SPECIFIC HEAT (J/(KG*K))

RECTNG,,L,,R
LSEL,S,,,2,4,2
LESIZE,ALL,,,12,-2 ! GRADED RADIAL LINE DIVISIONS
LSEL,INVE
LESIZE,ALL,,,100,1 ! GRADED AXIAL LINE DIVISIONS
ALLSEL
AMESH,1

LSEL,S,,,3 ! NO-SLIP WALL BOUNDARY
NSLL,S,1
D,ALL,VX
D,ALL,VY
SF,ALL,HFLUX,QW

LSEL,S,,,1 ! SYMMETRY BOUNDARY
NSLL,S,1
D,ALL,VY

LSEL,S,,,4 ! INLET BOUNDARY
NSLL,S,1
D,ALL,VY
D,ALL,PRES,PIN
D,ALL,TEMP,TIN

LSEL,S,,,2 ! OUTLET BOUNDARY
NSLL,S,1
D,ALL,VY
D,ALL,PRES
ALLSEL
FINISH

/SOLU
FLDATA,ITER,EXEC,300 ! # OF GLOBAL ITERATIONS
FLDATA,ITER,CHEC,10 ! CHECKPOINT FREQUENCY
FLDATA,TEMP,NOMI,TIN ! NOMINAL TEMPERATURE
FLDATA,NOMI,DENS,RHO ! FLUID DENSITY
FLDATA,NOMI,VISC,MU ! FLUID VISCOSITY
FLDATA,NOMI,COND,K ! FLUID THERMAL CONDUCTIVITY
FLDATA,NOMI,SPHT,CP ! FLUID SPECIFIC HEAT
FLDATA,OUTP,TAUW,T ! OUTPUT WALL SHEAR STRESS
SAVE
/out,scratch
SOLVE
/out

FLDATA,ITER,EXEC,50 ! # OF GLOBAL ITERATIONS
FLDATA,SOLU,TEMP,T ! ACTIVATE ENERGY EQUATION
FLDATA,SOLU,FLOW,F ! DEACTIVATE FLOW EQUATIONS
FLDATA,RELX,TEMP,1.0 ! NO RELAXATION FOR TEMP
/out,scratch
SOLVE
/out
FINISH

/POST1
SET,LAST

/RATIO,,,10 ! EXPAND Y-DISPLAY BY FACTOR OF 10
EPLOT

/EDGE,1,1
/CONTOUR,1,27
/TITLE,CONTOURS OF AXIAL VELOCITY
PLNSOL,VX ! PLOT CONTOURS OF AXIAL VELOCITY
VXC = VX(2) ! GET CENTERLINE AXIAL VELOCITY

PATH,PIPE,2,,48 ! DEFINE PATH WITH NAME = "PIPE"
PPATH,1,,L,0,0 ! DEFINE PATH POINTS BY LOCATION
PPATH,2,,L,R,0
PDEF,VX,VX ! MAP VX TO PATH
PDEF,TEMP,TEMP ! MAP TEMP TO PATH

PCALC,MULT,PROD1,VX,S ! MULTIPLY VX TIMES R COORDINATE
PCALC,INTG,VXM,PROD1,S,2/R**2 ! INTEGRATE AXIAL VELOCITY ALONG PATH
*GET,VXM,PATH,,LAST,VXM ! GET MEAN AXIAL VELOCITY

MDOT = RHO*VXM*PI*R**2 ! DETERMINE MASS FLOW RATE

/TITLE,CONTOURS OF WALL SHEAR STRESS
PLNSOL,TAUW ! PLOT CONTOURS OF WALL SHEAR STRESS
*GET,TAU,PLNSOL,,MAX ! GET WALL SHEAR STRESS

PCALC,MULT,PROD2,VX,TEMP ! MULTIPLY VX TIMES TEMP
PCALC,MULT,PROD3,PROD2,S ! MULTIPLY ABOVE TIMES R COORDINATE
PCALC,INTG,TM,PROD3,S,2/VXM/R**2 ! INTEGRATE TEMPERATURE ALONG PATH
*GET,TM_O,PATH,,LAST,TM ! GET OUTLET MEAN TEMPERATURE

/TITLE,CONTOURS OF TEMPERATURE
PLNSOL,TEMP ! PLOT CONTOURS OF TEMPERATURE
*GET,TW_O,PLNSOL,,MAX ! GET OUTLET WALL TEMPERATURE
TC_O = TEMP(2) ! GET OUTLET CENTERLINE TEMPERATURE

*STATUS ! LIST CURRENT PARAMETER VALUES
/RATIO
/TITLE,AXIAL VELOCITY PROFILE, VX(R)
/AXLAB,X,RADIAL COORDINATE, (M)
/AXLAB,Y,VELOCITY, (M/SEC)
/DEVICE,RASTOR,ON
PLPATH,VX ! PLOT VX ALONG PATH

/TITLE,OUTLET TEMPERATURE PROFILE, T(R)
/AXLAB,Y,TEMPERATURE, (K)
PLPATH,TEMP ! PLOT TEMP ALONG PATH

FINISH
/DELETE,vm121,pfl
/DELETE,vm121,rsw
/DELETE,scratch
*DIM,LABEL,CHAR,7,2
*DIM,VALUE,,7,3
LABEL(1,1) = 'VXC, ','VXM, ','MSFL, ','PRESS, ','Tmo, ','Two, ','Tco, '
LABEL(1,2) = 'cm/s ','cm/s ','kg/s ','Pa ','K ','K ','K '
*VFILL,VALUE(1,1),DATA,1.026,.513,.00136,.0125,341.4,342.2,341.0
*VFILL,VALUE(1,2),DATA,VXC*100,VXM*100,MDOT,TAU,TM_O,TW_O,TC_O
V1 = (VXC*100/1.026)
V2 = (VXM*100/.513)
V3 = (MDOT/.00136)
V4 = (TAU/.0125)
V5 = (TM_O/341.4)
V6 = (TW_O/342.2)
V7 = (TC_O/341.)
*VFILL,VALUE(1,3),DATA,V1,V2,V3,V4,V5,V6,V7
/COM
/OUT,vm121,vrt
/COM,------------------- VM121 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm121,vrt



VM122 (Pressure Drop in a Turbulent Flowing Fluid) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM122
/PREP7
/TITLE, VM122, PRESSURE DROP IN A FLOWING FLUID
C*** FLUID MECHANICS, BINDER, 3RD. ED., PAGE 118, ART. 8-6
ET,1,FLUID116,2 ! Use only pressure degrees of freedom
keyo,1,7,1
R,1,6 ! DIAMETER
MP,DENS,1,8.411E-5 ! BENZENE MASS DENSITY
MP,MU,1,.016 ! FRICTION FACTOR
N,1
N,2,2400
E,1,2
D,2,PRES,0 ! OUTLET REFERENCE PRESSURE
F,1,FLOW,121.3/386.4 ! INLET MASS FLOWRATE
OUTPR,BASIC,1
OUTPR,NLOAD,1
FINISH
/SOLU
SOLVE
*GET,DELTAP,NODE,1,PRES
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'DELTA P'
LABEL(1,2) = ',(PSI)'
*VFILL,VALUE(1,1),DATA,4.69
*VFILL,VALUE(1,2),DATA,DELTAP
*VFILL,VALUE(1,3),DATA,ABS(DELTAP/4.69)
/OUT,vm122,vrt
/COM
/COM,------------------- VM122 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm122,vrt


VM123 (Laminar Flow in a Piping System) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM123
/PREP7
/TITLE, VM123, LAMINAR FLOW IN A PIPING SYSTEM
C*** FLOW OF FLUIDS, CRANE TECH. PAPER NO. 410, PAGE 4-5, EX. 4-9
ET,1,FLUID116,2 ! THERMAL-FLOW PIPE
R,1,.4206 ! PIPE DIAMETER
rmore
rmore,,53 ! LOSS LENGTH
MP,DENS,1,1.7546 ! MASS DENSITY OF OIL
MP,MU,1,.05 ! INITIAL FRICTION FACTOR
MP,VISC,1,.010032 ! OIL VISCOSITY
N,1
N,2,300
E,1,2
D,2,PRES,0 ! OUTLET REFERENCE PRESSURE
F,1,FLOW,75.53/32.2 ! INLET MASS FLOW
OUTPR,BASIC,1
OUTPR,NLOAD,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,RE,NMISC,2
ESORT,RE
*GET,REY,SORT,,MAX
*GET,DELTAP,NODE,1,PRES
*STATUS
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'DELTA P ','Re'
LABEL(1,2) = 'lb/ft/ft '
*VFILL,VALUE(1,1),DATA,6160,708
*VFILL,VALUE(1,2),DATA,DELTAP,REY
*VFILL,VALUE(1,3),DATA,ABS(DELTAP/6160),ABS(REY/708)
/OUT,vm123,vrt
/COM
/COM,------------------- VM123 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm123,vrt



VM124 (Discharge of Water from a Reservoir) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM124
/PREP7
/TITLE, VM124, DISCHARGE OF WATER FROM A RESERVOIR
C*** ELEMENTARY THEORETICAL FLUID MECHANICS, BRENKERT, PAGE 224, PROB. 4
ET,1,FLUID116,2 ! FLOW PIPE WITH LOSS COEFFICIENTS
KEYO,1,7,3
KEYO,1,8,1
DENS = 1.94
MP,DENS,1,DENS
MP,MU,1,.025
MP,VISC,1,2.36E-5
TB,FCON ! NON-LINEAR FRICTION FACTOR TABLE
TBPT,,1e5,0.028
TBPT,,3e5,0.028
TBPT,,5e5,0.028
TBPT,,7e5,0.028
TBPT,,9e5,0.028
TBPT,,1e6,0.028
ACELY = 32.2
R,1,.25
RMORE
RMORE,10*ACELY*DENS ! INCLUDE PUMP HEAD
R,2,.25
RMORE
RMORE,,.5 ! INCLUDE SHARP-EDGE LOSS
R,3,.25
RMORE
RMORE,,.9 ! INCLUDE ELBOW LOSS
R,4,.25
RMORE
RMORE,,.9 ! INCLUDE ELBOW LOSS
N,1,-.01,10
N,2, ,10
N,3,20, 10
N,4,20
N,5,90
E,1,2
EGEN,4,1,-1,,,,,1 ! INCREMENT REAL CONSTANTS
ACEL,,ACELY ! GRAVITY LOAD
D,1,PRES,,,5,4 ! WATER SURFACE AND PIPE OUTLET AT ZERO PRESSURE
CNVTOL,FLOW,1,.0001 ! SET CONVERGENCE VALUE FOR FLUID FLOW WITH
! TOLERANCE LIMIT
OUTPR,,1 ! PRINT BASIC SOLUTION QUANTITIES OF SUBSTEP 1
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,R,NMISC,2
ESORT,R
*GET,RE,SORT,,MAX
ETABLE,FL,NMISC,3
ESORT,FL
*GET,FLOW,SORT,,MAX
*STATUS
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'FLOW RT. ','Re'
LABEL(1,2) = 'lb/sec '
*VFILL,VALUE(1,1),DATA,0.898,1.94E5
*VFILL,VALUE(1,2),DATA,FLOW,RE
*VFILL,VALUE(1,3),DATA,ABS(FLOW/0.898),ABS(RE/1.94E5)
/OUT,vm124,vrt
/COM
/COM,------------------- VM124 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F12.3,F12.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm124,vrt



VM125 (Radiation Heat Transfer Between Concentric Cylinders) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM125
/PREP7
/TITLE, VM125, RADIATION HEAT TRANSFER BETWEEN CONCENTRIC CYLINDERS
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND PRINTING, PAGE 260
ANTYPE,STATIC
ET,1,LINK32,,,,,,,1 ! HEAT CONDUCTING BAR; SUPPRESS SOLUTION OUTPUT
R,1,1 ! UNIT CROSS-SECTIONAL AREA (ARBITRARY)
MP,KXX,1,1 ! ARBITRARY CONDUCTIVITY DEFINED FOR
MP,KXX,2,1 ! INNER AND OUTER CYLINDERS
K,1
K,2,0,0,-1
K,3,-5
K,4,0,0,1
CIRCLE,1,1,2,3,,18 ! INNER CIRCLE; GENERATED CLOCKWISE
MAT,1
ESIZE,,1
LMESH,ALL
CIRCLE,1,2,4,3,,18 ! OUTER CIRCLE; GENERATED ANTI-CLOCKWISE
MAT,2
LMESH,19,36
FINISH
/AUX12
EMIS,1,.7
EMIS,2,.5
VTYPE,0 ! HIDDEN PROCEDURE FOR VIEW FACTORS
GEOM,1 ! GEOMETRY SPECIFICATION 2-D
WRITE,VM125 ! WRITE RADIATION MATRIX TO FILE VM125.SUB
FINISH
/PREP7
DOF,TEMP
ET,2,MATRIX50,1,,,,,1 ! SUPERELEMENT (RADIATION MATRIX)
TYPE,2
SE,VM125
TOFFST,460.0 ! TEMPERATURE OFFSET FOR ABSOLUTE SCALE
LSEL,S,LINE,,1,18
NSLL,S,1 ! SELECT INNER CYLINDER NODES
D,ALL,TEMP,540 ! T1 = 540 + 460 = 1000 DEG. R.
LSEL,S,LINE,,19,36
NSLL,S,1 ! SELECT OUTER CYLINDER NODES
D,ALL,TEMP,0.0 ! T2 = 460 DEG. R.
NSEL,ALL
LSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
ESEL,S,ELEM,,1,18 ! SELECT INNER ELEMENTS
NSLE ! AND ASSOCIATED NODES
PRRSOL ! PRINT HEAT FLOW FROM INNER TO OUTER CYLINDER
NSEL,INVE
PRRSOL ! PRINT HEAT FLOW FROM OUTER TO INNER CYLINDER
ESEL,ALL
FSUM,HEAT
*GET,Q,FSUM,0,ITEM,HEAT
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Q(BTU/hr'
LABEL(1,2) = '-in)'
*VFILL,VALUE(1,1),DATA,37
*VFILL,VALUE(1,2),DATA,Q
*VFILL,VALUE(1,3),DATA,ABS(Q/37)
/COM
/OUT,vm125,vrt
/COM,------------------- VM125 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/OUT
FINISH
/DELETE,VM125,sub
*LIST,vm125,vrt



VM126 (Heat Transferred to a Flowing Fluid) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM126
/PREP7
/TITLE, VM126, HEAT TRANSFERRED TO A FLOWING FLUID
C*** HEAT, MASS AND MOMENTUM TRANS, ROHSENOW AND CHOI, PAGE 168, EX 7.5
ET,1,FLUID116,1,2,,1 ! THERMAL-FLOW PIPE ELEMENT
ET,2,FLUID116,1
R,1,(1/12),.00545415 ! DIAMETER
RMORE,,,1.63,.08,.7,.35 ! FLOW DEPENDENT FILM COEFF.
MP,KXX,1,.017 ! BTU/hr-ft-F
MP,DENS,1,1.4377E-10 ! lbf-hr**2/ft**4
MP,C,1,1.002e8 ! BTU-ft/lbf-hr**2-F
MP,VISC,1,1.17418E-10 ! lbf-hr/ft**2
N,1
N,19,,,.46875 ! NODE JUST BEYOND
FILL,1,19,8,3,2 ! NODES ALONG PIPE AXIS
N,2
N,18
FILL,2,18,7,4,2 ! CONVECTION NODES (ARBITRARY LOCATION)
TYPE,1
E,1,3,2,4
EGEN,8,2,1
type,2
E,17,19 ! EXTENSION ELEMENT
D,1,TEMP,100 ! INLET AIR TEMPERATURE
D,2,TEMP,200,,18,2 ! WALL TEMPERATURE
SFE,ALL,,HFLUX,,1.1321e-8 ! FLOW RATE INPUT lbf-hr/ft
OUTPR,,LAST ! PRINT FINAL CONVERGED ITERATION
OUTPR,NLOAD,1
FINISH
/SOLU
EQSLV,JCG
SOLVE
FINISH
/POST1
ETABLE,HEAT,NMISC,5 ! STORE HEAT TRANSPORT RATE
PRETAB,HEAT ! PRINT HEAT TRANSPORT RATES PER ELEMENT
NSEL,S,NODE,,1,19,2 ! SELECT PIPE NODES
PRNSOL,TEMP ! PRINT TEMPERATURES ALONG PIPE LENGTH
*GET,TO,NODE,17,TEMP
ETABLE,HEAT,NMISC,5
ESORT,HEAT
*GET,QOUT,SORT,,MAX
*GET,QIN,SORT,,MIN
*STATUS
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'To ','Q(in)','Q(out)'
LABEL(1,2) = 'F ','BTU/hr','BTU/hr'
*VFILL,VALUE(1,1),DATA,123,113.28,139.33
*VFILL,VALUE(1,2),DATA,TO,QIN,QOUT
*VFILL,VALUE(1,3),DATA,ABS(TO/123),ABS(QIN/113.28),ABS(QOUT/139.33)
/COM
/OUT,vm126,vrt
/COM,------------------- VM126 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm126,vrt


VM127 (Buckling of a Bar with Hinged Ends (Line Elements)) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM127
/PREP7
MP,PRXY,,0.3
/TITLE, VM127, BUCKLING OF A BAR WITH HINGED SOLVES (LINE ELEMENTS)
C*** STR. OF MATL., TIMOSHENKO, PART 2, 3RD ED., PAGE 148
ET,1,BEAM3 ! BEAM ELEMENT
R,1,.25,52083E-7,.5 ! AREA,IZZ,HEIGHT
MP,EX,1,30E6
N,1
N,11,,100
FILL
E,1,2
EGEN,10,1,1
FINISH
/SOLU
ANTYPE,STATIC ! STATIC ANALYSIS
PSTRES,ON ! CALCULATE PRESTRESS EFFECTS
D,1,ALL ! FIX SYMMETRY END
F,11,FY,-1 ! UNIT LOAD AT FREE END
OUTPR,,1
SOLVE
FINISH
/SOLU
ANTYPE,BUCKLE ! BUCKLING ANALYSIS
BUCOPT,LANB,1 ! USE BLOCK LANCZOS EIGENVALUE EXTRACTION METHOD, EXTRACT 1 MODE
MXPAND,1 ! EXPAND 1 MODE SHAPE
SOLVE
*GET,FCR,MODE,1,FREQ
*STATUS
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Fcr '
LABEL(1,2) = 'lb '
*VFILL,VALUE(1,1),DATA,38.553
*VFILL,VALUE(1,2),DATA,FCR
*VFILL,VALUE(1,3),DATA,ABS(FCR/38.553)
/COM
/OUT,vm127,vrt
/COM,------------------- VM127 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm127,vrt



VM128 (Buckling of a Bar with Hinged Ends (Area Elements)) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM128
/PREP7
MP,PRXY,,0.3
/TITLE, VM128, BUCKLING OF A BAR WITH HINGED SOLVES (AREA ELEMENTS)
C*** STR. OF MATL., TIMOSHENKO, PART 2, 3RD ED., PAGE 148
ET,1,PLANE42,,,3 ! 2-D SOLID
R,1,.5 ! THICKNESS (SQUARE CROSS-SECTION)
MP,EX,1,30E6
MP,PRXY,1,0.3
N,1
N,11,,100
FILL
NGEN,2,11,1,11,,.5
E,12,13,2,1
EGEN,10,1,1
FINISH
/SOLU
PSTRES,ON ! CALCULATE PRESTRESS EFFECTS
D,1,ALL,,,12,11 ! FIX SYMMETRY SOLVE
F,11,FY,-.5,,22,11 ! UNIT LOAD AT FREE END DIVIDED BETWEEN NODES
OUTPR,,1
SOLVE
FINISH
/SOLU
ANTYPE,BUCKLE ! BUCKLING ANALYSIS
BUCOPT,SUBSP,1 ! USE SUBSPACE SOLUTION METHOD, EXTRACT 1 MODE
MXPAND,1 ! EXPAND 1 MODE SHAPE
SOLVE
*GET,FCR,MODE,1,FREQ
*STATUS
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Fcr '
LABEL(1,2) = 'lb '
*VFILL,VALUE(1,1),DATA,38.553
*VFILL,VALUE(1,2),DATA,FCR
*VFILL,VALUE(1,3),DATA,ABS(FCR/38.553)
/COM
/OUT,vm128,vrt
/COM,------------------- VM128 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM, Subspace Solution
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINI
/SOLVE
BUCOPT,LANB ,1 ! USE BLOCK LAN. SOLUTION METHOD, EXTRACT 1 MODE
SOLVE
*GET,FCR,MODE,1,FREQ
*STATUS
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Fcr '
LABEL(1,2) = 'lb '
*VFILL,VALUE(1,1),DATA,38.553
*VFILL,VALUE(1,2),DATA,FCR
*VFILL,VALUE(1,3),DATA,ABS(FCR/38.553)
/COM
/OUT,vm128,vrt,,APPEND
/COM,
/COM, Block-Lanczos Solution
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm128,vrt


VM129 (Numerical Differentiation and Integration) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM129
/TITLE, VM129, NUMERICAL DIFFERENTIATION AND INTEGRATION USING APDL COMMAND
C*** REFERENCE - ANY BASIC CALCULUS BOOK
*DIM,A,,145 ! DEFINE ARRAYS WITH DIMENSION
*DIM,B,,145
*DIM,C,,145
*DIM,D,,145
*DIM,E,,145
*DIM,F,,145
*DIM,G,,145
*DIM,H,,145
*VFILL,A(1),RAMP,0,1 ! ARRAY A(N) : TIME IN SECOND
*VFACT,0.043633 ! MULTIPLYING FACTOR : FREQUENCY = (PI/72)
*VFUN,B(1),COPY,A(1) ! RESULT ARRAY B(N)=FREQUENCY*A(N)
*VFUN,C(1),SIN,B(1) ! ARRAY C(N) : SIN(B(N))
*VFACT,1.2732 ! MULTIPLYING FACTOR : AMPLITUDE A
*VFUN,D(1),COPY,C(1) ! ARRAY D(N) : A*C(N)
*VOPER,E(1),D(1),DER1,A(1) ! ARRAY E(N) : FIRST DERIVATIVE OF D WRT TIME
*VOPER,F(1),D(1),INT1,A(1) ! ARRAY F(N) : SINGLE INTEGRAL (I1) OF D WRT TIME
*VOPER,G(1),D(1),DER2,A(1) ! ARRAY G(N) : SECOND DERIVATIVE OF D WRT TIME
*VOPER,H(1),D(1),INT2,A(1) ! ARRAY H(N) : DOUBLE INTEGRAL (I2) OF D WRT TIME
*VSCFUN,DERIV1,MAX,E(1) ! MAXIMUM VALUE OF FIRST DERIVATIVE
*VSCFUN,DERIV2,MAX,G(1) ! MAXIMUM VALUE OF SECOND DERIVATIVE
*STATUS ! LIST SCALAR PARAMETERS
*STATUS,F,37,37 ! LIST VALUE OF F(N) AT UPPER LIMIT (INTEGRAL I1)
*STATUS,H,37,37 ! LIST VALUE OF H(N) AT UPPER LIMIT (INTEGRAL I2)
*SET,INTER1,F(37,1,1)
*SET,INTER2,H(37,1,1)
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = '1ST DER ','2ND DER','1ST INT','2ND INT'
LABEL(1,2) = 'MAX','MAX','T(0-36)','T(0-36)'
*VFILL,VALUE(1,1),DATA,5.555E-2,2.424E-3,29.18,381.7
*VFILL,VALUE(1,2),DATA,DERIV1,DERIV2,INTER1,INTER2
DRV1=ABS(DERIV1/5.555E-2)
DRV2=ABS(DERIV2/2.424E-3)
INT1=ABS(INTER1/29.18)
INT2=ABS(INTER2/381.7)
*VFILL,VALUE(1,3),DATA,DRV1,DRV2,INT1,INT2
/COM
/OUT,vm129,vrt
/COM,------------------- VM129 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.6,' ',F10.6,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm129,vrt






VM130 (Fourier Series Generation for a Saw Tooth Wave) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM130
/TITLE, VM130, FOURIER SERIES GENERATION FOR A SAW TOOTH WAVE
/COM VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 102, PROB. 2
*DIM,COEFF,,24
*DIM,MODE,TABLE,24
*DIM,ISYM,TABLE,24
*DIM,THETA,TABLE,121
*DIM,CURVEI,TABLE,121 ! CURVE INPUT TO PROGRAM
*DIM,CURVEO,TABLE,121 ! CURVE WHICH WILL BE DEVELOPED
! FROM GENERATED COEFFICIENTS
*VFILL,MODE(2),RAMP,1,2 ! ODD MODE NUMBERS
*VFILL,ISYM(2),RAMP,-1,0 ! ISYM = -1 (SINE)
*VFILL,THETA(1),RAMP,0,3 ! THETA VALUES INCREMENT 3 DEGREES
*VFILL,CURVEI(1),RAMP,0,1/30 ! WAVE DATA: 0 TO 90 DEG
*VFILL,CURVEI(31),RAMP,1,-1/30 ! 90 TO 270 DEG
*VFILL,CURVEI(91),RAMP,-1,1/30 ! 270 TO 360 DEG
! CALCULATE FOURIER COEFFICIENT
*MFOURI,FIT, COEFF(1),MODE(1),ISYM(1),THETA(1),CURVEI(1)
! EVAL‎UATE SERIES BASED ON COEFFICIENTS
*MFOURI,EVAL‎,COEFF(1),MODE(1),ISYM(1),THETA(1),CURVEO(1)

*VWRITE ! WRITE OUTPUT IN TABULAR FORMAT
(///T14,'MODE',T24,'COEFF',T34,'ISYM',/)
*VWRITE, MODE(1),COEFF(1),ISYM(1)
(T10,F10.4,T20,F10.4,T30,F10.4,T40,F10.4)

*VWRITE
(///T14,'THETA',T23,'CURVE IN',T34,'CURVE OUT',/)
*VWRITE, THETA(1),CURVEI(1),CURVEO(1)
(T10,F10.4,T20,F10.4,T30,F10.4)
/SHOW,JPEG
/GFILE,500
JPEG,QUAL,100
/TRIAD,OFF
/PLOPTS,LOGO,0
/PLOPTS,INFO,2
/PLOPTS,WP,0
/RGB,INDEX,100,100,100,0
/RGB,INDEX,80,80,80,13
/RGB,INDEX,60,60,60,14
/RGB,INDEX,0,0,0,15
/YRANGE,-1.25,1.25,ALL
*VPLOT,THETA(1),CURVEI(1) ! PLOT INPUT CURVE VERSUS THETA
/USER
/NOERASE
/COM OVERLAY THE OUTPUT CURVE ON THE INPUT CURVE
*VPLOT,THETA(1),CURVEO(1) ! PLOT OUTPUT CURVE VERSUS THETA
*SET,M1,COEFF(2,1,1)
*SET,M3,COEFF(3,1,1)
*SET,M5,COEFF(4,1,1)
*SET,M7,COEFF(5,1,1)
*STATUS
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'M1 ','M2 ','M3 ','M4 '
LABEL(1,2) = 'COEF','COEF','COEF','COEF'
*VFILL,VALUE(1,1),DATA,.811,-.901E-1,.324E-1,-.165E-1
*VFILL,VALUE(1,2),DATA,M1,M3,M5,M7
*VFILL,VALUE(1,3),DATA,ABS(M1/.811),ABS(M3/(-.901E-1)),ABS(M5/(.324E-1)),ABS(M7/(-.165E-1))
/COM
/OUT,vm130,vrt
/COM,------------------- VM130 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm130,vrt

[RUN TO YOU]

vm1에서 막혀서 질문드립니다
*get,reac_2,fsum,,item,fy
이부분 get parameter에서 어디서 하는건가요? load인가여 ? ?