VM 131 - 230 로그파일

[지원이 아빠^^]

VM131 (Acceleration of a Rotating Crane Boom) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM131
/PREP7
/TITLE, VM131, ACCELERATION OF A ROTATING CRANE BOOM
C*** VECTOR MECHANICS FOR ENGINEERS, BEER & JOHNSTON, P 616, PROB. 15.13
ANTYPE,STATIC
ET,1,MASS21,,,2 ! GENERALIZED MASS WITHOUT ROTARY INERTIA
R,1,1 ! UNIT MASS
N,1,34.64,20
E,1
OMEGA,,,.5 ! ANGULAR VELOCITY OF RISING BOOM WRT GLOBAL
CGOMGA,,.3 ! ANGULAR VELOCITY OF CAB WRT REFERENCE SYSTEM
D,1,ALL
OUTRES,,1
OUTPR,RSOL,1
OUTPR,NLOAD,1
FINISH
/SOLU
SOLVE
NSEL,S,NODE,,1,1
FINI
/POST1
FSUM
*GET,AX,FSUM,,ITEM,FX
*GET,AY,FSUM,,ITEM,FY
*GET,AZ,FSUM,,ITEM,FZ
*STATUS
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'AX ','AY ','AZ '
LABEL(1,2) = 'ft/s/s','ft/s/s','ft/s/s'
*VFILL,VALUE(1,1),DATA,-11.78,-5,6
*VFILL,VALUE(1,2),DATA,(-1)*(AX),(-1)*(AY),(-1)*(AZ)
*VFILL,VALUE(1,3),DATA,ABS((-1)*AX/11.78),ABS((-1)*AY/5),ABS((-1)*AZ/6)
/COM
/OUT,vm131,vrt
/COM,------------------- VM131 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.2)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm131,vrt



VM132 (Stress Relaxation of a Tightened Bolt Due to Creep) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM132
/PREP7
/TITLE, VM132, STRESS RELAXATION OF A BOLT DUE TO CREEP
C*** STR. OF MATL., TIMOSHENKO, PART 2, 3RD ED., PAGE 531
ANTYPE,STATIC
ET,1,LINK1 ! SPAR ELEMENT
R,1,1,(1/30000) ! INITIAL STRAIN
MP,EX,1,30E6
TB,CREEP,1
TBDATA,1,4.8E-30,7 ! CREEP PROPERTIES
N,1
N,2,10
E,1,2
BFUNIF,TEMP,900 ! UNIFORM TEMPERATURE
TIME,1000
KBC,1
D,ALL,ALL ! FIX ALL DOFS
FINISH
/SOLU
SOLCONTROL,0
NSUBST,100
OUTPR,BASIC,10 ! PRINT BASIC SOLUTION FOR EVERY 10TH SUBSTEP
OUTRES,ESOL,1 ! STORE ELEMENT SOLUTION FOR EVERY SUBSTEP
SOLVE
FINISH
/POST26
ESOL,2,1,,LS,1,SIG ! STORE AXIAL STRESS
PRVAR,2 ! PRINT AXIAL STRESS VS TIME
*GET,T190,VARI,2,RTIME,190
*GET,T420,VARI,2,RTIME,420
*GET,T690,VARI,2,RTIME,690
*GET,T880,VARI,2,RTIME,880
*GET,T950,VARI,2,RTIME,950
*STATUS
*DIM,LABEL,CHAR,5,2
*DIM,VALUE,,5,3
LABEL(1,1) = 'SIG @ ','SIG @ ','SIG @ ','SIG @ ','SIG @ '
LABEL(1,2) = '190 hr','420 hr','690 hr','880 hr','950 hr'
*VFILL,VALUE(1,1),DATA,975,950,925,910,905
*VFILL,VALUE(1,2),DATA,T190,T420,T690,T880,T950
V1 = ABS(T190/975)
V2 = ABS(T420/950)
V3 = ABS(T690/925)
V4 = ABS(T880/910)
V5 = ABS(T950/905)
*VFILL,VALUE(1,3),DATA,V1,V2,V3,V4,V5
/COM
/OUT,vm132,vrt
/COM,------------------- VM132 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.2)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm132,vrt



VM133 (Motion of a Rod Due to Irradiation Induced Creep) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM133
/PREP7
MP,PRXY,,0.3
/TITLE, VM133, MOTION OF A ROD DUE TO IRRADIATION INDUCED CREEP
C*** REFERENCE - ANY BASIC CALCULUS BOOK
ANTYPE,STATIC
ET,1,BEAM23 ! PLASTIC BEAM
R,1,.25,.0052083,.5 ! AREA, IZZ, HEIGHT
MP,EX,1,300
TB,CREEP,1
TBDATA,55,0.5E-12,1E10 ! CREEP EQUATION CONSTANTS K1 AND K2
TBDATA,66,5 ! SELECT IRRADIATION INDUCED CREEP EQUATION
N,1
N,2,1
E,1,2
D,1,ALL ! FIX ONE END
F,2,FX,.25 ! FORCE INDUCING CONSTANT STRESS
FINISH
/SOLU
!SOLCONTROL,0
BFE,1,TEMP,1,1000,1000,1000,1000 ! APPLY CONSTANT TEMPERATURE
BFE,1,FLUE,1,0,0,0,0 ! APPLY ZERO FLUENCE
TIME,1E-8 ! NEAR ZERO TIME FOR FIRST LOAD STEP
OUTPR,BASIC,1 ! PRINT BASIC ELEMENT SOLUTION
OUTRES,EPCR,1 ! STORE CREEP STRAIN RESULTS FOR EVERY SUBSTEP
CNVTOL,F,,,,1E-6 ! NEAR ZERO VALUE FOR MINREF FIELD
CNVTOL,M,-1 ! CONVERGENCE CRITERION BASED UPON MOMENTS IS
! REMOVED AS IT IS NOT NEEDED FOR THIS TEST
SOLVE ! LOAD STEP 1
NSUBST,50,500,50
TIME,5
OUTPR,BASIC,5
BFE,1,FLUE,1,5E10,5E10,5E10,5E10 ! FINAL FLUENCES (RAMPED)
SOLVE ! LOAD STEP 2
FINISH
/POST26
ESOL,2,1,,LEPCR,1,EPCR ! STORE CREEP STRAIN
PRVAR,2 ! PRINT STRAIN VARIATION WITH TIME
*GET,T1,VARI,2,RTIME,0
*GET,T2,VARI,2,RTIME,.5
*GET,T3,VARI,2,RTIME,1
*GET,T4,VARI,2,RTIME,5
*STATUS
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'CRP STR @','CRP STR @','CRP STR @','CRP STR @'
LABEL(1,2) = '0 hr','.5 hr','1 hr','5 hr'
*VFILL,VALUE(1,1),DATA,0,.00197,.00316,.00497
*VFILL,VALUE(1,2),DATA,T1,T2,T3,T4
*VFILL,VALUE(1,3),DATA,000,ABS(T2/.00197),ABS(T3/.00316),ABS(T4/.00497)
/COM
/OUT,vm133,vrt
/COM,------------------- VM133 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm133,vrt







VM134 (Plastic Bending of a Clamped I-Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM134
/PREP7
MP,PRXY,,0.3
/TITLE, VM134, PLASTIC BENDING OF A CLAMPED I-BEAM
C*** THE ANALYSIS OF STRUCTURES, N.J. HOFF, 1964, P. 388
ANTYPE,STATIC
ET,1,BEAM24,,,1 ! PLASTIC BEAM WITH CENTROID AT NODES
R,1,0,0,0,10,0,.9415 ! BEAM SECTION PROPERTIES
RMORE,5,0,0,5,10.6,.0001
RMORE,0,10.6,0,10,10.6,.9415
MP,EX,1,29E6
TB,BKIN,1,1 ! BILINEAR KINEMATIC HARDENING BEHAVIOR
TBTEMP,0.0
TBDATA,1,38000,5.8E6 ! YIELD STRESSES AND TANGENT MODULUS
N,1
N,10,72
FILL
N,100,,,1
E,1,2,100
*REPEAT,9,1,1
D,1,ALL ! FIX ONE END
D,10,ROTY,,,,,UY,ROTX,ROTZ ! SYMMETRIC MID-SPAN B.C.
FINISH
/SOLU
SOLCONTROL,0
SFBEAM,1,1,PRES,2190 ! LOAD STEP 1: W1
*REPEAT,9,1
OUTPR,BASIC,LAST ! PRINT BASIC SOLUTION FOR LAST SUBSTEP
SOLVE
FINI
/POST1
*GET,DEF1,NODE,10,UZ
/POST26
RFOR,2,10,M,Y
RFOR,3,1,M,Y
PLVAR,2,3
*GET,MID1,VARI,2,EXTREM,VMAX
*GET,END1,VARI,3,EXTREM,VMAX
FINI
/SOLU
SFBEAM,1,1,PRES,3771 ! LOAD STEP 2: W2
*REPEAT,9,1
SOLVE
FINI
/POST1
*GET,DEF2,NODE,10,UZ
/POST26
RFOR,2,10,M,Y
RFOR,3,1,M,Y
PLVAR,2,3
*GET,MID2,VARI,2,EXTREM,VMAX
*GET,END2,VARI,3,EXTREM,VMAX
FINI
/SOLU
SFBEAM,1,1,PRES,9039 ! LOAD STEP 3: W3; PLASTIC YIELDING
*REPEAT,9,1
SOLVE
FINI
/POST1
*GET,DEF3,NODE,10,UZ
/POST26
RFOR,2,10,M,Y
RFOR,3,1,M,Y
PLVAR,2,3
*GET,MID3,VARI,2,EXTREM,VMAX
*GET,END3,VARI,3,EXTREM,VMAX
ESEL,S,ELEM,,1,1
/POST1
ETABLE,ESA1,LEPEL,1
ESORT,ESA1,,,1
*GET,EPELA,SORT,,MAX
ETABLE,ESB1,LEPPL,1
ESORT,ESB1,,,1
*GET,EPPLA,SORT,,MAX
/POST26
ESEL,S,ELEM,,9,9
/POST1
ETABLE,ESA2,LEPEL,1
ESORT,ESA2,,,1
*GET,EPELB,SORT,,MAX
ETABLE,ESB2,LEPPL,1
ESORT,ESB2,,,1
*GET,EPPLB,SORT,,MAX
*SET,ENDST,ABS(EPPLA+EPELA)
*SET,MIDST,ABS(EPELB+EPPLB)
*STATUS
FINI
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'MID DEFL ','MOM END ','MID MOM '
LABEL(1,2) = ' in ','in-lb','in-lb'
*VFILL,VALUE(1,1),DATA,-.160,-3.784E6,-1.892E6
*VFILL,VALUE(1,2),DATA,DEF1,END1,MID1
*VFILL,VALUE(1,3),DATA,ABS(DEF1/(-.160)),ABS(END1/(-3.784E6)),ABS(MID1/(-1.892E6))
/COM
/OUT,vm134,vrt
/COM,------------------- VM134 RESULTS COMPARISON ------------------
/COM,
/COM, W1=2190 lb/in | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F13.3,' ',F13.3,' ',1F6.2)
/COM,---------------------------------------------------------------
/OUT
/NOPR
LABEL(1,1) = 'MID DEFL ','MOM END ','MID MOM '
LABEL(1,2) = ' in ','in/lb','in/lb'
*VFILL,VALUE(1,1),DATA,-.357,-5.98E6,-3.78E6
*VFILL,VALUE(1,2),DATA,DEF2,END2,MID2
*VFILL,VALUE(1,3),DATA,ABS(DEF2/(-.357)),ABS(END2/(-5.98E6)),ABS(MID2/(-3.78E6))
/GOPR
/COM
/OUT,vm134,vrt,,APPEND
/COM,------------------- VM134 RESULTS COMPARISON ------------------
/COM,
/COM, W2=3771 lb/in | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F13.3,' ',F13.3,' ',1F6.2)
/COM,---------------------------------------------------------------
/OUT
/NOPR
*DIM,LABEL1,CHAR,5,2
*DIM,VALUE1,,5,3
LABEL1(1,1) = 'MID DEFL ','MOM END ','MID MOM ','TTL END ','TTL MID '
LABEL1(1,2) = ' in ','in-lb','in-lb','STRAIN','STRAIN'
*VFILL,VALUE1(1,1),DATA,-2.09,-1.51E7,-8.36E6,.02,.0089
*VFILL,VALUE1(1,2),DATA,DEF3,END3,MID3,ENDST,MIDST
V1 = ABS(DEF3/(-2.09))
V2 = ABS(END3/(-1.51E7))
V3 = ABS(MID3/(-8.36E6))
V4 = ABS(ENDST/.02)
V5 = ABS(MIDST/.0089)
*VFILL,VALUE1(1,3),DATA,V1,V2,V3,V4,V5
/GOPR
/COM
/OUT,vm134,vrt,,APPEND
/COM,------------------- VM134 RESULTS COMPARISON ------------------
/COM,
/COM, W3=9039 lb/in | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL1(1,1),LABEL1(1,2),VALUE1(1,1),VALUE1(1,2),VALUE1(1,3)
(1X,A8,A8,' ',F15.4,' ',F15.4,' ',1F6.2)
/COM,---------------------------------------------------------------
/OUT
/OUT,vm134,vrt,,APPEND
/COM,---------------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM134 NOT CONTAINED IN
/COM,THIS TABLE
/COM,---------------------------------------------------------------
/OUT
FINISH
*LIST,vm134,vrt



VM135 (Bending of a Beam on an Elastic Foundation) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM135
/PREP7
MP,PRXY,,0.3
/TITLE, VM135, BENDING OF A BEAM ON AN ELASTIC FOUNDATION
C*** STR. OF MATL., TIMOSHENKO, PART 2, 3RD ED., PAGE 12
ANTYPE,STATIC
ET,1,BEAM54 ! UNSYMMETRICAL BEAM ELEMENT
R,1,23,44,2.5,2.5 ! AREA, IZ, H/2, H/2
RMODIF,1,16,1515.15 ! ELASTIC FOUNDATION STIFFNESS
MP,EX,1,30E6
N,1
N,14,286
FILL
E,1,2
EGEN,13,1,1
D,1,UX ! FIX MOTION OF END ALONG X-DIRECTION
F,1,FY,-1000 ! APPLY DOWNWARD FORCE
F,1,MZ,10000 ! APPLY END MOMENT
OUTPR,,1
FINISH
/SOLU
SOLVE
*GET,UY,NODE,1,U,Y
*STATUS
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'END DISP '
LABEL(1,2) = ' in '
*VFILL,VALUE(1,1),DATA,-.03762
*VFILL,VALUE(1,2),DATA,UY
*VFILL,VALUE(1,3),DATA,ABS(UY/.03762)
/COM
/OUT,vm135,vrt
/COM,------------------- VM135 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT

FINISH
*LIST,vm135,vrt



VM136 (Large Deflection of a Buckled Bar (the Elastica)) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM136
/PREP7
MP,PRXY,,0.3
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM136, LARGE DEFLECTIONS OF A BUCKLED BAR (THE ELASTICA)
C*** THEORY OF ELASTIC STABILITY, TIMOSHENKO AND GERE, 2ND ED., PAGE 78
ANTYPE,STATIC
NLGEOM,ON ! ACTIVATE LARGE DEFLECTION PROCESS
ET,1,BEAM3,,,,,,,1 ! TURN OFF BEAM3 PRINTOUT
R,1,.25,52083E-7,.5 ! AREA, IZZ, HEIGHT OF BEAM
MP,EX,1,3E7
N,1
N,11,,100
FILL
E,1,2
EGEN,10,1,1
FINISH
/SOLU
SOLCONTROL,0
NEQIT,150 ! PERFORM MAXIMUM 150 EQUILIBRIUM ITERATIONS
OUTPR,BASIC,LAST ! PRINT BASIC SOLUTION AT THE END OF EACH LOAD STEP
D,1,ALL
FCR=-38.553 ! SET CRITICAL LOAD PARAMETER
PI=3.14159265359
F,11,FY,FCR*1.015 ! VERTICAL LOAD
F,11,FX,.5 ! SMALL HORIZONTAL LOAD
SOLVE ! LOAD STEP 1
FDEL,11,FX ! REMOVE PERTURBING HORIZONTAL LOAD
F,11,FY,FCR*1.063
SOLVE ! LOAD STEP 2
F,11,FY,FCR*1.152
SOLVE ! LOAD STEP 3
F,11,FY,FCR*1.293
SOLVE ! LOAD STEP 4
F,11,FY,FCR*1.518
SOLVE ! LOAD STEP 5
F,11,FY,FCR*1.884
SOLVE ! LOAD STEP 6
FINISH
/POST1
/USER
/FOCUS,,50,50 ! USER FOCUS TO CENTER ALL DISPLAYS
/DIST,,55 ! SELECT DISTANCE FOR MAGNIFICATION
/DSCALE,,1 ! SCALE TRUE TO GEOMETRY
SET,1,0
PLDISP,1
/NOERASE ! OVERLAY DISPLAYS ON SAME FRAME
SET,2,0
PLDISP
SET,3,0
PLDISP
*GET,UX3,NODE,11,U,X
*GET,UY3,NODE,11,U,Y
*GET,ROT3A,NODE,11,ROT,Z
SET,4,0
PLDISP
*GET,UX4,NODE,11,U,X
*GET,UY4,NODE,11,U,Y
*GET,ROT4A,NODE,11,ROT,Z
SET,5,0
PLDISP
*GET,UX5,NODE,11,U,X
*GET,UY5,NODE,11,U,Y
*GET,ROT5A,NODE,11,ROT,Z
SET,6,0
PLDISP
*GET,UX6,NODE,11,U,X
*GET,UY6,NODE,11,U,Y
*GET,ROT6A,NODE,11,ROT,Z
*STATUS
*SET,ROT6,(180*ROT6A/PI)
*SET,ROT5,(180*ROT5A/PI)
*SET,ROT4,(180*ROT4A/PI)
*SET,ROT3,(180*ROT3A/PI)
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'ROT Z ','UX','UY'
LABEL(1,2) = ' DEG',' in',' in'
*VFILL,VALUE(1,1),DATA,-60,59.3,-25.9
*VFILL,VALUE(1,2),DATA,ROT3,UX3,UY3
*VFILL,VALUE(1,3),DATA,ABS(ROT3/60),ABS(UX3/59.3),ABS(UY3/25.9)
/COM
/OUT,vm136,vrt
/COM,------------------- VM136 RESULTS COMPARISON -------------
/COM,
/COM, F=44.413 lb | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
/NOPR
*VFILL,VALUE(1,1),DATA,-80,71.9,-44
*VFILL,VALUE(1,2),DATA,ROT4,UX4,UY4
*VFILL,VALUE(1,3),DATA,ABS(ROT4/80),ABS(UX4/71.9),ABS(UY4/44)
/GOPR
/COM
/OUT,vm136,vrt,,APPEND
/COM,------------------- VM136 RESULTS COMPARISON -------------
/COM,
/COM, F=49.849 lb | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
/NOPR
*VFILL,VALUE(1,1),DATA,-100,79.2,-65.1
*VFILL,VALUE(1,2),DATA,ROT5,UX5,UY5
*VFILL,VALUE(1,3),DATA,ABS(ROT5/100),ABS(UX5/79.2),ABS(UY5/65.1)
/GOPR
/COM
/OUT,vm136,vrt,,APPEND
/COM,------------------- VM136 RESULTS COMPARISON -------------
/COM,
/COM, F=58.523 lb | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
/NOPR
*VFILL,VALUE(1,1),DATA,-120,80.3,-87.7
*VFILL,VALUE(1,2),DATA,ROT6,UX6,UY6
*VFILL,VALUE(1,3),DATA,ABS(ROT6/120),ABS(UX6/80.3),ABS(UY6/87.7)
/GOPR
/COM
/OUT,vm136,vrt,,APPEND
/COM,------------------- VM136 RESULTS COMPARISON -------------
/COM,
/COM, F=72.634 lb | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm136,vrt


VM137 (Large Deflection of a Circular Membrane) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM137
/PREP7
/TITLE, VM137, LARGE DEFLECTION OF A CIRCULAR MEMBRANE
C*** THEORY OF PLATES AND SHELLS, TIMOSHENKO, P. 404, EQ. 236
ET,1,SHELL51,,,,1
R,1,.0001 ! THICKNESS
MP,EX,1,30E6
MP,NUXY,1,.25
MP,ALPX,1,1E-5
N,1
N,11,10
FILL
E,1,2
EGEN,10,1,1
FINISH
/SOLU
ANTYPE,STATIC
NLGEOM,ON ! LARGE DEFLECTION OPTION
SSTIF,ON ! STRESS STIFFENING OPTION
CNVTOL,F,,,,1 ! USE FORCE CONVERGENCE ONLY, MINIMUM REFERENCE VALUE OF 1
OUTPR,,LAST
TUNIF,-50 ! THERMAL PRESTRESS TO START
NSEL,S,LOC,X,0
DSYM,SYMM,X ! SYMMETRY B.C. AT X=0
NSEL,ALL
D,11,ALL
SOLVE
KBC,1 ! STEP B.C.
SF,ALL,PRES,.1 ! APPLY PRESSURE LOAD
SOLVE
TUNIF,0 ! REMOVE THERMAL PRESSURES
SOLVE
/POST1
SET,3
*GET,UY,NODE,1,U,Y
ESEL,S,ELEM,,1,1
ETABLE,CENT,LS,5
ESORT,CENT
*GET,PRSCNT,SORT,,MAX
ESEL,S,ELEM,,10,10
ETABLE,CEN,LS,5
ESORT,CEN
*GET,PRSOUT,SORT,,MAX
*STATUS
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'Y DISP ','PRES CENT ','PRES RIM'
LABEL(1,2) = ' in',' psi',' psi'
*VFILL,VALUE(1,1),DATA,-.459,61010,47310
*VFILL,VALUE(1,2),DATA,UY,PRSCNT,PRSOUT
*VFILL,VALUE(1,3),DATA,ABS(UY/.459),ABS(PRSCNT/61010),ABS(PRSOUT/47310)
/COM
/OUT,vm137,vrt
/COM,------------------- VM137 RESULTS COMPARISON --------------
/COM,
/COM, LOAD STEP 3 | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm137,vrt





VM138 (Large Deflection Bending of a Circular Plate) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM138
/PREP7
/TITLE, VM138, LARGE DEFLECTION BENDING OF A CIRCULAR PLATE
C*** THEORY OF PLATES AND SHELLS, TIMOSHENKO, P. 401, EQ. 232
ANTYPE,STATIC
NLGEOM,ON ! LARGE DEFLECTION OPTION
SSTIF,ON ! STRESS STIFFENING OPTION
ET,1,SHELL51,,,,,,,1 ! SUPPRESS ELEMENT SOLUTION PRINTOUT
R,1,.0025 ! THICKNESS OF PLATE
MP,EX,1,2E11
MP,NUXY,1,0.3
N,1
N,11,.25
FILL
E,1,2
EGEN,10,1,1
OUTPR,,LAST
NSEL,S,LOC,X,0
DSYM,SYMM,X ! SYMMETRY B.C. AT X=0
NSEL,ALL
D,11,ALL ! FIX RIM
SFE,1,1,PRES,,6585.175 ! ELEMENT PRESSURE LOAD
*REPEAT,10,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
*GET,UY,NODE,1,U,Y
*STATUS
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Y DISP '
LABEL(1,2) = ' m'
*VFILL,VALUE(1,1),DATA,-.00125
*VFILL,VALUE(1,2),DATA,UY
*VFILL,VALUE(1,3),DATA,ABS(UY/.00125)
/COM
/OUT,vm138,vrt
/COM,------------------- VM138 RESULTS COMPARISON -------------
/COM,
/COM, LOAD STEP 3 | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm138,vrt



VM139 (Bending of a Long Uniformly Loaded Rectangular Plate) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM139
/PREP7
/TITLE, VM139, BENDING OF A LONG UNIFORMLY LOADED RECTANGULAR PLATE
C*** STR. OF MATL., TIMOSHENKO, PART 2, 3RD ED., PAGE 80
ANTYPE,STATIC
ET,1,SHELL63,,,,,,2 ! CONSISTENT PRESSURE LOADING OPTION
R,1,.375 ! PLATE THICKNESS
MP,EX,1,30E6
MP,NUXY,1,0.3
N,1
N,5,22.5
FILL
NGEN,2,10,1,5,,,9
E,1,2,12,11
EGEN,4,1,1
D,1,UX,,,,,UY,UZ
D,11,UX,,,,,UZ
D,ALL,ROTZ
NSEL,S,LOC,X,22.5
DSYM,SYMM,X,0,22.5 ! SYMMETRY B.C.'S AT CENTERLINE
NSEL,ALL
FINISH
/SOLU
SFE,ALL,2,PRES,0,10
OUTPR,BASIC,LAST
SOLVE ! ANALYSIS 1 : SMALL DEFLECTION SOLUTION
FINISH
/POST1
SET,1 ! ANALYSIS 1 : SMALL DEFLECTION SOLUTION
NSEL,S,LOC,Y,0
SHELL,BOT ! BOTTOM STRESSES ALONG LENGTH
PRNSOL,S,COMP
*GET,S2,NODE,5,S,X
PRNSOL,S,PRIN
NSEL,ALL
FINISH
/SOLU
NLGEOM,ON ! LARGE DEFLECTION OPTION
SSTIF,ON ! STRESS STIFFENING OPTION
SOLVE ! ANALYSIS 2 : LARGE DEFLECTION SOLUTION
FINISH
/POST1
SET,1 ! ANALYSIS 2 : CONVERGED LARGE DEFLECTION SOLUTION
NSEL,S,LOC,Y,0
SHELL,MID ! MIDDLE STRESSES ALONG LENGTH
PRNSOL,S,COMP
*GET,S3,NODE,1,S,X
PRNSOL,S,PRIN
SHELL,BOT ! BOTTOM STRESSES ALONG LENGTH
PRNSOL,S,COMP
*GET,S4,NODE,5,S,X
PRNSOL,S,PRIN
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'BOT PRS '
LABEL(1,2) = 'psi'
*VFILL,VALUE(1,1),DATA,108000
*VFILL,VALUE(1,2),DATA,S2
*VFILL,VALUE(1,3),DATA,ABS(S2/108000)
SAVE,TABLE1
*DIM,LABEL1,CHAR,2,2
*DIM,VALUE1,,2,3
LABEL1(1,1) = 'MID PRS ','BOT PRS '
LABEL1(1,2) = 'psi ','psi '
*VFILL,VALUE1(1,1),DATA,11240,25280
*VFILL,VALUE1(1,2),DATA,S3,S4
*VFILL,VALUE1(1,3),DATA,ABS(S3/11240),ABS(S4/25280)
SAVE,TABLE2
RESUME,TABLE1
/OUT,vm139,vrt
/COM,------------------- VM139 RESULTS COMPARISON --------------
/COM,
/COM,SMALL DEFLECTION SOLUTION
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/NOPR
RESUME,TABLE2
/GOPR
/COM,
/COM,LARGER DEFLECTION SOLUTION
*VWRITE,LABEL1(1,1),LABEL1(1,2),VALUE1(1,1),VALUE1(1,2),VALUE1(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM139 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm139,vrt











VM140 (Stretching, Twisting and Bending of a Long, Solid Shaft) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM140
/PREP7
/TITLE, VM140, STRETCHING, TWISTING AND BENDING OF A LONG SOLID SHAFT
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 296
ET,1,PLANE83,,,,2,,1
MP,EX,1,30E6
MP,NUXY,1,0 ! ZERO POISSONS RATIO
N,1
N,25,,24
FILL
NGEN,3,25,1,25,1,.25
E,51,53,3,1,52,28,2,26
EGEN,12,2,1
MODE,0,1 ! AXIAL + TORSION MODE
D,1,ALL,,,51,25 ! FIX SUPPORT
D,2,UZ,,,25 ! CENTERLINE CONSTRAINTS AGAINST TORSION
F,75,FY,100 ! APPLY AXIAL FORCE
F,75,FZ,400 ! APPLY TORSION
FINISH
/SOLU
OUTPR,BASIC,LAST ! PRINTOUT SOLUTION
SOLVE
MODE,1,1 ! BENDING MODE
DDELE,2,UZ,25 ! DELETE PREVIOUS UZ CONSTRAINTS
FDEL,75,ALL ! DELETE PREVIOUS FORCES
D,2,UY,,,25 ! CENTERLINE CONSTRAINTS AGAINST BENDING
F,75,FX,-50 ! APPLY VERTICAL FORCE
SOLVE
FINISH
/POST1
SET,1,1,,,,0.0 ! GET LOAD STEP 1 AT 0.0 DEGREES
LCWRITE,1 ! WRITE OUT AS LOAD CASE 1
SET,2,1,,,,0.0 ! GET LOAD STEP 2 AT 0.0 DEGREES
LCOPER,ADD,1 ! ADD LOAD CASE 1 TO LOAD CASE 2
ESEL,S,ELEM,,1 ! SELECT ELEMENT 1
NSLE
PRNSOL,S,COMP
PRNSOL,S,PRIN ! PRINT PRINCIPLE STRESSES
*GET,TOR,NODE,51,S,YZ
*GET,AXBND,NODE,51,S,Y
*GET,COMB,NODE,51,S,1
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'TORSION ','AXIAL+BEND ','COMBINED '
LABEL(1,2) = ' psi',' psi',' psi'
*VFILL,VALUE(1,1),DATA,1018.6,6238.9,6401
*VFILL,VALUE(1,2),DATA,TOR,AXBND,COMB
*VFILL,VALUE(1,3),DATA,ABS(TOR/1018.6),ABS(AXBND/6238.9),ABS(COMB/6401)
/COM
/OUT,vm140,vrt
/COM,------------------- VM140 RESULTS COMPARISON -------------
/COM,
/COM, LOAD STEP 3 | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,-----------------------------------------------------------
*STATUS
/OUT
FINISH
*LIST,vm140,vrt



VM141 (Diametral Compression of a Disk) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM141
/SHOW
/PREP7
smrt,off
/DEVICE,VECTOR,ON
/TITLE, VM141, DIAMETRAL COMPRESSION OF A DISK
! THEORY OF ELASTICITY, TIMOSHENKO AND GOODIER, 2ND ED., PG 107
! PLANE STRESS ELEMENTS (PLANE82 AND PLANE2)
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,PLANE2,,,3,,,,1 ! THICKNESS INPUT, SUPPRESS SOLUTION PRINTOUT
ET,2,PLANE82,,,3,,,,1
ET,3,PLANE82,,,3,,2 ! NODAL STRESS PRINTOUT SELECTED
R,1,.2 ! THICKNESS
MP,EX,1,30E6
MP,NUXY,1,0.3
CSYS,1 ! CYLINDRICAL COORDINATES
K,1,1,90
K,2,.5,90
K,4,1
K,5,1,50
L,1,5
LESIZE,1,,,7,5
L,5,4
LESIZE,2,,,4,2
CSYS,0 ! CARTESIAN COORDINATES
K,3
L,3,4
LESIZE,3,,,5
L,2,3
LESIZE,4,,,4,2
L,2,5
LESIZE,5,,,5
L,1,2
LESIZE,6,,,7,5
A,1,2,5,5
A,2,3,4,5
TYPE,2
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USING QUADS
AMESH,2 ! QUADRILATERAL MESHING (PLANE82)
EPLOT
TYPE,1
MSHK,0 ! FREE AREA MESH
MSHA,1,2D ! USING TRIS
AMESH,1 ! TRIANGLE MESHING (PLANE2)
EPLOT
NSEL,S,LOC,X,0
NSEL,R,LOC,Y,0
ESLN
TYPE,3
EMODIF,ALL ! MODIFY ALL SELECTED ELEMENTS
SAVE,VM141,DB
NSEL,S,LOC,Y,0
DSYM,SYMM,Y ! SYMMETRY ALONG X AXIS
NSEL,S,LOC,X,0
DSYM,SYMM,X ! SYMMETRY ALONG Y AXIS
NSEL,ALL
ESEL,ALL
OUTPR,NSOL,NONE ! NODAL DISPL. & REACTION FORCES PRINTOUT CONTROL
OUTPR,ESOL,ALL ! ELEMENTAL PRINTOUT CONTROL
FK,1,FY,-1000 ! APPLY HALF OF FORCE (SYMMETRY)
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,LOC,X,0 ! SELECT ONLY THE NODES OF INTEREST
NSEL,A,LOC,X,0.1
NSEL,R,LOC,Y,0
PRNSOL,S,COMP ! PRINT COMPONENT NODAL STRESSES
NSEL,R,LOC,X,0
NSEL,A,LOC,X,0.2
NSEL,R,LOC,Y,0
*GET,SNOD,NODE,,NUM,MIN ! GET STARTING NODE FOR PATH (X=0)
*GET,FNOD,NODE,,NUM,MAX ! GET END NODE FOR PATH (X=0.2)
NSEL,ALL
ESEL,ALL
PATH,STRESS1,2,,48 ! DEFINE PATH WITH NAME = "STRESS1"
PPATH,1,SNOD ! DEFINE PATH POINTS BY NODE
PPATH,2,FNOD
PDEF,SY,S,Y ! INTERPOLATE SY STRESS ON PATH
PRANGE,24 ! PRINT EVERY 24TH POINT
PRPATH,SY ! PRINT SY STRESS ALONG THE PATH
*GET,S1,PATH,0,MIN,SY
NSEL,R,LOC,X,0
NSEL,A,LOC,X,0.1
NSEL,R,LOC,Y,0
*GET,FNOD,NODE,,NUM,MAX
PATH,STRESS2,2,,48 ! DEFINE PATH WITH NAME = "STRESS2"
PPATH,1,SNOD
PPATH,2,FNOD
PDEF,SY,S,Y ! INTERPOLATE SY STRESS ON PATH
PRANGE,24 ! PRINT EVERY 24TH POINT
PRPATH,SY ! PRINT SY STRESS ALONG THE PATH
*GET,S2,PATH,0,MAX,SY
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'P (psi)','P (psi)'
LABEL(1,2) = ' X=0 ',' X=.1'
*VFILL,VALUE(1,1),DATA,-9549,-9298
*VFILL,VALUE(1,2),DATA,S1,S2
*VFILL,VALUE(1,3),DATA,ABS(S1/9549),ABS(S2/9298)
SAVE,TABLE_1
FINISH
/CLEAR, NOSTART
/FILNAM,GEN
/PREP7
smrt,off
! S.E. GENERATION PASS (SHELL ELEMENTS ,SHELL93)
RESUME,VM141,DB
ANTYPE,SUBST ! SUBSTRUCTURE GENERATION PASS
SEOPT,GEN
! NOTE: SINCE PLANE2 AND SHELL93 HAVE DIFFERENT NODE ORDER, DELETE OLD MESH
ACLEAR,1,2 ! DELETE NODES AND ELEMENTS
ETDELE,1,3 ! DELETE PREVIOUS ELEMENT TYPES
ET,1,SHELL93,,,,,,,1 ! THICKNESS INPUT, SUPPRESS SOLUTION PRINTOUT
ET,2,SHELL93,,,,,,,1
ET,3,SHELL93,,,,,2 ! NODAL STRESS PRINTOUT
/OUTPUT,SCRATCH
NUMCMP,NODE ! COMPRESS NODE NUMBER TO ZERO
/OUTPUT
TYPE,2
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USING QUADS
AMESH,2 ! MESH AREA 2 WITH QUADRILATERALS
EPLOT
TYPE,1
MSHK,0 ! FREE AREA MESH
MSHA,1,2D ! USING TRIS
AMESH,1 ! MESH AREA 1 WITH TRIANGLES
EPLOT
NSEL,S,LOC,X,0
NSEL,R,LOC,Y,0
ESLN
TYPE,3
EMODIF,ALL
NSEL,S,LOC,Y,0
DSYM,SYMM,Y ! SYMMETRY ALONG X AXIS
NSEL,S,LOC,X,0
DSYM,SYMM,X ! SYMMETRY ALONG Y AXIS
NSEL,ALL
ESEL,ALL
D,ALL,UZ,,,,,ROTX,ROTY ! CONSTRAIN UNNEEDED DOF'S
NSEL,S,LOC,X
NSEL,R,LOC,Y,1
*GET,NDOF,NODE,,NUM,MAX ! GET NODE NUMBER FOR MASTER DOF
M,NDOF,UY ! SELECT MASTER DOF AT LOAD APPLICATION POINT
NSEL,ALL
FINISH
/SOLU
SOLVE
SAVE ! SAVE SUBSTRUCTURE DATA BASE FOR EXPANSION PASS
PARSAV,SCALAR,GEN,PARM
FINISH
/CLEAR, NOSTART
/FILNAM,USE
PARRES,,GEN,PARM
/PREP7
smrt,off
/TITLE, VM141, DIAMETRAL COMPRESSION OF A DISK (S.E. USE PASS)
ET,1,MATRIX50
SE,GEN
F,NDOF,FY,-1000
FINISH
/SOLU
SOLVE
FINISH
/CLEAR, NOSTART
/FILNAM,GEN
RESUME
/SOLU
EXPASS,ON,YES ! EXPANSION PASS WITH ELEMENT SOLUTION
SEEXP,GEN,USE
/TITLE, VM141, DIAMETRAL COMPRESSION OF A DISK (S.E. EXPANSION PASS)
OUTPR,NSOL,NONE ! DISPLACEMENT PRINTOUT CONTROL
OUTPR,ESOL,ALL
EXPSOL,1,1
SOLVE
FINISH
/POST1
NSEL,R,LOC,X,0
NSEL,A,LOC,X,0.2
NSEL,R,LOC,Y,0
*GET,SNOD,NODE,,NUM,MIN ! GET STARTING NODE FOR PATH (X=0)
*GET,FNOD,NODE,,NUM,MAX ! GET END NODE FOR PATH (X=0.2)
NSEL,ALL
ESEL,ALL
PATH,STRESS3,2,,48 ! DEFINE PATH WITH NAME = "STRESS3"
PPATH,1,SNOD
PPATH,2,FNOD
PDEF,SY,S,Y ! INTERPOLATE SY STRESS ON PATH
PRANGE,24 ! PRINT EVERY 24TH POINT
PRPATH,SY ! PRINT SY STRESS ALONG THE PATH
*GET,S1,PATH,0,MIN,SY
NSEL,R,LOC,X,0
NSEL,A,LOC,X,0.1
NSEL,R,LOC,Y,0
*GET,FNOD,NODE,,NUM,MAX
NSEL,ALL
ESEL,ALL
PATH,STRESS4,2,,48 ! DEFINE PATH WITH NAME = "STRESS4"
PPATH,1,SNOD
PPATH,2,FNOD
PDEF,SY,S,Y ! INTERPOLATE SY STRESS ON PATH
PRANGE,24 ! PRINT EVERY 24TH POINT
PRPATH,SY ! PRINT SY STRESS ALONG THE PATH
*GET,S2,PATH,0,LAST,SY
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'P (psi)','P (psi)'
LABEL(1,2) = ' X=0 ',' X=.1'
*VFILL,VALUE(1,1),DATA,-9549,-9298
*VFILL,VALUE(1,2),DATA,S1,S2
*VFILL,VALUE(1,3),DATA,ABS(S1/9549),ABS(S2/9298)
SAVE,TABLE_2
FINISH
FINISH
/CLEAR, NOSTART
/PREP7
smrt,off
/TITLE, VM141, DIAMETRAL COMPRESSION OF A DISK
ET,1,PLANE145,4,5,3 ! DEFINE ELEMENT WITH P-LEVELS & THICKNESS INPUT
R,1,.2 ! THICKNESS
MP,EX,1,30E6 ! DEFINE MATERIAL PROPERTIES
MP,NUXY,1,0.3
PCIRC,,1,0,90 ! CREATE MODEL GEOMETRY
ESIZE,,5
AMESH,ALL ! MESH ALL AREAS
EPLOT
FINISH
/SOLU
NSEL,S,LOC,Y,0 ! APPLY BOUNDARY CONDITIONS
DSYM,SYMM,Y ! SYMMETRY ALONG X AXIS
NSEL,S,LOC,X,0
DSYM,SYMM,X ! SYMMETRY ALONG Y AXIS
NSEL,ALL
ESEL,ALL
F,NODE(0,1,0),FY,-1000 ! APPLY HALF OF FORCE (SYMMETRY)
PCONV,1,S,Y,NODE(0,0,0) ! SET CONVERGENCE CRITERIA FOR SY AT CENTER
PCONV,1,S,Y,NODE(.10,0,0) ! SET CONVERGENCE CRITERIA FOR SY AT X=0.1,Y=0
SOLVE
PRCONV ! PRINT P-CONVERGENCE HISTORY
/POST1
*GET,S1,NODE,12,S,Y
*GET,S2,NODE,22,S,Y
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'P (psi)','P (psi)'
LABEL(1,2) = ' X=0 ',' X=.1'
*VFILL,VALUE(1,1),DATA,-9549,-9298
*VFILL,VALUE(1,2),DATA,S1,S2
*VFILL,VALUE(1,3),DATA,ABS(S1/9549),ABS(S2/9298)
SAVE,TABLE_3
RESUME,TABLE_1
FINISH
/DELETE,SCRATCH
/DELETE,GEN,PARM
/DELETE,GEN,db
/DELETE,GEN,emat
/DELETE,GEN,esav
/DELETE,GEN,redm
/DELETE,GEN,rst
/DELETE,GEN,seld
/DELETE,GEN,sub
/DELETE,GEN,tri
/DELETE,USE,dsub
/DELETE,USE,emat
/DELETE,USE,esav
/DELETE,USE,rst
/DELETE,USE,sord
/DELETE,USE,tri
/DELETE,VM141,DB
/COM
/OUT,vm141,vrt
/COM,------------------- VM141 RESULTS COMPARISON ------------
/COM,
/COM, TARGET | ANSYS | RATIO
/COM, PLANE82 AND PLANE2
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.0,' ',F11.0,' ',1F6.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM, SHELL93
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.0,' ',F11.0,' ',1F6.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM, PLANE145
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.0,' ',F11.0,' ',1F6.3)
/COM,---------------------------------------------------------
/OUT
FINISH
! CLEANUP FILES
/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,TABLE_3
*LIST,vm141,vrt



VM142 (Stress Concentration At a Hole in a Plate) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM142
/FILNAM,vm142 ! DEFINE JOBNAME FOR THE COARSE MODEL
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
smrt,off
/TITLE, VM142, STRESS CONCENTRATION AT A HOLE IN A PLATE
C*** ROARK 4TH EDITION, PAGE 384.
/NOPR
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,PLANE2
MP,EX,1,30E6
MP,NUXY,1,0.3
K,1,6 ! KEYPOINTS
K,2,6,6
K,3,,6
K,4,,.5
K,5,.5
K,6
L,1,2 ! LINE SEGMENTS
L,2,3
L,3,4
LESIZE,3,,,4,.25 ! DEFINE NO. OF DIVISONS AND SPACING FOR LINE 3
LARC,4,5,6,0.5
LESIZE,4,,,6 ! DEFINE NO. OF DIVISONS FOR LINE 4
L,5,1
LESIZE,5,,,4,4 ! DEFINE NO. OF DIVISONS AND SPACING FOR LINE 5
AL,1,2,3,4,5 ! AREA DEFINED BY 5 BOUNDING LINES
ESIZE,,4 ! 4 DIVISIONS PER LINE
AMESH,ALL
/AUTO,1 ! AUTO SCALE ON WINDOW 1
/PLOPTS,INFO,0 ! TURN WINDOW DOCUMENTATION OFF
/PLOPTS,WINS,0
/WINDOW,,LTOP ! WINDOW 1 AT LEFT TOP CORNER
EPLOT
LSEL,S,LINE,,3,5,2
DL,ALL,,SYMM
LSEL,S,LINE,,1
NSLL,,1
SF,ALL,PRES,-1000. ! APPLY TENSION ON PLATE
LSEL,ALL
NSEL,ALL
CSYS,1
FINISH
/SOLU
SOLVE
FINISH
SAVE ! SAVE FILE AS VM142.DB
/POST1
SET,1,1
NSORT,S,X,,,3 ! SORT BASED ON SX, RETAIN ONLY THE HIGHEST 3
PRNSOL,S,COMP
/WINDOW,1,OFF ! TURN WINDOW 1 OFF
/NOERASE ! OVERLAY DISPLAYS
/DSCALE,2,1
/WINDOW,2,RTOP ! WINDOW 2 AT RIGHT TOP CORNER
PLNSOL,S,X
*GET,CRSESTR,NODE,18,S,X
*STATUS
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'MX STR '
LABEL(1,2) = 'CRS MODEL'
*VFILL,VALUE(1,1),DATA,3018
*VFILL,VALUE(1,2),DATA,CRSESTR
*VFILL,VALUE(1,3),DATA,ABS(CRSESTR/3018)
SAVE,TABLE_1
FINISH
/CLEAR, NOSTART ! CLEAR THE DATABASE
/FILNAM,SUBMODEL ! DEFINE JOBNAME FOR THE SUBMODEL
/PREP7
smrt,off
/NOPR
/TITLE, VM142, STRESS CONCENTRATION AT A HOLE IN A PLATE
C*** BOUNDARY INTERPOLATION, MODIFIED SECTION
ANTYPE,STATIC
ET,1,PLANE42
MP,EX,1,30E6
MP,NUXY,1,0.3
CSYS,1
K,10,.5,45 ! DEFINE KEYPOINTS FOR SUBMODEL
K,11,.5,90
K,12,1.5,45
K,13,1.5,90
A,10,12,13,11
ESIZE,,8 ! 8 DIVISIONS
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USING QUADS
AMESH,1
/WINDOW,2,OFF
/NOERASE
/PLOPTS,INFO,0
/PLOPTS,WINS,0
/WINDOW,1,LTOP ! WINDOW 1 AT LEFT TOP CORNER
/USER ! USER DEFINED SCALE
/DIST,1,3.3 ! USER DEFINED VIEW DISTANCE
/FOCUS,1,3,3 ! USER DEFINED FOCUS POINT
EPLOT
LSEL,S,LINE,,1,2
NSLL,,1 ! SELECT NODES OF CUT BOUNDARY
NWRITE ! WRITE GEOMETRY TO SUBMODEL.NODE
LSEL,ALL
NSEL,ALL
FINISH
SAVE ! SAVE SUBMODEL DATA IN FILE SUBMODEL.DB
/POST1
RESUME,vm142,db ! RESUME FROM FILE VM142.DB
FILE,vm142,rst ! DEFINE RESULTS FILE NAME
CBDOF,,,,,,,0,,0 ! ACTIVATE CUT BOUNDARY INTERPOLATION
FINISH
/PREP7
smrt,off
RESUME ! RESUME SUBMODEL FROM FILE SUBMODEL.DB
/NOPR
/INPUT,,cbdo,,:cb1 ! READ IN INTERPOLATED B.C.'S FROM SUBMODEL.CBDO
/GOPR
LSEL,S,LINE,,3 ! APPLY REMAINING BOUNDARY CONDITIONS
DL,ALL,,SYMM
FINISH
/SOLU
SOLVE
FINISH
/POST1
SET,1,1
NSORT,S,X,,,3
PRNSOL,S,COMP
/WINDOW,1,OFF
/AUTO,3
/WINDOW,3,BOT ! WINDOW 3 AT LOWER HALF
/NOERASE
/PLOPTS,MINM,1
/USER,3
/DIST,3,.2
/FOCUS,3,.2,.5
/CONTOUR,3,,AUTO ! AUTO CONTOUR SCALE FOR WINDOW 3
PLNSOL,SX
*GET,SUBSTR,NODE,18,S,X
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'MAX STRS'
LABEL(1,2) = ' SUBMOD'
*VFILL,VALUE(1,1),DATA,3018
*VFILL,VALUE(1,2),DATA,SUBSTR
*VFILL,VALUE(1,3),DATA,ABS(SUBSTR/3018 )
SAVE,TABLE_2
FINISH
/CLEAR,NOSTART
/FILNAM,SUBMODEL
/PREP7
smrt,off
/TITLE, VM142, STRESS CONCENTRATION AT A HOLE IN A PLATE
C*** ROARK 4TH EDITION, PAGE 384.
/NOPR
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,PLANE146
MP,EX,1,30E6
MP,NUXY,1,0.3
K,1,6 ! KEYPOINTS
K,2,6,6
K,3,,6
K,4,,.5
K,5,.5
K,6
L,1,2 ! LINE SEGMENTS
L,2,3
L,3,4
LESIZE,3,,,4,.25 ! DEFINE NO. OF DIVISONS AND SPACING FOR LINE 3
LARC,4,5,6,0.5
LESIZE,4,,,6 ! DEFINE NO. OF DIVISONS FOR LINE 4
L,5,1
LESIZE,5,,,4,4 ! DEFINE NO. OF DIVISONS AND SPACING FOR LINE 5
AL,1,2,3,4,5 ! AREA DEFINED BY 5 BOUNDING LINES
ESIZE,,4 ! 4 DIVISIONS PER LINE
AMESH,ALL
/AUTO,1 ! AUTO SCALE ON WINDOW 1
/PLOPTS,INFO,0 ! TURN WINDOW DOCUMENTATION OFF
/PLOPTS,WINS,0
/WINDOW,,LTOP ! WINDOW 1 AT LEFT TOP CORNER
EPLOT
LSEL,S,LINE,,3,5,2
DL,ALL,,SYMM
LSEL,S,LINE,,1
NSLL,,1
SF,ALL,PRES,-1000. ! APPLY TENSION ON PLATE
LSEL,ALL
NSEL,ALL
CSYS,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
SET,1,1
!PRNSOL,S,COMP
/WINDOW,1,OFF ! TURN WINDOW 1 OFF
/NOERASE ! OVERLAY DISPLAYS
/DSCALE,2,1
/WINDOW,2,RTOP ! WINDOW 2 AT RIGHT TOP CORNER
PLNSOL,S,X
*GET,SUBSTR,NODE,18,S,X
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'MAX STRS'
LABEL(1,2) = 'CRS MOD '
*VFILL,VALUE(1,1),DATA,3018
*VFILL,VALUE(1,2),DATA,SUBSTR
*VFILL,VALUE(1,3),DATA,ABS(SUBSTR/3018 )
SAVE,TABLE_3
FINISH
/DEL,SUBMODEL,cbdo
/DEL,SUBMODEL,db
/DEL,SUBMODEL,emat
/DEL,SUBMODEL,esav
/DEL,SUBMODEL,node
/DEL,SUBMODEL,rst
/DEL,SUBMODEL,tri
RESUME,TABLE_1
/OUT,vm142,vrt
/COM,-------------------(VM142)RESULTS COMPARISON---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,PLANE2
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,PLANE42
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM,PLANE146
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/OUT
FINISH
/DEL,TABLE_1
/DEL,TABLE_2
/DEL,TABLE_3
*LIST,vm142,vrt






VM143 (Fracture Mechanics Stress Intensity for a Crack in a Finite Width Plate) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM143
*CREATE,FRACT,MAC
! MACRO TO CREATE 3D SOLID95 CRACK TIP ELEMENTS FROM 3D SOLID45 ELEMENTS
! MAKE A COMPONENT CONTAINING THE CRACK TIP NODES (CRACKTIP)
! THE CRACK TIP IS BETWEEN NODES K AND O
! SET ELEMENT TYPE TO POINT TO SOLID95
! SET ARG1 TO N (THE TYPE OF THE ELEMENTS AROUND THE CRACK TIP)
!
/NOPR
NSEL,ALL
*GET,N,NODE,,NUM,MAX ! CURRENT MAXIMUM NODE NUMBER
CMSEL,S,CRACKTIP ! SELECT THE TIP NODES
ESLN ! ANY ELEMENTS ATTACHED
*GET,ELMAX,ELEM,,NUM,MAX ! CURRENT MAXIMUM ELEMENT NUMBER
*DO,IEL,1,ELMAX ! LOOP ON MAX ELEMENT
ELMI=IEL
*IF,ELMI,LE,0,EXIT ! NO MORE SELECTED
*GET,ELTYPE,ELEM,ELMI,ATTR,TYPE ! GET ELEMENT TYPE
*IF,ELTYPE,NE,ARG1,CYCLE ! CHECK FOR SELECTED ELEMENT
N3 = NELEM(ELMI,3) ! GET NODE 3 (K)
*IF,NSEL(N3),LE,0,CYCLE ! IT MUST BE SELECTED
N7 = NELEM(ELMI,7) ! GET NODE 7 (L)
*IF,NSEL(N7),LE,0,CYCLE ! IT MUST ALSO BE SELECTED
N1 = NELEM(ELMI,1) ! GET NODE 1 (I)
N2 = NELEM(ELMI,2) ! GET NODE 2 (J)
N5 = NELEM(ELMI,5) ! GET NODE 5 (M)
N6 = NELEM(ELMI,6) ! GET NODE 6 (N)

X3 = 0.75*NX(N3) ! WEIGHTED POSITION OF N3
Y3 = 0.75*NY(N3)
Z3 = 0.75*NZ(N3)
X = 0.25*NX(N2) + X3 ! QUARTER POINT LOCATION ( NODE (R) )
Y = 0.25*NY(N2) + Y3
Z = 0.25*NZ(N2) + Z3
N = N + 1 ! NEXT NODE
N10 = N
N,N10,X,Y,Z ! MIDSIDE NODE LOCATION
X = 0.25*NX(N1) + X3
Y = 0.25*NY(N1) + Y3
Z = 0.25*NZ(N1) + Z3
N = N + 1
N12= N
N,N12,X,Y,Z
X7 = 0.75*NX(N7)
Y7 = 0.75*NY(N7)
Z7 = 0.75*NZ(N7)
X = 0.25*NX(N6) + X7
Y = 0.25*NY(N6) + Y7
Z = 0.25*NZ(N6) + Z7
N = N + 1
N14 = N
N,N14,X,Y,Z
X = 0.25*NX(N5) + X7
Y = 0.25*NY(N5) + Y7
Z = 0.25*NZ(N5) + Z7
N = N + 1
N16 = N
N,N16,X,Y,Z
N4=N3
N8=N7
NSEL,ALL
TYPE,3
EN,ELMI,N1,N2,N3,N4,N5,N6,N7,N8 ! REDEFINE THE ELEMENT
EMORE,0,N10,0,N12,0,N14,0,N16
EMORE,
*ENDDO
CMSEL,U,CRACKTIP ! UNSELECT THE TIP NODES
NUMMRG,NODE ! MERGE MIDSIDE NODES
NSEL,ALL ! SELECT ALL ELEMENTS
ESEL,ALL ! SELECT ALL ELEMENTS
/GOPR
*END

/PREP7
SMRT,OFF
/TITLE, VM143, FRACTURE MECHANICS STRESS INTENSITY - CRACK IN A FINITE WIDTH PLATE
C*** BROWN AND SRAWLEY, ASTM SPECIAL TECHNICAL PUBLICATION NO. 410.
/COM, ****** CRACK IN 3-DIMENSIONS USING SOLID45 AND SOLID95
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,SOLID45
ET,2,SOLID45 ! ELEMENTS AROUND THE CRACK TIP
ET,3,SOLID95 ! CRACK TIP ELEMENTS CREATED USING MACRO FRACT
MP,EX,1,3E7
MP,NUXY,1,.3
CSYS,1 ! CYLINDRICAL COORDINATE SYSTEM
N,1
NGEN,9,20,1
N,11,.8
N,171,.8,180
FILL,11,171,7,31,20
CSYS,0 ! CARTESIAN COORDINATE SYSTEM
FILL,1,11,9,2,1,9,20,3
N,15,4
N,75,4,5
FILL,15,75,2,35,20
N,155,-1,5
FILL,75,155,3,95,20
N,172,-1
FILL,155,172,5,177,-1,,,.15
FILL,11,15,3,,,7,20,3
NGEN,2,200,1,177,,,,.25
E,2,22,1,1,202,222,201,201
EGEN,8,20,-1
E,2,3,23,22,202,203,223,222
EGEN,8,20,-1
EGEN,9,1,-8
EGEN,5,1,73,78
E,171,151,173,172,371,351,373,372
E,151,131,174,173,351,331,374,373
E,131,132,175,174,331,332,375,374
EGEN,3,1,-1
E,134,135,155,177,334,335,355,377
TYPE,2
EMODIF,1 ! MODIFY ELEMENTS 1 TO 8 FROM TYPE,1 TO TYPE,2
*REPEAT,8,1
NUMMRG,NODE ! MERGE COINCIDENT NODES
NSEL,S,LOC,X,0
NSEL,R,LOC,Y,0
CM,CRACKTIP,NODE
/NERR,0 ! TEMPORARILY NO WARNINGS OR ERRORS PRINTOUT
! (IN ORDER TO AVOID WARNING MESSAGES DUE TO
! MIDSIDE NODES LOCATION)
FRACT,2 ! CONVERSION MACRO, TYPE 2 IS SOLID45
! ELEMENTS AROUND THE CRACK TIP
/NERR,DEFA ! TURN ON THE WARNINGS OR ERRORS PRINTOUT
/OUTPUT
OUTPR,,ALL
OUTPR,VENG,ALL ! STORE STRAIN ENERGY FOR J-INTEGRAL EVAL‎UATION
NSEL,S,LOC,X,-1
DSYM,SYMM,X ! SYMMETRIC B.C.'S AT X = -1
NSEL,S,LOC,X,0,4
NSEL,R,LOC,Y,0
DSYM,SYMM,Y ! SYMMETRIC B.C.'S AT Y = 0 EXCEPT CRACK NODES
NSEL,ALL
D,ALL,UZ ! Z CONSTRAINTS FOR PLANE STRAIN PROBLEM
NSEL,S,LOC,Y,5
SF,ALL,PRES,-.5641895
NSEL,ALL
ESEL,ALL
FINISH
/OUTPUT,SCRATCH
/SOLU
SOLVE
FINISH
/OUTPUT
/POST1
ETABLE,SENE,SENE ! RETRIEVE STRAIN ENERGY PER ELEMENT
ETABLE,VOLU,VOLU ! RETRIEVE VOLUME PER ELEMENT
C*** IN POST1 DETERMINE KI (STRESS INTENSITY FACTOR) USING KCALC !**
PATH,KI1,3,,48 ! DEFINE PATH WITH NAME = "KI1"
PPATH,1,1 ! DEFINE PATH POINTS BY NODE
PPATH,2,406
PPATH,3,162
KCALC,,,1 ! COMPUTE KI FOR A HALF-MODEL WITH SYMM. B.C.
*GET,KI1,KCALC,,K,1 ! GET KI AS PARAMETER KI1
!********************************************************************************
!************************** J-INTEGRAL USER FILE *****************************
!*******************************************************************************
! ****NOTE:- IN GENERAL USAGE, THE USER FILE WOULD BE AVAILABLE IN THE
! LOCAL DIRECTORY RATHER THAN BEING CREATED IN THE INPUT
!*******************************************************************************
*CREATE,JIN1
STINFC ! DATA BLOCK NAME
SEXP,W,SENE,VOLU,1,-1 ! CALCULATE STRAIN ENERGY DENSITY
PATH,JINT,4,50,48 ! DEFINE PATH WITH NAME = "JINT"
PPATH,1,ARG1 ! DEFINE PATH POINTS BY NODE
PPATH,2,ARG2
PPATH,3,ARG3
PPATH,4,ARG4
PDEF,W,ETAB,W ! PUT STRAIN ENERGY DENSITY ON THE PATH
PCALC,INTG,J,W,YG ! INTEGRATE ENERGY W.R.T. GLOBAL Y
*GET,JA,PATH,,LAST,J ! GET FINAL VALUE OF INTEGRAL FOR 1ST TERM OF J
PDEF,CLEAR ! CLEAR OLD PATH VARIABLES
PVECT,NORM,NX,NY,NZ ! DEFINE THE PATH UNIT NORMAL VECTOR
PDEF,INTR,SX,SX ! PUT STRESS SX ON THE PATH
PDEF,INTR,SY,SY ! PUT STRESS SY ON THE PATH
PDEF,INTR,SXY,SXY ! PUT STRESS SXY ON THE PATH
PCALC,MULT,TX,SX,NX ! CALCULATE TRACTION TX
PCALC,MULT,C1,SXY,NY ! TX = SX*NX + SXY*NY
PCALC,ADD,TX,TX,C1
PCALC,MULT,TY,SXY,NX ! CALCULATE TRACTION TY
PCALC,MULT,C1,SY,NY ! TY = SXY*NX + SY*NY
PCALC,ADD,TY,TY,C1
*GET,DX,PATH,,LAST,S ! DEFINE PATH SHIFT AS 1% OF PATH LENGTH
DX=DX/100
PCALC,ADD,XG,XG,,,,-DX/2 ! SHIFT PATH FROM X TO X-DX/2 (GLOBAL X DIR.)
PDEF,INTR,UX1,UX ! DEFINE UX AT X-DX
PDEF,INTR,UY1,UY ! DEFINE UY AT X-DX
PCALC,ADD,XG,XG,,,,DX ! SHIFT PATH FROM X-DX/2 TO X+DX/2
PDEF,INTR,UX2,UX ! DEFINE UX AT X+DX
PDEF,INTR,UY2,UY ! DEFINE UY AT X+DX
PCALC,ADD,XG,XG,,,,-DX/2 ! SHIFT PATH BACK TO ORIGINAL POSITION
C=(1/DX)
PCALC,ADD,C1,UX2,UX1,C,-C ! CALCULATE DERIVATIVE DUX/DX
PCALC,ADD,C2,UY2,UY1,C,-C ! CALCULATE DERIVATIVE DUY/DX
PCALC,MULT,C1,TX,C1 ! DEFINE INTEGRAND
PCALC,MULT,C2,TY,C2 ! = TX*DUX/DX + TY*DUY/DX
PCALC,ADD,C1,C1,C2
PCALC,INTG,J,C1,S ! FORM SECOND INTEGRAL (W.R.T. PATH LENGTH S)
*GET,JB,PATH,,LAST,J ! GET FINAL VALUE OF INTEGRAL FOR 2ND TERM OF J
JINT=2*(JA-JB) ! ADD BOTH TERMS AND DOUBLE FOR HALF MODELS
PDEF,CLEAR ! CLEAR PATH VARIABLES
*END
C**************** IN POST1 DETERMINE KI FROM J-INTEGRAL !***********************
CON1=30E6/(1-(0.3*0.3)) ! J-TO-KI CONVERSION FACTOR
*ULIB,JIN1 ! ASSIGN LOCAL FILE JIN1 AS USER FILE
*USE,STINFC,4,45,125,164 ! USE DATA BLOCK STINFC AND GIVE PATH NODES
KI2=SQRT(CON1*JINT) ! CALCULATE KI FROM J
*STATUS,KI1 ! VIEW RESULTS
*STATUS,KI2
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'BY DISP ','BY J-'
LABEL(1,2) = 'EXTRP ','INT'
*VFILL,VALUE(1,1),DATA,1.0249,1.0249
*VFILL,VALUE(1,2),DATA,KI1,KI2
*VFILL,VALUE(1,3),DATA,ABS(KI1/1.0249),ABS(KI2/1.0249)
SAVE,TABLE_1
FINISH

/CLEAR, NOSTART ! CLEAR DATABASE FOR 2ND SOLUTION
/PREP7
SMRT,OFF
/TITLE, VM143, FRACTURE MECHANIC STRESS INTENSITY - CRACK IN A FINITE WIDTH PLATE
/COM, ****** CRACK IN 2-DIMENSIONS USING 2-D PLANE82 ******
ET,1,PLANE82,,,2 ! PLANE82 (PLANE STRAIN)
MP,EX,1,30E6
MP,NUXY,1,0.3
K,1 ! DEFINE KEYPOINTS AND LINE SEGMENTS
K,2,4
K,3,4,5
K,4,-1,5
K,5,-1
L,1,2
L,2,3
LESIZE,2,,,4
L,3,4
LESIZE,3,,,4
L,4,5,
LESIZE,4,,,6,.2
L,5,1
ESIZE,,5
KSCON,1,.15,1,8 ! DEFINE CRACK TIP ELEMENT SIZE
AL,1,2,3,4,5
DL,1,1,SYMM ! APPLY SOLID MODEL BOUNDARY CONDITIONS
DL,4,1,SYMM
SFL,3,PRES,-.5641895
AMESH,1
OUTPR,ALL
FINISH
/COM
/OUTPUT,SCRATCH
/SOLU
SOLVE
FINISH
/OUTPUT
/POST1
ETABLE,SENE,SENE ! RETRIEVE STRAIN ENERGY PER ELEMENT
ETABLE,VOLU,VOLU ! RETRIEVE VOLUME PER ELEMENT
C*** IN POST1 DETERMINE KI (STRESS INTENSITY FACTOR) USING KCALC !**
NSEL,S,LOC,Y,0 ! SELECT NODES FOR LPATH COMMAND
NSEL,R,LOC,X,0
*GET,NOD1,NODE,,NUM,MIN
NSEL,A,LOC,Y
NSEL,R,LOC,X,-.005,-.145
*GET,NOD2,NODE,,NUM,MIN
NSEL,A,LOC,Y
NSEL,R,LOC,X,-.145,-.155
*GET,NOD3,NODE,,NUM,MIN
NSEL,ALL
PATH,KI2,3,,48 ! DEFINE PATH WITH NAME = "KI2"
PPATH,1,NOD1 ! DEFINE PATH POINTS BY NODE
PPATH,2,NOD2
PPATH,3,NOD3
KCALC,,,1 ! COMPUTE KI FOR A HALF-MODEL WITH SYMM. B.C.
*GET,KI1,KCALC,,K,1 ! GET KI AS A PARAMETER KI1
C**************** IN POST1 DETERMINE KI FROM J-INTEGRAL !***********************
CSYS,1
NSEL,S,LOC,X,.5,.8 ! SELECT NODES FOR LPATH COMMAND IN STINFC
NSEL,R,LOC,Y,-1,1
*GET,NOD4,NODE,,NUM,MAX
NSEL,S,LOC,X,.5,.8
NSEL,R,LOC,Y,35,55
*GET,NOD5,NODE,,NUM,MAX
NSEL,S,LOC,X,.5,.8
NSEL,R,LOC,Y,120,145
*GET,NOD6,NODE,,NUM,MAX
NSEL,S,LOC,X,.5,.8
NSEL,R,LOC,Y,179,181
*GET,NOD7,NODE,,NUM,MIN
NSEL,ALL
CSYS,0
*USE,STINFC,NOD4,NOD5,NOD6,NOD7 ! USE DATA BLOCK STINFC AND GIVE PATH NODES
CON1=30E6/(1-(0.3*0.3)) ! J-TO-KI CONVERSION FACTOR
KI2=SQRT(CON1*JINT) ! CALCULATE KI FROM J
*STATUS,KI1 ! VIEW RESULTS
*STATUS,KI2
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'BY DISP ','BY J-'
LABEL(1,2) = 'EXTRP ','INT'
*VFILL,VALUE(1,1),DATA,1.0249,1.0249
*VFILL,VALUE(1,2),DATA,KI1,KI2
*VFILL,VALUE(1,3),DATA,ABS(KI1/1.0249),ABS(KI2/1.0249)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm143,vrt
/COM,------------------- VM143 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,USING SOLID95 AND SOLID45 (3-D ANALYSIS)
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,USING PLANE82 (2-D ANALYSIS)
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm143,vrt

/DELETE,FRACT,MAC


VM144 (Bending of a Composite Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM144
/PREP7
/TITLE, VM144, BENDING OF A COMPOSITE BEAM
C*** FORMULAS FOR STRESS AND STRAIN, ROARK, 5TH ED.
C*** USING LAYERED SHELL ELEMENT (SHELL99)
ANTYPE,STATIC
ET,1,SHELL99 ! 8 NODE LAYERED SHELL ELEMENT
R,1,2 ! 2 LAYERS PER ELEMENT
RMORE
RMORE,1,0,.2,2,0,.1 ! LAYER 1: 0.2 THK; LAYER 2: 0.1 THK
MP,EX,1,1.2E6 ! MATERIAL 1 PROPERTIES
MP,NUXY,1,0
MP,ALPX,1,18E-5
MP,ALPY,1,0.0
MP,EX,2,0.4E6 ! MATERIAL 2 PROPERTIES
MP,NUXY,2,0
MP,ALPX,2,6E-5
MP,ALPY,2,0
N,1
N,9,8
FILL
NGEN,3,10,1,9,,,.25
E,1,3,23,21,2,13,22,11
EGEN,4,2,-1 ! 4 ELEMENTS ALONG BEAM LENGTH
CP,1,ROTY,9,19,29 ! COUPLE FREE END NODES FOR ROTATION
D,1,ALL,,,21,10 ! FIXED END
F,19,MY,10 ! APPLY BENDING MOMENT AT FREE EDGE
BFUNIF,TEMP,100 ! ELEVATED TEMPERATURE LOAD
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,LOC,X,8 ! SELECT FREE EDGE
PRNSOL,U,Z ! PRINT DISPLACEMENTS
*GET,U1,NODE,9,U,Z
NSEL,S,LOC,Y ! SELECT NODES ALONG LENGTH
SHELL,TOP
PRNSOL,S,COMP ! PRINT TOP STRESSES
*GET,ST1,NODE,1,S,X
SHELL,BOT
PRNSOL,S,COMP ! PRINT BOTTOM STRESSES
*GET,SB1,NODE,1,S,X
ALLSEL
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DISP ','PRS TP ','PRS BTM '
LABEL(1,2) = 'in','psi','psi'
*VFILL,VALUE(1,1),DATA,.832,2258,1731
*VFILL,VALUE(1,2),DATA,U1,ST1,SB1
*VFILL,VALUE(1,3),DATA,ABS(U1/.832),ABS(ST1/2258),ABS(SB1/1731)
SAVE,TABLE_1
FINISH
/PREP7
C*** USING SHELL99 ELEMENTS WITH NODE OFFSET OPTION
ET,1,SHELL99 ! 8 NODE LAYERED SHELL ELEMENT
KEYOPT,1,11,2 ! WITH NODAL PLANE ON TOP FACE
R,1,1 ! BOTTOM LAYER
RMORE
RMORE,1,0,.2
ET,2,SHELL99 ! 8 NODE LAYERED SHELL ELEMENT
KEYOPT,2,11,1 ! WITH NODAL PLANE ON BOTTOM FACE
R,2,1 ! TOP LAYER
RMORE
RMORE,2,0,.1
EGEN,2,0,1,4,1,,1,1 ! GENERATE OVERLAPPING ELEMENTS
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,LOC,X,8 ! SELECT FREE EDGE
PRNSOL,U,Z ! PRINT DISPLACEMENTS
*GET,U2,NODE,9,U,Z
NSEL,S,LOC,Y ! SELECT NODES ALONG LENGTH
SHELL,TOP
ESEL,S,TYPE,,2 ! ELEMENTS REPRESENTING TOP LAYER
PRNSOL,S,COMP ! PRINT TOP STRESSES
*GET,ST2,NODE,1,S,X
SHELL,BOT
ESEL,S,TYPE,,1 ! ELEMENTS REPRESENTING BOTTOM LAYER
PRNSOL,S,COMP ! PRINT BOTTOM STRESSES
*GET,SB2,NODE,1,S,X
*VFILL,VALUE(1,1),DATA,.832,2258,1731
*VFILL,VALUE(1,2),DATA,U2,ST2,SB2
*VFILL,VALUE(1,3),DATA,ABS(U2/.832),ABS(ST2/2258),ABS(SB2/1731)
SAVE,TABLE_2
FINISH
/CLEAR,NOSTART
/PREP7
/TITLE, VM144, BENDING OF A COMPOSITE BEAM
C*** FORMULAS FOR STRESS AND STRAIN, ROARK, 5TH ED.
C*** USING LAYERED SOLID ELEMENTS (SOLID46)
ANTYPE,STATIC
ET,1,SOLID46,,,,,2,4 ! LAYERED SOLID ELEMENTS
R,1,2 ! 2 LAYERS
RMORE
RMORE,1,0,2,2,0,1 ! RELATIVE LAYER THICKNESSES
MP,EX,1,1.2E6 ! MATERIAL 1 PROPERTIES
MP,NUXY,1,0
MP,ALPX,1,1.8E-4
MP,ALPY,1,0.0
MP,ALPZ,1,0.0
MP,EX,2,0.4E6 ! MATERIAL 2 PROPERTIES
MP,NUXY,2,0
MP,ALPX,2,0.6E-4
MP,ALPY,2,0.0
MP,ALPZ,2,0.0
N,1
N,9,8
FILL
NGEN,2,10,1,9,1,,.5
NGEN,2,20,1,19,1,,,.3
E,1,2,12,11,21,22,32,31
EGEN,8,1,-1 ! 8 ELEMENTS ALONG LENGTH
D,1,ALL,,,31,10 ! FIXED END
F,9,FX,-(50/3),,19,10 ! APPLY NODAL FORCES TO GENERATE MOMENT
F,29,FX,(50/3),,39,10
BFUNIF,TEMP,100 ! ELEVATED TEMPERATURE LOAD
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,LOC,X,8
PRNSOL,U,Z ! PRINT FREE END DISPLACEMENTS
*GET,U3,NODE,9,U,Z
NSEL,S,LOC,Z,0.3
PRNSOL,S,COMP ! PRINT STRESSES ALONG TOP SURFACE
*GET,ST3,NODE,21,S,X
NSEL,S,LOC,Z
PRNSOL,S,COMP ! PRINT STRESSES ALONG BOTTOM SURFACE
*GET,SB3,NODE,1,S,X
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DISP ','PRS TP ','PRS BTM '
LABEL(1,2) = 'in','psi','psi'
*VFILL,VALUE(1,1),DATA,.832,2258,1731
*VFILL,VALUE(1,2),DATA,U3,ST3,SB3
*VFILL,VALUE(1,3),DATA,ABS(U3/.832),ABS(ST3/2258),ABS(SB3/1731)
SAVE, TABLE_3
FINISH
/CLEAR,NOSTART
/PREP7
/TITLE, VM144, BENDING OF A COMPOSITE BEAM
C*** FORMULAS FOR STRESS AND STRAIN, ROARK, 5TH ED.
C*** USING LAYERED SOLID ELEMENTS (SOLID191)
ANTYPE,STATIC
ET,1,SOLID191,,,,,2, ! LAYERED SOLID ELEMENTS
R,1,2 ! 2 LAYERS
RMORE
RMORE,1,0,2,2,0,1 ! RELATIVE LAYER THICKNESSES
MP,EX,1,1.2E6 ! MATERIAL 1 PROPERTIES
MP,NUXY,1,0
MP,ALPX,1,1.8E-4
MP,ALPY,1,0.0
MP,ALPZ,1,0.0
MP,EX,2,0.4E6 ! MATERIAL 2 PROPERTIES
MP,NUXY,2,0
MP,ALPX,2,0.6E-4
MP,ALPY,2,0.0
MP,ALPZ,2,0.0
N,1
N,9,8
FILL
NGEN,2,10,1,9,1,,.5
NGEN,2,20,1,19,1,,,.3
E,1,2,12,11,21,22,32,31
EGEN,8,1,-1 ! 8 ELEMENTS ALONG LENGTH
emid
nsel,s,loc,x
D,all,ALL, ! FIXED END
nsel,all
nlist,all
sfe,8,3,pres,,4000/3,4000/3,-4000/3,-4000/3 ! tapered pressure to apply moment on face
BFUNIF,TEMP,100 ! ELEVATED TEMPERATURE LOAD
FINISH
/SOLU
outpr,,1
SOLVE
FINISH
/POST1
NSEL,S,LOC,X,8
PRNSOL,U,Z ! PRINT FREE END DISPLACEMENTS
*GET,U3,NODE,9,U,Z
NSEL,S,LOC,Z,0.3
PRNSOL,S,COMP ! PRINT STRESSES ALONG TOP SURFACE
*GET,ST3,NODE,21,S,X
NSEL,S,LOC,Z
PRNSOL,S,COMP ! PRINT STRESSES ALONG BOTTOM SURFACE
*GET,SB3,NODE,1,S,X
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DISP ','PRS TP ','PRS BTM '
LABEL(1,2) = 'in','psi','psi'
*VFILL,VALUE(1,1),DATA,.832,2258,1731
*VFILL,VALUE(1,2),DATA,U3,ST3,SB3
*VFILL,VALUE(1,3),DATA,ABS(U3/.832),ABS(ST3/2258),ABS(SB3/1731)
SAVE, TABLE_4

RESUME,TABLE_1
/COM
/OUT,vm144,vrt
/COM,------------------- VM144 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING SHELL99 MODEL
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING SHELL99 (WITH NODE OFFSET)
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM,RESULTS USING SOLID46
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/NOPR
RESUME, TABLE_4
/GOPR
/COM,RESULTS USING SOLID191
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm144,vrt



VM145 (Stretching of an Orthotropic Solid) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM145
/PREP7
/TITLE, VM145, STRETCHING OF AN ORTHOTROPIC SOLID
C*** MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 225
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,SOLID64 ! ANISOTROPIC SOLID
MP,EX,2,10E6 ! LABELED MATERIAL PROPERTY INPUT
MP,EY,2,20E6
MP,EZ,2,40E6
MP,NUXY,2,.1
MP,NUYZ,2,.2
MP,NUXZ,2,.3
MP,GXY,2,10E6
MP,GYZ,2,10E6
MP,GXZ,2,10E6
TB,ANEL,1,,,1
TBDATA,1,.1E-6,-.5E-8,-.75E-8 ! UNINVERTED MATERIAL PROPERTY MATRIX INPUT
TBDATA,7,.5E-7,-.5E-8,,,,.25E-7
TBDATA,16,.1E-6,,,.1E-6,,.1E-6
N,1
N,2,1
NGEN,2,2,1,2,,,,1
NGEN,4,4,1,4,,,1
E,1,2,6,5,3,4,8,7
MAT,2
E,9,10,14,13,11,12,16,15
OUTPR,,1
D,1,ALL,,,9,8
D,3,UX,,,7,2
D,11,UX,,,15,2
D,2,UY,,,4
D,10,UY,,,12
D,2,UZ,,,14,4
D,5,UZ,,,13,8
F,2,FX,25,,16,2
F,5,FY,50,,8
F,13,FY,50,,16
FINISH
/SOLU
SOLVE
/POST1
*GET,UX,NODE,8,U,X
*GET,UY,NODE,8,U,Y
*GET,UZ,NODE,8,U,Z
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'X DISP ','Y DISP ','Z DISP '
LABEL(1,2) = ' in',' in',' in'
*VFILL,VALUE(1,1),DATA,.9E-5,.95E-5,-.175E-5
*VFILL,VALUE(1,2),DATA,UX,UY,UZ
*VFILL,VALUE(1,3),DATA,ABS(UX/(.9E-5)),ABS(UY/(.95E-5)),ABS(UZ/(-.175E-5))
/COM
/OUT,vm145,vrt
/COM,------------------- VM145 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F12.8,' ',F12.8,' ',1F5.3)
/COM,------------------------------------------------------------
/OUT
FINISH
*LIST,vm145,vrt



VM146 (Bending of a Reinforced Concrete Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM146
/PREP7
/TITLE, VM146, BENDING OF A REINFORCED CONCRETE BEAM
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 221
ANTYPE,STATIC
ET,1,SOLID65,,,,,2 ! REINFORCED CONCRETE SOLID ELEMENT
ET,2,LINK8 ! STEEL RODS
ET,3,PIPE16,,,,,,,1 ! DUMMY ELEMENTS FOR CONSTRAINT EQUATIONS
R,1
R,2,.15 ! HALF AREA OF ROD
R,3,1,.5 ! ARBITRARY CONSTANTS FOR DUMMY ELEMENTS
MP,EX,1,2E6 ! CONCRETE PROPERTIES
MP,NUXY,1,0
TB,CONCR,1
TBDATA,3,0.0,-1 ! ZERO TENSILE CRACKING STRENGTH
! REMOVE CRUSHING CAPABILITY
MP,EX,2,30E6 ! STEEL PROPERTIES
MP,NUXY,2,0.3
N,1
N,2,1.5
NGEN,5,2,1,2,1,,1.5
NGEN,2,10,1,10,1,,,5
E,7,8,10,9,17,18,20,19
TYPE,3 ! DEFINE DUMMY ELEMENTS FOR ROTZ DOF
REAL,3
E,10,8
E,20,18
EGEN,4,-2,1,3
TYPE,2 ! REINFORCING RODS AT THE BOTTOM SURFACE
MAT,2
REAL,2
E,1,2
E,11,12
CE,1,, 2,UX,-1, 6,UX,1, 6,ROTZ,3 ! CONSTRAINT EQUATION TO ENSURE
CE,2,,12,UX,-1,16,UX,1,16,ROTZ,3 ! PLANE SECTION REMAINS PLANE
CE,3,, 4,UX,-1, 6,UX,1, 6,ROTZ,1.5
CE,4,,14,UX,-1,16,UX,1,16,ROTZ,1.5
CE,5,, 8,UX,-1, 6,UX,1, 6,ROTZ,-1.5
CE,6,,18,UX,-1,16,UX,1,16,ROTZ,-1.5
CE,7,,10,UX,-1, 6,UX,1, 6,ROTZ,-3
CE,8,,20,UX,-1,16,UX,1,16,ROTZ,-3
NSEL,S,LOC,X
D,ALL,ALL ! FIX NODES IN Y-Z PLANE
NSEL,ALL
D,ALL,ROTY ! CONSTRAIN UNNEEDED PIPE ROTATIONS
F,6,MZ,300,,16,10 ! APPLY BENDING MOMENT
FINISH
/SOLU
AUTOTS,ON
NSUBST,5
OUTPR,,LAST
SOLVE
/POST1
ESEL,S,ELEM,,1,1
*GET,SCON,NODE,9,S,X
ESEL,S,ELEM,,13,13
ETAB,ST,LS,1
ESORT,ST
*GET,STL,SORT,,MAX
*STATUS
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'TSTR STL ','TSTR CON'
LABEL(1,2) = ' psi',' psi'
*VFILL,VALUE(1,1),DATA,387.28,-18.54
*VFILL,VALUE(1,2),DATA,STL,SCON
*VFILL,VALUE(1,3),DATA,ABS(STL/387.28),ABS(SCON/18.54)
/COM
/OUT,vm146,vrt
/COM,------------------- VM146 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F12.2,' ',F12.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM146 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm146,vrt



VM147 (Gray-Body Radiation within a Frustrum of a Cone) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM147
/PREP7
/TITLE, VM147, GRAY-BODY RADIATION WITHIN A FRUSTRUM OF A CONE
! REF: SIEGEL, R., HOWELL J.R., "THERMAL RADIATION HEAT TRANSFER"
! 2ND EDITION, HEMISPHERE PUBLISHING CORPORATION, 1981.
ET,1,LINK32 ! HEAT CONDUCTING BAR
N,1
N,2,0.075
N,3,0.075
N,4,0.05,0.075
N,5,0.05,0.075
N,6,0,0.075
MAT,1 ! SURFACE 1 (LOWER SURFACE)
E,1,2
MAT,2 ! SURFACE 2 (INSULATED OUTSIDE SURFACE)
E,3,4
MAT,3 ! SURFACE 3 (TOP SURFACE)
E,5,6
FINISH
/AUX12
EMIS,1,0.6
EMIS,2,0.8
EMIS,3,0.5
VTYPE,1 ! NON-HIDDEN (FAST) METHOD
GEOM,1,50 ! 2-D AXISYMMETRIC GEOM WITH 50 FACETS
MPRINT,1
STEF,5.6696E-8 ! STEFAN-BOLTZMANN CONSTANT IN MKS UNITS
WRITE,CONE,SUB ! WRITE RADIATION SUBSTRUCTURE MATRIX
FINISH
/CLEAR,NOSTART ! CLEAR DATABASE; DO NOT READ START.ANS FILE
/PREP7
ET,1,SURF151,,,1,1 ! 2-D AXISYMMETRIC THERMAL SURFACE EFFECT ELEMENT
KEYOPT,1,8,1 ! WITH HEAT FLUX LOADS
ET,2,MATRIX50,1 ! RADIATION SUBSTRUCTURE MATRIX (SUPERELEMENT)
N,1
N,2,0.075
E,2,1 ! LOWER SURFACE FOR HEAT FLUX
TYPE,2
SE,CONE,SUB ! READ IN RADIATION SUPERELEMENT
FINISH
/SOLU
ANTYPE,STATIC ! STEADY-STATE THERMAL ANALYSIS
SFE,1,1,HFLUX,,6000 ! APPLY HEAT FLUX LOAD ON SURFACE EFFECT ELEMENT
D,5,TEMP,550,,6
TUNIF,500 ! STARTING UNIFORM TEMPERATURE FOR NONLINEAR SOLUTION
SOLVE
FINISH
/POST1
NSEL,S,NODE,,1,2 ! SELECT LOWER SURFACE NODES
PRNSOL,TEMP ! LIST TEMPERATURES
*GET,T1,NODE,1,TEMP
*STATUS
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'TEMP '
LABEL(1,2) = ' K'
*VFILL,VALUE(1,1),DATA,904
*VFILL,VALUE(1,2),DATA,T1
*VFILL,VALUE(1,3),DATA,ABS(T1/904)
/COM
/OUT,vm147,vrt
/COM,------------------- VM147 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F12.0,' ',F12.0,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm147,vrt



VM148 (Bending of a Parabolic Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM148
/PREP7
/TITLE, VM148, BENDING OF A PARABOLIC BEAM
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 210
ANTYPE,STATIC
ET,1,SOLID95 ! 20 NODE SOLID ELEMENT
MP,EX,1,30E6
MP,EY,1,30E6
MP,EZ,1,30E6
MP,GXY,1,1.5E8
MP,GYZ,1,1.5E8
MP,GXZ,1,1.5E8
MP,NUXY,1,0
MP,NUYZ,1,0
MP,NUXZ,1,0
N,1,.05,SQRT(.05/4) ! NODE CLOSE TO TIP
*DO,I,2,9
N,I,(I-1)/2,SQRT((I-1)/8) ! NEXT EIGHT NODES
*ENDDO
N,11
N,19,4
FILL ! NODES ALONG THE AXIS
NSYMM,Y,20,1,9 ! REFLECT NODES IN Y DIRECTION
NGEN,3,30,1,29,1,,,-.1 ! GENERATE NODES ALONG THICKNESS
E,1,3,23,21,61,63,83,81
EMORE,2,13,22,11,62,73,82,71
EMORE,31,33,53,51
EGEN,4,2,1
F,11,FY,-500,,71,60 ! APPLY END LOAD AT TIP NODES
NSEL,S,LOC,X,4
D,ALL,ALL ! FIX NODES AT SUPPORTED END
NSEL,ALL
OUTPR,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
*GET,UY,NODE,11,U,Y
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Y DELF '
LABEL(1,2) = ' in'
*VFILL,VALUE(1,1),DATA,-.01067
*VFILL,VALUE(1,2),DATA,UY
*VFILL,VALUE(1,3),DATA,ABS(UY/.01067)
/COM
/OUT,vm148,vrt
/COM,------------------- VM148 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F12.5,' ',F12.5,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm148,vrt



VM149 (Rotation of a Tank of Fluid) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM149
/PREP7
SMRT,OFF
/TITLE, VM149, ROTATION OF A TANK OF FLUID
C*** ELEMENTARY THEORETICAL FLUID MECHANICS, BRENKERT, PAGE 54
ANTYPE,STATIC
ET,1,FLUID79,,,1 ! 2-D FLUID ELEMENT (AXISYMMETRIC)
MP,EX,1,3E3 ! BULK MODULUS
MP,DENS,1,9345E-8
K,1
K,2,48
KGEN,2,1,2,1,,-20
L,1,2
*REPEAT,2,2,2
LESIZE,ALL,,,12
L,1,3
*REPEAT,2,1,1
LESIZE,3,,,5
LESIZE,4,,,5
A,1,3,4,2
AMESH,1
ACEL,,386.4 ! GRAVITY
OMEGA,,1 ! CONSTANT ANGULAR VELOCITY
NSEL,R,LOC,X,0 ! CONSTRAIN FLUID TO FORM TANK WALLS
NSEL,A,LOC,X,48
D,ALL,UX
NSEL,ALL
NSEL,R,LOC,Y,-20
D,ALL,UY
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
SET,1,1
ETABLE,PREL,SMISC,1 ! STORE ELEMENT PRESSURES
UY1=UY(1) ! GET THE SURFACE ELEVATION AT X=0
UY26=UY(26) ! GET THE SURFACE ELEVATION AT X=12
UY29=UY(29) ! GET THE SURFACE ELEVATION AT X=24
UY33=UY(33) ! GET THE SURFACE ELEVATION AT X=40
UY26=UY26-UY1 ! ADJUST ELEVATIONS WRT CENTER
UY29=UY29-UY1
UY33=UY33-UY1
*GET,PR60,ELEM,60,ETAB,PREL ! GET PRESSURE FOR (CORNER) ELEMENT 60
*STATUS
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'ELEV (X=, ','ELEV (X=, ','ELEV (X=, ','PRESS, '
LABEL(1,2) = '12) in ','24) in ','40) in ','psi '
*VFILL,VALUE(1,1),DATA,.186,.745,2.070,.695
*VFILL,VALUE(1,2),DATA,UY26,UY29,UY33,PR60
*VFILL,VALUE(1,3),DATA,(UY26/.186),(UY29/.745),(UY33/2.070),(PR60/.695)
/COM
/OUT,vm149,vrt
/COM,------------------- VM149 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm149,vrt





VM150 (Acceleration of a Tank of Fluid) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM150
/PREP7
SMRT,OFF
/TITLE, VM150, ACCELERATION OF A TANK OF FLUID
C*** ELEMENTARY THEORETICAL FLUID MECHANICS, BRENKERT, PAGE 50
ANTYPE,STATIC
ET,1,FLUID80 ! 3-D FLUID ELEMENT
MP,EX,1,30E4 ! BULK MODULUS
MP,DENS,,9.345E-5 ! MASS DENSITY OF FLUID
K,1 ! SOLID MODEL USING KEYPTS, LINES AND VOLUME
K,2,,48
KGEN,2,1,2,1,,,-20
KGEN,2,1,4,1,1
L,1,2
*REPEAT,2,2,2
LESIZE,ALL,,,12
L,1,3
*REPEAT,2,1,1
LESIZE,3,,,5
LESIZE,4,,,5
LGEN,2,1,4,1,1
L,1,5
*REPEAT,2,1,1
LESIZE,9,,,1
LESIZE,10,,,1
V,1,2,4,3,5,6,8,7
VMESH,1
ACEL,,45,386.4 ! ACCELERATION OF TANK AND GRAVITY
NSEL,R,LOC,Z,-20 ! CONSTRAIN FLUID TO FORM TANK WALLS
D,ALL,UZ
NSEL,ALL
NSEL,R,LOC,Y,0
NSEL,A,LOC,Y,48
D,ALL,UY
NSEL,ALL
D,ALL,UX
FINISH
/SOLU
SOLVE
FINISH
/POST1
SET,1,1
ETABLE,PREL,SMISC,1 ! ELEMENT PRESSURE
NSEL,S,LOC,Y,8 ! SELECT 3 NODES ON LIQUID SURFACE
NSEL,A,LOC,Y,24
NSEL,A,LOC,Y,40
NSEL,R,LOC,Z,0
NSEL,R,LOC,X,0
PRNSOL,U,COMP ! PRINT DISPLACEMENTS ALONG SURFACE
NSEL,S,LOC,Z,-20 ! SELECT BOTTOM CORNER NODE
NSEL,R,LOC,Y,0
ESLN ! SELECT ASSOCIATED ELEMENT
PRETAB,PREL ! PRINT ELEMENT PRESSURE ITEM
NSEL,S,LOC,Y,8 ! SELECT TWO NODES ALONG FREE SURFACE
NSEL,A,LOC,Y,40 ! AT Y=8 AND Y=40 RESP. AND X=0
NSEL,R,LOC,Z
NSEL,R,LOC,X
*GET,N1,NODE,,NUM,MIN ! GET THE NODE NUMBERS SELECTED
*GET,N2,NODE,,NUM,MAX
Z1=UZ(N1) ! GET THE ELEVATIONS AT THESE NODES
Z2=UZ(N2)
Y1=NY(N1) ! GET THE Y COORDINATE
Y2=NY(N2)
SLOPE=((Z1-Z2)/(Y1-Y2)) ! FIND AVG. SLOPE OF LIQUID SURFACE
*GET,PR5,ELEM,5,ETAB,PREL
*STATUS
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'ELEV (Y=, ','ELEV (Y=, ','SLOPE, ','PRESS, '
LABEL(1,2) = '8) in ','40) in ',' ', 'psi '
*VFILL,VALUE(1,1),DATA,1.863,-1.863,-.1164,.7425
*VFILL,VALUE(1,2),DATA,Z1,Z2,SLOPE,PR5
*VFILL,VALUE(1,3),DATA,ABS(Z1/1.863),ABS(Z2/1.863),ABS(SLOPE/.1164),ABS(PR5/.7425)
/COM
/OUT,vm150,vrt
/COM,------------------- VM150 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.4,' ',F11.4,' ',1F6.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm150,vrt






VM151 (Nonaxisymmetric Vibration of a Circular Plate) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM151
/PREP7
MP,PRXY,,0.3
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM151, NONAXISYMMETRIC VIBRATION OF A CIRCULAR PLATE
C*** FORMULAS FOR NATURAL FREQUENCY AND MODE SHAPE, BLEVINS, PAGE 240
ET,1,SHELL61
R,1,.05 ! THICKNESS OF PLATE
MP,EX,1,30E6
MP,DENS,1,.00073
MP,PRXY,1,0.3
K,1
K,2,3
L,1,2
LESIZE,1,,,9
LMESH,1
M,ALL,UY
NSEL,S,LOC,X,0
D,ALL,UX
NSEL,S,LOC,X,3 ! SELECT NODE AT R=3 AND CONSTRAIN
D,ALL,UX,,,,,UY
NSEL,ALL
D,ALL,UZ ! CONSTRAIN TORSIONAL DOF'S
FINISH
/SOLU
ANTYPE,MODAL ! MODE FREQUENCY ANALYSIS
MXPAND,3 ! EXPAND FIRST 3 MODE SHAPES
MODOPT,REDUC
OUTPR,BASIC,ALL
MODE,0 ! ZERO HARMONIC MODE
SOLVE
FINISH
/POST1
/WINDOW,1,LTOP
SET,1,1
PLDISP,1
/NOERASE
/WINDOW,1,OFF
*GET,F1,MODE,0,FREQ
FINISH
/SOLU
MODE,1 ! FIRST HARMONIC MODE
SOLVE
FINISH
/POST1
/WINDOW,2,RTOP
SET,1,1
PLDISP,1
/WINDOW,2,OFF
*GET,F2,MODE,1,FREQ
FINISH
/SOLU
MODE,2 ! SECOND HARMONIC MODE
SOLVE
FINISH
/POST1
/WINDOW,3,BOT
SET,1,1
PLDISP,1
*GET,F3,MODE,1,FREQ
*STATUS
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'F(0,1) ','F(1,1) ','F(1,2) '
LABEL(1,2) = 'Hz ','Hz ','Hz '
*VFILL,VALUE(1,1),DATA,269.96,756.13,1391.3
*VFILL,VALUE(1,2),DATA,F1,F2,F3
*VFILL,VALUE(1,3),DATA,ABS(F1/269.96),ABS(F2/756.13),ABS(F3/1391.3)
/COM
/OUT,vm151,vrt
/COM,------------------- VM151 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.2,' ',F11.2,' ',1F6.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm151,vrt


VM152 (2-D Non-axisymmetric Vibration of a Stretched Circular Membrane (Using Harmonic Elements)) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM152
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM152, NONAXISYM. VIBR. OF A STRETCHED CIRCULAR MEMBRANE (HARMONIC ELS)
C*** VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., ART. 69, PAGE 438
ET,1,SHELL61
R,1,.00005 ! PLATE THICKNESS
MP,EX,1,30E6
MP,ALPX,1,1E-5
MP,DENS,1,.00073
MP,NUXY,1,0
K,1 ! DEFINE GEOMETRY
K,2,3
L,1,2
LESIZE,1,,,9
LMESH,1
NSEL,S,LOC,X,0
D,ALL,UX
NSEL,S,LOC,X,3
D,ALL,UX,,,,,UY
NSEL,ALL
M,ALL,UY
D,ALL,UZ
TREF,0 ! REFERENCE (STRESS-FREE) TEMPERATURE
BFUNIF,TEMP,-(20/3) ! COOL MEMBRANE TO INVOKE PRESOLESS
FINISH
/SOLU
ANTYPE,STATIC
PSTRES,ON ! STATIC PRESTRESS ANALYSIS
OUTPR,BASIC,ALL
SOLVE
FINISH
/SOLU
ANTYPE,MODAL
PSTRES,ON ! PRESTRESSED MODAL ANALYSIS
MXPAND,3
MODOPT,REDUC
MODE,0 ! ZERO HARMONIC MODE
SOLVE
FINISH
/POST1
/WINDOW,1,LTOP
SET,1,1 ! FOR WINDOW 1
PLDISP,1
/NOERASE
*GET,F11,MODE,0,FREQ
/WINDOW,1,OFF
/WINDOW,4,RBOT
SET,1,2 ! FOR 4TH WINDOW
PLDISP,1
*GET,F12,MODE,2,FREQ
/WINDOW,4,OFF
FINISH
/SOLU
MODE,1 ! FIRST HARMONIC MODE
SOLVE
FINISH
/POST1
/WINDOW,2,RTOP
SET,1,1
PLDISP,1
*GET,F21,MODE,0,FREQ
/WINDOW,2,OFF
FINISH
/SOLU
MODE,2 ! SECOND HARMONIC MODE
SOLVE
FINISH
/POST1
/WINDOW,3,LBOT
SET,1,1
PLDISP,1
*GET,F31,MODE,0,FREQ
*STATUS
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'F(0,1) ','F(1,1) ','F(2,1) ','F(0,2) '
LABEL(1,2) = 'Hz ','Hz ','Hz ','Hz '
*VFILL,VALUE(1,1),DATA,211.1,336.5,450.9,484.7
*VFILL,VALUE(1,2),DATA,F11,F21,F31,F12
*VFILL,VALUE(1,3),DATA,ABS(F11/211.1),ABS(F21/336.5),ABS(F31/450.9),ABS(F12/484.7)
/COM
/OUT,vm152,vrt
/COM,------------------- VM152 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.1,' ',F11.1,' ',1F6.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm152,vrt


VM153 (3-D Non-axisymmetric Circular Membrane (Using Cyclic Symmetry)) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM153
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/FILNAM,PRSMEMB
/PREP7
/TITLE, VM153, NONAXISYM. VIBR. OF A STRETCHED CIRCULAR MEMBRANE (STATIC)
! VIBRATION PROBS. IN ENGR., TIMOSHENKO, PAGE 439, ARTICLE 69
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,SHELL41,,1
R,1,.00005 ! PLATE THICKNESS
MP,EX,1,30E6
MP,ALPX,1,1E-5
MP,DENS,1,.00073
MP,NUXY,1,0
CSYS,1
N,1,.001
N,10,3
FILL
NGEN,4,10,1,10,1,,10
NROTAT,ALL ! ROTATE ALL NODES INTO CYLINDRICAL SYSTEM
E,1,2,12,11
EGEN,3,10,-1
EGEN,9,1,-3
NSEL,S,LOC,Y,0 ! DEFINE EDGE COMPONENTS FOR CYCLIC SYMM. MACRO
CM,RIGHT,NODE ! RIGHT EDGE OF THE SECTOR MODEL
NSEL,S,LOC,Y,30
CM,LEFT,NODE ! LEFT EDGE OF THE SECTOR MODEL
NSEL,ALL
/NOPR
CYCGEN ! CREATE DUPLICATE SECTOR
/GOPR
D,ALL,ALL,0 ! FIX ALL DISPLACEMENTS TO APPLY PRESTRESS
TREF,0 ! REFERENCE TEMPERATURE
BFUNIF,TEMP,-6.66666 ! COOL DOWN TO INDUCE PRESTRESS
FINISH
/SOLU ! SOLVE FOR STATIC SOLUTION
PSTRES,ON ! PRESTRESS KEY ON
SOLVE
FINISH

/PREP7
/TITLE, VM153, NONAXISYM. VIBR. OF A STRETCHED CIRCULAR MEMBRANE (MODAL)
ANTYPE,MODAL ! DEFINE MODAL ANALYSIS OPTIONS
MODOPT,LANB,4,1,1000,,,,2 ! USE BLOCK LANCZOS ITER, EXTRACT 4 MODES IN
! 1 TO 1000 HZ, LAGRANGE MULITPLIER METHOD FOR CEQNS
MXPAND,4 ! EXPAND 4 MODES
PSTRES,ON
DDEL,ALL,ALL ! RELEASE ALL DISPLACEMENTS AND THEN
NSEL,S,LOC,Y,0 ! DEFINE BOUNDARY CONDITIONS
NSEL,A,LOC,Y,30
D,ALL,UX,,,,,UY
NSEL,S,LOC,X,3
D,ALL,ALL,0
NSEL,ALL
FINISH

/SOLUTION
/OUTPUT,SCRATCH
CYCSOL,0,1,12,'RIGHT' ! MACRO, NODAL DIAMETER 0 TO 1, WITH 30 DEG. SECTORS
/OUTPUT
FINISH

/POST1
SET,1,1
*GET,F01_1,ACTIVE,,SET,FREQ ! NATURAL FREQ. FOR 1ST MODE, 0 MODAL DIAM.
SET,1,2
*GET,F02_1,ACTIVE,,SET,FREQ ! NATURAL FREQ. FOR 2ND MODE, 0 MODAL DIAM.
SET,2,1
*GET,F11_1,ACTIVE,,SET,FREQ ! NATURAL FREQ. FOR 1ST MODE, 1 MODAL DIAM.
SET,2,2
*GET,F11_2,ACTIVE,,SET,FREQ ! REPEATED FREQ. FOR 1ST MODE, 1 MODAL DIAM.
SET,2,3
*GET,F12_1,ACTIVE,,SET,FREQ ! NATURAL FREQ. FOR 2ND MODE, 1 MODAL DIAM.
SET,2,4
*GET,F12_2,ACTIVE,,SET,FREQ ! REPEATED FREQ. FOR 2ND MODE, 1 MODAL DIAM.
FINISH

/NOPR

/POST1
EXPAND,12 ! EXPAND RESULTS FOR THE FULL 12 SECTOR MODEL

/VIEW,,1,1,1
/VUP,1,Z
/GLINE,,-1 ! NO ELEMENT OUTLINE
/TRIAD,OFF

SET,1,2
/TITLE, VM153, STRETCHED CIRCULAR MEMBRANE - NODAL DIAM 0, MODE 2
PLNSOL,U,Z

SET,2,2
/TITLE, VM153, STRETCHED CIRCULAR MEMBRANE - NODAL DIAM 1, MODE 2
PLNSOL,U,Z
FINISH

*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'F(0,1) ','F(0,2) ','F(1,1) ','F(1,2) '
LABEL(1,2) = 'Hz ','Hz ','Hz ','Hz '
*VFILL,VALUE(1,1),DATA,211.1,484.7,336.5,616.1
*VFILL,VALUE(1,2),DATA,F01_1,F02_1,F11_1,F12_1
*VFILL,VALUE(1,3),DATA,ABS(F01_1/211.1),ABS(F02_1/484.7),ABS(F11_1/336.5),ABS(F12_1/616.1)
/COM
/OUT,vm153,vrt
/COM,------------------- VM153 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.1,' ',F11.1,' ',1F6.3)
/COM,----------------------------------------------------------
/OUT
/DELETE,PRSMEMB,tri
/DELETE,PRSMEMB,emat
/DELETE,PRSMEMB,esav
/DELETE,PRSMEMB,full
/DELETE,PRSMEMB,mode
/DELETE,PRSMEMB,rst
/DELETE,SCRATCH
*LIST,vm153,vrt


VM154 (Vibration of a Fluid Coupling) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM154
/PREP7
/TITLE, VM154, VIBRATION OF A FLUID COUPLING
C*** FRITZ, ASME J. OF ENG. FOR INDUST., VOL. 94, 1972, PP 167-173.
C*** USING FLUID COUPLING ELEMENTS (FLUID38)
ANTYPE,MODAL ! MODE-FREQUENCY ANALYSIS
MODOPT,REDUC
ET,1,FLUID38
ET,2,COMBIN14,,1 ! ELEMENT WITH UX DEGREE OF FREEDOM
R,1,8,7,1 ! GEOMETRIC PROPERTIES OF FLUID38
R,2,10 ! SPRING STIFFNESS
MP,DENS,1,934E-7
N,1
N,2
E,1,2
REAL,2
TYPE,2
E,1,2 ! TYPE 2 ELEMENT WITH REAL CONSTANT 2
M,1,UX
OUTPR,,1
D,1,UZ
D,2,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
*GET,F1,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'f FLD38 '
LABEL(1,2) = 'Hz'
*VFILL,VALUE(1,1),DATA,1.5293
*VFILL,VALUE(1,2),DATA,F1
*VFILL,VALUE(1,3),DATA,ABS(F1/1.5293)
SAVE,TABLE_1
FINISH
/SOLU
FINISH
/CLEAR, NOSTART
/PREP7
/TITLE, VM154, VIBRATION OF A FLUID COUPLING
C*** USING HARMONIC FLUID ELEMENTS (FLUID81)
ANTYPE,MODAL ! MODE-FREQUENCY ANALYSIS
MODOPT,REDUC
ET,1,FLUID81
ET,2,COMBIN14,,,2 ! 2-D LONGITUDINAL SPRING
R,2,10 ! HARMONIC SPRING CONSTANT
MP,EX,1,3E5
MP,DENS,1,934E-7
N,1,7
N,2,8
N,3,8,1
N,4,7,1
N,11
N,14,,1
E,1,2,3,4
TYPE,2
REAL,2
E,11,1 ! TYPE 2 ELEMENTS WITH REAL CONSTANT 2
E,14,4
NSEL,S,LOC,X,7
CP,1,UX,ALL ! APPROPRIATE NODAL DISPLACEMENTS COUPLED
NSEL,S,NODE,,1,4
CP,2,UZ,ALL
NSEL,ALL
M,1,UX
MODE,1
NSEL,S,LOC,X,8
D,ALL,UX ! APPLY DISPLACEMENT CONSTRAINTS
NSEL,S,NODE,,1,4
D,ALL,UY
NSEL,S,LOC,X,0
D,ALL,ALL
NSEL,ALL
FINISH
/SOLU
SOLVE
FINI
/POST1
*GET,F2,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'f FLD81 '
LABEL(1,2) = 'Hz'
*VFILL,VALUE(1,1),DATA,1.5293
*VFILL,VALUE(1,2),DATA,F2
*VFILL,VALUE(1,3),DATA,ABS(F2/1.5293)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm154,vrt
/COM,------------------- VM154 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.4,' ',F11.4,' ',1F6.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.4,' ',F11.4,' ',1F6.3)
/COM,----------------------------------------------------------
FINISH
/DELETE,TABLE_1
/DELETE,TABLE_2
/OUT
FINISH
*LIST,vm154,vrt


VM155 (Shape Optimization of a Cantilever Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM155
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
TK16=.25 ! SET INITIAL VALUES OF DESIGN VARIABLES
TK27=.25 ! THICKNESS AT ONE FOURTH LENGTH
TK38=.25 ! THICKNESS AT ONE HALF LENGTH
TK49=.25 ! THICKNESS AT THREE FOURTHS LENGTH
/PREP7
smrt,off
/TITLE,VM155: SHAPE OPTIMIZATION OF A CANTILEVER BEAM
/COM
/COM
/COM, REF. B. PRASAD AND R.T.HAFTKA
/COM, OPT. STRUCT. DESIGN WITH PLATE FINITE ELEMENTS
/COM, ASCE JOURNAL OF THE STRUCT. DIVISION
/COM, VOL. 105 (ST11) 1979 PP2367-2382
/COM
ET,1,PLANE42
MP,EX,1,10E6
MP,NUXY,1,0.3
K,1
K,5,10
KFILL
K,6,,TK16 ! DEFINE KEYPOINTS IN TERMS OF DESIGN VARIABLES
K,7,2.5,TK27
K,8,5,TK38
K,9,7.5,TK49
K,10,10,.15
SPLINE,6,7,8,9,10 ! DEFINE TOP EDGE WITH A SPLINE
L,1,6
*REPEAT,5,1,1
LSEL,S,LINE,,5,9
LESIZE,ALL,,,1
LSEL,ALL
A,1,2,7,6
*REPEAT,4,1,1,1,1
ESIZE,,4
AMESH,ALL
NSEL,S,LOC,Y
DSYM,SYMM,X
NSEL,S,LOC,X
DSYM,ASYM,Y
NSEL,ALL
FK,10,FX,1500 ! APPLY END COUPLE TO KEYPOINT
DK,1,ALL,0 ! FIX NODE AT KEYPOINT #1
FINISH
/SOLU
SOLVE
FINISH
/POST1
SET,LAST
ETABLE,VOLU,VOLU
PRNSOL,S,PRIN
NSORT,S,1 ! GET MAXIMUM STRESS
NSEL,S,LOC,X,0,9 ! IGNORE LOCAL STRESSES @ POINT OF LOAD
*GET,STRS,SORT,,MAX
NSEL,ALL
SSUM
*GET,TVOL,SSUM,,ITEM,VOLU ! TVOL = TOTAL VOLUME OF ELEMENTS
TVOL=TVOL*2 ! MULTIPLY BY TWO FOR SYMMETRY
NSEL,S,LOC,X,9.9,10.1
PRNSOL,U,Y
NSORT,U,Y,,1
PRNSOL,U,Y
*GET,DEFL,SORT,,MAX
*STATUS
DEFL=ABS(DEFL) ! USE ABS. VALUE OF MAX END DEFLECTION
/COM DEFINE STATE VARIABLES TO ENSURE CONSISTENT TAPER
DIF1=TK16-TK27
DIF2=TK27-TK38
DIF3=TK38-TK49
FINISH
/OPT
OPVAR,TVOL,OBJ,,,.01 ! OBJECTIVE FUNCTION
OPVAR,STRS,SV,,30000 ! STATE VARIABLES
OPVAR,DEFL,SV,,0.50
OPVAR,DIF1,SV,0,.1
OPVAR,DIF2,SV,0,.1
OPVAR,DIF3,SV,0,.1
OPVAR,TK16,DV,0.15,0.27,.001 ! DESIGN VARIABLES
OPVAR,TK27,DV,0.15,0.27,.001
OPVAR,TK38,DV,0.15,0.27,.001
OPVAR,TK49,DV,0.15,0.27,.001
OPSAVE,INITIAL,OPT ! SAVE INITIAL DESIGN
OPTYPE,SUBP ! OPT METHOD IS SUBPROBLEM APPROX.
OPSUBP,30 ! OPTIMIZE FOR 30 ITERATIONS (MAX)
OPEXE ! PERFORM SUB-PROBLEM APPROX. OPTIMIZATION
VR1=TVOL
VR2=DEFL
VR3=STRS
PARSAV,,RSET1
OPLIST,ALL,,1 ! LIST DESIGN SETS
/AXLAB,Y,VOLUME (TVOL) ! OBJECTIVE FUNCTION ALONG Y-AXIS
PLVAROPT,TVOL ! PLOT OBJECTIVE CONVERGENCE
OPRESU,INITIAL,OPT ! RESUME INITIAL DESIGN SET
OPVAR,DIF1,DEL ! DELETE ARTIFICIAL CONSTRAINTS
OPVAR,DIF2,DEL ! FOR FIRST ORDER METHOD
OPVAR,DIF3,DEL
OPTYPE,FIRST ! SPECIFY FIRST-ORDER METHOD
OPFRST,20 ! WITH MAXIMUM OF 20 ITERATIONS
STATUS
OPEXE ! PERFORM FIRST-ORDER OPTIMIZATION
VR4=TVOL
VR5=DEFL
VR6=STRS
OPLIST,ALL,,1 ! LIST DESIGN SETS
/AXLAB,Y,VOLUME (TVOL) ! OBJECTIVE FUNCTION ALONG Y-AXIS
PLVAROPT,TVOL ! PLOT OBJECTIVE CONVERGENCE
FINISH
PARRES,CHANGE,RSET1
*DIM,LABEL1,CHAR,3
*DIM,LABEL2,CHAR,3
*DIM,VALUE1,,3,3
*DIM,VALUE2,,3,3
LABEL1(1) = 'TVOL ','DEFL ','STRS '
LABEL2(1) = 'TVOL ','DEFL ','STRS '
*VFILL,VALUE1(1,1),DATA,3.60,0.500,30000
*VFILL,VALUE1(1,2),DATA,VR1,VR2,VR3
*VFILL,VALUE1(1,3),DATA,(VR1/3.6),(VR2/0.5),(VR3/30000)
*VFILL,VALUE2(1,1),DATA,3.60,0.500,30000
*VFILL,VALUE2(1,2),DATA,VR4,VR5,VR6
*VFILL,VALUE2(1,3),DATA,(VR4/3.6),(VR5/0.5),(VR6/30000)
/OUT,vm155,vrt
/COM
/COM,------------------- VM155 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM, SUBPROBLEM APPROX. METHOD
/COM,
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),VALUE1(1,3)
(1X,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,
/COM, FIRST ORDER METHOD
/COM.
*VWRITE,LABEL2(1),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------------
/OUT
/DELETE,INITIAL,OPT
FINISH
*LIST,vm155,vrt


VM156 (Natural Frequency of a Nonlinear Spring-Mass System) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM156
/PREP7
/TITLE, VM156, NATURAL FREQUENCY OF NONLINEAR SPRING-MASS SYSTEM
C*** VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 141
C*** USING NONLINEAR SPRING ELEMENT (COMBIN39)
ANTYPE,TRANS ! NONLINEAR TRANSIENT DYNAMIC ANALYSIS
ET,1,COMBIN39,,,2 ! ELEMENT WITH DISPLACEMENT ALONG NODAL Y-AXIS
ET,2,MASS21,,,4 ! MASS WITHOUT ROTARY INERTIA
R,1,0.0,0.0,.1,.204,.2,.432 ! SPRING DATA
RMORE,.3,.708,.4,1.056,.5,1.5
RMORE,.6,2.064,.7,2.772,.8,3.648
RMORE,.9,4.716,1.0,6.0
R,2,2588E-6 ! MASS DATA
N,1
N,2
E,1,2
TYPE,2
REAL,2
E,2
D,1,ALL
D,2,UX
IC,2,UY,-1 ! INITIAL DISPLACEMENT AND VELOCITY
KBC,1 ! STEP LOADING
SAVE
FINISH
/SOLU
SOLCONTROL,0
CNVTOL,F,1,1E-4 ! FORCE CONVERGENCE CRITERIA
OUTRES,NSOL,1
NSUBST,5
OUTPR,BASIC,NONE
TIME,.0002 ! TIME TO ALLOW INITIAL CHANGE IN ACCELERATION
LSWRITE ! WRITE LOAD STEP FILE 1
NSUBST,40
OUTPR,BASIC,LAST
TIME,0.18 ! TIME ARBITRARILY SELECTED
LSWRITE ! WRITE LOAD STEP FILE 2
LSSOLVE,1,2,1 ! READ IN 2 LOAD STEPS AND SOLVE
FINISH
/POST26
TIMERANGE,.003,.18
NSOL,2,2,U,Y,2UY
PRVAR,2 ! PRINT DISPLACEMENTS
*GET,PER,VARI,2,EXTREM,TMIN
*STATUS
FINISH
/POST1
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'PERIOD '
LABEL(1,2) = 'sec'
*VFILL,VALUE(1,1),DATA,.1447
*VFILL,VALUE(1,2),DATA,PER
*VFILL,VALUE(1,3),DATA,ABS(PER/.1447)
SAVE,TABLE_1
FINISH
/CLEAR,NOSTART
RESUME
/PREP7
C*** USING NONLINEAR ELASTIC MATERIAL (SPAR ELEMENT, LINK1)
ET,1,LINK1
R,1,.01 ! CROSS-SECTIONAL AREA
NROPT,MODI ! MODIFIED NEWTON-RAPHSON METHOD
MP,EX,1,12E4
TB,MELAS,1,1,5
TBTEMP,0
TBPT,DEFI,0.002,43.2
TBPT,DEFI,0.004,105.6
TBPT,DEFI,0.006,206.4
TBPT,DEFI,0.008,364.8
TBPT,DEFI,0.01,600
N,2,,-100 ! REDEFINE NODE 2
FINISH
/SOLU
LSSOLVE,1,2,1 ! READ IN LOAD STEPS AND SOLVE
FINISH
/POST26
TIMERANGE,.003,.18
NSOL,2,2,U,Y,2UY
PRVAR,2 ! PRINT DISPLACEMENTS
*GET,PER,VARI,2,EXTREM,TMIN
*STATUS
FINISH
/POST1
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'PERIOD '
LABEL(1,2) = 'sec'
*VFILL,VALUE(1,1),DATA,.1447
*VFILL,VALUE(1,2),DATA,PER
*VFILL,VALUE(1,3),DATA,ABS(PER/.1447)
SAVE,TABLE_2
RESUME,TABLE_1
/OUT,vm156,vrt
/COM,------------------- VM156 RESULTS COMPARISON --------------
/COM,
/COM, STIF39 | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM, STIF1
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
/COM,
FINISH
/DELETE,TABLE_1
/DELETE,TABLE_2
FINISH
*LIST,vm156,vrt


VM157 (Optimization of a Frame Structure) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
D1=0.1
D2=0.1
/VERIFY,VM157
/PREP7
MP,PRXY,,0.3
/TITLE, VM157: OPTIMIZATION OF A FRAME STRUCTURE
/COM REF. TOPPING AND ROBINSON, ENG.COMPUT., 1984, VOL.1, PP. 252-262
ANTYPE,STATIC
ET,1,BEAM3
C*** SET THE REAL CONSTANTS USING PARAMETRIC EXPRESSIONS
K=825000.0 ! DEFINE CONVENIENT PARAMETERS
D1CB=D1**3
D2CB=D2**3
R,1,(D1**2)/2,D1*(D1CB/24),D1
R,2,(D2**2)/2,D2*(D2CB/24),D2
MP,EX,1,1E10
N,1
N,2,,2.5
N,3,2.16506,3.75
REAL,1
E,1,2
REAL,2
E,2,3
D,1,ALL,0
F,3,FY,-2000 ! HALF LOAD DUE TO SYMMETRY
NSEL,S,LOC,X,2.1,2.2
DSYM,SYMM,X
NSEL,ALL
DLIST,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
ETABLE,VOLU,VOLU
ETABLE,MI,SMISC,6
ETABLE,MJ,SMISC,12
*GET,M11,ELEM,1,ETAB,MI
*GET,M21,ELEM,1,ETAB,MJ
*GET,M12,ELEM,2,ETAB,MI
*GET,M22,ELEM,2,ETAB,MJ
*STATUS
LIM1=D1CB*K ! BENDING MOMENT LIMITS
LIM2=D2CB*K
M11L=LIM1-(ABS(M11))
M21L=LIM1-(ABS(M21))
M12L=LIM2-(ABS(M12))
M22L=LIM2-(ABS(M22))
SSUM
*GET,TVOL,SSUM,,ITEM,VOLU
TVOL=TVOL*2
FINISH
/OPT
OPVAR,D1,DV,.05,.5 ! DESIGN VARIABLES
OPVAR,D2,DV,.05,.5
OPVAR,M11L,SV,0,2000 ! STATE VARIABLES
OPVAR,M21L,SV,0,2000
OPVAR,M12L,SV,0,2000
OPVAR,M22L,SV,0,2000
OPVAR,TVOL,OBJ,,,.00001 ! OBJECTIVE FUNCTION
OPTYPE,SUBP
OPSUBP,15
OPPRNT,ON
OPEXE
OPLIST,ALL,,1
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'VOL ','DIS(1) ','DIS(2) '
LABEL(1,2) = 'CUB m','m','m'
*VFILL,VALUE(1,1),DATA,.0764,.118,.129
*VFILL,VALUE(1,2),DATA,TVOL,D1,D2
*VFILL,VALUE(1,3),DATA,(TVOL/.0764),(D1/.118),(D2/.129)
/COM
/OUT,vm157,vrt
/COM,------------------- VM157 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F7.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm157,vrt


VM158 (Motion of a Bobbing Buoy) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM158
/PREP7
MP,PRXY,,0.3
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM158, MOTION OF A BOBBING BUOY
C*** ELEMENTARY THEORETICAL FLUID MECHANICS, BRENKERT, PAGE 37
ANTYPE,TRANS
NLGEOM,ON ! LARGE DISPLACEMENTS
ET,1,PIPE59,,,,,,,1
R,1,1,.03 ! DIAMETER, WALL THICKNESS
RMORE,,,,.3 ! DRAG COEFFICIENT
MP,EX,1,21E10
MP,DENS,1,8000
MP,PRXY,1,0.3
TB,WATER,1
TBDATA,3,30 ! DEPTH
TBDATA,4,1000 ! WATER DENSITY
N,1,,,-9
N,7,,,1
FILL
E,1,2
EGEN,6,1,1
FINISH
/SOLU
NSUBST,20 ! 20 SUBSTEPS
CNVTOL,U ! CONVERGENCE BASED ON DISPLACEMENTS
CNVTOL,F ! CONVERGENCE BASED ON FORCES
OUTPR,BASIC,LAST
OUTRES,NSOL,1
KBC,1
ALPHAD,3 ! MASS DAMPING FOR SLOW DYNAMICS
ACEL,,,9.807
D,1,UX,,,7,,UY,ROTX,ROTY,ROTZ ! CONSTRAIN ALL BUT UZ DOF
TIME,30
SOLVE
FINISH
/POST26
NSOL,2,1,U,Z
PRVAR,2
/GRID,1
/AXLAB,Y,DISP
PLVAR,2 ! DISPLAY TOP DISPLACEMENT VS. TIME
*GET,DISP,VARI,2,RTIME,30
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'DISP '
LABEL(1,2) = 'm '
*VFILL,VALUE(1,1),DATA,-.312
*VFILL,VALUE(1,2),DATA,DISP
*VFILL,VALUE(1,3),DATA,ABS(DISP/.312)
/COM
/OUT,vm158,vrt
/COM,------------------- VM158 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F6.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm158,vrt


VM159 (Temperature-controlled Heater) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM159
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM159, TEMPERATURE CONTROLLED HEATER
C*** REFERENCE - SELF-CHECKING (RESPONSE FOLLOWS INPUT REQUEST)
ANTYPE,TRANS
ET,1,MASS71,,,1 ! THERMAL MASS
ET,2,LINK34 ! CONVECTION ELEMENT
ET,3,COMBIN37,,,8,,1 ! CONTROL ELEMENT
R,1,2.7046E-4 ! THERMAL CAPACITANCE OF HEATER
R,2,2.7046E-3 ! THERMAL CAPACITANCE OF BOX
R,3,8.1812E-3 ! SURFACE AREA OF HEATER
R,4,4.1666E-2 ! SURFACE AREA OF BOX
R,5,,,,100,125,-10 ! CONTROL TEMPERATURES, HEAT FLOW
RMORE,,1 ! INITIAL CONTROL STATUS (ON)
MP,HF,1,4
N,1
*REPEAT,4,1
E,1 ! HEATER
TYPE,2
REAL,3
E,1,2 ! CONVECTION LINK
TYPE,1
REAL,2
E,2 ! BOX
TYPE,3
REAL,5
E,4,1,2 ! CONTROL
TYPE,2
REAL,4
E,2,3 ! CONVECTION LINK
FINISH
/SOLU
SOLCONTROL,0
TIME,.2
IC,1,TEMP,70 ! UNIFORM STARTING TEMPERATURE
IC,2,TEMP,70
KBC,1
D,3,TEMP,70
D,4,TEMP,0
AUTOTS,ON
OUTPR,,10
OUTRES,,ALL
DELTIM,0.001
SOLVE
FINISH
/POST26
NSOL,2,1,TEMP
NSOL,3,2,TEMP
ESOL,4,4,,NMISC,1,STAT
PRVAR,2,3,4
/GRID,1 ! DISPLAY BOX TEMP VS. TIME
/AXLAB,Y,TEMP
PLVAR,3
/GRID,0 ! DISPLAY STATUS VS. TIME
/AXLAB,Y,STAT
PLVAR,4
FINISH
/OUT,vm159,vrt
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM159 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm159,vrt


VM160 (Solid Cylinder with Harmonic Temperature Load) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM160
/PREP7
/TITLE, VM160, SOLID CYLINDER WITH HARMONIC TEMPERATURE LOAD
C*** HILDEBRAND, ADVANCED CALCULUS FOR APPLICATIONS, PAGE 447
ET,1,PLANE78 ! AXISYMMETRIC THERMAL SOLID
MP,KXX,1,1
N,1
N,9,20
FILL
NGEN,3,10,1,9,1,,2.5
E,1,3,23,21,2,13,22,11
EGEN,4,2,1
D,9,TEMP,80,,29,10 ! PEAK TEMPERATURE AT THETA=0
MODE,2,1 ! SYMMETRIC MODE WITH 2 WAVES AROUND PERIPHERY
FINISH
/SOLU
OUTPR,ALL,LAST ! PRINTOUT ELEMENT SOLUTION
SOLVE
FINISH
/POST1
SET,1,1,,,,0.0 ! STORE SOLUTION DATA AT 0 DEGREES
NSEL,S,NODE,,1,9 ! SELECT NODES 1-9
*GET,T1,NODE,1,TEMP
*GET,T2,NODE,3,TEMP
*GET,T3,NODE,5,TEMP
*GET,T4,NODE,7,TEMP
PRNSOL,TEMP ! PRINT TEMPERATURE
SET,1,1,,,,90.0 ! STORE SOLUTION DATA AT 90 DEGREES
*GET,T5,NODE,1,TEMP
*GET,T6,NODE,3,TEMP
*GET,T7,NODE,5,TEMP
*GET,T8,NODE,7,TEMP
PRNSOL,TEMP ! PRINT TEMPERATURE
*STATUS
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'T (ND=1) ','T (ND=3) ','T (ND=5) ','T (ND=7)'
LABEL(1,2) = 'F','F','F','F'
*VFILL,VALUE(1,1),DATA,0,5,20,45
*VFILL,VALUE(1,2),DATA,T1,T2,T3,T4
*VFILL,VALUE(1,3),DATA,ABS(0),ABS(T2/5),ABS(T3/20),ABS(T4/45)
/COM
/OUT,vm160,vrt
/COM,------------------- VM160 RESULTS COMPARISON -------------
/COM,
/COM,THETA=0 | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F8.3)
/NOPR
*VFILL,VALUE(1,1),DATA,0,-5,-20,-45
*VFILL,VALUE(1,2),DATA,T5,T6,T7,T8
*VFILL,VALUE(1,3),DATA,ABS(0),ABS(T6/5),ABS(T7/20),ABS(T8/45)
/GOPR
/COM,
/COM,THETA=90 | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F8.3)
/COM,---------------------------------------------------------
/OUT
FINISH
*LIST,vm160,vrt


VM161 (Heat Flow From an Insulated Pipe) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM161
/PREP7
/TITLE, VM161, HEAT FLOW FROM AN INSULATED PIPE
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 36, EX. 2-7
ANTYPE,STATIC
ET,1,SOLID90
MP,KXX,1,25
MP,KXX,2,.11
CSYS,1 ! CYLINDRICAL C.S.
N,1,.12791666
N,2,.14583333
N,3,.1875
NGEN,3,3,1,3,1,,15
NGEN,3,10,1,9,1,,,.5
E,1,21,27,7,2,22,28,8
EMORE,11,24,17,4,12,25,18,5
EMORE,30,34,36,32
EGEN,2,1,1
MAT,2
EMODIF,2
NSEL,S,LOC,X,.12791666
SF,ALL,CONV,40,300 ! CONVECTION ON THE INSIDE
NSEL,S,LOC,X,.1875
SF,ALL,CONV,4,80 ! CONVECTION ON THE OUTSIDE
NSEL,ALL
OUTPR,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
SET,1,1
ESEL,S,ELEM,,1,1
FSUM,HEAT
*GET,Q1,FSUM,0,ITEM,HEAT
*SET,Q,ABS((Q1*360/30))
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'q '
LABEL(1,2) = 'BTU/hr'
*VFILL,VALUE(1,1),DATA,362
*VFILL,VALUE(1,2),DATA,Q
*VFILL,VALUE(1,3),DATA,ABS(Q/362)
/COM
/OUT,vm161,vrt
/COM,------------------- VM161 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm161,vrt


VM162 (Cooling of a Circular Fin of Rectangular Profile) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM162
/PREP7
/TITLE, VM162, CIRCULAR COOLING FIN OF RECTANGULAR PROFILE
C*** CONDUCTION HEAT TRANSFER, SCHNEIDER, 2ND. PRINTING, PAGE 82, ART. 4-10
ANTYPE,STATIC
ET,1,SOLID90
MP,KXX,1,15
CSYS,1
N,1,.04167
N,9,.0625
FILL
NGEN,3,10,1,9,1,,2.5
NGEN,3,30,1,29,1,,,.002604
E,1,3,23,21,61,63,83,81
EMORE,2,13,22,11,62,73,82,71
EMORE,31,33,53,51
EGEN,4,2,1
OUTPR,,1
D,1,TEMP,100,,81,10
NSEL,S,LOC,Z
SF,ALL,CONV,100
NSEL,S,LOC,Z,0.005208
SF,ALL,CONV,100
NSEL,S,LOC,X,0.0625
SF,ALL,CONV,100
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
*GET,T,NODE,29,TEMP
FSUM,HEAT
*GET,Q1,FSUM,0,ITEM,HEAT
*SET,Q,ABS((Q1*360/5))
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'T2 ','q '
LABEL(1,2) = 'F','BTU/hr'
*VFILL,VALUE(1,1),DATA,53.22,102.05
*VFILL,VALUE(1,2),DATA,T,Q
*VFILL,VALUE(1,3),DATA,ABS(T/53.22),ABS(Q/102.05)
/COM
/OUT,vm162,vrt
/COM,------------------- VM162 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm162,vrt


VM163 (Groundwater Seepage (Permeability Analogy)) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM163
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM163 GROUNDWATER SEEPAGE
C*** A SIMPLE GUIDE TO FINITE ELEMENTS, R.J.OWEN AND E. HINTON, P.89
ANTYPE,STATIC ! THERMAL ANALYSIS
ET,1,PLANE55,,,1,,,,1 ! AXISYMMETRIC, SUPRESS ALL PRINTOUT
MP,KXX,1,0.864 ! PERMEABILITY
K,1
*REPEAT,3,1,,3.5
KGEN,2,1,3,1,8.0
KGEN,2,1,2,1,18.0
K,9,18,10
K,10,8,10
K,11,8.0,3.5
L,1,4 ! DEFINE LINE SEGMENTS AND MESH DIVISIONS
*REPEAT,3,1,1
L,10,9
L,11,8
L,4,7
LESIZE,ALL,,,8
A,1,4,5,2
A,2,5,6,3
A,4,7,8,5
A,11,8,9,10
ESIZE,,5
MSHK,2 ! MAPPED AREA MESH IF POSSIBLE
MSHA,0,2D ! USING QUADS
AMESH,ALL ! MESH AREAS
NUMMRG,NODE ! MERGE NODES AT BOTTOM OF CAISSON
NSEL,S,LOC,Y,7.0
D,ALL,TEMP,0
NSEL,S,LOC,Y,10
D,ALL,TEMP,3 ! PRESSURE HEAD
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
/CLABEL,,1
/CONTOUR,,20
/EDGE,,1
PLNSOL,TEMP ! DISPLAY PRESSURE CONTOURS
/VSCALE,,-1
PLVECT,TG ! DISPLAY THERMAL GRADIENT VECTORS
NSEL,S,LOC,Y,7.0
PRRSOL,HEAT ! PRINT FLOWRATE THROUGH SOIL
FSUM,HEAT
*GET,Q1,FSUM,0,ITEM,HEAT
*SET,Q,(Q1/(2*3.14159265))
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'q '
LABEL(1,2) = 'CUBm/DAY'
*VFILL,VALUE(1,1),DATA,8.6
*VFILL,VALUE(1,2),DATA,Q
*VFILL,VALUE(1,3),DATA,ABS(Q/8.6)
/COM
/OUT,vm163,vrt
/COM,------------------- VM163 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm163,vrt


VM164 (Drying of a Thick Wooden Slab (Diffusion Analogy)) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM164
/PREP7
/TITLE, VM164, DRYING OF A THICK WOODEN SLAB (DIFFUSION)
C*** HEAT, MASS AND MOMENTUM TRANS., ROHSENOW AND CHOI, 2ND. PR., PAGE 392
ANTYPE,TRANS
ET,1,LINK32
R,1,1 ! ARBITRARY AREA
MP,KXX,1,4E-5 ! DIFFUSION COEFFICIENT D
MP,DENS,1,1 ! ARBITRARY DENSITY AND CAPACITANCE
MP,C,1,1
N,1
N,11,(1/12)
FILL
E,1,2
EGEN,10,1,1
TUNIF,30 ! INITIAL MOISTURE CONCENTRATION (THAT OF WOOD)
D,11,TEMP,5 ! FINAL MOISTURE CONCENTRATION (AMBIENT)
FINISH
/SOLU
SOLCONTROL,0
AUTOTS,ON
OUTPR,,LAST
DELTIM,0.434
TIME,127 ! TIME AT END OF LOAD STEP
KBC,1 ! STEP BOUNDARY CONDITIONS
SOLVE
/POST1
*GET,T,NODE,1,TEMP
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = ' C '
LABEL(1,2) = ' % '
*VFILL,VALUE(1,1),DATA,10
*VFILL,VALUE(1,2),DATA,T
*VFILL,VALUE(1,3),DATA,ABS(T/10)
/COM
/OUT,vm164,vrt
/COM,------------------- VM164 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm164,vrt


VM165 (Current-Carrying Ferromagnetic Conductor) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM165
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM165, CURRENT CARRYING FERROMAGNETIC CONDUCTOR
C*** PRINCIPLES OF ELECTRIC AND MAGNETIC FIELDS, BOAST, PAGE 225
ET,1,PLANE13 ! 2-D COUPLED FIELD SOLID
ET,2,INFIN9 ! 2-D INFINITE BOUNDARY ELEMENT
EMUNIT,MKS ! MKS UNITS
MP,MURX,1,1 ! SET RELATIVE PERMEABILITY FOR AIR TO 1
TB,BH,2 ! B-H CURVE FOR MATERIAL 2
TBPT,,150,.21 ! H AND B RESPECTIVELY
TBPT,,300,.55
TBPT,,460,.80
TBPT,,640,.95
TBPT,,720,1.0
TBPT,,890,1.1
TBPT,,1020,1.15
TBPT,,1280,1.25
TBPT,,1900,1.40
TBPLOT,BH,2
TBPLOT,NB,2
/wind,1,top
/wind,2,bottom
/gtype,1,grph,1
/gtype,2,grph,1
/gcmd,1,tbplot,bh,2
/gcmd,2,tbplot,nb,2
gplot
/wind,2,off
/wind,1,full
SF=.0254 ! SET CONVERSION (INCHES TO METERS)
CSYS,1
K,1
K,2,.3,-2.5 ! INNER RADIUS OF RING
K,3,.45,-2.5 ! OUTER RADIUS OF RING
K,4,.75,-2.5 ! OUTER RADIUS OF SURROUNDING AIR
KPSCALE,ALL,,,SF,,,,,1 ! MOVE ORIGINAL KEYPOINTS TO NEW POSITION
CSYS,0
L,1,2
LESIZE,1,,,5
L,2,3
LESIZE,2,,,6
L,3,4
LSYMM,2,ALL
NUMMRG,KP ! MERGE KEYPOINTS
L,4,8 ! DEFINE OUTER RADIUS LINE SEGMENT
LESIZE,7,,,1
TYPE,2
ESIZE,,,1
LMESH,7 ! MESH LINE SEGMENT (WITH BOUNDARY ELEMENT)
A,2,6,1,1
A,2,3,7,6
A,3,4,8,7
ASEL,S,AREA,,2
AATT,2 ! ASSIGN MATERIAL 2 TO STEEL AREA
ASEL,ALL
ESIZE,,1 ! DEFAULT ELEMENT DIVISIONS=1
TYPE,1
AMESH,1,2
LDVA
AMESH,3
FINISH
/SOLU ! ENTER SOLVER
BFA,2,JS,,,438559 ! APPLY CURRENT DENSITY JS(Z)
MAGSOLV
FINISH
/POST1
CSYS,1
NSEL,S,LOC,X,.325*SF
NSEL,A,LOC,X,.375*SF
NSEL,A,LOC,X,.425*SF
RSYS,1 ! SET RESULTS C.S. TO CYLINDRICAL
PRNSOL,B,COMP ! PRINT NODAL FLUX DENSITY
*GET,B1,NODE,21,B,SUM
*GET,B2,NODE,23,B,SUM
*GET,B3,NODE,25,B,SUM
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = '@ R=','@ R=','@ R='
LABEL(1,2) = '.325','.375','.425'
*VFILL,VALUE(1,1),DATA,.48,1.03,1.22
*VFILL,VALUE(1,2),DATA,B1,B2,B3
*VFILL,VALUE(1,3),DATA,ABS(B1/.48),ABS(B2/1.03),ABS(B3/1.22)
/COM
/OUT,vm165,vrt
/COM,------------------- VM165 RESULTS COMPARISON --------------
/COM,
/COM,B, TESLA
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm165,vrt


VM166 (Long Cylinder in a Sinusoidal Magnetic Field) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM166
/PREP7
SMRT,OFF
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM166, LONG CYLINDER IN A SINUSOIDAL MAGNETIC FIELD
/COM, ELECTROMAGNETIC WORKSHOP, RAL-86-049, EMSON, PAGE 39
ANTYPE,HARMIC ! FULL HARMONIC ANALYSIS
ET,1,PLANE13 ! 2-D COUPLED-FIELD SOLID (AZ DOF)
EMUNIT,MKS ! MKS UNITS
MP,MURX,1,1 ! RELATIVE PERMEABILITY - AIR
MP,MURX,2,1 ! RELATIVE PERMEABILITY - ALUMINUM
MP,RSVZ,2,(1/25380711) ! RESISTIVITY - ALUMINUM
K,1
K,2,.03
K,3,.03,.03
K,4,,.03
CSYS,1
K,5,.05715
K,6,.05715,45
K,7,.05715,90
KGEN,2,5,7,1,.0127
KGEN,2,8,10,1,.77015
L,2,5
*REPEAT,3,1,1
L,5,8
*REPEAT,3,1,1
L,8,11
*REPEAT,3,1,1
CSYS,0
A,1,2,3,4 ! DEFINE AREAS
CSYS,1
A,2,5,6,3
*REPEAT,3,3,3,3,3
A,3,6,7,4
*REPEAT,3,3,3,3,3
ASEL,S,AREA,,3,6,3
AATT,2
ASEL,ALL
LESIZE,1,,,4,.5 ! DEFINE LINE SEGMENTS AND DIVISIONS
*REPEAT,3,1
LESIZE,4,,,5
*REPEAT,3,1
LESIZE,7,,,9,25
*REPEAT,3,1
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USING QUADS
ESIZE,,6
AMESH,ALL
PI=3.141592654
DTH=(7.5*PI)/180. ! THETA INCREMENT
*DO,THP,0,90,3.75 ! IMPOSE EXTERIOR NODAL POTENTIALS
NSEL,S,LOC,X,.83,.85 ! SELECT NODES AT OUTERMOST RADIUS
NSEL,R,LOC,Y,(THP-1.),(THP+1.)
TH=(THP*PI)/180
VAL=-(COS(TH)*.084) ! CALCULATE POTENTIAL
D,ALL,AZ,VAL
NSEL,ALL
*ENDDO
CSYS,0
NSEL,S,LOC,X,0
D,ALL,AZ,0 ! IMPOSE DIRICHLET BOUNDARY CONDITION
NSEL,ALL
HARFRQ,60 ! SET FREQUENCY = 60 HZ
FINI
/SOLU
SOLVE
FINI
/POST1
SET,1 ! REAL RESULTS
NSEL,S,NODE,,1
PRNSOL,B,COMP ! PRINT NODAL REAL FLUX DENSITY AT ORIGIN
*GET,BR1,NODE,1,B,X
*GET,BR2,NODE,1,B,Y
SET,1,1,,1 ! IMAGINARY RESULTS
PRNSOL,B,COMP ! PRINT NODAL IMAGINARY FLUX DENSITY AT ORIGIN
*GET,BI1,NODE,1,B,X
*GET,BI2,NODE,1,B,Y
ESEL,S,MAT,,2
POWERH ! CALCULATE TIME-AVERAGE POWER LOSS
*DIM,LABEL,CHAR,5,2
*DIM,VALUE,,5,3
LABEL(1,1) = 'BX REAL ','BY REAL ','BX IM ','BY IM ','PWR LOSS '
LABEL(1,2) = 'T','T','T','T','W/m'
*VFILL,VALUE(1,1),DATA,0,-.00184,0,-.02102,2288
*VFILL,VALUE(1,2),DATA,BR1,BR2,BI1,BI2,PAVG
*VFILL,VALUE(1,3),DATA,1,ABS(BR2/.00184),1,ABS(BI2/.02102),ABS(PAVG/2288)
/OUT,vm166,vrt
/COM,------------------- VM166 RESULTS COMPARISON --------------
/COM,
/COM,RESULTS AT ORIGIN
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm166,vrt


VM167 (Transient Eddy Currents in a Semi-Infinite Solid) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,vm167
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM167, TRANSIENT EDDY CURRENTS IN A SEMI-INFINITE SOLID
/COM, HOLMAN, J.P., 'HEAT TRANSFER', 4TH EDITION, MCGRAW HILL,
/COM, INC., 1976, PAGE 104, EQN. 4-14 (ANALOGOUS FIELD SOLUTION)
ET,1,PLANE13 ! 2-D COUPLED-FIELD SOLID, AZ DOF
EMUNIT,MKS ! MKS UNITS
MP,MURX,1,1 ! RELATIVE PERMEABILITY - AIR
MP,MURX,2,1 ! RELATIVE PERMEABILITY - ALUMINUM
MP,RSVX,2,4E-7 ! RESISTIVITY - ALUMINUM
N,1
N,41,20
FILL,1,41,,,,,,20
NGEN,2,50,1,41,1,,.4
MAT,2
E,1,2,52,51
EGEN,40,1,-1
FINISH
/SOLU
ANTYPE,TRANS ! TRANSIENT ANALYSIS
NSEL,S,LOC,X,0
D,ALL,AZ,2 ! APPLY STEP POTENTIAL
NSEL,INVE
IC,ALL,AZ,0 ! INITIAL CONDITION ON REMAINING POTENTIALS
NSEL,S,LOC,X,20
D,ALL,AZ,0 ! SET FAR-FIELD POTENTIAL TO ZERO
NSEL,ALL
KBC,1 ! STEPPED BOUNDARY CONDITIONS
DELTIM,.0002,.0002,.005 ! DEFINE TIME STEP SIZES
AUTOTS,ON ! AUTO TIME-STEPPING
TIME,.15 ! TIME AT END OF 1ST LOAD STEP
OUTRES,ALL,ALL
SOLVE
DELTIM,,,,ON ! CARRY OVER TIME STEP USED PREVIOUSLY
TIME,.24 ! TIME AT END OF 2ND LOAD STEP
SOLVE
FINISH
/POST26
NSOL,2,4,A,Z ! STORE NODE 4 VECTOR POTENTIAL
NSOL,3,6,A,Z ! STORE NODE 6 VECTOR POTENTIAL
NSOL,4,8,A,Z ! STORE NODE 8 VECTOR POTENTIAL
DERIV,5,2 ! CALCULATE DA/DT
DERIV,6,3
DERIV,7,4
ADD,5,5,,,JEDDY_4,,,-.25E7 ! FIND EDDY CURRENT, -(DA/DT)/(RESISTIVITY)
ADD,6,6,,,JEDDY_6,,,-.25E7
ADD,7,7,,,JEDDY_8,,,-.25E7
SOLU,8,DTIM ! STORE TIME STEP SIZE
SOLU,9,RESE ! STORE RESPONSE EIGENVALUE
SOLU,10,NCMIT ! STORE NO. OF CUMULATIVE ITERATIONS
STORE,MERGE ! MERGE DATA WITH PREVIOUSLY STORED DATA
/AXLAB,Y,A
/GROPT,AXNSC,2.0
PLVAR,2,3,4 ! DISPLAY VECTOR POTENTIAL VS. TIME
/AXLAB,Y,EDDY
PLVAR,5,6,7 ! DISPLAY EDDY CURRENT DENSITY VS. TIME
PRVAR,2,3,4,5,6,7 ! PRINT VALUES
*GET,V1,VARI,2,RTIME,.15
*GET,V2,VARI,3,RTIME,.15
*GET,V3,VARI,4,RTIME,.15
*GET,E1,VARI,5,RTIME,.15
*GET,E2,VARI,6,RTIME,.15
*GET,E3,VARI,7,RTIME,.15
PRVAR,8,9,10 ! PRINT SOLUTION SUMMARY DATA
FINISH
/POST1
NSEL,S,NODE,,4,8,2
ESLN,S,0
SET,,,,,.15 ! SELECT ITERATION AT TIME=.15
PRITER
PRNSOL,B,COMP ! PRINT NODAL FLUX DENSITY
*GET,F1,NODE,4,B,Y
*GET,F2,NODE,6,B,Y
*GET,F3,NODE,8,B,Y
*STATUS
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = '@ X=','@ X=','@ X='
LABEL(1,2) = '.2517','.4574','.6914'
*VFILL,VALUE(1,1),DATA,.831,.282,.05
*VFILL,VALUE(1,2),DATA,V1,V2,V3
*VFILL,VALUE(1,3),DATA,ABS(V1/.831),ABS(V2/.282),ABS(V3/.05)
/COM
/OUT,vm167,vrt
/COM,------------------- VM167 RESULTS COMPARISON ---------------
/COM,
/COM,VECTOR POTENTIALS (WB/M)
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F14.3,' ',F14.3,' ',1F7.3)
/COM,
/NOPR
*VFILL,VALUE(1,1),DATA,3.707,1.749,.422
*VFILL,VALUE(1,2),DATA,F1,F2,F3
*VFILL,VALUE(1,3),DATA,ABS(F1/3.707),ABS(F2/1.749),ABS(F3/.422)
/GOPR
/COM,FLUX DENSITY (T)
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F14.3,' ',F14.3,' ',1F7.3)
/COM,
/NOPR
*VFILL,VALUE(1,1),DATA,-.777E7,-.663E7,-.243E7
*VFILL,VALUE(1,2),DATA,E1,E2,E3
*VFILL,VALUE(1,3),DATA,ABS(E1/(.777E7)),ABS(E2/(.663E7)),ABS(E3/(.243E7))
/GOPR
/COM,EDDY CURRENT DENSITY (A/M/M)
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F14.0,' ',F14.0,' ',1F7.3)
/COM-------------------------------------------------------------
/OUT
FINISH
*LIST,vm167,vrt


VM168 (Magnetic Field in a Nonferrous Solenoid) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM168
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM168, MAGNETIC FIELD IN A NONFERROUS SOLENOID
/COM, PRINCIPLES OF ELECTRIC AND MAGNETIC FIELDS, BOAST, PG.243
ANTYPE,STATIC
ET,1,SOLID5,10 ! 3D COUPLED-FIELD SOLID, MAG DOF
ET,2,SOURC36 ! CURRENT SOURCE ELEMENT
EMUNIT,MKS ! MKS UNITS
MP,MURX,1,1 ! RELATIVE PERMEABILITY - AIR
/COM !** DEFINE CONVENIENT PARAMETERS !**
I=0.5 ! CURRENT
NI=115.5 ! MMF
S=2.5 ! SOLENOID 1/2 LENGTH
R=0.5 ! SOLENOID RADIUS
THK=.0216 ! SOLENOID THICKNESS
INM=.0254 ! INCHES TO METER CONVERSION
INC=.0001 ! SET SMALL RADIUS
TH=5 ! SET ANGLE
L=7.5 ! SET BOUNDARY LENGTH
R,1,1,NI,THK*INM,S*2*INM,1,50 ! COIL REAL CONSTANTS
CSYS,1
N,1,INC,-TH ! CREATE NODES FOR SOLID5
N,8,INC,-TH,S-.1
FILL
N,9,INC,-TH,S
N,10,INC,-TH,S+.1
N,19,INC,-TH,L-.1
FILL,10,19,,,,,,2
N,20,INC,-TH,L
NGEN,4,20,1,20,1,R/3,,,5
NGEN,7,20,61,80,1,(5.5/6),,,10
NSEL,S,LOC,Z,0
DSYS,1
NLIST,ALL
NSEL,ALL
DSYS,0
NGEN,2,200,ALL,,,,(TH*2)
E,22,222,202,2,21,221,201,1 ! CREATE SOLID5 ELEMENTS
EGEN,19,1,-1
EGEN,9,20,-19
NUMMRG,NODE ! MERGE NODES NEAR X=0 AXIS
N,500,R ! CREATE NODES FOR SOURC36
N,501,R,90
N,502
TYPE,2
E,500,501,502 ! CREATE SOURC36 ELEMENT
NSCALE,,ALL,,,INM,,INM ! SCALE MODEL TO METERS
D,ALL,MAG,0 ! SET MAG=0 EVERYWHERE
FINISH
/SOLU
MAGOPT ! RSP STRATEGY (DEFAULT)
OUTPR,ALL,NONE
SOLVE
FINISH
/POST1
PATH,FIELD,2,,48 ! DEFINE PATH WITH NAME = "FIELD"
PPATH,1,1 ! DEFINE PATH POINTS BY NODE
PPATH,2,20
PDEF,BZ,B,Z
PRPATH,BZ ! PRINT BZ ALONG COIL AXIS
/SHOW,,GRPH,1
PLPATH,BZ ! DISPLAY BZ ALONG COIL AXIS
*GET,S1A,PATH,0,MIN,BZ
*GET,S2A,PATH,0,MAX,BZ
*SET,S1,(S1A*1E6)
*SET,S2,(S2A*1E6)
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'BZ T ','BZ T'
LABEL(1,2) = 'Z=0','Z=.1905m'
*VFILL,VALUE(1,1),DATA,1120,2.12
*VFILL,VALUE(1,2),DATA,S2,S1
*VFILL,VALUE(1,3),DATA,ABS(S2/1120),ABS(S1/2.12)
/OUT,vm168,vrt
/COM,------------------- VM168 RESULTS COMPARISON --------------
/COM,ANSWERS MULTIPLIED BY 1E6
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM168 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm168,vrt


VM169 (Permanent Magnet Circuit With an Air Gap) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM169
/config,nproc,4
/PREP7
smrt,off
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM169, PERMANENT MAGNET CIRCUIT WITH AN AIR GAP
! MAGNETO-SOLID MECHANICS, MOON, PG. 275
! USING TETRAHEDRAL SOLID ELEMENTS (SOLID98)
ET,1,SOLID98,10 ! TETRAHEDRAL COUPLED-FIELD SOLID
EMUNIT,MKS ! MKS UNITS
MP,MURX,1,1
MP,MURX,2,1E5 ! IRON RELATIVE PERMEABILITY
MP,MURX,3,5.30504 ! PERMANENT MAGNET RELATIVE PERMEABILITY
MP,MGXX,3,129900 ! MGXX
MP,MGZZ,3,-75000 ! MGZZ
LOCAL,11,0,,,,,,30 ! ROTATED LOCAL CARTESIAN SYSTEM
K,1
K,2,1.5E-2
K,3,2.5E-2
KGEN,2,1,3,1,,1E-2
KGEN,2,4,6,1,,2E-2
KGEN,2,7,9,1,,1E-3
KGEN,2,10,12,1,,1E-2
A,1,2,5,4 ! CREATE AREAS
A,2,3,6,5
A,5,6,9,8
A,10,11,14,13
A,11,12,15,14
A,8,9,12,11
K,16,,,1E-2
L,1,16
VDRAG,1,2,3,4,5,6,20 ! DRAG AREAS TO CREATE VOLUMES
VSEL,S,,,1
VATT,3 ! SET MATERIAL ATTRIBUTES
VSEL,S,,,6
VATT,1
VSEL,S,,,2,3
VSEL,A,,,4,5
VATT,2
VSEL,S,,,1,5
ESIZE,,1
MSHK,0 ! FREE VOLUME MESH
MSHA,1,3D ! USING TETS
VMESH,ALL
VSEL,ALL
VMESH,6 ! MESH AIR GAP
NSEL,,LOC,X,0
D,ALL,MAG,0 ! SET FLUX-NORMAL BOUNDARY CONDITION
NSEL,ALL
WSORT,Y ! REORDER WAVEFRONT
FINISH
/SOLU
MAGSOLV,2 ! RSP METHOD
FINISH
/POST1
RSYS,11
/VIEW,,6E-2,5E-2,6E-2
/EDGE,1,1
/DEVICE,VECTOR,1 ! TURN ON WIREFRAME MODE
PLVECT,B ! DISPLAY B VECTOR
/VSCALE,,,1 ! SET FOR UNIFORM VECTOR SCALING
PLVECT,H ! DISPLAY H VECTOR
ESEL,,MAT,,1 ! SELECT AIR ELEMENTS
PRNSOL,B,COMP ! PRINT B
NSORT,B,SUM
*GET,B1,SORT,,MAX
PRNSOL,H,COMP ! PRINT H
NSORT,H,SUM
*GET,H1,SORT,,MAX
ESEL,,MAT,,3 ! SELECT PERMANENT MAGNET ELEMENTS
PRNSOL,B,COMP ! PRINT B
NSORT,B,SUM
*GET,B2,SORT,,MAX
PRNSOL,H,COMP ! PRINT H
NSORT,H,SUM
*GET,H2,SORT,,MAX
*STATUS
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'B T ','H A/m ','B T ','H A/m '
LABEL(1,2) = 'PMAG','PMAG','AIR','AIR'

*VFILL,VALUE(1,1),DATA,.7387,39150,.7387,587860
*VFILL,VALUE(1,2),DATA,B2,H2,B1,H1
*VFILL,VALUE(1,3),DATA,ABS(B2/.7387),ABS(H2/39150),ABS(B1/.7387),ABS(H1/587860)
/COM
/OUT,vm169,vrt
/COM,------------------- VM169 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F12.4,' ',F12.4,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
/DELETE,magsolv,out
/DELETE,scratch
*LIST,vm169,vrt


VM170 (Magnetic Field From a Square Current Loop) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM170
/PREP7
/TITLE, VM170, MAGNETIC FIELD FROM A SQUARE CURRENT LOOP
/COM, REF. BOAST, "PRINCIPLES OF ELECTRIC AND MAGNETIC FIELDS"
/COM, PG. 200
ET,1,LINK68 ! LINK68 ELEMENT
R,1,1 ! ARBITRARY AREA
MP,RSVX,1,4.0E-8 ! RESISTIVITY
N,1 ! DEFINE NODES FOR LOOP
N,2,1.5
N,3,1.5,,1.5
N,4,,,1.5
N,5 ! NODES 1 AND 5 OVERLAP
N,6,,.35 ! NODE FOR RESULTS EXTRACTION
E,1,2 ! GENERATE ELEMENTS
EGEN,4,1,-1
D,5,VOLT,0 ! GROUND VOLTAGE IN WIRE
F,1,AMPS,7.5 ! APPLY CURRENT AT "CUT"
FINISH
/SOLU
OUTPR,ESOL,LAST ! BASIC ELEMENT PRINTOUT
SOLVE ! SOLVE ELECTRIC CURRENT CONDUCTION
BIOT,NEW ! CALCULATE HS FIELD VIA BIOT-SAVART INTEG.
*GET,HX,NODE,6,HS,X ! GET HS(X) AS A PARAMETER
*GET,HY,NODE,6,HS,Y ! GET HS(Y)
*GET,HZ,NODE,6,HS,Z ! GET HS(Z)
MUZRO=12.5664E-7 ! DEFINE FREE=SPACE PERMEABILITY
BX=MUZRO*HX ! CALCULATE FLUX DENSITY
BY=MUZRO*HY
BZ=MUZRO*HZ
*STATUS ! SHOW PARAMETER STATUS
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'BX ','BY ','BZ '
LABEL(1,2) = 'TESLA','TESLA','TESLA'
*VFILL,VALUE(1,1),DATA,2.010E-6,-.662E-6,2.01E-6
*VFILL,VALUE(1,2),DATA,BX,BY,BZ
*VFILL,VALUE(1,3),DATA,ABS(BX/(2.01E-6)),ABS(BY/.662E-6),ABS(BZ/(2.01E-6))
/COM
/OUT,vm170,vrt
/COM,------------------- VM170 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F12.9,' ',F12.9,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm170,vrt


VM171 (Permanent Magnet Circuit With an Elastic Keeper) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM171
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM171, PERMANENT MAGNET CIRCUIT WITH AN ELASTIC KEEPER
/COM, MAGNETO-SOLID MECHANICS, MOON, PG. 275
ET,1,PLANE13,4 ! 2-D COUPLED-FIELD SOLID (UX,UY,AZ DOF'S)
ET,2,COMBIN14,,,2
R,1,1.6534E5 ! SPRING CONSTANT
MP,EX,1,1E2
MP,EX,2,10E10
MP,EX,3,10E10
MP,EX,4,10E10
MP,NUXY,1,0.0
*REP,4,,1
MP,KXX,1,1 ! APPLY DUMMY KXX TO PREVENT WARNING MSGS.
*REP,4,,1
EMUNIT,MKS ! MKS UNITS
MP,MURX,1,1 ! AIR RELATIVE PERMEABILITY
MP,MURX,2,1E5 ! IRON RELATIVE PERMEABILITY
MP,MURX,3,5.30504 ! PERMANENT MAGNET RELATIVE PERMEABILITY
MP,MGXX,3,149990.0 ! COERCIVE FORCE (X-DIRECTION)
MP,MURX,4,1E5 ! KEEPER RELATIVE PERMEABILITY
N,1
N,6,5E-2
FILL
NGEN,6,6,1,6,1E-2,,1E-2
N,37,0,6E-2
N,38,5E-2,6E-2
MAT,3
E,2,3,9,8
EGEN,3,1,-1
MAT,2
E,1,2,8,7
EGEN,3,6,-1
E,5,6,12,11
EGEN,3,6,-1
MAT,4
E,25,26,32,31
EGEN,5,1,-1
MAT,1
E,19,20,26,25
E,23,24,30,29
TYPE,2 ! SPRINGS
E,37,31
E,38,36
D,37,ALL,0,,38 ! CONSTRAIN SPRING
ESEL,S,MAT,,2,3
NSLE
D,ALL,UX,0,,,,UY ! CONSTRAIN PERMANENT MAGNET STRUCTURE
ESEL,ALL
NSEL,S,LOC,X,0
NSEL,A,LOC,X,5E-2
NSEL,A,LOC,Y,0
NSEL,A,LOC,Y,5E-2
D,ALL,AZ,0 ! SET EXTERIOR FLUX-PARALLEL BOUNDARY
NSEL,ALL
CP,1,AZ,8,9,10,11,14 ! COUPLE INTERNAL NODES
CP,1,AZ,17,20,23,26
CP,1,AZ,27,28,29
NSLE ! SELECT ONLY NODES USED IN MODEL
D,ALL,UX,0 ! CONSTRAIN ALL HORIZONTAL DISPLACEMENTS
D,ALL,TEMP,0 ! CONSTRAIN UNUSED TEMP DOF
ESEL,S,MAT,,1 ! SELECT KEEPER ELEMENTS
NSEL,S,LOC,Y,4E-2 ! SELECT NODES AT BOTTOM SURFACE
SF,ALL,MXWF ! APPLY MAXWELL PRESSURE SURFACE
NSEL,ALL
ESEL,ALL
FINISH
/SOLU
NLGEOM,ON ! ACTIVATE LARGE DEFLECTION
CNVTOL,F ! SET FORCE CONVERGENCE (USE DEFAULTS)
CNVTOL,CSG ! SET CSG CONVERGENCE (.001% OF DEFAULT)
SOLVE
FINISH
/POST1
NSEL,S,LOC,Y,4e-2
PRNSOL,U,COMP ! PRINT NODAL DISPLACEMENTS
*GET,Y1,NODE,25,U,Y
*SET,Y,ABS(Y1)
ESEL,S,MAT,,3
NSLE
PRNSOL,B,COMP ! PRINT NODAL FLUX DENSITY IN PERMANENT MAGNET
*GET,B,NODE,2,B,X
NSEL,ALL
ESEL,S,MAT,,2,4 ! SELECT ONLY ELEMENTS OF IRONAND KEEPER
/EDGE,1,1
/DSCALE,1,1 ! TRUE SCALING OPTION
PLDISP,1 ! DISPLAY DEFLECTED AND UNDEFLECTED SHAPE
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'DEFL ','MFLUX '
LABEL(1,2) = 'm','T'
*VFILL,VALUE(1,1),DATA,1.5E-3,.2496
*VFILL,VALUE(1,2),DATA,Y,B
*VFILL,VALUE(1,3),DATA,ABS(Y/1.5E-3),ABS(B/.2495)
/COM
/OUT,vm171,vrt
/COM,------------------- VM171 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm171,vrt


VM172 (Stress Analysis of a Long, Thick, Isotropic Solenoid) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM172
/PREP7
smrt,off
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM172, STRESS ANALYSIS OF A LONG, THICK, ISOTROPIC SOLENOID
/COM, MAGNETO-SOLID MECHANICS, MOON, PG. 275, 2D ANALYSIS
ANTYPE,STATIC ! COUPLED FIELD ANALYSIS
ET,1,PLANE13,,,1 ! PLANE13, AZ DOF, AXISYMMETRIC OPTION
ET,2,PLANE13,4,,1 ! PLANE13, AZ,UX,UY DOF, AXISYMMETRIC OPTION
MP,EX,2,10.76E10 ! SOLENOID MODULUS OF ELASTICITY
MP,NUXY,2,.35 ! SOLENOID POISSON RATIO
EMUNIT,MKS ! MKS UNITS
MP,MURX,1,1 ! RELATIVE PERMEABILITY=1.0
MP,MURX,2,1
K,1
K,2,1E-2
K,3,2E-2
L,1,2
LESIZE,1,,,5
L,2,3
LESIZE,2,,,20
LGEN,2,ALL,,,,2E-3
A,1,2,5,4 ! AREA 1=AIR
A,2,3,6,5 ! AREA 2=SOLENOID
ASEL,S,AREA,,2
AATT,2,,2
ASEL,ALL
ESIZE,,1
MSHK,2 ! MAPPED AREA MESH IF POSSIBLE
MSHA,0,2D ! USING QUADS
AMESH,ALL
ESEL,S,MAT,,2
NSLE,S
NSEL,R,LOC,Y,2E-3
CP,1,UY,ALL ! COUPLE SOLENOID NODAL UY DISP.
NSEL,S,LOC,X,2E-2 ! SELECT NODES AT OUTER RADIUS
CP,2,AZ,ALL ! COUPLE AZ TO ENSURE FLUX-PARALLEL B.C.
FINISH
/SOLU
NSEL,S,LOC,X,0
D,ALL,AZ,0 ! SET FLUX PARALLEL B.C.
ESEL,S,MAT,,2
BFE,ALL,JS,,,,1E+6 ! APPLY CURRENT DENSITY LOAD
NSLE
NSEL,R,LOC,Y,0
DSYM,SYMM,2 ! APPLY STRUCTURAL SYMMETRY B.C.
NSEL,ALL
ESEL,ALL
KBC,1 ! STEP BOUNDARY CONDITIONS
OUTRES,,LAST
SOLVE
FINISH
/POST1
SET,1
ESEL,S,MAT,,2 ! SELECT SOLENOID NODES AND ELEMENTS
NSLE
/AXLAB,X,DISTANCE
/AXLAB,Y,STRESS - 2-D MODEL
/GTHK,AXIS,2
PATH,COIL1,2,,48 ! DEFINE PATH WITH NAME = "COIL1"
PPATH,1,2 ! DEFINE PATH POINTS BY NODE
PPATH,2,13
PDEF,SZ,S,Z
PDEF,BY,B,Y
/YRANGE,500,1500
PLPATH,SZ ! DISPLAY CIRCUM STRESS THRU SOLENOID
/YRANGE,0,125
/AXLAB,Y,FLUX DENSITY - 2-D MODEL
PLPATH,BY ! DISPLAY AXIAL FLUX DENSITY THRU SOLENOID
NSEL,S,LOC,X,1e-2
NSEL,A,LOC,X,1.3e-2
NSEL,A,LOC,X,1.7e-2
PRNSOL,B,COMP ! PRINT AXIAL FLUX DENSITY
PRNSOL,S,COMP ! PRINT COMPONENT STRESSES
*GET,B1,NODE,7,B,SUM
*GET,B2,NODE,19,B,SUM
*GET,B3,NODE,27,B,SUM
*GET,S1,NODE,7,S,Z
*GET,S2,NODE,19,S,Z
*GET,S3,NODE,27,S,Z
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
LABEL(1,1) = 'B, T ','B, T ','B, T ','PRS ','PRS ','PRS '
LABEL(1,2) = 'R=1E-2','R=1.3E-2','R=1.7E-2','R=1E-2','R=1.3E-2','R=1.7E-2'
*VFILL,VALUE(1,1),DATA,0.01257,8.796E-3,3.77E-3,146.7,97.79,62.44
*VFILL,VALUE(1,2),DATA,B1,B2,B3,S1,S2,S3
*VFILL,VALUE(1,3),DATA,(B1/0.01257),(B2/8.796E-3),(B3/3.77E-3),(S1/146.7),(S2/97.79),(S3/62.44)
SAVE,TABLE_1
FINISH
/CLEAR,NOSTART
/PREP7
smrt,off
/TITLE, VM172, STRESS ANALYSIS OF A LONG, THICK, ISOTROPIC SOLENOID
/COM, MAGNETO-SOLID MECHANICS, MOON, PG. 275, 3D ANALYSIS
ANTYPE,STATIC ! COUPLED FIELD ANALYSIS
ET,1,62 ! MAGNETO-STRUCTURAL ELEMENT
ET,2,97 ! MAGNETIC FIELD ELEMENT
ET,3,47 ! INFINITE ELEMENT
MP,EX,2,10.76E10 ! SOLENOID MODULUS OF ELASTICITY
MP,NUXY,2,.35 ! SOLENOID POISSON RATIO
EMUNIT,MKS ! MKS UNITS
MP,MURX,1,1 ! RELATIVE PERMEABILITY=1.0
MP,MURX,2,1
K,1 ! CREATE 2-D MESH
K,2,1E-2
K,3,2E-2
L,1,2
LESIZE,1,,,5
L,2,3
LESIZE,2,,,20
LGEN,2,ALL,,,,,2E-3
A,1,2,5,4 ! AREA 1=AIR
A,2,3,6,5 ! AREA 2=SOLENOID
ESIZE,,1
MSHK,2 ! MAPPED AREA MESH IF POSSIBLE
MSHA,0,2D ! USING QUADS
TYPE,3 ! MESH WITH INFIN47
AMESH,ALL
TYPE,2 ! ASSIGN 3-D ELEMENT TYPE
MAT,1
ESIZE,,2 ! TWO DIVISIONS FOR SOLID ELEMENTS
VROTAT,1,,,,,,1,4,10,1 ! ROTATE 10 DEGREES
TYPE,1
MAT,2
VROTAT,2,,,,,,1,4,10,1
NUMMRG,NODE ! MERGE COINCIDENT NODES
ACLEAR,1,2 ! CLEAR INFIN47 ELEMENT MESH
CSYS,1
NROTAT,ALL ! ROTATE NODES TO CYLINDRICAL COORDINATES
ESEL,S,MAT,,2
NSLE
NSEL,R,LOC,Z,2E-3
CP,1,UZ,ALL ! COUPLE SOLENOID NODAL UZ DISP.
ESEL,ALL
NSEL,S,LOC,X,2E-2 ! SELECT NODES AT OUTER RADIUS
CP,2,AY,ALL ! COUPLE AY TO ENSURE FLUX-PARALLEL COND.
FINISH
/SOLU
NSEL,S,LOC,X,0
D,ALL,AX,0,,,,AY,AZ ! FLUX-PARALLEL ALONG SOLENOID AXIS
ESEL,S,MAT,,2
BFE,ALL,JS,,,1E+6 ! APPLY CURRENT DENSITY LOAD
NSLE,S
NSEL,R,LOC,Z,0
D,ALL,UZ,0 ! APPLY STRUCTURAL SYMMETRY B.C. TO SOLENOID
NSLE,S
NSEL,R,LOC,Y,0
D,ALL,UY,0
NSLE,S
NSEL,R,LOC,Y,10
D,ALL,UY,0
NSEL,ALL
ESEL,ALL
D,ALL,AX,0,,,,AZ ! ONLY AY REQUIRED FOR AXISYM. FIELD
KBC,1 ! STEP BOUNDARY CONDITIONS
OUTRES,,LAST
CNVTOL,F,1E-3 ! DEFINE FORCE CONVERGENCE VALUE
SOLVE
FINISH
/POST1
SET,LAST
ESEL,S,MAT,,2 ! SELECT SOLENOID NODES AND ELEMENTS
NSLE
/AXLAB,X,DISTANCE
/AXLAB,Y,STRESS - 3-D MODEL
/GTHK,AXIS,2
PATH,COIL2,2,,48 ! DEFINE PATH WITH NAME = "COIL2"
PPATH,1,2
PPATH,2,13
RSYS,1
PDEF,SY,S,Y
PDEF,BZ,B,Z
/YRANGE,500,1500
PLPATH,SY ! DISPLAY CIRCUM STRESS THRU SOLENOID
/YRANGE,0,125
/AXLAB,Y,FLUX DENSITY - 3-D MODEL
PLPATH,BZ ! DISPLAY AXIAL FLUX DENSITY THRU SOLENOID
NSEL,S,LOC,X,1E-2
NSEL,A,LOC,X,1.3E-2
NSEL,A,LOC,X,1.7E-2
NSEL,R,LOC,Y,0
PRNSOL,B,COMP ! PRINT AXIAL FLUX DENSITY
PRNSOL,S,COMP ! PRINT COMPONENT STRESSES
*GET,B1,NODE,7,B,SUM
*GET,B2,NODE,19,B,SUM
*GET,B3,NODE,27,B,SUM
*GET,S1,NODE,7,S,Y
*GET,S2,NODE,19,S,Y
*GET,S3,NODE,27,S,Y
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
LABEL(1,1) = 'B, T ','B, T ','B, T ','PRS ','PRS ','PRS '
LABEL(1,2) = 'R=1E-2','R=1.3E-2','R=1.7E-2','R=1E-2','R=1.3E-2','R=1.7E-2'
*VFILL,VALUE(1,1),DATA,0.01257,8.796E-3,3.77E-3,146.7,97.79,62.44
*VFILL,VALUE(1,2),DATA,B1,B2,B3,S1,S2,S3
*VFILL,VALUE(1,3),DATA,(B1/0.01257),(B2/8.796E-3),(B3/3.77E-3),(S1/146.7),(S2/97.79),(S3/62.44)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm172,vrt
/COM,------------------- VM172 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,PRESSURES HAVE UNITS OF N/M**2
/COM,
/COM,RESULTS USING PLANE13:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',e12.5,' ',e12.5,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING SOLID62/97:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',e12.5,' ',e12.5,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/OUT
FINISH
*LIST,vm172,vrt

/DELETE,TABLE_1
/DELETE,TABLE_2


VM173 (Centerline Temperature of an Electrical Wire) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM173
/PREP7
/TITLE, VM173, CENTERLINE TEMPERATURE OF AN ELECTRICAL WIRE
C*** HEAT, MASS AND MOMENTUM TRANS., ROHSENOW AND CHOI, 2ND. PR., PAGE 106,
C*** EX. 6.5, USING SOLID5 ELEMENTS
ET,1,SOLID5,1 ! SOLID5, TEMP,VOLT,MAG DOF OPTION
MP,KXX,1,13 ! THERMAL CONDUCTIVITY
MP,RSVX,1,8.983782E-8 ! ELECTRICAL RESISTIVITY
CSYS,1
N,1,1E-10,-5 ! MOVE AWAY FROM ORIGIN FOR THETA SPEC.
N,6,.03125,-5
FILL
NGEN,2,10,1,6,1,,10 ! MODEL 10 DEG. SECTOR
NGEN,2,20,1,16,1,,,-(1/12) ! ARBITRARY Z-LENGTH OF 1 INCH
NUMMRG,NODE ! MERGE COINCIDENT NODES AT ORIGIN
E,2,12,1,1,22,32,21,21 ! GENERATE ELEMENTS
E,2,3,13,12,22,23,33,32
EGEN,4,1,2
CP,1,TEMP,1,21 ! COUPLING TO INSURE AXIAL SYMMETRY
CP,2,TEMP,2,12,22,32 ! COUPLING TO INSURE CIRCUMFERENTIAL SYMMETRY
CPSGEN,5,1,2
NSEL,S,LOC,Z,0
D,ALL,VOLT,0 ! SET VOLTAGES
NSEL,INVE
D,ALL,VOLT,-(.1/12) ! .1 VOLT/FT OVER 1 IN LENGTH
NSEL,S,LOC,X,.03125
SF,ALL,CONV,5,70
NSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
NSEL,S,LOC,X,0
PRNSOL,TEMP ! RESULTS AT CENTERLINE
*GET,T,NODE,1,TEMP
NSEL,S,LOC,X,.03125
PRNSOL,TEMP ! RESULTS AT OUTER RADIUS
*GET,TEMP,NODE,6,TEMP ! GET TEMPERATURE AT SURFACE NODE
PI=2*ASIN(1)
LENG=2*(0.375/12)*SIN(PI/36) ! LENGTH ALONG 10 DEG ON OUTER FACE
AREA=LENG*36 ! COMPUTE AREA OF OUTER FACE (360 DEG)
HRATE=AREA*5.0*(TEMP-70) ! TOTAL HEAT DISSIPATION RATE
*STATUS ! SHOW PARAMETER STATUS
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'T(CL) ','T(S) ','Q '
LABEL(1,2) = 'DEG F','DEG F','BTU/hr/ft'
*VFILL,VALUE(1,1),DATA,419.9,417.9,341.5
*VFILL,VALUE(1,2),DATA,T,TEMP,HRATE
*VFILL,VALUE(1,3),DATA,ABS(T/419.9),ABS(TEMP/417.9),ABS(HRATE/341.5)
/COM
/OUT,vm173,vrt
/COM,------------------- VM173 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT

FINISH
*LIST,vm173,vrt



VM174 (Bimetallic Beam Under Thermal Load) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM174
/PREP7
MP,PRXY,,0.3
MP,PRXY,,0.3
SMRT,OFF
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM174, BIMETALLIC BEAM UNDER THERMAL LOAD
/COM, THEORY OF THERMAL STRESS, BOLEY AND WEINER,
/COM, 1985 PRINTING, PG. 429
ANTYPE,STATIC ! COUPLED FIELD STATIC ANALYSIS
NLGEOM,ON ! LARGE DEFLECTION
ET,1,PLANE13,4,,2 ! 2-D COUPLED FIELD SOLID, PLANE STRESS
MP,EX,1,10E6
MP,EX,2,10E6
MP,ALPX,1,14.5E-6
MP,ALPX,2,2.5E-6
MP,KXX,1,5 ! THERMAL CONDUCTIVITY
MP,KXX,2,5
MP,PRXY,1,0.3
K,1 ! DEFINE GEOMETRY
K,2,5
KGEN,3,1,2,1,,.05
L,1,2
*REPEAT,3,2,2
LESIZE,ALL,,,5
A,1,2,4,3
AATT,2
A,3,4,6,5
ESIZE,,1
AMESH,ALL
NSEL,S,LOC,X,0
NSEL,R,LOC,Y,.05
D,ALL,UY
NSEL,S,LOC,Y,.1
D,ALL,TEMP,400.0 ! APPLY TOP SURFACE TEMPERATURE
NSEL,S,LOC,Y,0
D,ALL,TEMP,400.0 ! APPLY BOTTOM SURFACE TEMPERATURE
NSEL,S,LOC,X,5
DSYM,SYMM,0,X
NSEL,ALL
FINISH
/SOLU
CNVTOL,F,,,,0.1 ! CONVERGENCE BASED ON FORCE ONLY
SOLVE
FINISH
/POST1
SET,1
/DSCALE,1,1 ! TRUE SCALING OPTION
PLDISP,1 ! DISPLAY DEFLECTED AND UNDEFLECTED SHAPE
NSEL,S,LOC,X,5
NSEL,R,LOC,Y,.05
PRNSOL,U,COMP ! PRINT DISPLACEMENTS
*GET,Y,NODE,7,U,Y
PRNSOL,TEMP ! PRINT TEMPERATURES
*GET,T,NODE,7,TEMP
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'Y ','TEMP,'
LABEL(1,2) = 'in',' F'
*VFILL,VALUE(1,1),DATA,.9,400
*VFILL,VALUE(1,2),DATA,Y,T
*VFILL,VALUE(1,3),DATA,ABS(Y/.9),ABS(T/400)
/COM
/OUT,vm174,vrt
/COM,------------------- VM174 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm174,vrt


VM175 (Natural Frequency of a Piezoelectric Transducer) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM175
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM175, NATURAL FREQUENCY OF A PIEZOELECTRIC TRANSDUCER
/COM, COMPUTATION OF THE VIBRATIONAL MODES FOR PIEZOELECTRIC
/COM, ARRAY TRANSDUCERS USING A MIXED FINITE ELEMENT
/COM, PERTURBATION METHOD, BOUCHER, D., LAGIER, M., MAERFELD,
/COM, C., IEEE TRANS. SONICS AND ULTRASONICS, VOL. SU-28,
/COM, NO. 5, SEPTEMBER 1981., PG. 318-330
/COM,
ET,1,SOLID5,3 ! 3-D COUPLED-FIELD SOLID, PIEZO OPTION
MP,DENS,3,7500 ! DENSITY
MP,PERX,3,7.124E-9 ! PERMITTIVITY (X AND Y DIRECTION)
MP,PERZ,3,5.841E-9 ! PERMITTIVITY (Z DIRECTION)
TB,PIEZ,3 ! DEFINE PIEZ. TABLE
TBDATA,16,10.5 ! E61 PIEZOELECTRIC CONSTANT
TBDATA,14,10.5 ! E52 PIEZOELECTRIC CONSTANT
TBDATA,3,-4.1 ! E13 PIEZOELECTRIC CONSTANT
TBDATA,6,-4.1 ! E23 PIEZOELECTRIC CONSTANT
TBDATA,9,14.1 ! E33 PIEZOELECTRIC CONSTANT
TB,ANEL,3 ! DEFINE STRUCTURAL TABLE
TBDATA,1,13.2E10,7.1E10,7.3E10 ! INPUT [C] MATRIX
TBDATA,7,13.2E10,7.3E10
TBDATA,12,11.5E10
TBDATA,16,3.0E10
TBDATA,19,2.6E10
TBDATA,21,2.6E10

L=10E-3 ! SET LENGTH
W=10E-3 ! SET WIDTH
H=20E-3 ! SET HEIGHT
K,1
K,2,L
K,3,L,W
K,4,,W
KGEN,2,1,4,1,,,H
L,1,5
LESIZE,1,,,4
ESIZE,,2
MSHK,1 ! MAPPED VOLUME MESH
MSHA,0,3D ! USING HEX
V,1,2,3,4,5,6,7,8
MAT,3
VMESH,1
NSEL,S,LOC,X,0
DSYM,SYMM,X ! SYMMETRY BOUNDARY CONSTRAINTS
NSEL,S,LOC,Y,0
DSYM,SYMM,Y
NSEL,ALL
FINISH
/SOLU
ANTYP,MODAL
MODOPT,LANB,10,50000,150000 ! BLOCK LANCZOS, EXTRACT 10 MODES
MXPAND,10 ! EXPAND ALL MODES
/COM, ** RESONANCE FREQUENCY B.C.'S **
NSEL,S,LOC,Z,0
D,ALL,VOLT,0 ! GROUND BOTTOM ELECTRODE
NSEL,S,LOC,Z,H
D,ALL,VOLT,0 ! SHORT-CIRCUIT TOP ELECTRODE
NSEL,ALL
SOLVE
*GET,F1,MODE,2,FREQ
*GET,F2,MODE,5,FREQ
FINISH
/POST1
/VIEW,1,1,1,1
/VUP,,Z
/TYPE,,4
*DO,I,1,10
SET,LS,I
PLDISP,1 ! DISPLAY ANTI-RESONANCE MODE SHAPES
*ENDDO
FINISH
/SOLU
ANTYPE,MODAL
MODOPT,LANB,10,50000,150000 ! BLOCK LANCZOS, EXTRACT 10 MODES
MXPAND,10
/COM, ** ANTI-RESONANCE FREQUENCY B.C.'S **
NSEL,S,LOC,Z,H
DDELE,ALL,VOLT ! DELETE VOLT CONSTRAINTS ON TOP ELECTRODE
NSEL,ALL
SOLVE
*GET,F3,MODE,4,FREQ
*GET,F4,MODE,8,FREQ
FINISH
/POST1
*DO,I,1,10
SET,LS,I
PLDISP,1 ! DISPLAY RESONANCE MODE SHAPES
*ENDDO
*STATUS
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'F1 ','F2 '
LABEL(1,2) = 'Hz','Hz'
*VFILL,VALUE(1,1),DATA,66560,88010
*VFILL,VALUE(1,2),DATA,F1,F2
*VFILL,VALUE(1,3),DATA,ABS(F1/66560),ABS(F2/88010)
/COM
/OUT,vm175,vrt
/COM,------------------- VM175 RESULTS COMPARISON -------------
/COM,
/COM, SHORT CIRCUIT
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,
/NOPR
*VFILL,VALUE(1,1),DATA,81590,93410
*VFILL,VALUE(1,2),DATA,F3,F4
*VFILL,VALUE(1,3),DATA,ABS(F3/81590),ABS(F4/93410)
/GOPR
/COM, OPEN CIRCUIT
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm175,vrt


VM176 (Frequency Response of Electrical Input Admittance for a Piezoelectric Transducer) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM176
/PREP7
SMRT,OFF
/TITLE, VM176, FREQUENCY RESPONSE OF ELECTRICAL INPUT ADMITTANCE FOR A
/COM PIEZOELECTRIC TRANSDUCER
/COM KAGAWA AND YAMABUCHI, FINITE ELEMENT SIMULATION OF A COMPOSITE
/COM PIEZOELECTRIC ULTRASONIC TRANSDUCER, IEEE TRANS. SONICS AND
/COM ULTRASONICS, VOL. SU-26, NO.2, MARCH 1979
ET,1,SOLID5,0 ! 3-D COUPLED-FIELD SOLID
MP,DENS,3,7730 ! NEPEC DENSITY
MP,EX,2,7.03E10 ! ALUMINUM MODULUS OF ELASTICITY
MP,NUXY,2,.345 ! ALUMINUM POISSON RATIO
MP,DENS,2,2690 ! ALUMINUM DENSITY
MP,EX,4,10E9 ! ADHESIVE MODULUS OF ELASTICITY
MP,DENS,4,1700 ! ADHESIVE DENSITY
MP,NUXY,4,.38 ! ADHESIVE POISSON RATIO

TB,PIEZ,3 ! DEFINE PIEZO. TABLE FOR NEPEC
TBDATA,3,-6.10 ! PIEZO MATRIX CONSTANTS
TBDATA,6,-6.10
TBDATA,9,15.70
MP,PERX,3,8.7969E-9 ! PERMITTIVITY
TB,ANEL,3 ! DEFINE STRUCTURAL TABLE FOR NEPEC
TBDATA,1,12.80E10,6.8E10,6.6E10 ! INPUT [C] MATRIX FOR NEPEC
TBDATA,7,12.8E10,6.6E10
TBDATA,12,11.0E10
TBDATA,16,2.1E10
TBDATA,19,2.1E10
TBDATA,21,2.1E10

/COM ** DEFINE GEOMETRIC PARAMETERS **
R=27.5E-3 ! DISK RADIUS
HA=15.275E-3 ! ALUMINUM 1/2 HEIGHT LOCATION
HN=5E-3 ! NEPEC 1/2 HEIGHT
HB=5.275E-3 ! ADHESIVE MATERIAL HEIGHT
RDIV=5 ! NO. ELEMENTS ALONG RADIUS
HADV=3 ! NO. ELEMENTS ALONG ALUMINUM HEIGHT
HNDV=2 ! NO. ELEMENTS ALONG NEPEC HEIGHT
HBDV=1 ! NO. ELEMENTS ALONG ADHESIVE HEIGHT
ZRO=1E-5 ! DEFINE ZERO FOR KEYPOINT LOCATION
CSYS,1
K,1,ZRO,-5 ! DEFINE KEYPOINTS FOR MESH, WEDGE ELEMENTS
K,2,R,-5 ! ARE NOT ALLOWED BY MESH MODULE SO KEYPOINTS
K,3,R,-5,HN ! ARE DEFINED NEAR ZERO AND LATER MERGED
K,4,ZRO,-5,HN
K,5,R,-5,HB
K,6,ZRO,-5,HB
K,7,R,-5,HA
K,8,ZRO,-5,HA
KGEN,2,1,8,1,,10
L,2,3 ! DEFINE LINE SEGMENTS
LESIZE,1,,,HNDV
L,3,5
LESIZE,2,,,HBDV
L,5,7
LESIZE,3,,,HADV
L,2,10
LESIZE,4,,,1
V,11,3,4,12,10,2,1,9 ! CREATE NEPEC VOLUME
VATT,3 ! ASSIGN MATERIAL ATTRIBUTES
V,13,5,6,14,11,3,4,12 ! CREATE ADHESIVE VOLUME
VSEL,S,VOLU,,2
VATT,4 ! ASSIGN MATERIAL ATTRIBUTES
V,15,7,8,16,13,5,6,14 ! CREATE ALUMINUM VOLUME
VSEL,S,VOLU,,3
VATT,2 ! ASSIGN MATERIAL ATTRIBUTES
VSEL,ALL
MSHK,1 ! MAPPED VOLUME MESH
MSHA,0,3D ! USING HEX
ESIZE,,RDIV
SHPP,OFF ! TURN OFF SHAPE CHECKING TO ALLOW
! FOR WEDGE SHAPE MESH OF SOLIDS
VMESH,ALL ! MESH ALL VOLUMES
NUMMRG,NODE ! MERGE NODES TO CREATE WEDGE ELMENTS
! AT AXIS
NSEL,S,LOC,Y,-5
DSYM,SYMM,Y,1 ! SYMMETRY B.C. AT THETA=-5 DEG.
NSEL,S,LOC,Y,5
DSYM,SYMM,Y,1 ! SYMMETRY B.C. AT THETA=5 DEG.
NSEL,S,LOC,X,0,.001
DSYM,SYMM,X,1 ! SYMMETRY B.C. AT X=0
NSEL,S,LOC,Z,0
DSYM,SYMM,Z,1 ! SYMMETRY B.C. AT Z=0
NSEL,S,LOC,Z,HN ! SELECT NODES AT TOP ELECTRODE
CP,1,VOLT,ALL ! COUPLE VOLT DOF ON ELECTRODE
*GET,N1,NODE,,NUM,MIN ! GET NODE ON ELECTRODE
D,N1,VOLT,-0.5 ! APPLY -0.5 VOLT TO TOP ELECTRODE
NSEL,S,LOC,Z,0 ! SELECT NODES AT SYMMETRY PLANE
D,ALL,VOLT,0.0 ! SET VOLT TO ZERO AT SYMMETRY PLANE
NSEL,ALL
FINISH
/SOLU
EQSLV,SPARSE ! USING SPARSE MATRIX SOLVER
ANTYPE,HARMIC ! PERFORM HARMONIC ANALYSIS
OUTRES,ALL,ALL ! STORE EVERY SUBSTEP
HARFRQ,5000,35000 ! SOLVE FOR FREQ=20KHZ AND 35KHZ
NSUBST,2
KBC,1 ! STEP BOUNDARY CONDITIONS
EQSLV,ICCG ! ICCG SOLVER
SOLVE
HARFRQ,39000,45000 ! SOLVE FOR FREQ=42KHZ AND 45KHZ
SOLVE
HARFRQ,46000,54000 ! SOLVE FOR FREQ=50KHZ AND 54KHZ
SOLVE
FINISH
/POST26
RFORCE,2,N1,AMPS ! STORE CHARGES ON ELECTRODE
PI2=(3.14159*2.)
PROD,3,2,1,,MHOS,,,PI2 ! CALCULATE ADMITTANCE (10 DEG. SLICE)
PROD,4,3,,,MMHO,,,36000 ! CALCULATE TOTAL ADMITTANCE (MMHOS)
PRVAR,4 ! PRINT ELECTRICAL ADMITTANCE VS. FREQUENCY
*GET,F1,VARI,4,RTIME,20000
*GET,F2,VARI,4,RTIME,35000
*GET,F3,VARI,4,RTIME,42000
*GET,F4,VARI,4,RTIME,45000
*GET,F5,VARI,4,RTIME,50000
*GET,F6,VARI,4,RTIME,54000
*STATUS
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
LABEL(1,1) = 'Y MMHOS ','Y MMHOS','Y MMHOS ','Y MMHOS ','Y MMHOS ','Y MMHOS '
LABEL(1,2) = '@20 kHz','@35 kHz','@42 kHz','@45 kHz','@50 kHz','@54 kHz'
*VFILL,VALUE(1,1),DATA,.41,.9,2,0,.39,.65
*VFILL,VALUE(1,2),DATA,F1,F2,F3,F4,F5,F6
*VFILL,VALUE(1,3),DATA,ABS(F1/.41),ABS(F2/0.9),ABS(F3/2),0,ABS(F5/.39),ABS(F6/0.65)
/COM
/OUT,vm176,vrt
/COM,------------------- VM176 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT

FINISH
*LIST,vm176,vrt


VM177 (Natural Frequency of a Submerged Ring) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM177
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM177, NATURAL FREQUENCY OF SUBMERGED RING
/COM, REF. "FINITE ELEMENT SOLUTION OF FLUID STRUCTURE
/COM, INTERACTION PROBLEMS" SCHROEDER & MARCUS
/COM, SHOCK & VIBRATION SYMPOSIUM, SAN DIEGO, 1975
/COM, USING FLUID30 AND SHELL63 AND FULL HARMONIC ANALYSIS (ANTYPE=3)
ET,1,FLUID30 ! FLUID ELEMENTS INTERFACING WITH STRUCTURE
ET,2,SHELL63 ! SHELL ELEMENTS TO MODEL STEEL RING
ET,3,FLUID30,,1 ! NON-INTERFACING FLUID ELEMENTS
R,1,1
R,2,0.25
MP,DENS,1,9.6333E-5
MP,SONC,1,57480.0 ! SPEED OF SOUND IN WATER
MP,EX,2,30.E6
MP,DENS,2,7.4167E-4
MP,NUXY,2,0.3
CSYS,1
N,1,10.0
N,7,30.0
FILL
NGEN,9,10,1,10,1,0,(90/8)
NGEN,2,100,1,99,1,0,0,1 ! DEFINE UPPER PLANE OF NODES
E,1,101,111,11,2,102,112,12
EGEN,6,1,-1
EGEN,8,10,-6
TYPE,2
REAL,2
MAT,2
E,1,101,111,11
EGEN,8,10,-1
NSEL,S,LOC,X,10.0
ESLN
ESEL,INVE
TYPE,3
REAL,1
MAT,1
EMODIF,ALL ! CHANGE ELEMENT TYPE TO TYPE 3
ESEL,ALL
NSEL,S,LOC,X,10
SF,ALL,FSI ! COUPLE STRUCTURAL MOTION & FLUID PRESS.
NSEL,ALL
D,7,PRES,0.0,,87,10 ! SET PRESSURE AT OUTER RADIUS TO ZERO
D,107,PRES,0.0,,187,10
NSEL,S,LOC,X,10.0
NSEL,R,LOC,Y,90.0
DSYM,SYMM,X
NSEL,S,LOC,X,10.0
NSEL,R,LOC,Y,0.0
DSYM,SYMM,Y
NSEL,ALL
D,1,UZ,0.0,,7,6
D,81,UZ,0.0,,87,6
F,1,FX,1.0 ! EXCITE THE EVEN MODES OF VIBRATION
F,81,FY,0,1.0
FINISH
/SOLU
ANTYPE,HARMIC ! FULL HARMONIC ANALYSIS
HARFRQ,36.59,36.64 ! SELECT FREQUENCY RANGE
NSUBST,5
KBC,1
OUTRES,,1
EQSLV,ICCG ! ICCG SOLVER
/OUT,SOLVE,LOG ! DIVERT PLATFORM DEPENDENT SOLVER OUTPUT
SOLVE
/OUT
FINISH
/POST26
NSOL,2,1,U,X
NSOL,3,41,U,X
NSOL,4,81,U,Y
PRVAR,2,3,4 ! PRINT DISPLACEMENTS OF RING VS. FREQUENCY
FINISH
/POST1
SET,1,2
PLDISP,1
*GET,F1,ACTIVE,0,SET,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'F, '
LABEL(1,2) = ' HZ'
*VFILL,VALUE(1,1),DATA,35.62
*VFILL,VALUE(1,2),DATA,F1
*VFILL,VALUE(1,3),DATA,ABS(F1/35.62 )
SAVE,TABLE_1
SET,1,2,,1
PLDISP,1
FINISH
/CLEAR, NOSTART ! CLEAR DATABASE BEFORE STARTING PART 2
/PREP7
/COM, USING FLUID29 AND BEAM3 AND UNSYMMETRIC MATRIX MODAL ANALYSIS (ANTYPE=2)
ET,1,FLUID29 ! FLUID ELEMENTS INTERFACING WITH STRUCTURE
ET,2,BEAM3 ! BEAM ELEMENTS TO MODEL STEEL RING
ET,3,FLUID29,,1 ! NON-INTERFACING FLUID ELEMENTS
MP,EX,1,1
MP,DENS,1,9.6333E-5
MP,SONC,1,57480.0
MP,EX,2,30.E6
MP,DENS,2,7.4167E-4
MP,NUXY,2,0.3
R,1,1
R,2,.25,(.25**3)/12,.25
CSYS,1
N,1,10.0
N,7,30.0
FILL
NGEN,9,10,1,10,1,0,(90/8)
E,1,2,12,11 ! DEFINE FLUID ELEMENTS INTERFACE WITH STRUCTURE
EGEN,6,1,-1
EGEN,8,10,-6
TYPE,2
MAT,2
REAL,2
E,1,11 ! DEFINE BEAM ELEMENTS TO MODEL STEEL RING
EGEN,8,10,-1
ESEL,,TYPE,,2
NSLE
NSEL,R,LOC,Y,90
DSYM,SYMM,X ! APPLY SYMMETRY BOUNDARY CONDITION ON RING
NSLE
NSEL,R,LOC,Y,0
DSYM,SYMM,Y
ESEL,ALL
NSEL,S,LOC,X,10
ESLN
ESEL,INVE
TYPE,3
MAT,1
REAL,1
EMODIF,ALL ! DEFINE UNCOUPLED FLUID ELEMENTS
NSEL,ALL
ESEL,S,TYPE,,1 ! DEFINE FLUID-STRUCTURE INTERFACE
NSEL,R,LOC,X,10
SF,ALL,FSI ! COUPLE STRUCTURAL MOTION & FLUID PRESS.
ESEL,ALL
NSEL,S,LOC,X,30
D,ALL,PRES,0.0 ! SET PRESSURE AT OUTER RADIUS TO ZERO
NSEL,ALL
FINISH
/SOLU
ANTYPE,MODAL ! MODAL ANALYSIS
MODOPT,UNSYM,4,-100 ! SELECT UNSYMMETRIC MATRIX MODE EXTRACTION
MXPAND,,36.50,36.60 ! EXPAND THE MODES OVER A SELECTED FREQUENCY
SOLVE ! RANGE
FINISH
/POST1
SET,1,1
PLDISP,1
*GET,F2,ACTIVE,0,SET,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'F, '
LABEL(1,2) = ' Hz'
*VFILL,VALUE(1,1),DATA,35.62
*VFILL,VALUE(1,2),DATA,F2
*VFILL,VALUE(1,3),DATA,ABS(F2/35.62 )
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm177,vrt
/COM,------------------- VM177 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING FLUID30 & SHELL63
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING FLUID29 & BEAM3
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
/DELETE,TABLE_1
/DELETE,TABLE_2
FINISH
*LIST,vm177,vrt


VM178 (Plane Poiseuille Flow) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM178
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM178, PLANE POISEULEE FLOW
! FOUNDATIONS OF FLUID MECHANICS, S.W. YUAN, SECTION 8.36
/PREP7
smrt,off
ET,1,FLUID141 ! FLUID ELEMENT
FLDATA,NOMI,DENS,1 ! DENSITY
FLDATA,NOMI,VISC,1 ! VISCOSITY
K,1,0 ! GEOMETRY
K,2,10.
K,3,10.,2.
K,4, 0.,2.
L,1,2
LESIZE,1,,,8
L,2,3
LESIZE,2,,,6
L,3,4
LESIZE,3,,,8
L,4,1
LESIZE,4,,,6
A,1,2,3,4
AMESH,1
LSEL,S,LINE,,4 ! SELECT LINE SEGMENT AT INLET
NSLL,S,1 ! SELECT NODES ON INLET LINE SEGMENT
D,ALL,VY ! NO VELOCITY IN Y DIRECTION
D,ALL,PRES,0.1 ! INLET PRESSURE = 0.1 PSI
LSEL,S,LINE,,2 ! SELECT LINE SEGMENT AT OUTLET
NSLL,S,1
D,ALL,VY ! NO VELOCITY IN Y DIRECTION
D,ALL,PRES,0.0 ! OUTLET PRESSURE = 0.0 PSI
LSEL,S,LINE,,1,3,2
NSLL,S,1
D,ALL,VX,,,,,VY ! NO SLIP BC AT CHANNEL EDGES
LSEL,S,LINE,,ALL
NSEL,S,NODE,,ALL
NSEL,S,LOC,X,10. ! GET NODE NUMBERS FOR PATH ENDPOINTS
NSEL,R,LOC,Y, 0.
*GET,NOD1,NDMX
NSEL,S,LOC,X,10.
NSEL,R,LOC,Y, 2.
*GET,NOD2,NDMX
NSEL,ALL
FINISH
/SOLU
/OUT,SCRATCH ! REDIRECT CONVERGENCE OUTPUT
FLDATA,ITER,EXEC,50 ! # OF ITERATIONS
SOLVE
/OUT
FINISH
/POST1
SET,1,1
/EDGE,1,1
PLVECT,V ! DISPLAY VELOCITY VECTORS
/EDGE,1,0
PATH,VXX,2,,48 ! DEFINE PATH WITH NAME = "VXX"
PPATH,1,NOD1 ! DEFINE PATH POINTS BY NODE
PPATH,2,NOD2
PDEF,VX,V,X
PRPATH,VX
/AXLAB,Y,VELOCITY
PLPATH,VX ! DISPLAY VELOCITY PROFILE
LSEL,S,LINE,,ALL
NSEL,S,NODE,,ALL
NSEL,S,LOC,X,10
NSEL,R,LOC,Y,1
*GET,NOD2,NDMX
*GET,V1,NODE,NOD2,V,X
LSEL,S,LINE,,ALL
NSEL,S,NODE,,ALL
NSEL,S,LOC,X,10
NSEL,R,LOC,Y,(1+(1/3))
*GET,NOD3,NDMX
*GET,V2,NODE,NOD3,V,X
LSEL,S,LINE,,ALL
NSEL,S,NODE,,ALL
NSEL,S,LOC,X,10
NSEL,R,LOC,Y,(1+(2/3))
*GET,NOD4,NDMX
*GET,V3,NODE,NOD4,V,X
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = '@ Y=','@ Y=','@ Y='
LABEL(1,2) = '1 in ','1.33 in','1.67 in'
*VFILL,VALUE(1,1),DATA,.005,.0044,.0028
*VFILL,VALUE(1,2),DATA,V1,V2,V3
*VFILL,VALUE(1,3),DATA,ABS(V1/.005),ABS(V2/.0044),ABS(V3/.0028)
FINISH
/DELETE,SCRATCH
/DELETE,vm178,pfl
/DELETE,vm178,rsw
/OUT,vm178,vrt
/COM,------------------- VM178 RESULTS COMPARISON --------------
/COM,
/COM,
/COM,VX (in/sec) | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm178,vrt


VM179 (Dynamic Double Rotation of a Jointed Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM179
/PREP7
/TITLE, VM179, DYNAMIC DOUBLE ROTATION OF A JOINTED BEAM
C*** REFERENCE -- ANY BASIC MECHANICS TEXT
ANTYPE,TRANS ! FULL TRANSIENT DYNAMIC ANALYSIS
NLGEOM,ON ! LARGE DEFLECTION
SSTIF,OFF ! TURN OFF STRESS STIFFENING
NROPT,FULL,,OFF ! USE FULL NEWTON-RAPHSON WITHOUT ADAPTIVE DESCENT
ET,1,COMBIN7,,1 ! JOINT LOCK-UP WHEN STOP ENGAGED
ET,2,BEAM4
R,1,1E6,1E6,1E6,1E7,0,.05 ! TF = .05
RMORE,0,.5,,,,0.08727 ! 5 DEG. UPPER LIMIT
R,2,1,1,1,1,1
MP,EX,1,70E9 ! ALUMINUM MATERIAL PROPERTIES
MP,DENS,1,1E-6
MP,NUXY,1,.35
BETAD,3.1831E-6 ! 1% DAMPING AT 1000 HZ
N,1
N,2,1
N,3,1
N,4,2
N,5,1,-1 ! NODE 5 IS USED FOR ORIENTING JOINT
TYPE,1
REAL,1
E,2,3,5,5,1 ! JOINT ELEMENT
TYPE,2
REAL,2
E,1,2 ! BEAMS
E,3,4
D,1,UX,0,,,,UY,UZ,ROTX,ROTY ! ALLOW ONLY Z-ROTATION AT PINNED END
KBC,1
FINISH
/OUTPUT,SCRATCH
/SOLU
PRED,ON
NSUBST,5
F,1,MZ,.7854 ! BEGIN ROTZ WITH NON-ZERO ACCELERATION
TIME,.05
SOLVE
NSUBST,60
TIME,1 ! DELTA THETA-Z = 45 DEG. ( AT 1 SEC )
SOLVE
NSUBST,5
F,1,MZ,-.7854 ! SLOW ROTZ W/ "INSTANTANEOUS" REVERSAL OF APPLIED MOMENT
TIME,1.05
SOLVE
NSUBST,60
TIME,2 ! DELTA THETA-Z = 90 DEG. ( AT 2 SEC )
SOLVE
FINISH
/OUTPUT
/POST1
SET,2
PRNSOL,DOF
*GET,DX1,NODE,4,U,X
*GET,DY1,NODE,4,U,Y
*GET,RZ1,NODE,4,ROT,Z
ESEL,S,TYPE,,1
ETABLE,ROT_STAT,NMISC,1
ETABLE,ROTATE,NMISC,9
ESEL,ALL
PRETAB,ROTATE,ROT_STAT
SET,4
PRNSOL,DOF
*GET,DX2,NODE,4,U,X
*GET,DY2,NODE,4,U,Y
*GET,RZ2,NODE,4,ROT,Z
ESEL,S,TYPE,,1
ETABLE,REFL
ESEL,ALL
PRETAB,ROTATE,ROT_STAT
FINISH
PARSAV
/COPY,,rdb,,rest,rdb ! SAVE THE FILES NEEDED FOR RESTART (NOT NEEDED
/COPY,,ldhi,,rest,ldhi ! FOR STRAIGHT-THRU RUN)
/COPY,,r001,,rest,r001
/COPY,,rst,,rest,rst ! NEEDED FOR CONTINUITY OF THE RESULTS FILE
/CLEAR,NOSTART ! CLEAR THE DATABASE (TO SIMULATE RESTART)
/COM,
/COM, ----- RESTART ANALYSIS -----
/COPY,rest,rdb,,file,rdb ! COPY THE FILES NEEDED FOR RESTART (NOT NEEDED
/COPY,rest,ldhi,,file,ldhi ! FOR STRAIGHT-THRU RUN)
/COPY,rest,r001,,file,r001
/COPY,rest,rst,,file,rst
/OUTPUT,SCRATCH
/SOLU
ANTYPE,,REST ! USE RESTART ANALYSIS TO DEFINE MORE LOADSTEPS
NSUBST,5
F,1,MZ,0 ! REMOVE M1, ALLOW ROTZ MOTION TO STABILIZE
TIME,2.05
SOLVE
NSUBST,60
F,3,MX,.5 ! DELTA THETA-X = 5 DEG., THEN STOP ( AT 3 SEC )
TIME,3
SOLVE
FINISH
/OUTPUT
PARRES ! RESTORE PARAMETERS FROM INITIAL RUN
/POST1
SET,LAST
PRNSOL,DOF
*GET,DX3,NODE,4,U,X
*GET,DY3,NODE,4,U,Y
*GET,DZ3,NODE,4,U,Z
*GET,RX3,NODE,4,ROT,X
*GET,RZ3,NODE,4,ROT,Z
ESEL,S,TYPE,,1
ETABLE,ROT_STAT,NMISC,1
ETABLE,ROTATE,NMISC,9
ESEL,ALL
PRETAB,ROTATE,ROT_STAT
*STATUS
*DIM,LABEL,CHAR,11,2
*DIM,VALUE,,11,3
LABEL(1,1) = 'DX T1 ','DY T1 ','AZ T1 ','DX T2 ','DY T2 ','AZ T2 ','DX T3 ','DY T3 ','DZ T3 '
LABEL(10,1) = 'AX T3 ','AZ T3 '
LABEL(1,2) = 'in','in','rad','in','in','rad','in','in','in'
LABEL(10,2) = 'RAD','RAD'
*VFILL,VALUE(1,1),DATA,-.5858,1.4142,.7854,-2,2,1.5708,-2,1.9962,.08716
*VFILL,VALUE(10,1),DATA,.08727,1.5708
*VFILL,VALUE(1,2),DATA,DX1,DY1,RZ1,DX2,DY2,RZ2,DX3,DY3,DZ3
*VFILL,VALUE(10,2),DATA,RX3,RZ3
V1 = ABS(DX1/.5858)
V2 = (DY1/1.4142)
V3 = (RZ1/.7854)
V4 = ABS(DX2/2)
V5 = (DY2/2)
V6 = (RZ2/1.5708)
V7 = ABS(DX3/2)
V8 = (DY3/1.9962)
*VFILL,VALUE(1,3),DATA,V1,V2,V3,V4,V5,V6,V7,V8
*VFILL,VALUE(9,3),DATA,(DZ3/.08716),(RX3/.08727),(RZ3/1.5708)
/COM
/OUT,vm179,vrt
/COM,------------------- VM179 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT

FINISH
*LIST,vm179,vrt


VM180 (Bending of a Curved Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM180
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
smrt,off
/TITLE, VM180, BENDING OF A CURVED BEAM
C*** THEORY OF ELASTICITY, TIMOSHENKO & GOODIER, 3RD ED., P. 78
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,PLANE2
ET,2,BEAM3
R,2,1,1,1 ! ARBITRARY BEAM ELEMENT REAL CONSTANTS
MP,EX,1,30E6
MP,NUXY,1,0
CSYS,1
K,1,3.5
K,2,3.5,90
KGEN,2,1,2,1,1.0
L,2,4 ! CREATE STIFFENING BEAM ELEMENTS
LESIZE,1,,,4
TYPE,2
REAL,2
LMESH,1
L,1,2 ! CREATE CURVED BEAM
LESIZE,2,,,25
L,3,4
LESIZE,3,,,25
ESIZE,,4
A,1,2,4,3
AATT,1,1,1
AMESH,1
NROTAT,ALL
DK,1,ALL,,,1 ! DEFINE KEYPOINT CONSTRAINTS AND FORCES
DK,3,UY,,,1 ! IN GLOBAL CYLINDRICAL COORDINATE SYSTEM
FK,2,FY,100
FK,4,FY,-100
FINISH
/SOLU
SOLVE
FINISH
/POST1
RSYS,1
NSEL,R,LOC,X,3.5 ! SELECT INNER RADIUS NODES
NSEL,U,LOC,Y,90
PRNSOL,S,COMP
NSORT,S,Y
*GET,SI,SORT,,MAX
NSEL,ALL
NSEL,R,LOC,X,4.5 ! SELECT OUTER RADIUS NODES
NSEL,U,LOC,Y,90
PRNSOL,S,COMP
NSORT,S,Y
*GET,SO,SORT,,MIN
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'INR STR ','OTR STR '
LABEL(1,2) = 'psi ','psi '
*VFILL,VALUE(1,1),DATA,655,-555
*VFILL,VALUE(1,2),DATA,SI,SO
*VFILL,VALUE(1,3),DATA,ABS(SI/655),ABS(SO/555)
/COM
/OUT,vm180,vrt
/COM,------------------- VM180 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm180,vrt


VM181 (Natural Frequency of a Flat Circular Plate with a Clamped Edge) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM181
/PREP7
MP,PRXY,,0.3
SMRT,OFF
/TITLE, VM181, NATURAL FREQUENCY OF A FLAT CIRCULAR PLATE WITH A CLAMPED EDGE
C*** FORMULAS FOR NATURAL FREQUENCY AND MODE SHAPE, BLEVINS, PAGE 241
ET,1,PLANE2,,,1 ! AXISYMMETRIC ELEMENTS
MP,EX,1,3E7
MP,DENS,1,0.00073
MP,PRXY,1,0.3
K,1
K,2,17
KGEN,2,1,2,1,,.5
L,1,2
L,3,4
LESIZE,ALL,,,10 ! TEN DIVISIONS ALONG LENGTH
ESIZE,,1
A,1,2,4,3
AMESH,1
NSEL,R,LOC,X,0
D,ALL,UX
NSEL,ALL
DK,2,ALL,,,1
DK,4,UX,,,1
FINISH
/SOLU
ANTYPE,MODAL ! MODAL ANALYSIS
MODOPT,SUBSP,9
EQSLVE,PCG ! POWERSOLVER
SOLVE
*GET,F1,MODE,1,FREQ
*GET,F2,MODE,2,FREQ
*GET,F3,MODE,3,FREQ
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'F (0,0) ','F (0,1) ','F (0,2) '
LABEL(1,2) = 'Hz','Hz','Hz'
*VFILL,VALUE(1,1),DATA,172.64,671.79,1505.7
*VFILL,VALUE(1,2),DATA,F1,F2,F3
*VFILL,VALUE(1,3),DATA,ABS(F1/172.64),ABS(F2/671.79),ABS(F3/1505.7)
/COM
/OUT,vm181,vrt
/COM,------------------- VM181 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F15.2,' ',1F10.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm181,vrt


VM182 (Transient Response of a Spring-mass System) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM182
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM182; TRANSIENT RESPONSE OF A SPRING-MASS SYSTEM
C*** R. K. VIERCK, "VIBRATION ANALYSIS", 2ND EDITION, SEC.5-8
ANTYPE,MODAL ! MODE-FREQUENCY ANALYSIS
MODOPT,REDUC,2,,,2 ! PRINT TWO REDUCED MODE SHAPES
ET,1,COMBIN40,,,2 ! UY DOF
R,1,6,,2 ! K1=6 N/M M1=2 KG
R,2,16,,2 ! K2=16 N/M M2=2 KG
N,1
N,2,0,1
N,3,0,2
REAL,1
E,1,2
REAL,2
E,2,3
M,1,UY,2 ! UY MASTERS AT NODES 1 & 2
D,3,ALL
OUTPR,,ALL
FINISH
/SOLU
SOLVE
FINISH
/SOLU
ANTYPE,TRANS ! TRANSIENT DYNAMIC ANALYSIS
TRNOPT,MSUP,2 ! MODE SUPERPOSITION, BOTH MODES
DELTIM,0.01 ! INTEGRATION TIME STEP = .01
OUTPR,,NONE
OUTRES,,1
KBC,1 ! STEP BOUNDARY CONDITIONS
F,1,FY,0 ! FORCE = 0 AT TIME = 0 (INIT. CONDITIONS)
SOLVE
TIME,1.8
F,1,FY,50 ! FORCE = 50N FROM TIME = 0 TO 1.8 SEC
SOLVE
TIME,2.4
F,1,FY,0 ! FORCE = 0 FROM TIME = 1.8 TO 2.4 SEC
SOLVE
FINISH
/POST26
FILE,,rdsp ! REDUCED DISPLACEMENTS FILE
NSOL,2,1,U,Y,UY1
NSOL,3,2,U,Y,UY2
/GRID,1
/AXLAB,Y,DISP
PLVAR,2,3 ! DISPLAY DISPLACEMENT RESPONSE VS. TIME
PRVAR,2,3
*GET,Y1,VARI,2,RTIME,1.3
*GET,Y2,VARI,3,RTIME,1.3
*GET,Y3,VARI,2,RTIME,2.4
*GET,Y4,VARI,3,RTIME,2.4
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'DISP 1 ','DISP 2 '
LABEL(1,2) = 'm','m'
*VFILL,VALUE(1,1),DATA,14.48,3.99
*VFILL,VALUE(1,2),DATA,Y1,Y2
*VFILL,VALUE(1,3),DATA,ABS(Y1/14.48),ABS(Y2/3.99)
SAVE,TABLE_1
*VFILL,VALUE(1,1),DATA,18.32,6.14
*VFILL,VALUE(1,2),DATA,Y3,Y4
*VFILL,VALUE(1,3),DATA,ABS(Y3/18.32),ABS(Y4/6.14),
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm182,vrt
/COM,------------------- VM182 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS AT T=1.3 S
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS AT T=2.4 S
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
/DELETE,TABLE_1
/DELETE,TABLE_2
FINISH
*LIST,vm182,vrt


VM183 (Harmonic Response of a Spring-mass System) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM183
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM183, HARMONIC RESPONSE OF A SPRING-MASS SYSTEM
C*** R.K. VIERCK, "VIBRATION ANALYSIS", 2ND EDITION, SECTION 4-2
ANTYPE,MODAL ! MODE - FREQUENCY ANALYSIS
MODOPT,REDUC,2,,,2 ! PRINT TWO REDUCED MODE SHAPES
ET,1,COMBIN40,,,2 ! UY DOF
R,1,6,,2 ! K1=6 N/M M1=2 KG
R,2,16,,2 ! K2=16 N/M M2=2 KG
N,1
N,2,0,1
N,3,0,2
REAL,1
E,1,2
REAL,2
E,2,3
M,1,UY,2 ! UY MASTERS AT NODES 1 & 2
OUTPR,,ALL
D,3,ALL
FINISH
/SOLU
SOLVE
FINISH
/SOLU
ANTYPE,HARMIC ! HARMONIC ANALYSIS
HROPT,MSUP,2 ! MODE SUPERPOSITION USING TWO MODES
HARFRQ,0.1,1.0 ! RANGE OF FREQUENCIES FROM 0.1 TO 1.0 HZ
F,1,FY,50
KBC,1 ! STEP BOUNDARY CONDITIONS
NSUBST,50
OUTPR,,NONE
OUTRES,,1
SOLVE
FINISH
/POST26
FILE,,rfrq ! REDUCED FREQUENCIES FILE
NSOL,2,1,U,Y,UY1
NSOL,3,2,U,Y,UY2
/GRID,1
/AXLAB,Y,DISP
PLVAR,2,3 ! DISPLAY DISPLACEMENT RESPONSE VS. FREQUENCY
PRVAR,2,3
*GET,Y1,VARI,2,RTIME,.226
*GET,Y2,VARI,3,RTIME,.226
*GET,Y3,VARI,2,RTIME,.910
*GET,Y4,VARI,3,RTIME,.910
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'DISP 1 ','DISP 2 '
LABEL(1,2) = 'm','m'
*VFILL,VALUE(1,1),DATA,-1371.7,-458.08
*VFILL,VALUE(1,2),DATA,Y1,Y2
*VFILL,VALUE(1,3),DATA,ABS(Y1/1371.7),ABS(Y2/458.08)
SAVE,TABLE_1
*VFILL,VALUE(1,1),DATA,-.8539,.1181
*VFILL,VALUE(1,2),DATA,Y3,Y4
*VFILL,VALUE(1,3),DATA,ABS(Y3/.8539),ABS(Y4/.1181),
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm183,vrt
/COM,------------------- VM183 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS AT .226 Hz
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS AT .910 Hz
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm183,vrt

/DELETE,TABLE_1
/DELETE,TABLE_2
FINISH


VM184 (Straight Cantilever Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM184
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
smrt,off
/TITLE, VM184, STRAIGHT CANTILEVER BEAM
C*** ANY BASIC MECHANICS OF MATERIALS TEXT
C*** USING SOLID5 HEXAHEDRONS
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,SOLID5,2 ! MULTI-FIELD SOLID5
MP,EX,1,1E7
MP,NUXY,1,0.3
K,1
K,2,6
KGEN,2,1,2,1,,.2
KGEN,2,1,4,1,,,.1
L,1,2
LESIZE,ALL,,,10
ESIZE,,1
V,1,2,4,3,5,6,8,7
VMESH,1
NSEL,S,LOC,X,0
D,ALL,ALL ! CONSTRAIN LEFT END
NSEL,ALL
FK,2,FX,0.25 ! APPLY AXIAL FORCES
*REPEAT,4,2
NOORDER
FINISH
/SOLU
SOLVE
FKDELE,ALL,FX ! DELETE AXIAL FORCES
FK,2,FY,0.25 ! APPLY IN-PLANE LOADS
*REPEAT,4,2
SOLVE
FKDELE,ALL,FY ! DELETE IN-PLANE LOADS
FK,2,FZ,0.25 ! APPLY OUT-OF-PLANE LOADS
*REPEAT,4,2
SOLVE
FINISH
/POST1 ! PRINT END DISPLACEMENTS AS RATIO OF ANSYS:TARGET
CSYS,0
*CREATE,MAC ! DEFINE MACRO TO CALCULATE ANSYS:TARGET RATIOS
SET,ARG1,1
LCDEF,ARG1,ARG1
NSEL,S,LOC,X,6 ! SELECT NODE AT END OF BEAM
PRNSOL,U,COMP ! PRINT DISPLACEMENTS
LCFACT,ARG1,ARG2 ! APPLY SCALE FACTOR "ARG2" TO LOAD CASE 1
LCASE,ARG1
PRNSOL,U,COMP ! PRINT DISPLACEMENTS
*END
/COM *** USE MACRO TO PROCESS ALL 3 LOADCASES ***
*USE,MAC,1,(1/3E-5)
SET,1,1
LCSEL,S,0,0
N1=NODE(6,0,0)
*GET,UX1,NODE,N1,U,X
*USE,MAC,2,(1/.108)
SET,2,1
LCSEL,S,0,0
*GET,UY1,NODE,N1,U,Y
*USE,MAC,3,(1/.432)
SET,3,1
LCSEL,S,0,0
*GET,UZ1,NODE,N1,U,Z
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFL X ','DEFL Y ','DEFL Z '
LABEL(1,2) = 'in','in','in'
*VFILL,VALUE(1,1),DATA,3E-5,.108,.432
*VFILL,VALUE(1,2),DATA,UX1,UY1,UZ1
*VFILL,VALUE(1,3),DATA,ABS(UX1/(3E-5)),ABS(UY1/.108),ABS(UZ1/.432)
SAVE,TABLE_1
FINISH
/CLEAR, NOSTART

/PREP7
smrt,off
MOPT,VMESH,MAIN
MOPT,AMESH,ALTE
/TITLE, VM184, STRAIGHT CANTILEVER BEAM
C*** USING SOLID92 TETRAHEDRONS
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,SOLID92 ! STRUCTURAL SOLID92
MP,EX,1,1E7
MP,NUXY,1,0.3
K,1
K,2,,.2
KGEN,2,1,2,1,,,.1
KGEN,2,1,4,1,(2/3)
ESIZE,,1
V,1,2,4,3,5,6,8,7
VMESH,1
VGEN,9,1,1,1,(2/3),,,4 ! GENERATE 9 VOLUMES TO COMPLETE BEAM
NSEL,S,LOC,X,0
D,ALL,ALL ! CONSTRAIN LEFT END
SAVE
/COM *** GET NODE NUMBERS FOR LOAD APPLICATION ***
NSEL,S,LOC,X,6
NSEL,R,LOC,Y,.1
NSEL,R,LOC,Z,.05
*GET,MIDD,NDMX
NSEL,S,LOC,X,6
NSEL,R,LOC,Y,.2
NSEL,R,LOC,Z,.05
*GET,TOPP,NDMX
NSEL,S,LOC,X,6
NSEL,R,LOC,Y,.0
NSEL,R,LOC,Z,.05
*GET,BOTT,NDMX
NSEL,S,LOC,X,6
NSEL,R,LOC,Y,.1
NSEL,R,LOC,Z,.10
*GET,LFT,NDMX
NSEL,S,LOC,X,6
NSEL,R,LOC,Y,.1
NSEL,R,LOC,Z,.00
*GET,RGHT,NDMX
NSEL,ALL
/COM *** APPLY LOADS TO PARAMETRIC NODE NUMBERS ***
F,RGHT,FX,(1/6)
F,LFT,FX,(1/6)
F,TOPP,FX,(1/6)
F,BOTT,FX,(1/6)
F,MIDD,FX,(1/3)
FINISH
/SOLU
SOLVE
FDELE,ALL ! REMOVE ALL FORCES
F,RGHT,FY,(1/6)
F,LFT,FY,(1/6)
F,TOPP,FY,(1/6)
F,BOTT,FY,(1/6)
F,MIDD,FY,(1/3)
SOLVE
FDELE,ALL ! REMOVE ALL FORCES
F,RGHT,FZ,(1/6)
F,LFT,FZ,(1/6)
F,TOPP,FZ,(1/6)
F,BOTT,FZ,(1/6)
F,MIDD,FZ,(1/3)
SOLVE
FINISH
/POST1 ! PRINT END DISPLACEMENTS AS RATIO OF ANSYS:TARGET
/COM *** USE MACRO TO PROCESS ALL 3 LOADCASES ***
*USE,MAC,1,(1/3E-5)
SET,1,1
LCSEL,S,0,0
N1=NODE(6,0,0)
*GET,UX2,NODE,N1,U,X
*USE,MAC,2,(1/.108)
SET,2,1
LCSEL,S,0,0
*GET,UY2,NODE,N1,U,Y
*USE,MAC,3,(1/.432)
SET,3,1
LCSEL,S,0,0
*GET,UZ2,NODE,N1,U,Z
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFL X ','DEFL Y ','DEFL Z '
LABEL(1,2) = 'in','in','in'
*VFILL,VALUE(1,1),DATA,3E-5,.108,.432
*VFILL,VALUE(1,2),DATA,UX2,UY2,UZ2
*VFILL,VALUE(1,3),DATA,ABS(UX2/(3E-5)),ABS(UY2/.108),ABS(UZ2/.432)
SAVE,TABLE_2
FINISH
/CLEAR, NOSTART

/PREP7
smrt,off
MOPT,VMESH,MAIN
MOPT,AMESH,ALTE
/COM *** REPEAT USING SOLID98 TETRAHEDRONS ***
RESUME ! RESTORE PREP7 DATABASE
ET,1,SOLID98,2 ! MULTI-FIELD SOLID98
/COM *** GET NODE NUMBERS FOR LOAD APPLICATION ***
NSEL,S,LOC,X,6
NSEL,R,LOC,Y,.1
NSEL,R,LOC,Z,.05
*GET,MIDD,NDMX
NSEL,S,LOC,X,6
NSEL,R,LOC,Y,.2
NSEL,R,LOC,Z,.05
*GET,TOPP,NDMX
NSEL,S,LOC,X,6
NSEL,R,LOC,Y,.0
NSEL,R,LOC,Z,.05
*GET,BOTT,NDMX
NSEL,S,LOC,X,6
NSEL,R,LOC,Y,.1
NSEL,R,LOC,Z,.10
*GET,LFT,NDMX
NSEL,S,LOC,X,6
NSEL,R,LOC,Y,.1
NSEL,R,LOC,Z,.0
*GET,RGHT,NDMX
NSEL,ALL
/COM *** APPLY LOADS TO PARAMETRIC NODE NUMBERS ***
F,RGHT,FX,(1/6)
F,LFT,FX,(1/6)
F,TOPP,FX,(1/6)
F,BOTT,FX,(1/6)
F,MIDD,FX,(1/3)
FINISH
/SOLU
SOLVE
FDELE,ALL ! REMOVE ALL FORCES
F,RGHT,FY,(1/6)
F,LFT,FY,(1/6)
F,TOPP,FY,(1/6)
F,BOTT,FY,(1/6)
F,MIDD,FY,(1/3)
SOLVE
FDELE,ALL ! REMOVE ALL FORCES
F,RGHT,FZ,(1/6)
F,LFT,FZ,(1/6)
F,TOPP,FZ,(1/6)
F,BOTT,FZ,(1/6)
F,MIDD,FZ,(1/3)
SOLVE
FINISH
/POST1 ! PRINT END DISPLACEMENTS AS RATIO OF ANSYS:THEORY
/COM *** USE MACRO TO PROCESS ALL 3 LOADCASES ***
*USE,MAC,1,(1/3E-5)
SET,1,1
LCSEL,S,0,0
N1=NODE(6,0,0)
*GET,UX3,NODE,N1,U,X
*USE,MAC,2,(1/.108)
SET,2,1
LCSEL,S,0,0
*GET,UY3,NODE,N1,U,Y
*USE,MAC,3,(1/.432)
SET,3,1
LCSEL,S,0,0
*GET,UZ3,NODE,N1,U,Z
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFL X ','DEFL Y ','DEFL Z '
LABEL(1,2) = 'in','in','in'
*VFILL,VALUE(1,1),DATA,3E-5,.108,.432
*VFILL,VALUE(1,2),DATA,UX3,UY3,UZ3
*VFILL,VALUE(1,3),DATA,ABS(UX3/(3E-5)),ABS(UY3/.108),ABS(UZ3/.432)
SAVE,TABLE_3
FINISH
/CLEAR,NOSTART

/PREP7
smrt,off
MOPT,VMESH,ALTE
MOPT,AMESH,ALTE
ANTYPE,STATIC ! STATIC ANALYSIS
ET,1,SOLID147
MP,EX,1,1E7
MP,NUXY,1,0.3
K,1
K,2,6
KGEN,2,1,2,1,,.2
KGEN,2,1,4,1,,,.1
L,1,2
LESIZE,ALL,,,10
ESIZE,,1
V,1,2,4,3,5,6,8,7
VMESH,1
NSEL,S,LOC,X,0
D,ALL,ALL ! CONSTRAIN LEFT END
NSEL,ALL
FK,2,FX,0.25 ! APPLY AXIAL FORCES
*REPEAT,4,2
NOORDER
FINISH
/SOLU
SOLVE
FKDELE,ALL,FX ! DELETE AXIAL FORCES
FK,2,FY,0.25 ! APPLY IN-PLANE LOADS
*REPEAT,4,2
SOLVE
FKDELE,ALL,FY ! DELETE IN-PLANE LOADS
FK,2,FZ,0.25 ! APPLY OUT-OF-PLANE LOADS
*REPEAT,4,2
SOLVE
FINISH
/POST1 ! PRINT END DISPLACEMENTS AS RATIO OF ANSYS:TARGET
CSYS,0
*CREATE,MAC ! DEFINE MACRO TO CALCULATE ANSYS:TARGET RATIOS
SET,ARG1,1
LCDEF,ARG1,ARG1
NSEL,S,LOC,X,6 ! SELECT NODE AT END OF BEAM
PRNSOL,U,COMP ! PRINT DISPLACEMENTS
LCFACT,ARG1,ARG2 ! APPLY SCALE FACTOR "ARG2" TO LOAD CASE 1
LCASE,ARG1
PRNSOL,U,COMP ! PRINT DISPLACEMENTS
*END
/COM *** USE MACRO TO PROCESS ALL 3 LOADCASES ***
*USE,MAC,1,(1/3E-5)
SET,1,1
LCSEL,S,0,0
N1=NODE(6,0,0)
*GET,UX1,NODE,N1,U,X
*USE,MAC,2,(1/.108)
SET,2,1
LCSEL,S,0,0
*GET,UY1,NODE,N1,U,Y
*USE,MAC,3,(1/.432)
SET,3,1
LCSEL,S,0,0
*GET,UZ1,NODE,N1,U,Z
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFL X ','DEFL Y ','DEFL Z '
LABEL(1,2) = 'in','in','in'
*VFILL,VALUE(1,1),DATA,3E-5,.108,.432
*VFILL,VALUE(1,2),DATA,UX1,UY1,UZ1
*VFILL,VALUE(1,3),DATA,ABS(UX1/(3E-5)),ABS(UY1/.108),ABS(UZ1/.432)
SAVE,TABLE_4
RESUME,TABLE_1
/COM *** CLIPPED AND CAPPED DISPLAY OF STRESS CONTOURS ***
NSEL,ALL
/VIEW,1,2,1,1
EPLOT ! ELEMENT PLOT
/TYPE,1,CAP ! DISPLAY TYPE CAP
/DIST,1,.2
/FOCUS,1,.3,.15,.09 ! SET FOCUS FOR SECTION LOCATION
PLNSOL,S,X ! STRESS CONTOUR PLOT
/COM
/OUT,vm184,vrt
/COM,------------------- VM184 RESULTS COMPARISON ------------
/COM,
/COM, TARGET | ANSYS | RATIO
/COM, SOLID5
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.6,' ',F11.6,' ',1F6.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM, SOLID92
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.6,' ',F11.6,' ',1F6.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM, SOLID98
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.6,' ',F11.6,' ',1F6.3)
/NOPR
RESUME,TABLE_4
/GOPR
/COM
/COM, SOLID147
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.6,' ',F11.6,' ',1F6.3)
/COM,---------------------------------------------------------
/OUT
FINISH
/DELETE,MAC
/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,TABLE_3
/DELETE,TABLE_4
*LIST,vm184,vrt


VM185 (AC Analysis of a Slot Embedded Conductor) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM185
/PREP7
SMRT,OFF
/TITLE, VM185, AC ANALYSIS OF A SLOT EMBEDDED CONDUCTOR
C*** KONRAD, A., "INTEGRODIFFERENTIAL FINITE ELEMENT FORMULATION
C*** OF TWO-DIMENSIONAL STEADY-STATE SKIN EFFECT PROBLEMS",
C*** IEEE TRANS. MAGNETICS, VOL. MAG-18, NO. 1, JAN. 1982
C*** PP. 284-292.
C***
ET,1,PLANE13 ! PLANE13, AZ DOF, (FOR AIR)
ET,2,PLANE13,6 ! PLANE13, AZ VOLT DOF, (FOR CONDUCTOR)
EMUNIT,MKS ! DEFINE SYSTEM UNITS
MP,MURX,1,1 ! RELATIVE PERMEABILITY
MP,MURX,2,1
RES=1.724E-8 ! DEFINE RESISTIVITY OF CONDUCTOR
MP,RSVZ,2,RES ! CONDUCTOR RESISTIVITY
A=6.45E-3 ! DEFINE GEOMETRY IN TERMS OF PARAMETERS
B=8.55E-3
C=8.45E-3
D=18.85E-3
E=8.95E-3
F=(D-E)/2

PTXY,0,0,D,0,D,C,D-F,C ! CREATE POLYGON AREA OF CONDUCTOR
PTXY,D-F,B+C,F,B+C,F,C,0,C
POLY
RECTNG,F,F+E,B+C,B+C+A ! CREATE AIR AREA
AGLUE,1,2 ! GLUE AREAS TOGETHER

ASEL,S,AREA,,3
AATT,1,,1 ! SET ATTRIBUTES FOR AIR
ASEL,S,AREA,,1
AATT,2,,2 ! SET ATTRIBUTES FOR CONDUCTOR
ASEL,ALL
ESIZE,D/15 ! SET ELEMENT EDGE LENGTH
MSHK,0 ! FREE AREA MESH
MSHA,1,2D ! USING TRIS
AMESH,ALL ! MESH AREAS
ESEL,S,MAT,,2 ! SELECT ALL NODES IN CONDUCTOR
NSLE,S
CP,1,VOLT,ALL ! COUPLE ALL NODES IN VOLT
I=1.0 ! DEFINE TOTAL CURRENT
ASUM ! CALCULATE AREA ATTRIBUTES
*GET,AREA,AREA,1,AREA ! GET AREA OF CONDUCTOR
*GET,N1,NODE,,NUM,MIN ! SELECT A NODE IN THE CONDUCTOR
F,N1,AMPS,I ! APPLY 1 AMP TOTAL CURRENT
ESEL,ALL
NSEL,S,LOC,Y,.02345 ! SELECT NODES AT TOP PLANE
D,ALL,AZ,0 ! SET FLUX PARALLEL B.C.
NSEL,ALL
FINISH
/SOLU
ANTYPE,HARMIC ! HARMONIC ANALYSIS
HARFRQ,45 ! SET OPERATING FREQUENCY
SOLVE
FINISH
/POST1
SET,1,1 ! RETRIEVE REAL SOLUTION
ETABLE,JT,NMISC,7 ! STORE TOTAL CURRENT DENSITY
ETABLE,JS,SMISC,1 ! STORE SOURCE CURRENT DENSITY
ETABLE,JE,NMISC,6 ! STORE EDDY CURRENT DENSITY
/PNUM,MAT,1
/EDGE,1,1
/NUM,1
/SHOW,JPEG
/GFILE,500
JPEG,QUAL,100
/TRIAD,OFF
/PLOPTS,LOGO,0
/PLOPTS,INFO,2
/PLOPTS,WP,0
/RGB,INDEX,100,100,100,0
/RGB,INDEX,80,80,80,13
/RGB,INDEX,60,60,60,14
/RGB,INDEX,0,0,0,15
PLNSOL,A,Z ! DISPLAY FLUX LINES
/NUM,0
ESEL,MAT,2 ! SELECT COPPER ONLY
PLETAB,JT,1 ! DISPLAY TOTAL CURRENT DENSITY
PLETAB,JE,1 ! DISPLAY EDDY CURRENT DENSITY
*GET,JSR,ELEM,1,ETAB,JS ! GET REAL COMPONENT OF JS
ACRE=JSR*RES/I ! CALCULATE AC RESISTANCE/LENGTH
SET,1,1,,1 ! READ IN IMAGINARY DATA
ETABLE,REFL ! REFILL ELEMENT TABLE WITH IMAG. DATA
*GET,JSI,ELEM,1,ETAB,JS ! GET IMAGINARY COMPONENT OF JS
ACRA=JSI*RES/I ! CALCULATE AC REACTANCE/LENGTH
DCRE=RES/AREA ! CALCULATE DC RESISTANCE/LENGTH
RAT=ACRE/DCRE ! AC/DC LOSS RATIO
/OUTPUT
/GOPR
*STATUS ! SHOW PARAMETER STATUS
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'JS ','JS ','LOSS '
LABEL(1,2) = '(RE)','(IM)','RATIO'
*VFILL,VALUE(1,1),DATA,10183,27328,2.33
*VFILL,VALUE(1,2),DATA,JSR,JSI,RAT
*VFILL,VALUE(1,3),DATA,ABS(JSR/10183),ABS(JSI/27328),ABS(RAT/2.33)
/COM
/OUT,vm185,vrt
/COM,------------------- VM185 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.2,' ',F11.2,' ',1F6.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM185 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm185,vrt


VM186 (Transient Analysis of a Slot Embedded Conductor) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM186
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM186, TRANSIENT ANALYSIS OF A SLOT EMBEDDED CONDUCTOR
C*** KONRAD, IEEE TRANS., MAGNETICS, VOL. MAG-18, NO. 1, JAN. 1982
/NOPR
ANTYPE,TRANS ! NONLINEAR TRANSIENT DYNAMIC ANALYSIS
ET,1,PLANE13 ! PLANE13, AZ DOF, (FOR AIR)
ET,2,PLANE13,6 ! PLANE13, AZ VOLT DOF, (FOR CONDUCTOR)
EMUNIT,MUZRO,1 ! SET MUZERO=1
MP,MURX,1,1 ! RELATIVE PERMEABILITY
MP,MURX,2,1 ! RELATIVE PERMEABILITY (CONDUCTOR)
MP,RSVX,2,1 ! RESISTIVITY (CONDUCTOR)
N,1
N,8,,7
FILL
NGEN,2,8,1,8,1,1
MAT,2
TYPE,2
E,1,2,10,9
EGEN,4,1,-1
MAT,1
TYPE,1
E,5,6,14,13
EGEN,3,1,-1
CP,1,AZ,1,9 ! COUPLE AZ TO ENSURE 1-D SOLUTION
*REPEAT,5,1,,1,1
ESEL,,MAT,,2
NSLE
CP,6,VOLT,ALL ! COUPLE VOLT IN CONDUCTOR
ESEL,ALL
NSEL,S,LOC,Y,7
D,ALL,AZ,0 ! FLUX-PARALLEL B.C.
NSEL,ALL
FINISH
/SOLU
EQSLV,JCG,1E-9 ! USE THE JACOBI CONJUGATE GRADIENT SOLVER
T=1E-8 ! INITIALIZE TIME PARAMETER
C=0 ! INITIALIZE COUNTER PARAMETER
N=80 ! NUMBER OF TIME INCREMENTS PER TURN
PI=2*ASIN(1) ! VALUE OF PI
CON=2*PI/N ! SET TIME INCREMENT
NEQIT,1 ! 1 ITERATION PER TIME STEP
*CREATE,LOAD ! CREATE MACRO TO SET UP LOAD STEPS
TIME,T
I=4*SIN(T) ! CALCULATE CURRENT
F,1,AMPS,I ! APPLY CURRENT TO A NODE IN CONDUCTOR
T=T+CON ! INCREMENT TIME
C=C+1 ! INCREMENT COUNTER
OUTRES,ALL,1
*IF,C,EQ,((N*.75)+1),THEN ! SET FOR PRINTOUT AT DESIRED TIME POINTS
OUTPR,,1
*ELSEIF,C,EQ,(N+1),THEN
OUTPR,,1
*ELSE
OUTPR,,0
*ENDIF
SOLVE
*END
*DO,I,1,81 ! REPEAT MACRO EXECUTION
*USE,LOAD ! EXECUTE MACRO
*ENDDO
FINISH
/POST26
NUMVAR,12 ! INCREASE STORAGE ARRAY SIZE
ESOL,2,1,,NMISC,6,JE ! STORE JE
*REPEAT,4,1,1
ESOL,6,1,,VOLUME ! STORE VOLUME
*REPEAT,4,1,1
PROD,2,2,6 ! CALCULATE IE=JE*VOLUME
*REPEAT,4,1,1,1
ADD,2,2,3,4,IE ! SUMM IE OVER ALL CONDUCTOR ELEMENTS
ADD,10,2,5,,IE ! IE TOTAL
ESOL,2,1,,SMISC,1,JS ! STORE JS
*REPEAT,4,1,1
PROD,2,2,6 ! CALCULATE IS=JS*VOLUME
*REPEAT,4,1,1,1
ADD,2,2,3,4,IS ! SUM IS OVER ALL CONDUCTOR ELEMENTS
ADD,11,2,5,,IS ! IS TOTAL
ESOL,2,1,,NMISC,7,JT ! STORE JT
*REPEAT,4,1,1
PROD,2,2,6 ! CALCULATE IT=JT*VOLUME
*REPEAT,4,1,1,1
ADD,2,2,3,4,IT ! SUM IT OVER ALL CONDUCTOR ELEMENTS
ADD,12,2,5,,IT ! IT TOTAL
/AXLAB,Y,CURRENT
/GROPT,AXNSC,2.0
PRVAR,10,11,12 ! PRINT EDDY, SOURCE, AND TOTAL CURRENT
PLVAR,10,11,12 ! DISPLAY EDDY, SOURCE, AND TOTAL CURRENT
FINISH
/POST1
SET,61,1,,,4.7124
*GET,A1,NODE,1,A,Z
*GET,A2,NODE,4,A,Z
*GET,A3,NODE,7,A,Z
SET,81,1,,,6.2832
*GET,A4,NODE,1,A,Z
*GET,A5,NODE,4,A,Z
*GET,A6,NODE,7,A,Z
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'NODE ','NODE ','NODE '
LABEL(1,2) = '1','4','7'
*VFILL,VALUE(1,1),DATA,-15.18,-14.68,-4
*VFILL,VALUE(1,2),DATA,A1,A2,A3
*VFILL,VALUE(1,3),DATA,ABS(A1/15.18),ABS(A2/14.68),ABS(A3/4)
SAVE,TABLE_1
*VFILL,VALUE(1,1),DATA,-3.26,-.92,0
*VFILL,VALUE(1,2),DATA,A4,A5,A6
*VFILL,VALUE(1,3),DATA,ABS(A4/3.26),ABS(A5/.92),
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm186,vrt
/COM,------------------- VM186 RESULTS COMPARISON --------------
/COM,
/COM, VECTOR POTENTIAL | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS AT T=(3*PI/2)
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS AT T=(2*PI)
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/OUT
FINISH
*LIST,vm186,vrt

/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,LOAD
FINISH


VM187 (Bending of a Curved Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM187
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
smrt,off
/TITLE, VM187, BENDING OF A CURVED BEAM
C*** FORMULAS FOR STRESS AND STRAIN, ROARK, 4TH ED.
ANTYPE,STATIC
ET,1,SOLID5,2 ! USING SOLID5 HEXAHEDRONS, DISPLACEMENT DOF ONLY
MP,EX,,1E7
MP,NUXY,,.25
CSYS,1
K,1,4.12 ! DEFINE KEYPOINTS
K,2,4.32
KGEN,2,1,2,1,,,.1
KGEN,2,1,4,1,,90
L,1,5
LESIZE,1,,,20
V,1,2,4,3,5,6,8,7 ! DEFINE VOLUME
ESIZE,,1
VMESH,1 ! CREATE NODES AND ELEMENTS
NSEL,S,LOC,Y,0
D,ALL,ALL,0 ! BOUNDARY CONDITIONS AND LOADING
NSEL,ALL
FK,5,FY,.25 ! APPLY LOAD
*REPEAT,4,1
NOORDER
FINISH
/SOLU
SOLVE
FINISH
*CREATE,MAC ! CREATE A MACRO TO DO POSTPROCESSING
/POST1
CSYS,0
NSEL,S,LOC,X,0,.001,,1 ! SELECT NODES AT FREE END OF BEAM
PRNSOL,U,COMP
LCDEF,1,1
LCFACT,1,(1/.08854)
LCASE,1
PRNSOL,U,COMP
FINISH
*END
*GET,U1,NODE,5,U,Y
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'DEFL '
LABEL(1,2) = 'in '
*VFILL,VALUE(1,1),DATA,.08854
*VFILL,VALUE(1,2),DATA,U1
*VFILL,VALUE(1,3),DATA,ABS(U1/.08854)
SAVE,TABLE_1
*USE,MAC ! EXECUTE POSTPROCESSING MACRO
/CLEAR, NOSTART
/PREP7
smrt,off
/TITLE, VM187, BENDING OF A CURVED BEAM
ET,1,SOLID92 ! USING SOLID92 TETRAHEDRONS
MP,EX,,1E7
MP,NUXY,,.25
CSYS,1
K,1,4.12 ! DEFINE KEYPOINTS
K,2,4.32
KGEN,2,1,2,1,,,.1
KGEN,2,1,4,1,,4.5
V,1,2,4,3,5,6,8,7 ! DEFINE VOLUMES
VGEN,20,1,1,1,,4.5,,4
ESIZE,,1
VMESH,ALL ! CREATE NODES AND ELEMENTS
NSEL,S,LOC,Y,0
D,ALL,ALL,0 ! BOUNDARY CONDITIONS AND LOADING
NSEL,S,LOC,Y,90
CP,1,UY,ALL ! COUPLE UY DOF ON LOADED FACE
NSEL,R,LOC,X,4.32
NSEL,R,LOC,Z,0
F,ALL,FY,1 ! APPLY LOAD
NSEL,ALL
SAVE
FINISH
/SOLU
SOLVE
FINISH
*USE,MAC ! EXECUTE POSTPROCESSING MACRO
NDE=NODE(0,4.32,0)
*GET,UY2,NODE,NDE,U,Y
*SET,U2,(UY2/(1/.08854))
*STATUS
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'DEFL '
LABEL(1,2) = 'in '
*VFILL,VALUE(1,1),DATA,.08854
*VFILL,VALUE(1,2),DATA,U2
*VFILL,VALUE(1,3),DATA,ABS(U2/.08854)
SAVE,TABLE_2
/PREP7
smrt,off
RESUME
ET,1,SOLID98,2 ! ANALYZE AGAIN USING SOLID98 TETRAHEDRONS
FINISH
/SOLU
SOLVE
FINISH
*USE,MAC ! EXECUTE POSTPROCESSING MACRO
NDE=NODE(0,4.32,0)
*GET,UY3,NODE,NDE,U,Y
*SET,U3,(UY3/(1/.08854))
*STATUS
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'DEFL '
LABEL(1,2) = 'in '
*VFILL,VALUE(1,1),DATA,.08854
*VFILL,VALUE(1,2),DATA,U3
*VFILL,VALUE(1,3),DATA,ABS(U3/.08854)
SAVE,TABLE_3
/PREP7
smrt,off
RESUME
ET,1,SOLID148,2 ! ANALYZE AGAIN USING SOLID98 TETRAHEDRONS
FINISH
/SOLU
SOLVE
FINISH
*USE,MAC ! EXECUTE POSTPROCESSING MACRO
NDE=NODE(0,4.32,0)
*GET,UY3,NODE,NDE,U,Y
*SET,U3,(UY3/(1/.08854))
*STATUS
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'DEFL '
LABEL(1,2) = 'in '
*VFILL,VALUE(1,1),DATA,.08854
*VFILL,VALUE(1,2),DATA,U3
*VFILL,VALUE(1,3),DATA,ABS(U3/.08854)
SAVE,TABLE_4
RESUME,TABLE_1
/COM
/OUT,vm187,vrt
/COM,------------------- VM187 RESULTS COMPARISON ------------
/COM,
/COM, TARGET | ANSYS | RATIO
/COM, SOLID5
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.6,' ',F11.6,' ',1F6.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM, SOLID92
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.6,' ',F11.6,' ',1F6.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM, SOLID98
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.6,' ',F11.6,' ',1F6.3)
/NOPR
RESUME,TABLE_4
/GOPR
/COM,
/COM, SOLID148
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.6,' ',F11.6,' ',1F6.3)
/COM,---------------------------------------------------------
/OUT
FINISH
/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,TABLE_3
/DELETE,TABLE_4
/DELETE,MAC
*LIST,vm187,vrt


VM188 (Force Calculation on a Current Carrying Conductor) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM188
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
smrt,off
/TITLE, VM188, FORCE CALCULATION ON A CURRENT CARRYING CONDUCTOR
/COM, REF: MOON, FRANCIS C., MAGNETO-SOLID MECHANICS, PG. 418, 1984
ET,1,PLANE53 ! 8-NODE QUADRILATERAL MAGNETICS ELEMENT
ET,2,INFIN9 ! 2-D INFINITE BOUNDARY ELEMENT
EMUNIT,MKS ! MKS UNITS
MP,MURX,1,1 ! MATERIAL 1 RELATIVE PERMEABILITY=1.0
MP,MURX,2,1 ! MATERIAL 2 RELATIVE PERMEABILITY=1.0
D=.01 ! DEFINE GEOMETRY IN TERMS OF PARAMETERS
A=.012
T=.002
OB=.04 ! OUTER BOUNDARY SIZE
X1=D/2-T/2
X2=D/2+T/2
GP=.0002 ! GAP FOR THIN AIR LAYER NEXT TO CONDUCTOR
RECTNG,0,OB,0,OB ! DEFINE BOOLEAN AREAS
RECTNG,0,.012,0,.012
RECTNG,X1,X2,0,A/2
RECTNG,X1-GP,X2+GP,0,A/2+GP
AOVLAP,ALL ! OVERLAP AREAS
ASEL,S,AREA,,3
AATT,2 ! ASSIGN MATERIAL ATTRIBUTE TO CONDUCTOR
ASEL,ALL
KSEL,S,LOC,X,0,.012 ! SELECT KEYPOINTS FOR KESIZE SPEC.
KSEL,R,LOC,Y,0,.012
KESIZE,ALL,A/8 ! ASSIGN ELEMENT SIZE AT KEYPOINTS
KSEL,INVE
KESIZE,ALL,OB/5
KSEL,ALL
LSEL,S,LOC,X,OB ! SELECT FAR-FIELD BOUNDARY LINES
LSEL,A,LOC,Y,OB
TYPE,2
LMESH,ALL ! MESH WITH INFINITE LINE ELMENTS
LSEL,ALL
MSHK,0 ! FREE AREA MESH
MSHA,0,2D ! USING QUADS
TYPE,1
AMESH,ALL ! MESH AREAS WITH PLANE13
FINISH
/SOLU
ANTYPE,STATIC ! STATIC MAGNETICS ANALYSIS
ESEL,S,MAT,,2 ! SELECT CONDUCTOR ELEMENTS
BFE,ALL,JS,,,,1E6 ! APPLY CURRENT DENSITY TO CONDUCTOR
NSLE,S ! SELECT NODES IN CONDUCTOR REGION
BF,ALL,MVDI,1 ! APPLY VIRTUAL WORK DISPLACEMENT = 1
NSEL,INVE ! SELECT ALL OTHER NODES
BF,ALL,MVDI,0 ! APPLY VIRTUAL WORK DISPLACEMENT = 0
NSEL,ALL
ESEL,ALL
SOLVE
FINISH
/POST1
ETABLE,FMAGX,FMAG,X ! STORE J*B FORCE INFORMATION
ETABLE,FVWX,NMISC,3 ! STORE VIRTUAL WORK FORCE
SSUM ! SUM TABLE ENTRIES
*GET,FXL,SSUM,,ITEM,FMAGX ! GET J*B FORCE AS PARAMETER
FXL=FXL*2 ! TOTAL LORENTZ FORCE
*GET,FXVW,SSUM,,ITEM,FVWX ! GET VIRTUAL WORK FORCE AS PARAMETER
FXVW=FXVW*2 ! TOTAL VIRTUAL WORK FORCE
PATH,MAXWELL,4,,48 ! DEFINE PATH WITH NAME = "MAXWELL"
PPATH,1,,.012,0,0 ! DEFINE PATH POINTS BY LOCATION
PPATH,2,,.012,.012,0
PPATH,3,,0,.012,0
PPATH,4,,0,0,0
FOR2D ! COMMAND MACRO FOR MAXWELL STRESS FORCE CALC
FXM=FX*2 ! TOTAL MAXWELL FORCE (SYMMETRY)
*STATUS ! SHOW RESULTS
/PBC,PATH,1 ! ACTIVATE PATH B.C. FOR DISPLAY
PLF2D ! DISPLAY FLUX LINES
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'F (LRNZ) ','F (MAXW) ','F (VW) '
LABEL(1,2) = 'N/m','N/m','N/m'
*VFILL,VALUE(1,1),DATA,-9.684E-3,-9.684E-3,-9.684E-3
*VFILL,VALUE(1,2),DATA,FXL,FXM,FXVW
*VFILL,VALUE(1,3),DATA,ABS(FXL/(9.684E-3)),ABS(FXM/(9.684E-3)),ABS(FXVW/(9.684E-3))
/COM
/OUT,vm188,vrt
/COM,------------------- VM188 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.6,' ',F15.6,' ',1F10.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
/nopr
/DELETE,for2d,out
/DELETE,scratch
/DELETE,vm188,gsav
FINISH
*LIST,vm188,vrt


VM189 (Hollow Sphere in a Uniform Magnetic Field) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM189
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM189, HOLLOW SPHERE IN A UNIFORM MAGNETIC FIELD
/COM, COMPEL, VOL 7, NOS. 1&2, 89-101, 1988
/COM, TEAM WORKSHOP PROBLEM NO. 6
ET,1,SOLID97,1 ! MAGNETIC SOLID
ET,2,PLANE13 ! 2-D MAGNETIC OPTION
ET,3,SOLID96 ! MAGNETIC SCALAR SOLID
ET,4,INTER115 ! INTERFACE ELEMENT
EMUNIT,MKS ! MKS UNITS
MP,MURX,1,1 ! RELATIVE PERMEABILITY, AIR
MP,MURX,2,1 ! RELATIVE PERMEABILITY, ALUMINUM
MP,RSVX,2,2E-9 ! RESISTIVITY, ALUMINUM

CIR=.05 ! SHELL INSIDE RADIUS
COR=.055 ! SHELL OUTSIDE RADIUS
MOD=.6 ! MODEL OUTSIDE DIMENSION

RECTNG,0,MOD,0,MOD ! CREATE 2-D GEOMETRY
PCIRC,CIR,COR,,90
AOVLAP,ALL
CSYS,1
LSEL,S,LOC,Y,45 ! SET LINE SEGMENT DIVISIONS
LESIZE,ALL,,,12
LSEL,S,LOC,X,MOD,1
LESIZE,ALL,,,6
LSEL,S,LOC,X,(CIR+COR)/2
LESIZE,ALL,,,6
LSEL,S,LOC,X,CIR/2
LESIZE,ALL,,,12
KSEL,S,LOC,X,COR
KESIZE,ALL,.01
LSEL,S,LOC,X,COR+(MOD-COR)/2
LSEL,ALL
KSEL,ALL
CSYS,0
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USING QUADS
ET,2,PLANE13 ! USE PLANE13 TO MESH AREA
TYPE,2
AMAP,4,4,2,5,6 ! MAP MESH AREA 4 BY CORNERS
AMESH,ALL ! MAP MESH REMAINING AREAS
ALLSEL,ALL
TYPE,1 ! SWITCH TO 3-D SOLID96 ELEMENT
ESIZE,,2 ! SPECIFIY CIRCUMFERENTIAL DIVISIONS
MAT,2
VROTAT,2,,,,,,4,6,20 ! CREATE 20 DEG. SLICE OF SHELL
TYPE,3 ! SCALAR POTENTIAL ELEMENTS
MAT,1
VROTAT,3,4,,,,,4,6,20 ! CREATE 20 DEG. SLICE OF AIR
MODMSH,DETACH ! DETACH SOLID MODEL
NUMMRG,NODE ! MERGE NODES
ESEL,S,TYPE,,2 ! SELECT 2-D ELEMENTS
EDELE,ALL ! DELETE 2-D ELEMENTS
ESEL,S,TYPE,,1
NSLE,S
ESEL,INVE
TYPE,4
ESURF ! MESH INTERFACE ELEMENTS
ALLSEL,ALL
LOCAL,11,1,,,,,-90 ! CREATE LOCAL CYLINDRICAL C.S.
NROTAT,ALL ! ROTATE NODES
ESEL,S,TYPE,,4 ! SELECT INTERFACE ELEMENTS
NSLE,S ! SELECT NODES AT INTERFACE
CSYS,2
NROTAT,ALL ! ROTATE INTERFACE NODES
FINISH
/SOLU
ANTYPE,HARMIC ! FULL HARMONIC ANALYSIS
HARFRQ,50 ! 50 HERTZ FREQUENCY
D,ALL,AX,0 ! SET A*N=0 AT INTERFACE
CSYS,11
ESEL,S,TYPE,,1
NSLE,S
NSEL,R,LOC,Y,0 ! SELECT NODES AT ONE PLANE
DSYM,ASYM,Y,11 ! APPLY FLUX-PARALLEL CONDITIONS
NSLE,S
NSEL,R,LOC,Y,-20 ! SELECT NODES AT OTHER PLANE
DSYM,ASYM,Y,11 ! APPLY FLUX-PARALLEL CONDITIONS
NSLE,S
NSEL,R,LOC,Z,0
NSEL,R,LOC,Y,-10
D,ALL,AY,0 ! APPLY FLUX-NORMAL CONSTRAINT
ESEL,S,TYPE,,1
NSLE,S
NSEL,R,LOC,X,0
D,ALL,AX,0,,,,AY,AZ ! FLUX-PARALLEL AT SYMMETRY AXIS
NSEL,ALL

MU=16*ATAN(1)*1E-7 ! DEFINE FREE-SPACE PERMEABILITY
CSYS,0
NSEL,S,LOC,Y,MOD
D,ALL,MAG,-MOD/MU ! APPLY POTENTIAL TO GIVE 1 TESLA FIELD
NSEL,S,LOC,Y,0
D,ALL,MAG,0

CSYS,11
ESEL,S,MAT,,2 ! SELECT SHELL ELEMENTS
NSLE,S ! SELECT NODES ATTACHED TO SHELL
NSEL,R,LOC,Y,0 ! SELECT NODES AT ONE PLANE
D,ALL,VOLT,0 ! SET TIME-INTEGRATED POTENTIAL TO 0
NSLE,S
NSEL,R,LOC,Y,-20 ! SELECT NODES AT OTHER PLANE
D,ALL,VOLT,0 ! SET TIME-INTEGRATED POTENTIAL TO 0
NSEL,ALL
ESEL,ALL
EQSLV,JCG,1e-6 ! JCG SOLVER
SOLVE ! SOLVE HARMONIC ANALYSIS
FINISH
/POST1
SET,1,1
/VIEW,,-1,.5,.5
/VUP,1,Y
/EDGE,,1
ESEL,S,MAT,,2 ! SELECT SHELL ELEMENTS
NSLE,S
PLVECT,JT,,,JT,VECT,ELEM,ON ! PLOT REAL EDDY CURRENTS
SET,1,1,,1
PLVECT,JT,,,JT,VECT,ELEM,ON ! PLOT IMAGINARY EDDY CURRENTS
POWERH ! CALCULATE POWER LOSS
PAVG=PAVG*8*4.5 ! CALCULATE FOR TOTAL SHELL
NSEL,ALL
ESEL,ALL
NORIG=NODE(0,0,0) ! GET NODE NUMBER AT ORIGIN
SET,1
*GET,BYR,NODE,NORIG,B,Y ! GET BY (REAL)
SET,1,1,,1
*GET,BYI,NODE,NORIG,B,Y ! GET BY (IMAGINARY)
BYM=SQRT(BYR**2+BYI**2) ! CALCULATE BY (MAGNITUDE)
*STATUS
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'BY (0,0)','POW LS '
LABEL(1,2) = ' T',' W'
*VFILL,VALUE(1,1),DATA,.0524,10062
*VFILL,VALUE(1,2),DATA,BYM,PAVG
*VFILL,VALUE(1,3),DATA,ABS(BYM/.0524),ABS(10062/PAVG)
/COM
/OUT,vm189,vrt
/COM,------------------- VM189 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F15.4,' ',1F10.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm189,vrt


VM190 (Ferromagnetic Inductor) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM190
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
smrt,off
/TITLE, VM190, FERROMAGNETIC INDUCTOR
/COM, CHAPMAN, "ELECTRIC MACHINERY FUNDAMENTALS", MCGRAW-HILL,
/COM, 1985, EXAMPLE 1-1, PG. 14
ET,1,SOLID98,10 ! 10-NODE TETRAHEDRAL, MAG OPTION
ET,2,INFIN47 ! INFINITE ELEMENT
ET,3,SOURC36 ! CURRENT ELEMENT
EMUNIT,MKS ! MKS UNITS
MP,MURX,1,1 ! RELATIVE PERMEABILITY OF AIR
MP,MURX,2,2500 ! RELATIVE PERMEABILITY OF IRON
R,1,1,200,.02,.25 ! COIL DIMENSIONS AND CURRENT
LOCAL,11,0,-.325 ! SHIFT ORIGIN TO CENTER OF MODEL
WPCSYS,,11 ! WORKING PLANE FOR SOLID MODELLING
N,1,.125,0,0 ! CREATE NODES TO LOCATE COIL
N,2,.235,0,0
N,3,.235,.235,0
TYPE,3
E,2,3,1 ! DEFINE COIL
BLOCK,.05,.20,0,.05,0,.45 ! CREATE SOLID MODEL OF IRON
BLOCK,.20,.50,0,.05,.30,.45
BLOCK,.50,.60,0,.05,0,.45
VGLUE,ALL
BLOCK,0,.65,0,.10,0,.50 ! CREATE SOLID MODEL OF AIR
VOVLAP,ALL ! OVERLAP AIR AND IRON
ASEL,S,AREA,,8,10
ASEL,A,AREA,,4
MSHK,0 ! FREE MESH
MSHA,1,3D ! USING TETS
MSHA,1,2D ! USING TRIS
ESIZE,.10
TYPE,2
AMESH,ALL ! MESH EXTERIOR BOUNDARY WITH INFIN47
TYPE,1
MAT,2
VMESH,4,6 ! MESH IRON
MAT,1
VMESH,2 ! MESH AIR
NSEL,S,LOC,Z,0
D,ALL,MAG,0 ! SET FLUX-NORMAL SYMMETRY CONDITION
NSEL,ALL
FINISH
/SOLU
ANTYPE,STATIC ! STATIC MAGNETIC FIELD ANALYSIS
MAGSOLV,4
FINISH
/POST1
PATH,IRON,7,,48 ! DEFINE PATH WITH NAME = "IRON"
PPATH,1,,-.2,0,0 ! DEFINE PATHS POINTS BY
PPATH,2,,-.2,0,.20
PPATH,3,,-.2,0,.375
PPATH,4,,.025,0,.375
PPATH,5,,.225,0,.375
PPATH,6,,.225,0,.20
PPATH,7,,.225,0,0
*CREATE,MAC ! CREATE MACRO FOR MMF CALCULATION
PDEF,HX,H,X ! INTERPOLATE H FIELD TO PATH
PDEF,HY,H,Y
PDEF,HZ,H,Z
PVECT,TANG,TX,TY,TZ ! INTERPOLATE UNIT TANGENTS
PDOT,D,HX,HY,HZ,TX,TY,TZ ! PERFORM DOT PRODUCT
PCALC,INTG,MMF,D,S ! INTEGRATE OVER PATH
*GET,MMF,PATH,,LAST,MMF ! GET MMF
MMF=MMF*2 ! MULTIPLY BY 2 FOR SYMMETRY
*STATUS,MMF
*END
ESEL,S,MAT,,2 ! SELECT IRON ELEMENTS
*USE,MAC ! USE MACRO TO CALCULATE MMF
/VIEW,,1,-3,1
/VUP,1,Z
/TRIAD,OFF
/PBC,PATH,1 ! SHOW PATH ON DISPLAY
/AUTO
WPSTYL,,,,,,,OFF
NSLE,S ! SELECT NODES ATTACHED TO IRON
/COM *** THE FOLLOWING ANNOTATION COMMANDS ARE ***
/COM *** TYPICALLY GENERATED INTERACTIVELY ***
/ANUM,1,12,-.28056,.71310 ! ANNOTATION NUMBER, TYPE, AND HOT SPOT
/LSYMBOL,-.282,.511,269,4,1.0 ! ANNOTATION SYMBOL DEFINITION - ARROW
/LINE,-.282,.511,-.279,.915 ! ANNOTATION LINE DEFINITION
/ANUM,2,4,-.21690,.91150
/LINE,-.282,.911,-.151,.911
/ANUM,3,1.14734,.93021
/TLABEL,-.133,.930,CONTOUR PATH FOR ! ANNOTATION LOCATION AND TEXT
/ANUM,4,1,.91097E-01,.87406
/TLABEL,-.136,.874,LINE INTEGRAL
/ANNOT,ON
/TITLE, VM190: MAGNETIC FLUX DENSITY
PLNSOL,B,SUM ! DISPLAY FLUX DENSITY IN IRON
FINISH
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'MMF DRP '
LABEL(1,2) = 'A-t'
*VFILL,VALUE(1,1),DATA,200
*VFILL,VALUE(1,2),DATA,MMF
*VFILL,VALUE(1,3),DATA,ABS(MMF/200),
/COM
/OUT,vm190,vrt
/COM,------------------- VM190 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
/DELETE,MAC
/DELETE,scratch
/DELETE,magsolv,out
*LIST,vm190,vrt


VM191 (Hertz Contact Between Two Cylinders) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM191
/TITLE, VM191, HERTZ CONTACT BETWEEN TWO CYLINDERS
/COM "FINITE ELEMENT ANALYSIS OF HERTZ CONTACT PROBLEM"
/COM N. CHANDRASEKARAN, W.E. HAISLER, R.E. GOFORTH,
/COM FINITE ELEMENTS IN ANALYSIS AND DESIGN 3, 1987, PP 39-56.
/PREP7
SMRT,OFF
/COM 2-D ANALYSIS USING PLANE42 AND CONTAC48
ANTYPE,STATIC
ET,1,PLANE42 ! 2-D SOLID ELEMENTS
MP,EX,1,30000 ! SMALLER CYLINDER PROPERTIES
MP,NUXY,1,0.25
MP,EX,2,29120 ! LARGER CYLINDER PROPERTIES
MP,NUXY,2,0.30
ET,2,CONTAC48 ! 2-D CONTACT ELEMENTS
R,2,3E4,,,,0.001 ! KN=30000, TOLS=0.001
CSYS,1
K,1 ! CREATE BIGGER CYLINDER
K,2,13
K,3,13,82
K,4,13,90
K,5,11,90
L,1,5
L,2,3
LESIZE,ALL,,,7
L,3,4 ! TARGET SURFACE (LINE 3)
LOCAL,11,1,,13
L,3,5
CSYS,1
A,1,2,3,5
A,5,3,4,4
MAT,2
MSHK,1 ! MAPPED AREA MESH
MSHA,0,2D ! USING QUADS
ESIZE,,4
AMESH,1,2
LOCAL,12,1,,23-1E-5,,-90 ! INTRODUCE SLIGHT INTERFERENCE
K,11 ! CREATE SMALLER CYLINDER
K,12,10
K,13,10,8
K,14,10,90
K,15,8
L,11,15
L,13,14
LESIZE,7,,,6
LESIZE,8,,,6
L,12,13 ! CONTACTOR SURFACE (LINE 9)
CSYS,11
L,13,15
CSYS,12
MAT,1
A,12,13,15,15
A,15,13,14,11
ESIZE,,6
AMESH,3,4
LSEL,S,LINE,,9 ! SELECT CONTACT NODES ON SMALLER CYLINDER
NSLL,,1
CM,CYL1,NODE ! CONTACT NODES COMPONENT
LSEL,S,LINE,,3 ! SELECT TARGET NODES ON BIGGER CYLINDER
NSLL,,1
CM,CYL2,NODE ! TARGET NODES COMPONENT
NSEL,ALL
TYPE,2
REAL,2
GCGEN,CYL1,CYL2 ! GENERATE ASYMMETRIC CONTACT ELEMENTS
CSYS,0
NSEL,S,LOC,Y,23 ! SELECT TOP EDGE OF MODEL
CP,1,UY,ALL ! COUPLE NODES ON TOP EDGE
*GET,NC,NODE,,NUM,MIN ! GET LOWEST NODE NUMBER (MASTER)
NSEL,S,LOC,X ! SYMMETRY CONSTRAINTS
D,ALL,UX
NSEL,S,LOC,Y
D,ALL,UY
NSEL,ALL
FINISH

/SOLU
D,NC,UY,-0.005 ! APPLY SMALL DISPLACEMENT TO ENGAGE CONTACT
SOLVE ! SOLVE FIRST LOAD STEP
DDELE,NC,UY ! DELETE IMPOSED DISPLACEMENT
F,NC,FY,-1600 ! APPLY HALF LOAD ON (SYMMETRY) MODEL
SOLVE ! SOLVE SECOND LOAD STEP
FINISH

/POST1
NSEL,,LOC,Y,23 ! SELECT TOP EDGE OF SMALLER CYLINDER
*GET,D,NODE,NC,U,Y ! GET APPROACH DISTANCE (D)
ESEL,S,TYPE,,2 ! SELECT CONTACT ELEMENTS
ETABLE,NSTAT,NMISC,1 ! STORE CONTACT STATUS
ESEL,R,ETAB,NSTAT,2,2 ! SELECT ELEMENTS WITH CONTACT (STAT=2)
CMSEL,S,CYL1 ! SELECT CONTACT COMPONENT NODES
NSLE,R ! RESELECT NODES WITH CONTACT
NSORT,LOC,X,1 ! SORT CONTACT NODES BY ASCENDING X LOCATION
*GET,B,SORT,,MAX ! GET SEMI-CONTACT LENGTH (B)
*STATUS
*GET,DEF,NODE,1,U,X
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'AP DIS ','S-CON LEN '
LABEL(1,2) = ' mm',' mm'
*VFILL,VALUE(1,1),DATA,-.4181,1.2
*VFILL,VALUE(1,2),DATA,D,B
*VFILL,VALUE(1,3),DATA,ABS(D/.4181),ABS(B/1.2)
SAVE,TABLE_1
FINISH
/CLEAR, NOSTART
/PREP7 $SMRT,OFF
ANTYPE,STATIC
ET,1,SOLID45 ! 3-D SOLID ELEMENTS
MP,EX,1,30000 ! SMALLER CYLINDER PROPERTIES
MP,NUXY,1,0.25
MP,EX,2,29120 ! LARGER CYLINDER PROPERTIES
MP,NUXY,2,0.30
ET,2,CONTAC49 ! 3-D CONTACT ELEMENTS
R,2,3E4,,,,0.001 ! KN=30000, TOLS=0.001
CSYS,1
K,1 ! CREATE LOWER BIGGER CYLINDER
K,2,13
K,3,13,82
K,4,13,90
K,5,11,90
KGEN,2,1,5,1,,,1,100 ! UNIT THICKNESS SLICE
L,1,5
L,2,3
L,101,105
L,102,103
LESIZE,ALL,,,7
L,1,101
*REPEAT,5,1,1
LESIZE,5,,,1
*REPEAT,5,1
LOCAL,11,1,,13
L,3,5
L,103,105
CSYS,1
MAT,2
MSHK,1 ! MAPPED VOLUME MESH
MSHA,0,3D ! USING HEX
ESIZE,,4
V,1,2,3,5,101,102,103,105
V,5,3,4,4,105,103,104,104
VMESH,ALL
LOCAL,12,1,,23-1E-5,,-90 ! INTRODUCE SLIGHT INTERFERENCE
K,11 ! CREATE UPPER SMALLER CYLINDER
K,12,10
K,13,10,8
K,14,10,90
K,15,8
KGEN,2,11,15,1,,,1,100
L,11,15
L,13,14
LESIZE,18,,,6
LESIZE,19,,,6
L,11,111
*REPEAT,5,1,1
LESIZE,20,,,1
*REPEAT,5,1
CSYS,11
L,13,15
L,113,115
CSYS,12
MAT,1
ESIZE,,6
V,12,13,15,15,112,113,115,115
V,15,13,14,11,115,113,114,111
VMESH,3,4
ASEL,S,AREA,,12
NSLA,,1
CM,CYL1,NODE ! CONTACT NODES COMPONENT
ASEL,S,AREA,,8 ! SELECT TARGET NODES ON BIGGER CYLINDER
NSLA,,1
CM,CYL2,NODE ! TARGET NODES COMPONENT
NSEL,ALL
TYPE,2
REAL,2
GCGEN,CYL1,CYL2 ! GENERATE ASYMMETRIC CONTACT ELEMENTS
CSYS,0
NSEL,S,LOC,Y,23 ! SELECT TOP EDGE OF MODEL
CP,1,UY,ALL ! COUPLE NODES ON TOP EDGE
*GET,NC,NODE,,NUM,MIN ! GET LOWEST NODE NUMBER (MASTER)
NSEL,S,LOC,X ! SYMMETRY CONSTRAINTS
D,ALL,UX
NSEL,S,LOC,Y
D,ALL,UY
NSEL,S,LOC,Z
D,ALL,UZ
NSEL,ALL
FINISH

/SOLU
D,NC,UY,-0.001 ! APPLY SMALL DISPLACEMENT TO ENGAGE CONTACT
SOLVE ! SOLVE FIRST LOAD STEP
DDELE,NC,UY ! DELETE IMPOSED DISPLACEMENT
F,NC,FY,-1600 ! APPLY HALF LOAD ON (SYMMETRY) MODEL
SOLVE ! SOLVE SECOND LOAD STEP
FINISH

/POST1
NSEL,,LOC,Y,23 ! SELECT TOP EDGE OF SMALLER CYLINDER
*GET,D,NODE,NC,U,Y ! GET APPROACH DISTANCE (D)
ESEL,S,TYPE,,2 ! SELECT CONTACT ELEMENTS
ETABLE,NSTAT,NMISC,1 ! STORE CONTACT STATUS
ESEL,R,ETAB,NSTAT,2,2 ! SELECT ELEMENTS WITH CONTACT (STAT=2)
CMSEL,S,CYL1 ! SELECT CONTACT COMPONENT NODES
NSLE,R ! RESELECT NODES WITH CONTACT
NSORT,LOC,X,1 ! SORT CONTACT NODES BY ASCENDING X LOCATION
*GET,B,SORT,,MAX ! GET SEMI-CONTACT LENGTH (B)
*STATUS
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'AP DIS ','S-CON LEN '
LABEL(1,2) = ' mm',' mm'
*VFILL,VALUE(1,1),DATA,-.4181,1.2
*VFILL,VALUE(1,2),DATA,D,B
*VFILL,VALUE(1,3),DATA,ABS(D/.4181),ABS(B/1.2)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm191,vrt
/COM,------------------- VM191 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING 2-D ANALYSIS:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING 3-D ANALYSIS:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm191,vrt


VM192 (Cooling of a Billet by Radiation) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM192
/PREP7
SMRT,OFF
/TITLE, VM192, COOLING OF A BILLET BY RADIATION
/COM THERMAL RADIATION HEAT TRANSFER, SIEGEL AND HOWELL, 2ND EDITION,
/COM PG. 229, PROBLEM NO. 21.
ET,1,SOLID70 ! 3-D THERMAL SOLID ELEMENT
ET,2,SURF152,,,,1,1 ! 3-D THERMAL SURFACE EFFECT ELEMENTS
KEYOPT,2,9,1 ! RADIATION OPTION
R,2,1,0.1712E-8 ! FORM FACTOR = 1, STEFAN-BOLTZMANN CONSTANT
MP,KXX,1,10000 ! ARBITRARY CONDUCTIVITY
MP,C,1,0.11
MP,DENS,1,487.5
MP,EMIS,2,1 ! BLACK BODY EMISSIVITY
BLOCK,,2,,2,,4
ESIZE,,1
VMESH,1 ! MESH WITH A SINGLE SOLID70 ELEMENT
TYPE,2
REAL,2
MAT,2
N,100,5,5,5 ! EXTRA "SPACE" NODE FOR RADIATION
ESURF,100 ! GENERATE SURF152 ELEMENTS
FINISH

/SOLU
SOLCONTROL,0
ANTYPE,TRANS ! TRANSIENT ANALYSIS
D,100,TEMP,530 ! SPECIFY SURROUNDING ABSOLUTE TEMPERATURE
TUNIF,2000 ! INITIAL BILLET ABSOLUTE TEMPERATURE
AUTOTS,ON
KBC,1 ! STEP SURROUNDING TEMPERATURE IN FIRST TIME STEP
DELTIM,0.005 ! INITIAL (MINIMUM) INTEGRATION TIME STEP
OUTRES,,ALL
OUTPR,NSOL,LAST
TIME,3.7 ! TRANSIENT TIME SPAN
SOLVE
FINISH

/POST26
NSOL,2,1,TEMP,,TEMP
PRVAR,2 ! PRINT TEMPERATURE HISTORY OF BILLET
*GET,T,VARI,2,RTIME,3.7
*DIM,VALUE,,1,3
*DIM,LABEL,CHAR,1,2
LABEL(1,1) = 'TEMP (B) '
LABEL(1,2) = 'DEG R'
*VFILL,VALUE(1,1),DATA,1000
*VFILL,VALUE(1,2),DATA,T
*VFILL,VALUE(1,3),DATA,ABS(T/1000)
/COM
/OUT,vm192,vrt
/COM,------------------- VM192 RESULTS COMPARISON --------------
/COM,
/COM, LOAD STP 4 | TARGET | ANSYS | RATIO
/COM,
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F8.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm192,vrt


VM193 (Adaptive Analysis of 2-D Heat Transfer with Convection) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM193
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM193, TWO DIMENSIONAL HEAT TRANSFER WITH CONVECTION
C*** "THE STANDARD NAFEMS BENCHMARKS", TEST NO. T4,
C*** NAFEMS, REV 3, OCTOBER 1990.
ANTYPE,STATIC
ET,1,PLANE55
MP,KXX,1,52.0
K,1
K,2,.6
K,3,.6,1.0
K,4,,1.0
K,5,.6,.2
L,1,2
L,2,5
L,5,3
L,3,4
L,4,1
AL,ALL
DK,1,TEMP,100,,1
DK,2,TEMP,100,,1
SFL,2,CONV,750.0,,0.0
SFL,3,CONV,750.0,,0.0
SFL,4,CONV,750.0,,0.0
FINISH
ADAPT,10,,5,0.2,1 ! FINAL PERCENT ERROR NEAR 5% WITHIN 10 LOOPS
/POST1
PLNSOL,TEMP ! DISPLAY TEMP CONTOURS IN FINAL MESH
*GET,TEPC,PRERR,,TEPC
KSEL,,,,5
NSLK
*GET,N1,NODE,,NUM,MAX
*GET,TEMP1,NODE,N1,TEMP
*STATUS
*DIM,VALUE,,1,3
*DIM,LABEL,CHAR,1,2
LABEL(1,1) = 'TEMP '
LABEL(1,2) = 'DEG C'
*VFILL,VALUE(1,1),DATA,18.3
*VFILL,VALUE(1,2),DATA,TEMP1
*VFILL,VALUE(1,3),DATA,ABS(TEMP1/18.3)
/COM
/OUT,vm193,vrt
/COM,------------------- VM193 RESULTS COMPARISON --------------
/COM,
/COM, LOAD STP 4 | TARGET | ANSYS | RATIO
/COM,
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F8.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm193,vrt


VM194 (Element Birth/Death in a Fixed Bar with Thermal Loading) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM194
/PREP7
/TITLE, VM194, ELEMENT BIRTH/DEATH IN A FIXED BAR WITH THERMAL LOADING
/COM ANY STANDARD MECHANICS OF MATERIALS TEXT
ET,1,LINK1 ! 2-D SPAR ELEMENTS
MP,EX,1,30E6 ! BAR MATERIAL PROPERTIES
MP,ALPX,1,.00005
MP,EX,2,30E6
MP,ALPX,2,.00005 ! MATERIAL PROPERTIES FOR RE-BORN ELEMENT
MP,REFT,2,100 ! REFERENCE TEMPERATURE FOR ELEMENT BIRTH
R,1,1.0
N,1
N,4,10
FILL
E,1,2
EGEN,3,1,-1 ! GENERATE THREE ELEMENTS
FINISH

/SOLU
ANTYPE,STATIC
D,1,ALL,,,4,3 ! FIX BOTH ENDS OF THE BAR
TREF,0 ! ZERO REFERENCE TEMPERATURE
TUNIF,100 ! UNIFORM TEMPERATURE THERMAL LOAD
NROPT,FULL
OUTPR,BASIC,ALL
SOLVE
EKILL,2 ! KILL CENTER ELEMENT
SOLVE
EALIVE,2 ! RESURRECT CENTER ELEMENT
MPCHG,2,2 ! AND CHANGE TO MATERIAL 2 FOR STRAIN-FREE BIRTH
SOLVE
TUNIF,0 ! REMOVE THERMAL LOADING
SOLVE
/POST1
ESEL,S,ELEM,,1,2
ETABLE,FO,SMISC,1
ESORT,FO
*GET,F,SORT,,MAX
ETABLE,STR,LEPTH,1
ESORT,STR
*GET,S1,SORT,,MAX
*GET,S2,SORT,,MIN
*STATUS
*DIM,VALUE,,3,3
*DIM,LABEL,CHAR,3,2
LABEL(1,1) = 'PRESS ','MAX STRS ','MAX STRS '
LABEL(1,2) = 'psi','EL(1)','EL(2)'
*VFILL,VALUE(1,1),DATA,150000,0,-.005
*VFILL,VALUE(1,2),DATA,F,S1,S2
*VFILL,VALUE(1,3),DATA,ABS(F/150000),0,ABS(S2/.005)
/COM
/OUT,vm194,vrt
/COM,------------------- VM194 RESULTS COMPARISON --------------
/COM,
/COM, LOAD STP 4 | TARGET | ANSYS | RATIO
/COM,
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F8.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm194,vrt


VM195 (Toggle Mechanism) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM195
/PREP7
MP,PRXY,,0.3
/TITLE, VM195, TOGGLE MECHANISM
C*** KINEMATICS AND DYNAMICS OF MACHINES, MARTIN, 2ND ED., P 56, FIG 3-22
ET,1,COMBIN7
ET,2,BEAM4
ET,3,COMBIN14
ET,4,COMBIN7,,1 ! LOCK-UP JOINT WHEN STOP ENGAGED
ET,5,LINK11
R,1,1E9,1E3,1E3,1E3 ! REVOLUTE JOINT, ALLOW 37 DEG. ROTATION
RMORE,,,,,0.6435,0.6435
R,2,.01,8.3333E-6,8.3333E-6,.1,.1 ! BEAM PROPERTIES
R,3,166.6667 ! SPRING STIFFNESS
R,4,1E9,1E3,1E3,1E3 ! REVOLUTE JOINT, ALLOW 74 DEG. ROTATION
RMORE,,,,,1.287,1.287
DIST=(SQRT(12.2)-1) ! DISTANCE TO MOVE ACTUATOR
R,5,(100/DIST) ! ACTUATOR STIFFNESS (F=100=KX)
MP,EX,1,1E9
N,1,,0.8
N,2,1.6,2.0
N,3,1.6,2.0
N,4,3.2,3.2
N,5
N,6,1.6,1.2
N,7,1.6,1.2
N,8,1.6,1.2
N,9,3.2
N,10,5
N,11,1.6,2.0,1
N,12,1.6,1.2,1
N,21,3.2,4.2
TYPE,1
REAL,1
E,2,3,11
E,6,8,12
E,6,7,12
TYPE,4
REAL,4
E,7,8,12
TYPE,2
REAL,2
E,1,2
E,2,4
E,3,6
E,5,7
E,8,9
TYPE,3
REAL,3
E,9,10
TYPE,5
REAL,5
E,4,21
D,1,UX,,,5,4,UY
D,9,UY
D,10,ALL,,,21,11
D,ALL,UZ
SFE,11,2,PRES,,102 ! ACTUATOR FORCE, INCREASE BY 2% TO ENSURE IMPACT
FINISH
/SOLU
NLGEOM,ON
NSUBST,5
CNVTOL,F,,,,1
CNVTOL,M,,,,0.5
OUTPR,,LAST
SOLVE
/POST1
*GET,UY,NODE,4,U,Y
*GET,UX,NODE,9,U,X
ESEL,S,ELEM,,10,10
ETABLE,FORCE,SMISC,1
ESORT,FORCE
*GET,F,SORT,,MIN
*STATUS
*DIM,VALUE,,3,3
*DIM,LABEL,CHAR,3,2
LABEL(1,1) = 'FORCE ','UY ','UX '
LABEL(1,2) = 'MAX','ND=4','ND=9'
*VFILL,VALUE(1,1),DATA,-133.33,-2.4,.8
*VFILL,VALUE(1,2),DATA,F,UY,UX
*VFILL,VALUE(1,3),DATA,ABS(F/133.33),ABS(UY/2.4),ABS(UX/.8)
/COM
/OUT,vm195,vrt
/COM,------------------- VM195 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F8.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm195,vrt


VM196 (Counter-Balanced Loads on a Block) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM196
/PREP7
MP,PRXY,,0.3
SMRT,OFF
/TITLE, VM196, COUNTER-BALANCED LOADS ON A BLOCK
C*** ANY BASIC MECHANICS BOOK
ET,1,SOLID45
MP,EX,1,70E9 ! ALUMINUM
MP,DENS,1,2712
MP,PRXY,1,0.3
WPOFFS,,,300 ! AXIS OF ROTATION 300 M
BLOCK,-1,1,-1,1,0,3 ! 3 M HIGH BY 2 M SQUARE
ESIZE,1
VMESH,ALL
DK,1,ALL ! CONSTRAIN 6 DOF SUCH THAT NO ROTATIONS OCCUR
DK,4,UX
DK,6,UY
DK,7,UZ
FINISH
/SOLU
ANTYPE,STATIC
IRLF,1 ! INERTIA RELIEF CALCULATIONS
FK,5,FX,-2000
FK,5,FY,3000
OUTPR,RSOL,1 ! PRINT REACTION SOLUTION
SOLVE
IRLIST ! LIST INERTIA RELIEF LOADS AND ACCELERATIONS
*GET,MX,ELEM,,MMOR,X
*GET,MY,ELEM,,MMOR,Y
*GET,MZ,ELEM,,MMOR,Z
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'MOM X ','MOM Y','MOM Z'
LABEL(1,2) = 'N-m','N-m','N-m'
*VFILL,VALUE(1,1),DATA,-909000,-606000,-5000
*VFILL,VALUE(1,2),DATA,MX,MY,MZ
*VFILL,VALUE(1,3),DATA,ABS(MX/909000),ABS(MY/606000),ABS(MZ/5000)
/COM
/OUT,vm196,vrt
/COM,------------------- VM196 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM196 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm196,vrt


VM197 (GES Write/Read for Thick-Walled Cylinder with Spherical End Caps) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM197
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM197, IGES WRITE/READ FOR THICK-WALLED CYLINDER WITH SPHERICAL END CAPS
/COM, ANY BASIC GEOMETRY TEXT

RADIUS=20 ! INSIDE RADIUS
THICK=10 ! WALL THICKNESS
LENGTH=50 ! CYLINDER LENGTH (WITHOUT END CAPS)

CYLIND,RADIUS,RADIUS+THICK,0,LENGTH,90,270 ! CREATE HOLLOW CYLINDER
WPROTA,,90 ! ROTATE WORKING PLANE FOR CREATION OF END CAPS
SPHERE,RADIUS,RADIUS+THICK,180,270 ! CREATE END CAP AT ONE END OF CYLINDER
WPOFFS,,LENGTH ! MOVE WORKING PLANE TO OTHER END OF CYL
SPHERE,RADIUS,RADIUS+THICK,90,180 ! CREATE END CAP AT OTHER END OF CYLINDER

/VIEW,1,1,1,1 ! SET VIEW DIRECTION FOR DISPLAY
/TYPE,1,4 ! SET TYPE OF DISPLAY TO PRECISE HIDDEN
/TRIAD,OFF ! TURN OFF COORDINATE SYSTEM TRIAD ON DISPLAYS
WPSTYL,,,,,,,OFF ! TURN OFF WORKING PLANE TRIAD ON DISPLAYS
VPLOT

IGESOUT,VM197,IGS ! WRITE IGES FILE NAMED VM197.IGS
FINISH
PARSAV,ALL ! SAVE PARAMETERS (TO BE AVAILABLE AFTER CLEAR)
/CLEAR, NOSTART
/AUX15
IOPTN,IGES,NODEFE ! SELECT NO DEFEATURING IGES IMPORT
IOPTN,MERGE,YES
IOPTN,SOLID,NO
IGESIN,VM197,IGS ! READ IN IGES FILE NAMED VM197.IGS
FINISH
/PREP7
VSUM ! PERFORM VSUM FOR SUBSEQUENT *GET OF TOT VOLUME

PARRES ! RESUME PARAMETERS SAVED PRIOR TO CLEAR
*GET,VOLUME,VOLU,,VOLU ! VOLUME = TOTAL VOLUME OF GEOMETRY THAT WAS READ
! IN FROM IGES FILE (FROM VSUM)

PI=(4.0)*ATAN(1.0) ! HAVE ANSYS CALCULATE VALUE FOR PI
CAPVOL=2/3*PI*(((RADIUS+THICK)**3)-(RADIUS**3)) ! CALC VOL OF TWO END CAPS
CYLVOL=.5*LENGTH*PI*(((RADIUS+THICK)**2)-(RADIUS**2)) ! CALC VOL OF THE CYLINDER
CALCVOL=CAPVOL+CYLVOL ! TOTAL CALC'D VOL = CYL VOL + END CAPS VOL

NORMVOL=VOLUME/CALCVOL ! NORMALIZE ANSYS'S VOLUME BY CALCULATED VOLUME

CAPVOL= ! DELETE PARAMETERS USED IN CALC. OF VOLUME
CYLVOL=
PI=
RADIUS= ! DELETE PARAMETERS USED IN MODEL GENERATION
THICK=
LENGTH=
*DIM,VALUE,,1,3
*DIM,LABEL,CHAR,1,2
LABEL(1,1) = 'VOLUME '
LABEL(1,2) = 'NO UNTS'
*VFILL,VALUE(1,1),DATA,79063
*VFILL,VALUE(1,2),DATA,VOLUME
*VFILL,VALUE(1,3),DATA,ABS(VOLUME/79063)
/COM
/OUT,vm197,vrt
/COM,------------------- VM197 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F8.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
/NOPR
/DELETE,VM197,IGS
FINISH
*LIST,vm197,vrt


VM198 (Large Strain In-plane Torsion Test) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM198
/SHOW,,,1
EL='VISCO106'
*DIM,A,CHAR,2 ! DEFINE AND DIMENSION THE CHARACTER PARAMETER A
A(1)='UX','UY' ! SET CHARACTER STRINGS AS VALUES OF CHARACTER
! PARAMETER A
! ANALYZE THE PROBLEM WITH ELEMENT VISCO106
/PREP7
/TITLE, VM198, LARGE STRAIN IN-PLANE TORSION TEST (%EL%)
! "SOME COMPUTATIONAL ASPECTS ....",NAGTEGAAL ET AL.
ET,1,VISCO106 ! 2-D 4-NODE VISCOPLASTIC ELEMENT
MP,EX,1,7200
MP,NUXY,1,0.33
TB,BISO,1 ! BILINEAR ISOTROPIC HARDENING
TBDATA,1,10 ! YIELD STRESS
TBDATA,2,40 ! TANGENT MODULUS
SAVE ! SAVE DATABASE FOR LATER USE
CSYS,1
N,1,10
N,11,20
FILL
NGEN,2,100,1,11,1,,3
E,1,2,102,101
EGEN,10,1,1,1
! APPLY BOUNDARY CONDITIONS
NSEL,S,LOC,X,20
D,ALL,ALL ! CLAMP OUTER SURFACE
NSEL,ALL
! ROTATE APPROPRIATE NODES AND APPLY COUPLING
LOCAL,11,0,,,,3
NROTAT,101,111
CSYS,0
CP,1,A(1),2,102 ! USE A(1) VALUE FOR DOF LABEL
CP,2,A(2),2,102 ! USE A(2) VALUE FOR DOF LABEL
CPSGEN,9,1,1,2,1
FINISH
/OUTPUT,SCRATCH ! DIVERT VOLUMINOUS SOLUTION OUTPUT
/SOLU
! CREATE SOLUTION OPTIONS AND LOADING MACRO FOR MULTIPLE USE
*CREATE,SOLD,MAC
SOLCONTROL,0
ANTYPE,STATIC
NLGEOM,ON ! LARGE STRAIN OPTION ACTIVATED
NEQIT,100 ! 100 EQUILIBRIUM ITERATIONS ALLOWED
CUTC,PLSLIMIT,0.5 ! RESET MAXIMUM PLASTIC INCREMENTAL STRAIN
D,ARG1,ARG2,,,ARG3,ARG4,ARG5
SOLVE
OUTRES,ESOL,1 ! STORE RESULTS FOR EVERY SUBSTEP
NSTP = 10 ! NO. OF LOAD STEPS USED
T1 = 60/NSTP ! ROTATION PER LOAD STEP
T2 = 3.1415927/180 ! PARAMETER FOR FURTHER CALCULATIONS
T33 = T1*T2 ! DEGREES TO RADIANS CONVERSION
*DO,I,1,NSTP ! USE DO LOOP FOR LOADING
T3 = (I*T33) ! CURRENT ANGLE
T4 = (10*SIN(T3)) ! UY DISPLACEMENT
T5 = (10*COS(T3))
T5 = (T5-10) ! UX DISPLACEMENT
D,ARG1,ARG2,T5,,ARG3,ARG4
D,ARG1,ARG5,T4,,ARG3,ARG4
SOLVE
*ENDDO
*END
SOLD,1,A(1),101,100,A(2) ! USE A(1) AND A(2) AS ARG2 AND ARG5 VALUES FOR
FINISH ! DOF LABELS
/OUTPUT
! CREATE POST PROCESSING MACRO FOR MULTIPLE USE
*CREATE,POSP,MAC
!COM PLOT THE FINAL DISPLACED GEOMETRY USING POST1
/POST1
SET,NSTP+1
/DSCALE,1,1
/DIST,1,13
PLDISP,1
/DIST,1
FINISH
! OBTAIN MAXIMUM SHEAR STRESS USING POST26
/POST26
ESOL,2,1,1,S,1
ESOL,3,1,1,S,3
FILLDATA,5,1,,,0,6
ADD,4,2,3,,SHEAR,,,-1/2,1/2 ! COMPUTE MAX. SHEAR USING
! PRINCIPAL STRESSES
PRVAR,4,5
/GRID,1
/XRANGE,0,60
/YRANGE,-60,0
/AXLAB,X,ROTATION (DEGREES)
/AXLAB,Y,SHEAR STRESS (PSI)
XVAR,5
PLVAR,4
*GET,P1,VARI,4,RTIME,11
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'PRS MAX '
LABEL(1,2) = 'psi'
*VFILL,VALUE(1,1),DATA,-48
*VFILL,VALUE(1,2),DATA,P1
*VFILL,VALUE(1,3),DATA,ABS(P1/48)
FINISH
*END
POSP
SAVE,TABLE_1
/CLEAR, NOSTART
! ANALYZE THE SAME PROBLEM WITH ELEMENT VISCO108
/PREP7
RESUME
EL='VISCO108'
/STATUS,TITLE ! DISPLAY TITLE WITH NEW VALUE OF PARAMETER EL
ET,1,VISCO108 ! 2-D, 8-NODE VISCOPLASTIC ELEMENT
N,1,10
N,21,20
FILL
CSYS,1
NGEN,3,30,1,21,1,,1.5
E,1,3,63,61,2,33,62,31
EGEN,10,2,1,1,1
NSLE
NSEL,INVE
NDELE,ALL
! APPLY BOUNDARY CONDITIONS
NSEL,S,LOC,X,20
D,ALL,ALL
! ROTATE APPROPRIATE NODES AND APPLY COUPLING
NSEL,S,NODE,,61,81
LOCAL,11,0,,,,3
NROTAT,ALL
NSEL,S,NODE,,31,51,2
LOCAL,12,0,,,,1.5
NROTAT,ALL
NSEL,ALL
CSYS,0
CP,1,A(1),3,33,63
CP,2,A(2),3,33,63
CPSGEN,9,2,1,2,1
CP,21,A(1),2,62
CP,22,A(2),2,62
CPSGEN,10,2,21,22,1
FINISH
/OUTPUT,SCRATCH ! DIVERT VOLUMINOUS SOLUTION OUTPUT
/SOLU
SOLD,1,A(1),61,30,A(2)
FINISH
/OUTPUT
! POSTPROCESS SOLUTION RESULTS USING POSP MACRO
POSP
SAVE,TABLE_2
/CLEAR, NOSTART
! ANALYZE THE SAME PROBLEM WITH ELEMENT VISCO107
/PREP7
RESUME
EL='VISCO107'
/STATUS,TITLE ! DISPLAY TITLE WITH NEW VALUE OF PARAMETER EL
ET,1,VISCO107
CSYS,1
N,1,10
N,11,20
FILL
NGEN,2,100,1,11,1,,3
NGEN,2,200,1,111,1,,,1
E,1,2,102,101,201,202,302,301
EGEN,10,1,1,1
! APPLY BOUNDARY CONDITIONS
D,ALL,UZ
NSEL,S,LOC,X,20
D,ALL,ALL ! CLAMP OUTER SURFACE
NSEL,ALL
! ROTATE APPROPRIATE NODES AND APPLY COUPLING
LOCAL,11,0,,,,3
NROTAT,101,111
NROTAT,301,311
CSYS,0
CP,1,A(1),2,102,202,302
CP,2,A(2),2,102,202,302
CPSGEN,9,1,1,2,1
FINISH
/OUTPUT,SCRATCH ! DIVERT VOLUMINOUS SOLUTION OUTPUT
/SOLU
SOLD,1,A(1),301,100,A(2)
FINISH
/OUTPUT
POSP ! POSTPROCESS RESULTS USING POSP MACRO
SAVE,TABLE_3
RESUME,TABLE_1
/COM
/OUT,vm198,vrt
/COM,------------------- VM198 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING VISCO106
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM,RESULTS USING VISCO107
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING VISCO108
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
/NOPR
/DELETE,POSP,MAC
/DELETE,SOLD,MAC
/DELETE,SCRATCH
/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,TABLE_3
FINISH
*LIST,vm198,vrt


VM199 (Viscoplastic Analysis of a Body Undergoing Shear Deformation) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM199
/PREP7
/TITLE, VM199, VISCOPLASTIC ANALYSIS OF A BODY UNDERGOING SHEAR DEFORMATION
! " AN IMPLICIT STRESS UPDATE ....", LWO ET AL.
! VISCO106 ELEMENT
ET,1,VISCO106 ! 2-D, 4-NODE VISCOPLASTIC ELEMENT
MP,EX,1,60.6E9
MP,NUXY,1,0.4999
TB,ANAND,1 ! VISCOPLASTIC MODEL BY ANAND
TBDATA,1,29.7E6
TBDATA,2,21.08999E3
TBDATA,3,1.91E7
TBDATA,4,7.0
TBDATA,5,0.23348
TBDATA,6,1115.6E6
TBDATA,7,18.92E6
TBDATA,8,0.07049
TBDATA,9,1.3
SAVE ! SAVE DATABASE FOR LATER USE
N,1
N,2,1E-2
N,3,1E-2,1E-2
N,4,,1E-2
E,1,2,3,4
D,1,ALL,,,2
FINISH
/OUTPUT,SCRATCH ! DIVERT VOLUMINOUS SOLUTION OUTPUT
/SOLU
SOLCONTROL,0
ANTYPE,STATIC
NLGEOM,ON ! LARGE DEFORMATION ACTIVATED
OUTRES,RSOL,ALL ! STORE REACTION RESULTS FOR ALL SUBSTEPS
BFUNIF,TEMP,673 ! UNIFORM TEMPERATURE OF 673 K
D,3,ALL,0.0,,4
TIME,0.000001 ! NEAR ZERO TIME FOR FIRST LOAD STEP
SOLVE
NSUBST,20
D,3,UX,0.2E-2,,4
TIME,20
SOLVE
FINISH
/OUTPUT
/POST26
RFORCE,2,3,F,X
RFORCE,3,4,F,X
ADD,4,2,3,,LOAD,,,(1/100),(1/100)
! THE FX FORCE IS DIVIDED BY 100 BECAUSE THE DEFAULT OUT-
! OF-PLANE THICKNESS IS 1 METER WHILE PROBLEM CONSIDERED
! HAS OUT-OF-PLANE THICKNESS OF 0.01 METER WHICH IS 100
! TIMES LESS THAN 1 METER.
PRVAR,4
*GET,F1,VARI,4,RTIME,20
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Fx '
LABEL(1,2) = 'N'
*VFILL,VALUE(1,1),DATA,845
*VFILL,VALUE(1,2),DATA,F1
*VFILL,VALUE(1,3),DATA,ABS(F1/845)
SAVE,TABLE1
FINISH
/CLEAR, NOSTART
! VISCO108 ELEMENT TYPE
/PREP7
RESUME
ET,1,VISCO108 ! 2-D, 8-NODE VISCOPLASTIC ELEMENT
N,1
N,2,1E-2
N,3,1E-2,1E-2
N,4,,1E-2
N,5,0.5E-2
N,6,1E-2,0.5E-2
N,7,0.5E-2,1E-2
N,8,,0.5E-2
E,1,2,3,4,5,6,7,8
D,1,ALL
D,2,ALL
D,5,ALL
FINISH
/OUTPUT,SCRATCH ! DIVERT VOLUMINOUS SOLUTION OUTPUT
/SOLU
SOLCONTROL,0
NLGEOM,ON ! LARGE DEFORMATION ACTIVATED
OUTRES,RSOL,ALL ! STORE REACTION RESULTS FOR ALL SUBSTEPS
BFUNIF,TEMP,673 ! UNIFORM TEMPERATURE OF 673 K
D,3,ALL,0.0,,8
TIME,0.000001 ! NEAR ZERO TIME FOR FIRST LOAD STEP
SOLVE
NSUBST,20
D,3,UX,0.2E-2,,4
D,7,UX,0.2E-2
D,6,UX,0.1E-2,,8,2
TIME,20
SOLVE
FINISH
/OUTPUT
/POST26
RFORCE,2,3,F,X
RFORCE,3,4,F,X
RFORCE,4,7,F,X
ADD,5,2,3,4,LOAD,,,(1/100),(1/100),(1/100)
PRVAR,5
*GET,F1,VARI,5,RTIME,20
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Fx '
LABEL(1,2) = 'N'
*VFILL,VALUE(1,1),DATA,845
*VFILL,VALUE(1,2),DATA,F1
*VFILL,VALUE(1,3),DATA,ABS(F1/845)
SAVE,TABLE2
FINISH

/CLEAR, NOSTART
! VISCO107 ELEMENT
/PREP7
RESUME
ET,1,VISCO107 !3-D, 8-NODE VISCOPLASTIC ELEMENT
N,1
N,2,1E-2
N,3,1E-2,1E-2
N,4,,1E-2
NGEN,2,4,1,4,1,,,1E-2
E,1,2,3,4,5,6,7,8
D,1,ALL,,,2
D,5,ALL,,,6
FINISH
/OUTPUT,SCRATCH ! DIVERT VOLUMINOUS SOLUTION OUTPUT
/SOLU
SOLCONTROL,0
NLGEOM,ON ! LARGE DEFORMATION ACTIVATED
OUTRES,RSOL,ALL ! STORE REACTION RESULTS FOR ALL SUBSTEPS
BFUNIF,TEMP,673 ! UNIFORM TEMPERATURE OF 673 K
D,3,ALL,0.0,,8
TIME,0.000001 ! NEAR ZERO TIME FOR FIRST LOAD STEP
SOLVE
NSUBST,20
D,3,UX,0.2E-2,,4
D,7,UX,0.2E-2,,8
TIME,20
SOLVE
FINISH
/OUTPUT
/POST26
RFORCE,2,3,F,X
RFORCE,3,4,F,X
RFORCE,4,7,F,X
RFORCE,5,8,F,X
ADD,6,2,3,4
ADD,7,6,5,,LOAD
PRVAR,7
*GET,F1,VARI,7,RTIME,20
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Fx '
LABEL(1,2) = 'N'
*VFILL,VALUE(1,1),DATA,845
*VFILL,VALUE(1,2),DATA,F1
*VFILL,VALUE(1,3),DATA,ABS(F1/845)
/COM
/OUT,vm199,vrt
/COM,------------------- VM199 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,VISCO107 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F8.3)
/NOPR
RESUME,TABLE1
/GOPR
/COM,
/COM,VISCO106 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F8.3)
/NOPR
RESUME,TABLE2
/GOPR
/COM,
/COM,VISCO108 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F8.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm199,vrt


VM200 (Viscoelastic Sandwich Seal Analysis) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM200
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM200, VISCOELASTIC SANDWICH SEAL ANALYSIS
/COM, ----- 2-D ANALYSIS -----
/COM, "FE CALCULATIONS OF RESIDUAL STRESSES ....",SOULES ET AL.
ET,1,VISCO88,,,1 ! AXISYMMETRIC 2-D VISCOELASTIC ELEMENT
*CREATE,MAC1 ! MACRO FOR MATERIAL PROPERTIES
/COM, MATERIAL ONE IS G-11 GLASS AND MATERIAL TWO IS ALUMINA
/COM, NOTE THAT ALUMINA IS AN ELASTIC MATERIAL THEREFORE IT
/COM, DOES NOT HAVE VISCOELASTICITY AND STRUCTURAL RELAXATION
/COM, MATERIAL PROPERTIES OF ALUMINA
TB,EVISC,2
TBDATA,31,52.6E-7 ! THERMAL EXPANSION COEFFICENTS FOR ALUMINA
TBDATA,32,.119E-7 ! LOCATIONS 31-33
TBDATA,33,-1.0E-11
TBDATA,46,1.435E5 ! SHEAR MODULUS AT TIME = 0
TBDATA,47,1.435E5 ! SHEAR MODULUS AT TIME = INFINITY
TBDATA,48,3.11E5 ! BULK MODULUS AT TIME = 0
TBDATA,49,3.11E5 ! BULK MODULUS AT TIME = INFINITY
/COM, MATERIAL PROPERTIES OF G-11 GLASS
TB,EVISC,1
TBDATA,1,6.45D4 ! H/R
TBDATA,2,0.53 ! VALUE OF X
TBDATA,3,6 ! NO. OF MAXWELL ELEMENTS FOR STRUCTURAL RELAXATION
TBDATA,6,0.108 ! COEFFICIENTS OF THE MAXWELL ELEMENTS FOR
TBDATA,7,0.443 ! VOLUME DECAY (STRUCTURAL RELAXATION)
TBDATA,8,0.166 ! LOCATIONS 6-11
TBDATA,9,0.161
TBDATA,10,0.046
TBDATA,11,0.076
TBDATA,16,3.00 ! RELAXATION TIMES FOR VOLUME DECAY FUNCTION
TBDATA,17,0.671 ! LOCATIONS 16-21
TBDATA,18,0.247
TBDATA,19,0.091
TBDATA,20,0.033
TBDATA,21,0.008
TBDATA,26,3.43E-5 ! THERMAL EXPANSION COEFF. IN LIQUID STATE
TBDATA,31,64.7E-7 ! THERMAL EXPANSION COEFF. IN GLASS (SOLID) STATE
TBDATA,32,.02E-7 ! LOCATIONS 31-32
TBDATA,36,618 ! FICTIVE TEMPERATURE LOCATIONS 36-41
TBDATA,37,618
TBDATA,38,618
TBDATA,39,618
TBDATA,40,618
TBDATA,41,618
TBDATA,46,2.79D4 ! SHEAR MODULUS AT TIME = 0
TBDATA,47,0.0D0 ! SHEAR MODULUS AT TIME = INFINITY
TBDATA,48,6.05D4 ! BULK MODULUS AT TIME = 0
TBDATA,49,6.05D4 ! BULK MODULUS AT TIME = INFINITY
TBDATA,50,3 ! THREE MAXWELL ELEMENTS FOR SHEAR RELAXATION
TBDATA,51,0.422 ! COEFF. FOR SHEAR RELAXATION LOCATIONS 51-53
TBDATA,52,0.423
TBDATA,53,0.155
TBDATA,61,0.0689 ! RELAXATION TIMES FOR SHEAR RELAXATION
TBDATA,62,0.0065 ! LOCATIONS 61-63
TBDATA,63,0.0001
TBDATA,71,0 ! NO BULK MODULUS RELAXATION
*END
*USE,MAC1 ! EXECUTE MACRO FOR MATERIAL PROPERTIES
:COM, CREATE FINITE ELEMENT MODEL
N,1,
N,3,,0.00025
FILL
N,5,0,(0.00025+0.00325)
FILL
NGEN,3,10,1,5,1,.001
MAT,2
E,1,21,23,3,11,22,13,2
MAT,1
E,3,23,25,5,13,24,15,4
/COM, APPLY BOUNDARY CONDITIONS AND COUPLING
NSEL,S,LOC,Y
DSYM,SYMM,Y
NSEL,S,LOC,X
DSYM,SYMM,X
NSEL,ALL
D,1,ALL
CP,1,UX,21,22,23,24,25
CP,2,UY,2,22
CP,3,UY,3,13,23
CPSGEN,2,2,2,3,1
FINISH
/COM SINCE THE SOLUTION OUTPUT IS VOLUMINOUS IT IS DIVERTED TO A
/COM SCRATCH FILE
/OUTPUT,SCRATCH
*CREATE,MAC2 ! CREATE MACRO FOR ANALYSIS TYPE AND LOADING
/SOLU
SOLCONTROL,0
ANTYPE,STATIC
/COM, TEMPERATURE SET UP
TREF,618
TOFFST,273
TUNIF,618
TIME,1E-5
CNVTOL,F,,,,.00001 ! VERY SMALL MINIMUM ENFORCED
! FOR CONVERGENCE
SOLVE
OUTRES,ESOL,1 ! STORE RESULTS FOR EVERY SUBSTEP
NSUBST,200
TUNIF,460 ! COOLING
TIME,3160
SOLVE
TIME,(14400+3160) ! ISOTHERMAL HOLD
SOLVE
TUNIF,18 ! FURTHER COOLING
TIME,(14400+12000)
SOLVE
*END
FINISH
*USE,MAC2 ! EXECUTE ANALYSIS AND LOADING MACRO
/OUTPUT
/POST26
ESOL,2,2,,BFE,TEMP
ESOL,3,2,3,S,X,STRESS
*CREATE,MAC3 ! MACRO FOR PROCESSING RESULTS
XVAR,2
/GRID,1
/AXLAB,X,TEMPERATURE
/AXLAB,Y,IN-PLANE STRESS (MPA)
PLVAR,3
*GET,MXSX,VARI,3,EXTREM,VMAX ! MAXIMUM IN-PLANE STRESS
NSTORE,20 ! STORE EVERY 20TH TIME POINT RESULTS
PRVAR,2,3
*END
*USE,MAC3 ! EXECUTE POSTPROCESSING MACRO
*SET,P1,(MXSX)
*GET,T1,VARI,3,EXTREM,TMAX
*GET,TE,VARI,2,RTIME,T1
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'PRES MX ','TEMP '
LABEL(1,2) = 'MPa','DEG C'
*VFILL,VALUE(1,1),DATA,12.5,460
*VFILL,VALUE(1,2),DATA,P1,TE
*VFILL,VALUE(1,3),DATA,ABS(P1/12.5),ABS(TE/460)
SAVE,TABLE_1
FINISH
/CLEAR,NOSTART ! CLEAR THE DATABASE
/PREP7
/TITLE, VM200, VISCOELASTIC SANDWICH SEAL ANALYSIS
/COM, ----- 3-D ANALYSIS -----
ET,1,89 ! 3-D VISCOELASTIC ELEMENT
*USE,MAC1 ! EXECUTE MACRO FOR MATERIAL PROPERTIES
/COM, CREATE FINITE ELEMENT MODEL
N,1,
N,3,0.00025
FILL
N,5,(0.00025+0.00325)
FILL
NGEN,3,10,1,5,1,,.001
NGEN,3,100,1,25,1,,,0.001
MAT,2
E,1,3,23,21,201,203,223,221
EMORE,2,13,22,11,202,213,222,211
EMORE,101,103,123,121
EGEN,2,2,1,1,1,-1
NSLE,S
NSEL,INVE
NDELE,ALL
NSLE,S
/COM, APPLY BOUNDARY CONDITIONS AND COUPLING
NSEL,S,LOC,Y
DSYM,SYMM,Y
NSEL,S,LOC,X
DSYM,SYMM,X
NSEL,S,LOC,Z
DSYM,SYMM,Z
NSEL,S,LOC,Y,0.002
CP,1,UY,ALL
NSEL,S,LOC,Z,0.002
CP,2,UZ,ALL
NSEL,S,LOC,X,0.00025
CP,3,UX,ALL
NSEL,S,LOC,X,0.0035
CP,4,UX,ALL
NSEL,ALL
FINISH
/COM, SINCE THE SOLUTION OUTPUT IS VOLUMINOUS IT IS DIVERTED TO A
/COM, SCRATCH FILE
/OUTPUT,SCRATCH
*USE,MAC2 ! EXECUTE ANALYSIS AND LOADING MACRO
/OUTPUT
/POST26
ESOL,2,2,,BFE,TEMP
ESOL,3,2,3,S,Y,STRESS
*USE,MAC3 ! EXECUTE POSTPROCESSING MACRO
*SET,P2,(MXSX)
*GET,T2,VARI,3,EXTREM,TMAX
*GET,TE2,VARI,2,RTIME,T2
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'PRES MX ','TEMP '
LABEL(1,2) = 'MPa','DEG C'
*VFILL,VALUE(1,1),DATA,12.5,460
*VFILL,VALUE(1,2),DATA,P2,TE2
*VFILL,VALUE(1,3),DATA,ABS(P2/12.5),ABS(TE2/460)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm200,vrt
/COM,------------------- VM200 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING VISCO88
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING VISCO89
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
/NOPR
/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,MAC1
/DELETE,MAC2
/DELETE,MAC3
/DELETE,SCRATCH
FINISH
*LIST,vm200,vrt


VM201 (Rubber Cylinder Pressed Between Two Plates) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM201
/config,nproc,4
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
R = 0.2 ! RADIUS OF CYLINDER
/PREP7
smrt,off
/TITLE, VM201, RUBBER CYLINDER PRESSED BETWEEN TWO PLATES
/COM REF: T. SUSSMAN, K.J. BATHE, "A FE FORMULATION FOR NONLINEAR ..."
/COM COMPUTERS & STRUCTURES, VOL. 26, NOS. 1/2, 1987
ET,1,HYPER56 ! 2-D 4-NODE MIXED U-P HYPERELASTIC SOLID
ET,2,CONTAC26 ! 2-D POINT-TO-GROUND CONTACT ELEMENT
R,2,2000 ! SET SURFACE STIFFNESS
MP,EX,1,2.82 ! YOUNG'S MODULUS [MPA]
MP,NUXY,1,0.49967 ! POISSON'S RATIO
TB,MOONEY,1 ! MOONEY-RIVLIN CONSTANTS [MPA]
TBDATA,1,0.293
TBDATA,2,0.177
CSYS,1 ! SWITCH TO CYLINDRICAL C.S.
K,1 ! DEFINE KEYPOINTS
K,2,R,-90
K,3,R
K,4,(0.5*R),-90
K,5,(0.6*R),-45
K,6,(0.5*R)
K,7,R,-45
L,2,7
L,7,3
CSYS,0 ! SWITCH TO CARTESIAN C.S.
A,2,7,5,4
A,7,3,6,5
A,4,5,6,1
ESIZE,,4 ! SET ELEMENT DIVISION SIZE
AMESH,ALL ! MESH ALL AREAS
SAVE ! SAVE MODEL FOR SECOND ANALYSIS
*CREATE,CONTAC2D,MAC ! MACRO TO GENERATE CONTACT ELEMENTS
N,1001,(-2*R),-R ! TARGET SURFACE NODES
N,1002,(2*R) ,-R
CSYS,1 ! SWITCH TO CYLINDRICAL C.S.
TYPE,2
REAL,2
*DO,J,1,ARG1
NODC = NODE(R,90*((J-1)/ARG1-1),0)
E,NODC,1001,1002
*ENDDO
CSYS,0 ! SWITCH TO CARTESIAN C.S.
NSEL,S,LOC,X ! SELECT LEFT EDGE
D,ALL,UX ! CONSTRAIN LEFT EDGE IN UX
NSEL,S,LOC,Y ! SELECT TOP EDGE
CP,1,UY,ALL ! COUPLE TOP EDGE IN UY
*GET,NCEN,NODE,,NUM,MIN ! GET MINIMUM NODE NUMBER FROM SELECTED SET
NSEL,ALL
*END
CONTAC2D,8 ! USE MACRO CONTAC2D
FINISH

*CREATE,SOLVIT,MAC ! MACRO TO SOLVE MODEL
/SOLU
SOLCONTROL,0
ANTYPE,STATIC
CNVTOL,F,,,,-1
NLGEOM,ON ! INCLUDE LARGE DEFORMATION EFFECTS
NSUBST,6 ! SPECIFY NUMBER OF SUBSTEPS IN LOAD STEP
OUTRES,,1 ! WRITE SOLUTION FOR EVERY SUBSTEP
D,NCEN,UY,-0.1 ! APPLY DISPLACEMENT UY = -0.1 TO COUPLED NODES
SOLVE
FINISH
*END
SOLVIT ! USE MACRO SOLVE2D

*CREATE,PLOTS,MAC ! MACRO FOR POST-PROCESSING
/POST1
/DSCALE,1,1
PLDISP,1 ! PLOT DISPLACED SHAPE
FINISH
/POST26
/AXLAB,Y,FORCE
/AXLAB,X,DISPLACEMENT
NSOL,2,NCEN,U,Y
RFORCE,3,NCEN,F,Y
PROD,2,2,,,,,,-2
PROD,3,3,,,,,,-2
XVAR,2
PLVAR,3 ! PLOT DISPLACEMENT VS FORCE
PRVAR,2,3 ! PRINT DISPLACEMENT, FORCE
*GET,F1,VARI,3,RTIME,.5
*GET,F2,VARI,3,RTIME,1
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'F @ ','F @ '
LABEL(1,2) = '.1','.2'
*VFILL,VALUE(1,1),DATA,.25,1.4
*VFILL,VALUE(1,2),DATA,F1,F2
*VFILL,VALUE(1,3),DATA,ABS(F1/.25),ABS(F2/1.4)
FINISH
*END
PLOTS ! USE MACRO PLOTS
SAVE,TABLE_1
RESUME
/PREP7
smrt,off
ESEL,S,TYPE,,1
ET,3,HYPER74 ! 2-D 8-NODE MIXED U-P HYPERELASTIC SOLID
EMODIF,ALL,TYPE,3 ! SWITCH ELEMENTS TO HIGHER ORDER
EMID ! ADD MIDSIDE NODES
ESEL,ALL
CONTAC2D,16 ! USE MACRO TO GENERATE CONTACT ELEMENTS
FINISH
SOLVIT ! USE MACRO TO OBTAIN SOLUTION
PLOTS ! USE MACRO TO POSTPROCESS
SAVE,TABLE_2
RESUME
/PREP7
smrt,off
ET,5,HYPER58 ! 3-D 8-NODE MIXED U-P HYPERELASTIC SOLID
ET,6,CONTAC49 ! 3-D POINT-TO-SURFACE CONTACT ELEMENT
ET,7,MESH200,6 ! 2-D 4-NODED QUAD
R,6,2000,,,,0.1
R,7,0.05
ALLSEL
TYPE,5
ESIZE,,1
VEXT,ALL,,,,,1
N,1001,,-R ! CREATE TARGET PLANE OF NODES
N,1002,2*R,-R
N,1003,2*R,-R,8*R
N,1004,,-R,8*R
TYPE,7
REAL,7
E,1002,1001,1004,1003
NSEL,S,NODE,,1001,1004
CM,TARGET,NODE ! DEFINE TARGET COMPONENT NODES
D,ALL,ALL,0
CSYS,1 ! SWITCH TO CYLINDRICAL C.S.
ESEL,S,TYPE,,5
NSLE
NSEL,R,LOC,X,R
CM,CONTAC,NODE ! DEFINE CONTACT COMPONENT NODES
ESEL,S,TYPE,,5,7
TYPE,6
REAL,6
GCGEN,CONTAC,TARGET ! GENERATE 3-D CONTACT ELEMENTS
CSYS,0 ! SWITCH TO CARTESIAN C.S.
NSEL,ALL
D,ALL,UZ ! CONSTRAIN ALL NODES IN Z (PLANE STRAIN)
NSEL,S,LOC,X
D,ALL,UX
NSEL,S,LOC,Y
CP,1,UY,ALL ! COUPLE TOP NODES IN Y
*GET,NCEN,NODE,,NUM,MIN
ESEL,S,TYPE,,5,6
NSLE
FINISH

SOLVIT ! USE MACRO TO OBTAIN SOLUTION
PLOTS ! USE MACRO TO POSTPROCESS
SAVE,TABLE_3
RESUME,TABLE_1
/COM
/OUT,vm201,vrt
/COM,------------------- VM201 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING HYPER56:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING HYPER74:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM,RESULTS USING HYPER78:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/OUT
FINISH
/NOPR
/DELETE,CONTAC2D,MAC
/DELETE,PLOTS,MAC
/DELETE,SOLVIT,MAC
/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,TABLE_3
*LIST,vm201,vrt


VM202 (Transverse Vibrations of a Shear Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM202
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM202, TRANSVERSE VIBRATIONS OF A SHEAR BEAM
/COM, REF: R. BLEVINS, FORMULAS FOR NATURAL FREQUENCY AND MODE SHAPE, 1979.
ANTYPE,MODAL
ET,1,SHELL28
R,1,0.1 ! DEFINE REAL CONSTANT SET 1; THICKNESS OF SHELL
MP,EX, 1,200E9
MP,NUXY,1,0.27
MP,DENS,1,7860.0
N,1 ! DEFINE NODES
N,2,10
N,3,10,10
N,4, ,10
NGEN,9,4,1,4,1,,,3.75
E,1,2,6,5 ! DEFINE ELEMENTS
EGEN,3,1,-1
E,4,1,5,8
EGEN,8,4,-4
D,ALL,UZ ! DEFINE BOUNDARY CONDITIONS
D,1,UX,,,4,1,UY
NSEL,S,LOC,Z,3.75 ! SELECT NODES AT COMMON Z LOCATION
CP,1,UX,ALL ! COUPLE NODES IN X AND Y DOF
CP,2,UY,ALL
NSEL,S,LOC,Z,7.5
CP,3,UX,ALL
CP,4,UY,ALL
NSEL,S,LOC,Z,11.25
CP,5,UX,ALL
CP,6,UY,ALL
NSEL,S,LOC,Z,15
CP,7,UX,ALL
CP,8,UY,ALL
NSEL,S,LOC,Z,18.75
CP,9,UX,ALL
CP,10,UY,ALL
NSEL,S,LOC,Z,22.5
CP,11,UX,ALL
CP,12,UY,ALL
NSEL,S,LOC,Z,26.25
CP,13,UX,ALL
CP,14,UY,ALL
NSEL,S,LOC,Z,30
CP,15,UX,ALL
CP,16,UY,ALL
NSEL,ALL
FINISH
/SOLU
MXPAND,4 ! EXPAND FIRST TWO REPEATED MODES
MODOPT,REDUC
TOTAL,8 ! SET AUTOMATIC MASTER DOF GENERATION TO 8
SOLVE
*GET,F1,MODE,1,FREQ
*GET,F2,MODE,3,FREQ
FINISH
/POST1
SET,1,1
/VUP,,Z
/VIEW,,,1
PLDISP,1 ! DISPLAY DISPLACEMENTS (FIRST MODE)
SET,1,3
PLDISP,1 ! DISPLAY DISPLACEMENTS (SECOND MODE)
*STATUS
*DIM,VALUE,,2,3
*DIM,LABEL,CHAR,2,2
LABEL(1,1) = 'F1 ','F2 '
LABEL(1,2) = 'Hz ','Hz '
*VFILL,VALUE(1,1),DATA,17.375,52.176
*VFILL,VALUE(1,2),DATA,F1,F2
*VFILL,VALUE(1,3),DATA,ABS(F1/17.375),ABS(F2/52.176)
/COM
/OUT,vm202,vrt
/COM,------------------- VM202 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F8.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm202,vrt


VM203 (Dynamic Load Effect on Simply-Supported Thick Square Plate) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM203
/SHOW,JPEG
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/PREP7
/TITLE, VM203, DYNAMIC LOAD EFFECT ON SIMPLY-SUPPORTED THICK SQUARE PLATE
/COM REFERENCE: NAFEMS FORCED VIBRATION BENCHMARKS, TEST 21R
ET,1,SHELL93,,,,,1 ! DEFINE ELEMENT TYPE
MP,EX,1,200E9 ! DEFINE MATERIAL PROPERTIES
MP,NUXY,1,0.3
MP,ALPX,1,0.1E-5
MP,DENS,1,8000
R,1,1 ! DEFINE REAL CONSTANTS
N,1,0,0,0 ! DEFINE MODEL
N,9,0,10,0
FILL
NGEN,5,40,1,9,1,2.5
N,21,1.25,0,0
N,29,1.25,10,0
FILL,21,29,3
NGEN,4,40,21,29,2,2.5
EN,1,1,41,43,3,21,42,23,2
EGEN,4,2,1
EGEN,4,40,1,4
FINISH


/SOLU
ANTYPE,MODAL ! DEFINE ANALYSIS TYPE AS MODAL VIBRATION
MODOPT,REDUC
MXPAND,16,,,YES
SFE,ALL,,PRES,,-1E6 ! PRESS LOAD OF 1000,000 N/M**2
D,ALL,UX,0,,,,UY,ROTZ ! APPLY CONSTRAINTS
D,1,UZ,0,0,9,1,ROTX
D,161,UZ,0,0,169,1,ROTX
D,1,UZ,0,0,161,20,ROTY
D,9,UZ,0,0,169,20,ROTY
NSEL,S,LOC,X,.1,9.9
NSEL,R,LOC,Y,.1,9.9
M,ALL,UZ ! SELECT MASTERS
NSEL,ALL
SOLVE
*GET,F,MODE,1,FREQ
FINISH
/SOLU
/TITLE, VM203, RANDOM VIBRATION , RESPONSE TO UNIFORM PSD FORCE
ANTYPE,SPECTR ! DEFINE ANALYSIS TYPE
SPOPT,PSD,2,ON ! USE FIRST 2 MODES, CALC ELEM. STRESSES
PSDUNIT,1,PRES ! DEFINE TYPE OF PSD AS A PRESSURE SPECTRUM
DMPRAT,0.02
PSDFRQ,1,1,1.0,80.0
PSDVAL,1,1.0,1.0 ! IN N**2/HZ
LVSCALE,1 ! USE AND SCALE THE LOAD VECTOR GENERATED AT MODAL ANALYSIS
PFACT,1,NODE
PSDRES,DISP,REL
PSDCOM
SOLVE
FINISH

/POST1
SET,3,1 ! ONE SIGMA DISPLACEMENT SOLUTION RESULTS
/VIEW,1,2,3,4
PLNSOL,U,Z
PRNSOL,U,Z
FINISH

/SOLUTION
ANTYPE,HARMIC ! REDEFINE ANALYSIS TYPE AND SOLVE AGAIN
HROPT,MSUP ! USING MODE SUPERPOSITION HARMONIC ANALYSIS
HROUT,OFF,ON ! PRINT AMPLITUDE & PHASE, CLUSTER FREQUENCIES
KBC,1
HARFRQ,1,80
DMPRAT,0.02
NSUBSTEP,10
SOLVE
FINISH

/POST26
FILE,,rfrq
PRCPLX,1
NSOL,2,85,U,Z
PSDDAT,6,1,1.0,80,1.0
PSDTYP,2
PSDCAL,7,2
PSDPRT
PRVAR,2,7
*GET,P,VARI,7,EXTREM,VMAX
*STATUS
/VIEW
/AXLAB,Y,PSD (M^2/HZ)
PLVAR,7
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'f ','PSD '
LABEL(1,2) = 'Hz','SQmmS/Hz'
*VFILL,VALUE(1,1),DATA,45.9,3.4018E-3
*VFILL,VALUE(1,2),DATA,F,P
*VFILL,VALUE(1,3),DATA,ABS(F/45.9),ABS(P/(3.4018E-3))
/COM
/OUT,vm203,vrt
/COM,------------------- VM203 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F11.6,' ',F11.6,' ',1F6.3)
/COM,-----------------------------------------------------------
/COM,
/OUT
FINISH
*LIST,vm203,vrt


VM204 (Solid Model of an Axial Bearing) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM204
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/UNITS,BIN
/PREP7
/TITLE, VM204, SOLID MODEL OF AN AXIAL BEARING
/COM ANY BASIC GEOMETRY TEXT
BASEWD=8.0 ! BASE WIDTH
BASEDP=4.0 ! BASE DEPTH
BASEHT=1.0 ! BASE HEIGHT
BRNGWD=4.0 ! BEARING HOUSING WIDTH
BRNGDP=3.0 ! BEARING HOUSING DEPTH
BRNGHT=2.0 ! BEARING HOUSING HEIGHT
GRVDIA=3.5 ! GROOVE DIAMETER
BRCKWD=2.0 ! BRACKET WIDTH
BRCKDP=0.5 ! BRACKET DEPTH
SPRTHT=BRNGHT/2 ! SUPPORT HOLE HEIGHT
SPRTRAD=0.5 ! SUPPORT HOLE RADIUS
BLOCK,-BASEWD/2,BASEWD/2,0,-BASEHT,0,BASEDP ! BASE
BLOCK,-BRNGWD/2,BRNGWD/2,0,BRNGHT,0,BRNGDP ! BEARING HOUSING
WPAVE,BRNGWD/2,0,0 ! MOVE WORKING PLANE ORIGIN
BLOCK,0,BRCKWD,0,BRNGHT,0,BRCKDP ! RIGHT BRACKET
WPAVE,-BRNGWD/2,0,0
BLOCK,0,-BRCKWD,0,BRNGHT,0,BRCKDP ! LEFT BRACKET
WPAVE,0,BRNGHT,0
CYLIND,0,GRVDIA/2,0,BRNGWD
VSBV,2,5 ! GROOVE
LOCAL,11,1,BRNGWD/2+(BASEWD-BRNGWD)/4,SPRTHT ! LOCAL COORD SYSTEM
WPCSYS,1,11 ! MOVE WP TO LOCAL CS
CYLIND,0,SPRTRAD,0,1
VSBV,3,2 ! SUPPORT HOLE
LOCAL,12,1,-BRNGWD/2-(BASEWD-BRNGWD)/4,SPRTHT
WPCSYS,1,12
CYLIND,0,SPRTRAD,0,1
VSBV,4,2 ! SUPPORT HOLE
CSYS,0 ! CARTESIAN COORD SYSTEM
WPAVE,BRNGWD/2+(BASEWD-BRNGWD)/4,,BASEDP*0.75
WPROTA,,90
CYLIND,0,SPRTRAD,0,1
VSBV,1,2 ! SUPPORT HOLE
WPOFFS,-BRNGWD-(BASEWD-BRNGWD)/2 ! OFFSET WORKING PLANE
CYLIND,0,SPRTRAD,0,1
VSBV,4,1 ! SUPPORT HOLE
CSYS,11
K,100,(BASEWD-BRNGWD)/4,0,0
K,101,(BASEWD-BRNGWD)/4,90,0
K,102,(BASEWD-BRNGWD)/4,90,1
K,103,(BASEWD-BRNGWD)/4,0,1
A,100,101,102,103 ! CUTTING AREA
VSBA,5,3,SEPO ! ROUND
VDELE,1,,,1
CSYS,12
K,105,(BASEWD-BRNGWD)/4,180,0
K,106,(BASEWD-BRNGWD)/4,90,0
K,107,(BASEWD-BRNGWD)/4,90,1
K,108,(BASEWD-BRNGWD)/4,180,1
A,105,106,107,108 ! CUTTING AREA
VSBA,3,3,SEPO ! ROUND
VDELE,1,,,1
VGLUE,ALL ! GLUE VOLUMES - CONTINUITY
/TYPE,1,4
/VIEW,1,1,2,3 ! VIEWING ANGLE
/AUTO,1
/TRIAD,OFF
VPLOT ! DISPLAY VOLUMES
VSUM ! CALCULATE TOTAL VOLUME
*GET,TVOL,VOLU,,VOLU
*STATUS
*DIM,VALUE,,1,3
*DIM,LABEL,CHAR,1,2
LABEL(1,1) = 'VOLUME '
LABEL(1,2) = 'NO UNTS '
*VFILL,VALUE(1,1),DATA,42.997
*VFILL,VALUE(1,2),DATA,TVOL
*VFILL,VALUE(1,3),DATA,ABS(TVOL/42.997)
/COM
/OUT,vm204,vrt
/COM,------------------- VM204 RESULTS COMPARISON--------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F8.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm204,vrt


VM205 (Adaptive Analysis of an Elliptic Membrane Under a Uniformly-Distributed Load) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM205
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
/TITLE, VM205, ELLIPTIC MEMBRANE UNDER A UNIFORMLY-DISTRIBUTED LOAD
/COM, NAFEMS (REF.58), TEST NO. LE1 (MODIFIED)
/COM, USING 2-D STRUCTURAL SOLID, PLANE42
ANTYPE,STATIC
ET,1,PLANE42,,,3 ! DEFINE ELEMENT AS PLANE42 FOR PLANE STRESS
! WITH THICKNESS
MP,EX,1,210E9 ! DEFINE MATERIAL PROPERTIES
MP,NUXY,1,.3
R,1,0.1 ! SET THICKNESS
LOCAL,11,1,,,,,,,0.5 ! DEFINE ELLIPTICAL COORD. SYSTEM
K,1,2,90 ! CREATE MODEL GEOMETRY
K,2,2,0 ! DEFINE KEYPOINTS
L,1,2 ! DEFINE LINE SEGMENTS
LOCAL,12,1,,,,,,,0.8461585
K,3,3.25,90
K,4,3.25,0.0
L,3,4
CSYS,0
L,2,4
L,1,3
AL,2,4,1,3 ! DEFINE AREA
DL,4,1,SYMM ! APPLY BOUNDARY CONDITIONS
DL,3,1,SYMM
SFL,2,PRES,-10E6 ! APPLY LINE PRESSURE LOAD
MSHK,2 ! MAPPED AREA MESH IF POSSIBLE
MSHA,0,2D ! USING QUADS
SAVE ! SAVE DATABASE
FINISH
ADAPT,4,7,,,1 ! USE ANSYS PREDEFINED MACRO FOR ADAPTIVE MESHING
! AND SOLUTION WITH NSOLN=3, STARGT=7, AND FACMX=1
*CREATE,MAC ! CREATE MACRO FOR POST PROCESSING
/POST1
EPLOT ! PLOT ELEMENTS
PRERR ! PRINT THE ENERGY NORM PERCENT ERROR (SEPC)
NSEL,S,LOC,Y,0.0
NSEL,R,LOC,X,2.0
*GET,MNODE,NODE,,NUM,MAX
*GET,SY_D,NODE,MNODE,S,Y ! GET DESIRED STRESS SY VALUE
NSEL,ALL
ESEL,ALL
*STATUS ! SHOW STATUS OF PARAMETERS
*END
*USE,MAC ! USE POST PROCESSING MACRO
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'TAN STR '
LABEL(1,2) = 'MPa'
*VFILL,VALUE(1,1),DATA,92.70
*VFILL,VALUE(1,2),DATA,(SY_D/1000000)
*VFILL,VALUE(1,3),DATA,ABS((SY_D/1000000)/92.7)
SAVE,TABLE1
FINISH
/CLEAR, NOSTART ! CLEAR DATABASE BEFORE STARTING PART 2
/COM, USING 2-D 8-NODE STRUCTURAL SOLID, PLANE82
/PREP7
SMRT,OFF
RESUME ! RESUME DATABASE
ET,1,PLANE82,,,3 ! DEFINE ELEMENT AS PLANE82 FOR PLANE STRESS
! WITH THICKNESS
FINISH
ADAPT,2,5,,,1 ! USE ANSYS PREDEFINED MACRO FOR ADAPTIVE MESHING
! AND SOLUTION WITH NSOLN=2, STARGT=5, AND FACMX=1
*USE,MAC ! USE POST PROCESSING MACRO
*DIM,VALUE,,1,3
*DIM,LABEL,CHAR,1,2
LABEL(1,1) = 'TAN STR '
LABEL(1,2) = 'MPa'
*VFILL,VALUE(1,1),DATA,92.70
*VFILL,VALUE(1,2),DATA,(SY_D/1000000)
*VFILL,VALUE(1,3),DATA,ABS((SY_D/1000000)/92.7)
SAVE,TABLE2
RESUME,TABLE1
/COM
/OUT,vm205,vrt
/COM,------------------- VM205 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,PLANE42 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F8.3)
/NOPR
RESUME,TABLE2
/GOPR
/COM,
/COM,PLANE82 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F8.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm205,vrt


VM206 (Stranded Coil with Voltage Excitation) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM206
/PREP7
SMRT,OFF
/TITLE,VM206,STRANDED COIL MODEL, WITH VOLTAGE EXCITATION
/COM, REF: BOAST "ELECTRIC AND MAGNETIC FIELDS", PG. 247, EQN. 12.18
ET,1,53,,,1 ! AIR
ET,2,53,2,,1 ! VOLTAGE FORCED COIL
ET,3,110,,,1 ! FAR-FIELD

EMUNIT,MKS
MP,MURX,1,1
MP,MURX,2,1
MP,RSVX,2,3.00E-8 ! RESISTIVITY OF COIL

S=.02 ! COIL WIDTH AND HEIGHT
N=500 ! NUMBER OF TURNS
R=3*S/2 ! COIL MIDSPAN RADIUS

RECTNG,S,2*S,0,S/2
PCIRC,0,6*S,0,90
PCIRC,0,12*S,0,90
AOVLAP,ALL
ASEL,S,AREA,,1
AATT,2,1,2
ASUM
*GET,A,AREA,,AREA ! AREA OF 1/2 COIL CROSS-SECTION
ASEL,S,AREA,,5
AATT,1,1,1
ASEL,S,AREA,,4
AATT,1,1,3
ASEL,ALL
CSYS,1
LSEL,S,LOC,X,9*S
LESIZE,ALL,,,1
ESIZE,,8
AMESH,4

*GET,A,AREA,,AREA ! AREA OF 1/2 COIL CROSS-SECTION
R,1,2*A,500,,1,1 ! COIL CONSTANTS
ASEL,S,AREA,,1
LSLA,S
LESIZE,ALL,,,5
LSEL,ALL
ASEL,ALL
CSYS,0
KSEL,S,LOC,X,0
KSEL,R,LOC,Y,0
KESIZE,ALL,S/5
AMESH,ALL

NSEL,ALL

N1=NODE(S,0,0) ! GET A NODE ON THE COIL
N2=NODE(0,0,0) ! GET NODE AT ORIGIN

ESEL,S,MAT,,2 ! GET COIL ELEMENTS
NSLE,S
CP,1,CURR,ALL ! COUPLE CURR DOF IN COIL
*GET,ELM,ELEM,,NUM,MIN ! GET AN ELEMENT NUMBER IN THE COIL REGION
NSEL,ALL
ESEL,ALL
CSYS,1
NSEL,S,LOC,X,12*S
SF,ALL,INF
NSEL,S,LOC,X,0
D,ALL,AZ,0
NSEL,ALL
FINISH

/SOLU
ANTYPE,STATIC
ESEL,S,MAT,,2
BFE,ALL,VLTG,,12 ! 12 VOLT LOAD
ESEL,ALL
SOLVE
FINISH

/POST1
SET,LAST
ESEL,S,MAT,,2 ! SELECT COIL ELEMENTS
ETABLE,RES,NMISC,8 ! STORE ELEMENT RESISTANCE
ETABLE,IND,NMISC,9 ! STORE ELEMENT INDUCTANCE
SSUM
*GET,CRES,SSUM,,ITEM,RES ! GET COIL RESISTANCE
*GET,CIND,SSUM,,ITEM,IND ! GET COIL INDUCTANCE
CRES=2*CRES ! COIL RESISTANCE
CIND=2*CIND ! COIL INDUCTANCE
ICUR=12/CRES ! CALCULATE COIL CURRENT
*GET,NCUR,NODE,N1,CURR ! GET SOLUTION CURRENT
ESEL,ALL
FINISH
PI=4*ATAN(1)
W=2*PI*60
IMAG=12/SQRT(CRES**2+W**2*CIND**2)
ANG=-ATAN(W*CIND/CRES)
REALCURR=IMAG*COS(ANG) ! TARGET REAL CURRENT
IMAGCURR=IMAG*SIN(ANG) ! TARGET IMAGINARY CURRENT
/SOLU
ESEL,ALL
ANTYPE,HARM
HARFRQ,60
SOLVE
FINISH

/POST1
SET,1
*GET,CURREAL,NODE,N1,CURR ! COMPARE TO REALCURR
SET,1,1,,1
*GET,CURIMAG,NODE,N1,CURR ! COMPARE TO IMAGCURR
*DIM,LABEL,CHAR,5,2
*DIM,VALUE,,5,3
LABEL(1,1) = 'INDUCTAN','RESISTAN','COIL CUR','REAL SOL','IMAG SOL'
LABEL(1,2) = 'CE,HENRY','CE, OHM ','RENT ','UTION ','UTION '
*VFILL,VALUE(1,1),DATA,.01274,3.534,3.395,1.192,-1.621
*VFILL,VALUE(1,2),DATA,CIND,CRES,ICUR,CURREAL,CURIMAG
V1 = ABS(CIND/.01274)
V2 = ABS(CRES/3.534)
V3 = ABS(ICUR/3.395)
V4 = ABS(CURREAL/1.192)
V5 = ABS(CURIMAG/1.621)
*VFILL,VALUE(1,3),DATA,V1,V2,V3,V4,V5
/COM
/OUT,vm206,vrt
/COM,------------------- VM206 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm206,vrt


VM207 (Stranded Coil Excited by External Circuit) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM207
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
SMRT,OFF
/TITLE,VM207, STRANDED COIL MODEL, CIRCUIT-FED OPTION
/COM, REF: BOAST "ELECTRIC AND MAGNETIC FIELDS", PG. 247, EQN. 12.18
ET,1,53,,,1 ! AIR
ET,2,53,3,,1 ! CIRCUIT-COUPLED STRANDED COIL
ET,3,110,,,1 ! FAR-FIELD
ET,4,124,0 ! EXTERNAL RESISTOR
ET,5,124,4,4 ! INDEPENDENT VOLTAGE SOURCE, PIECEWISE LINEAR LOAD
ET,6,124,5 ! STRANDED COIL (TO FEA DOMAIN)
R,2,2 ! 2 OHM RESISTOR
R,3,1 ! SYMMETRY FACTOR FOR COIL
EMUNIT,MKS
MP,MURX,1,1
MP,MURX,2,1
MP,RSVX,2,3.04878E-8 ! RESISTIVITY OF COIL
S=.02
N=500
R=3*S/2
N,1 ! CREATE NODES FOR CIRCUIT ELEMENTS
*REPEAT,4,1
RECTNG,S,2*S,0,S/2
PCIRC,0,6*S,0,90
PCIRC,0,12*S,0,90
AOVLAP,ALL
ASEL,S,AREA,,1
AATT,2,1,2
ASUM
*GET,A,AREA,,AREA ! AREA OF 1/2 COIL CROSS-SECTION
ASEL,S,AREA,,5
AATT,1,1,1
ASEL,S,AREA,,4
AATT,1,1,3
ASEL,ALL
CSYS,1
LSEL,S,LOC,X,9*S
LESIZE,ALL,,,1
ESIZE,,8
AMESH,4
*GET,A,AREA,,AREA ! AREA OF 1/2 COIL CROSS-SECTION
R,1,2*A,500,,1,.9
ASEL,S,AREA,,1
LSLA,S
LESIZE,ALL,,,5
LSEL,ALL
ASEL,ALL
CSYS,0
KSEL,S,LOC,X,0
KSEL,R,LOC,Y,0
KESIZE,ALL,S/5
AMESH,ALL
N1=NODE(S,0,0) ! GET A NODE ON THE COIL
TYPE,5 ! VOLTAGE SOURCE
R,4,0,12,.01,12,.010001,0 ! PIECEWISE LINEAR LOAD
REAL,4
E,2,1,4 ! VOLTAGE SOURCE ELEMENT
TYPE,4 ! RESISTOR
REAL,2
E,2,3 ! EXTERNAL RESISTOR ELEMENT
TYPE,6 ! STRANDED COIL (TO FEA DOMAIN)
REAL,3
E,3,1,N1 ! STRANDED COIL "ELEMENT"
ESEL,S,MAT,,2 ! GET COIL ELEMENTS
NSLE,S
CP,1,CURR,ALL ! COUPLE CURR DOF IN COIL
CP,2,EMF,ALL ! COUPLE EMF DOF IN COIL
*GET,ELM,ELEM,,NUM,MIN ! GET AN ELEMENT NUMBER IN THE COIL REGION
NSEL,ALL
ESEL,ALL
FINISH
/SOLU
ANTYPE,STATIC
TIME,1E-9
CSYS,1
NSEL,S,LOC,X,12*S
SF,ALL,INF ! APPLY INFINITE SURFACE FLAG
CSYS,0
NSEL,S,LOC,X,0
D,ALL,AZ,0
NSEL,ALL
D,1,VOLT,0 ! GROUND
SOLVE
FINISH
/POST1
SET,LAST
ESEL,S,MAT,,2 ! SELECT COIL ELEMENTS
ETABLE,RES,NMISC,8 ! STORE ELEMENT RESISTANCE
ETABLE,IND,NMISC,9 ! STORE ELEMENT INDUCTANCE
SSUM
*GET,CRES,SSUM,,ITEM,RES ! GET COIL RESISTANCE
*GET,CIND,SSUM,,ITEM,IND ! GET COIL INDUCTANCE
CRES=2*CRES
CIND=2*CIND
ESEL,ALL
FINISH
/SOLU
ANTYPE,TRANS
OUTRES,ALL,ALL ! STORE EVERY SUBSTEP
DELTIM,.0004
TIME,.01
SOLVE
FINISH
/POST26
NSOL,2,N1,CURR ! GET CURRENT IN COIL
RES=CRES+2
I01=(12/RES)*(1-(EXP(-RES*.01/CIND)))
PRVAR,2
PLVAR,2
*GET,ICUR,VARI,2,RTIME,.01
/AXLAB,X,TIME
/AXLAB,Y,CURRENT IN COIL (AMPS)
/SHOW
PLVAR,2 ! PLOT COIL CURRENT VS TIME.
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'INDUCTAN','RESISTAN','CURRENT,'
LABEL(1,2) = 'CE,HENRY','CE, OHM ',' AMPS '
*VFILL,VALUE(1,1),DATA,.01274,3.9908,1.9849
*VFILL,VALUE(1,2),DATA,CIND,CRES,ICUR
*VFILL,VALUE(1,3),DATA,ABS(CIND/.01274),ABS(CRES/3.9908),ABS(ICUR/1.9849)
/COM
/OUT,vm207,vrt
/COM,------------------- VM207 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm207,vrt


VM208 (RL Circuit with Controlled Source) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM208
/PREP7
/TITLE, VM208, TEST CIRCUIT COMPONENT CCCS IN HARMONIC ANALYSIS
/COM REV.5.2 SDS-98
/COM, SEE SCHAUMS OUTLINE "BASIC CIRCUIT ANALYSIS", 2ND ED, 1992,
/COM, PROBLEM 14.23, FIGURE 14-25.
/NOPR
ET,1,CIRCU124,4 ! VOLTAGE SOURCE
ET,2,CIRCU124,3 ! CURRENT SOURCE
ET,3,CIRCU124,0 ! RESISTOR
ET,4,CIRCU124,1 ! INDUCTOR
ET,5,CIRCU124,12 ! CURRENT CONTROLLED CURRENT SOURCE

R,1,15,30 ! VOLTAGE SOURCE
R,2,5,-45 ! CURRENT SOURCE
R,3,3 ! R1
R,4,2 ! R2
R,5,4 ! L1
R,6,-3 ! CCCS GAIN

N,1
NGEN,10,1,1,1,1

TYPE,1
REAL,1
E,2,1,7 ! V1
TYPE,3
REAL,3
E,2,3 ! R1
TYPE,4
REAL,5
E,3,1 ! L1
TYPE,3
REAL,4
E,3,4 ! R2
TYPE,5
REAL,6
E,3,4,5,2,1,7 ! CCCS
TYPE,2
REAL,2
E,1,4 ! C1

FINISH
/SOLU
ANTYP,HARM
D,1,VOLT,0
PI=4*ATAN(1)
HARFRQ,1/(2*PI)
OUTPR,ALL,ALL
HROUT,OFF
SOLVE
FINISH

/POST1
SET,1,1 ! READ IN REAL SOLUTION
PRESOL,ELEM ! PRINT CIRCUIT SOLUTION PER ELEMENT
SET,1,1,,1 ! READ IN IMAGINARY SOLUTION
PRESOL,ELEM ! PRINT CIRCUIT SOLUTION PER ELEMENT
FINISH
/POST26
NSOL,2,4,VOLT
PRVAR,2
*GET,REAL,VARI,2,RTIME,15915
*GET,IMAG,VARI,2,ITIME,15915
FINISH
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'REAL VOL','IMAG VOL'
LABEL(1,2) = 'TAGE, V ','TAGE, V '
*VFILL,VALUE(1,1),DATA,16.44,-1.41
*VFILL,VALUE(1,2),DATA,REAL,IMAG
*VFILL,VALUE(1,3),DATA,ABS(REAL/16.44),ABS(IMAG/1.41)
/COM
/OUT,vm208,vrt
/COM,------------------- VM208 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm208,vrt


VM209 (Multiple Species Flow Entering a Circular Pipe) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM209
/PREP7
/TITLE,VM209, ENTRANCE FLOW OF SPECIES THROUGH A CIRCULAR PIPE
/NOPR
/COM
/COM -----------------------------------------------------------------------
/COM
/COM TEST THE SPECIES TRANSPORT EQUATION.
/COM
/COM FLOW OF TWO SPECIES THROUGH A CIRCULAR PIPE IS CONSIDERED.
/COM THE FLOW IS HYDRODYNAMICALLY DEVELOPED. THIS IS ACHIEVED BY SPECIFYING
/COM THE PRESURE AT THE INLET AND OUTLET. UNIFORM BUT DISSIMILIAR
/COM MASS FRACTIONS ARE SPECIFIED AT THE INLET AND WALL. SYMMETRY BOUNDARY
/COM CONDITIONS ARE APPLIED AT THE PIPE CENTERLINE. BOTH SPECIES HAVE THE
/COM SAME DENSITY, VISCOSITY, MASS DIFFUSION COEFFICIENT. RESULTING MASS
/COM FRACTION DISTRUBUTIONS ARE ANALOGOUS TO THAT OF TEMPERATURE
/COM IN GREATZ PROBLEM ( HYDRODYNAMICALLY FULLY DEVELOPED, THERMALLY
/COM DEVELOPING FLOW IN A PIPE WITH UNIFORM WALL TEMPERATURE.) THE RESULTS
/COM ARE COMPARED WITH ANALYTICAL SOLUTION ( REF: CONVECTIVE HEAT AND MASS
/COM TRANSFER, THIRD ED., KAYS, W.M., CRAWFORD,M.E,MCGRAW-HILL,1993.)
/COM
/COM ------------------------------------------------------------------------
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
ET,1,FLUID141,,,2 ! 2D AXISYMMETRIC XR SYSTEM
MSHK,1
MSHA,0,2D
PI = ACOS( -1.0 )
L = 0.1 ! PIPE LENGHT (m)
R = 0.0025 ! PIPE RADIUS (m)
NRD = 12 ! NO. OF DIVISIONS IN THE RADIAL DIRECTION
RS = 4 ! SPACING RATIO IN THE RADIAL DIRECTION
NXD = 100 ! NO. OF DIVISIONS IN THE AXIAL DIRECTION
XS = 1 ! SPACING RATIO IN THE AXIAL DIRECTION
PIN = 1.28 ! INLET PRESSURE
YBIN = 1.0 ! MASS FRACTION OF SPECIES B AT THE INLET
YBWALL = 0.0 ! MASS FRACTION OF SPECIES B AT THE WALL
RHO = 1.0 ! DENSITY (kg/m**3)
MU = 1.0E-5 ! VISCOSITY (Pa*s)
DIFF = 1.43E-5 ! DIFFUSION COEFFICIENT (m**2/s)
!
! DEFINE GEOMETRY AND GENERATE MESH
!
RECT,,L,,R
LESIZE,2,,,NRD,-RS
LESIZE,4,,,NRD,-RS
LESIZE,1,,,NXD,XS
LESIZE,3,,,NXD,1/XS
AMESH,1
KEYOPT,1,1,2 ! SET THE NUMBER OF SPECIES TO TW0
!
! APPLY THE BOUNDARY CONDITIONS
!
LSEL,S,,,4 ! INLET BC'S
NSLL,S,1
D,ALL,PRES,PIN ! PRESSURE
D,ALL,SP01,1.0-YBIN ! MASS FRACTION OF A
D,ALL,SP02,YBIN ! MASS FRACTION OF B
ALLS
LSEL,S,,,2 ! OUTLET BC'S
NSLL,S,1
D,ALL,PRES,0.0 ! PRESSURE
ALLS
LSEL,S,,,3 ! WALL BC'S
NSLL,S,1
D,ALL,VX,0.0 ! AXIAL VELOCITY IS SET TO ZERO
D,ALL,VY,0.0 ! RADIAL VELOCITY IS SET TO ZERO
D,ALL,SP01,1.0-YBWALL ! MASS FRACTION OF A
D,ALL,SP02,YBWALL ! MASS FRACTION OF B
ALLS
LSEL,S,,,1 ! SYMMETRY BC'S
NSLL,S,1
D,ALL,VY,0.0 ! RADIAL VELOCITY IS SET TO ZERO
ALLS
/SOLU
!
! SOLUTION OPTIONS
!
FLDA,ITER,EXEC,700 ! NO. OF GLOBAL ITERATIONS
FLDATA,ITER,CHEC,50 ! CHECKPOINT FREQUENCY
FLDA,PROT,VISC,CONSTANT
FLDA,PROT,DENS,CONSTANT
FLDA,NOMI,DENS,RHO ! FLUID DENSITY
FLDA,NOMI,VISC,MU ! FLUID VISCOSITY
!
FLDA,SOLU,SPEC,T ! ACTIVATE SPECIES TRANSPORT EQUATIONS
MSDATA,1 ! DESIGNATE ALGEBRAIC SPECIES
MSSPEC,1,SP01 ! ESTABLISH SPECIES 1
MSSPEC,2,SP02 ! ESTABLISH SPECIES 2
MSMETH,2,1 ! SPECIFY THE METHOD OF SOLUTION
MSNOMF,1,(1.0-YBWALL) ! INITIAL CONDITION FOR SPECIES 1
MSNOMF,2,YBWALL ! INITIAL CONDITION FOR SPECIES 2
MSRELAX,2,1.0 ! NO RELAXATION FOR SPECIES
FLDATA,PROT,VISC,CMIX ! RE-SPECIFY VISCOSITY AS OF MIXTURE
FLDATA,PROT,DENS,CMIX ! RE-SPECIFY DENSITY AS OF MIXTURE
FLDATA,VARY,VISC,T ! ALLOW MIXTURE VISCOSITY TO VARY
FLDATA,VARY,DENS,T ! ALLOW MIXTURE DENSITY TO VARY
MSPROP,1,VISC,CONSTANT,MU ! VISCOSITY OF SP01
MSPROP,2,VISC,CONSTANT,MU ! VISCOSITY OF SP02
MSPROP,1,DENS,CONSTANT,RHO ! DENSITY OF SP01
MSPROP,2,DENS,CONSTANT,RHO ! DENSITY OF SP02
MSPROP,1,MDIF,CONSTANT,DIFF ! MASS DIFFUSION COEFFICIENT OF SP01
MSPROP,2,MDIF,CONSTANT,DIFF ! MASS DIFFUSION COEFFICIENT OF SP02
!
SOLVE
FINISH
SAVE
!
! POST PROCESSING
!
/POST1
SET,LAST
/TRIAD,OFF ! DO NOT SHOW TRIAD
/RATIO,1,1,10 ! SCALE THE R_COORDINATE FOR CLEARITY
EPLOT ! PLOT THE MESH
/EDGE,1,1 ! SHOW THE EDGES ONLY
/CONTOUR,1,21 ! SET THE NUMBER OF CONTOUR LEVELS
/TITLE,CONTOURS OF AXIAL VELOCITY
PLNSOL,VX ! PLOT CONTOURS OF AXIAL VELOCITY
/TITLE,CONTOURS OF MASS FRACTION OF SPECIES A
PLNSOL,SP01 ! PLOT CONTOURS OF MASS FRACTION (A)
/TITLE,CONTOURS OF MASS FRACTION OF SPECIES B
PLNSOL,SP02 ! PLOT CONTOURS OF MASS FRACTION (B)
VAVE = 0.125*PIN*R**2/(L*MU) ! CALC. THE AVERAGE VELOCITY FROM INPUT
DATA
RE = 2*RHO*R*VAVE/MU ! CALC. THE REYNOLDS NUMBER
SC = (MU/RHO)/DIFF ! CALC. THE SCHMIDT NUMBER
*DIM,XCORD,,10 ! DECLARE AN ARRAY TO STORE AXIAL COORDINATES
*DIM,AVEYB,,10,2 ! DECLARE AN ARRAY TO STORE AVERAGE MASS
*DIM,RAT,,10
! FRACTIONS OF SPECIES B AT VARIOUS AXIAL
! LOCATIONS ( BOTH CALCULATED AND ANALYTICAL)

/NOPR
*DIM,pth,char,10
pth(1)='pth1'
pth(2)='pth2'
pth(3)='pth3'
pth(4)='pth4'
pth(5)='pth5'
pth(6)='pth6'
pth(7)='pth7'
pth(8)='pth8'
pth(9)='pth9'
pth(10)='pth10'
/GOPR
*DO,I,1,10
XCORD(I) = L*I/10 ! DETERMINE THE AXIAL LOCATION
N1 = NODE(XCORD(I),0,0)
N2 = NODE(XCORD(I),R,0)
PATH,pth(i),2,,48 ! DEFINE THE PATH
PPATH,1,N1 ! DEFINE THE PATH POINT
PPATH,2,N2 ! DEFINE THE PATH POINT
PDEF,SP02,SP02
PCALC,INTG,YBC,SP02,S ! INTEGRATE ALONG THE PATH TO CALC. TOTAL
! MASS FRACTION
*GET,YBC,PATH,,LAST,YBC
AVEYB(I,1) = YBC/R ! CALCULATE AVERAGE MASS FRACTION OF B
ARG = XCORD(I)/(R*RE*SC)
TERM0 = 0.1024204*EXP(-7.313*ARG)
TERM1 = 0.0121946*EXP(-44.61*ARG)
TERM2 = 0.0040650*EXP(-113.9*ARG)
TERM3 = 0.0019284*EXP(-215.2*ARG)
TERM4 = 0.0010987*EXP(-348.6*ARG)
TERM = TERM0 + TERM1 + TERM2 + TERM3 + TERM4
! CALCULATE THE AVERAGE MASS FRACTION
! ANALYTICALLY
AVEYB(I,2) = YBWALL - 8.0*(YBWALL-YBIN)*TERM
RAT(I) = AVEYB(I,1)/AVEYB(I,2)
*ENDDO
*vlen,10
/COM
/OUT,vm209,vrt
/COM,------------------- VM209 RESULTS COMPARISON ---------------
/COM,
/COM,Axial location(m)| TARGET | ANSYS | RATIO
/COM,
*VWRITE,XCORD(1),AVEYB(1,2),AVEYB(1,1),RAT(1)
(4(5x,f8.4))
/COM,
/COM,-------------------------------------------------------------
/OUT
FINISH
*LIST,vm209,vrt


VM210 (Pyramid Validation of Tetrahedron to Hexahedron Interface) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM210
/TITLE,VM210, BENDING OF HEX-TO-TET INTERFACE, FORMATION OF PYRAMIDS
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
SMRT,OFF
ET,1,95 !ELEMENT TYPE SOLID95
ET,2,95 !ELEMENT TYPE SOLID95
MP,EX,1,30E6 !ELASTIC MODULUS
MP,NUXY,1,0.3 !POISSON RATIO
P = 200 !FORCE
W = 31.071 !WIDTH
H = 33.917 !HEIGHT
L = 37.264 !LENGTH
I = 1/12*(W)*(H**3) !MOMENT OF INERTIA
SURF = P/(W*H) !SURFACE FORCE
BLOCK,-W/2, 0 , 0 , H/2, 0 , L
BLOCK, 0 , W/2, 0 , H/2, 0 , L !CREATE BLOCKS
BLOCK, 0 , W/2,-H/2, 0 , 0 , L !FORMING MIDPLANES
BLOCK,-W/2, 0 ,-H/2, 0 , 0 , L
WPOFF,,,L/2 !OFFSET WORKPLANE
WPLANE,-1,0,0,18.632,.87653,.402592,18.896,-.437455,.894952,18.72
WPLANE,-1,0,0,18.632,.890222,.338091,18.937,-.405661,.893273,18.826
VSBW,ALL,,
VGLUE,ALL
NUMCMP,ALL
/VIEW, 1, 0.9227 , 0.3132 ,-0.2246
/ANG, 1, 4.473
/PNUM,LINE,1
/NUM,-1
LPLO
/PNUM,LINE,0
/NUM,0
LESIZE,ALL,,,2
MOPT,PYRA,ON !MESH SET TO TRANSITIONAL PYRAMID
MSHK,1
MSHA,0
MSHM,0
TYPE,1
VSEL,S,VOLU,,1,2,1
VSEL,A,VOLU,,5,7,2
VMESH,ALL !VMESH ELEMENT TYPE 1
MSHK,0
MSHA,1,3D
MSHM,0
TYPE,2
VSEL,S,VOLU,,3,4,1
VSEL,A,VOLU,,6,8,2
VMESH,ALL !VMESH ELEMENT TYPE 2
VSEL,ALL
CSYS,4 ! USE WP AS LOCAL COOR. SYS
NSEL,S,LOC,Z,0 ! SELECT ALL NODES ON WP
CSYS,0 ! REVERT COOR. SYS TO CART.
ESLN ! ALL ELEMENTS ATTACHED TO WP NODES
NSLE ! AND ALL NODES ATT. TO ELEMS
/SHRINK,0.5
/VIEW,1, 0.51440 , -0.35450 , -0.78090
/ANG,1 ,1.41
EPLO ! ADJUST VIEW AND CAPTURE INTERFACE
/SHRINK,0
!
! THIS IS THE SECTION CONTAINING THE LOADING. THE MOMENT
! USED IN THE VERIFICATION EQUATION IS THE SUM OF ALL
! OF THE MOMENTS ON THE AREA LOCATED AT Z=0 OR Z=L. NOTE
! THAT THE LOADS ON EITHER AREA FORM A COUPLE.
!
SFGRAD,PRES,,Y,H/2,2*SURF/H !APPLY GRADIENT SURFACE LOADS
ASEL,S,LOC,Z,0
ASEL,A,LOC,Z,L
SFA,ALL,1,PRES,SURF,
ALLS
SFTRAN

! LOADS END

NSEL,S,LOC,X,W/2 !DEFINE DOF CONSTRAINTS
NSEL,R,LOC,Y,0 !SIMILAR TO PATCH TEST
NSEL,R,LOC,Z,0 !CONSTRAINTS
D,ALL, UX ,
D,ALL, UY ,
D,ALL, UZ ,

NSEL,S,LOC,X,-W/2
NSEL,R,LOC,Y,0
NSEL,R,LOC,Z,0
D,ALL, UY ,
D,ALL, UZ ,

NSEL,S,LOC,X,W/2
NSEL,R,LOC,Y,0
NSEL,R,LOC,Z,L
D,ALL, UY ,
! !CONSTRAINTS END
ALLSEL

FINISH

/SOLUTION
SOLVE !SOLVE
FINISH

/POST1
SET,LAST
PRRSOL !PRINT REACTION SOLUTIONS

/GRA,OFF
/VIEW,1,1,0,0
/GLINE,1,0
/DEV,VECT,ON
PLNSOL,S,Z !Z-STRESS CONTOUR
/NUM,0

MST1=0 !INIT PARAMETERS
NDE1=0
MST2=0
NDE2=0
MST3=0
NDE3=0

*DIM,RESULTS,ARRAY,3 !DEFINE ARRAY PARAMETER RESULTS

! !CALCULATION : TOP AVERAGE OF STRESS
!
NSEL,S,LOC,Y,H/2 !SELECT NODES IN TOP AREA
*GET,NUMNOD1,NODE,,COUNT !OBTAIN NUMBER OF TOP SURFACE NODES

ZSTR1=0
TOTAL=0
COUNT=0

*DO,J,1,NUMNOD1,1
NDE1=NDNEXT(NDE1)
NSEL,,,,NDE1
ESLN
*GET,NUMELM,ELEM,0,COUNT !GET NUMBER OF ELEMS CONNECTED TO NDE1
ELNUM=0
TRIP=0
*DO,K,1,NUMELM,1 !LOOP ON ELEMS CONNECTED TO NDE1
ELNUM=ELNEXT(ELNUM)
*DO,L,1,8,1 !VOLUME : SOLID95 CORNER NODES
POS=NELEM(ELNUM,L) !CHECK POS 1-8 ON SOLID95 FOR
! NODE NUMBER
*IF,POS,EQ,NDE1,THEN
TRIP=1 !SET TRIP IF OUR CURRENTLY SELECTED
!NODE IS CORNER OF ELEMENT ELNUM
*ENDIF
*IF,TRIP,EQ,1,EXIT
*ENDDO
*IF,TRIP,EQ,1,EXIT
*ENDDO

*IF,TRIP,NE,1,THEN
NSEL,S,LOC,Y,H/2 !IF ENTRY IS GAINED TO HERE
ESEL,ALL !THEN IT MUST BE THAT NDE1 IS A
*CYCLE !MIDNODE : NO STRESS CALC WANTED!
*ENDIF

ALLSEL
*GET,ZSTR1,NODE,NDE1,S,Z !IF ENTRY GAINED TO THIS POINT OF
TOTAL=TOTAL+ZSTR1 !THE LOOP, THEN GRAB Z-STRESS AT
COUNT=COUNT+1 !NODE NDE1 AND ADD IT TO TOTAL.
NSEL,S,LOC,Y,H/2 !RESET SELECTED SETS TO WHAT IS
ESEL,ALL !NEEDED.
*ENDDO

MST1=(TOTAL/COUNT) !AVERAGE OF Z-STRESS ON TOP SURFACE
RESULTS(1)=MST1



NSEL,S,LOC,Y,0 !SELECT NODES ALONG Z AXIS
NSEL,R,LOC,X,0 ! ( THE NURTRAL AXIS )
*GET,NUMNOD2,NODE,,COUNT !OBTAIN NUMBER OF TOP SURFACE NODES

ZSTR2=0
COUNT=0
TOTAL=0

*DO,J,1,NUMNOD2,1 ! LOGIC IS SIMILAR TO ABOVE *DO LOOP!
NDE2=NDNEXT(NDE2)
NSEL,,,,NDE2
ESLN
*GET,NUMELM,ELEM,0,COUNT
ELNUM=0
TRIP=0
*DO,K,1,NUMELM,1
ELNUM=ELNEXT(ELNUM)
*DO,L,1,8,1 !VOLUME : SOLID95 CORNER NODES
POS=NELEM(ELNUM,L)
*IF,POS,EQ,NDE2,THEN
TRIP=1
*ENDIF
*IF,TRIP,EQ,1,EXIT
*ENDDO
*IF,TRIP,EQ,1,EXIT
*ENDDO

*IF,TRIP,NE,1,THEN
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,0
ESEL,ALL
*CYCLE
*ENDIF

ALLSEL


*GET,ZSTR2,NODE,NDE2,S,Z
TOTAL=TOTAL+ZSTR2
COUNT=COUNT+1
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,0
ESEL,ALL
*ENDDO

MST2=TOTAL/COUNT !AVERAGE STRESS OF NEURTRAL AXIS
RESULTS(2)=MST2



NSEL,S,LOC,Y,-H/2 !SELECT NODES IN BOTTOM AREA
*GET,NUMNOD3,NODE,,COUNT

ZSTR3=0
COUNT=0
TOTAL=0

*DO,J,1,NUMNOD3,1 ! LOGIC IS SIMILAR TO ABOVE *DO LOOP!
NDE3=NDNEXT(NDE3)
NSEL,,,,NDE3
ESLN
*GET,NUMELM,ELEM,0,COUNT
ELNUM=0
TRIP=0
*DO,K,1,NUMELM,1
ELNUM=ELNEXT(ELNUM)
*DO,L,1,8,1 !VOLUME : SOLID CORNER NODES
POS=NELEM(ELNUM,L)
*IF,POS,EQ,NDE3,THEN
TRIP=1
*ENDIF
*IF,TRIP,EQ,1,EXIT
*ENDDO
*IF,TRIP,EQ,1,EXIT
*ENDDO

*IF,TRIP,NE,1,THEN
NSEL,S,LOC,Y,-H/2
ESEL,ALL
*CYCLE
*ENDIF

ALLSEL

*GET,ZSTR3,NODE,NDE3,S,Z
TOTAL=TOTAL+ZSTR3
COUNT=COUNT+1
NSEL,S,LOC,Y,-H/2
ESEL,ALL
*ENDDO

MST3=TOTAL/COUNT !AVERAGE STRESS ON SELECTED NODES
RESULTS(3)=MST3
!CALCULATE THE RATIOS
RAT1=MST1/(-SURF)
RAT2=MST2
RAT3=MST3/SURF

*DIM,RATIO,ARRAY,3 !DEFINE ARRAY PARAMETER RATIO
*VFILL,RATIO(1),DATA,RAT1,RAT2,RAT3 !DEFINE ARRAY PARAMETER TAR

*DIM,TAR,ARRAY,3
*VFILL,TAR(1),DATA,(-SURF),0,SURF

*DIM,LABEL,CHAR,3,2
LABEL(1,1) = 'TOP'
LABEL(1,2) = 'STRESS'

LABEL(2,1) = 'MIDDLE'
LABEL(2,2) = 'STRESS'

LABEL(3,1) = 'BOTTOM'
LABEL(3,2) = 'STRESS'

/COM
/OUT,vm210,vrt
/COM,------------------- VM210 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),TAR(1),RESULTS(1),RATIO(1)
(1X,A8,A8,' ',F12.4,' ',F10.4,' ',1F9.3)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vm210,vrt


VM211 (Rubber Cylinder Pressed Between Two Plates) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
!! CPU 500
/VERIFY,VM211
/CONFIG,NPROC,4
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
R = 0.2 ! RADIUS OF CYLINDER
/PREP7
SMRT,OFF
/TITLE, VM211, RUBBER CYLINDER PRESSED BETWEEN TWO PLATES
/COM REF: T. SUSSMAN, K.J. BATHE, "A FE FORMULATION FOR NONLINEAR ..."
/COM COMPUTERS & STRUCTURES, VOL. 26, NOS. 1/2, 1987
ET,1,HYPER56 ! 2-D 4-NODE MIXED U-P HYPERELASTIC SOLID
ET,2,TARGE169 ! 2-D TARGET ELEMENT
ET,3,CONTA171 ! 2-D CONTACT ELEMENT
R,2,,,2 ! SET STIFFNESS
MP,EX,1,2.82 ! YOUNG'S MODULUS [MPA]
MP,NUXY,1,0.49967 ! POISSON'S RATIO
TB,MOONEY,1 ! MOONEY-RIVLIN CONSTANTS [MPA]
TBDATA,1,0.293
TBDATA,2,0.177
CSYS,1 ! SWITCH TO CYLINDRICAL C.S.
K,1 ! DEFINE KEYPOINTS
K,2,R,-90
K,3,R
K,4,(0.5*R),-90
K,5,(0.6*R),-45
K,6,(0.5*R)
K,7,R,-45
L,2,7
L,7,3
CSYS,0 ! SWITCH TO CARTESIAN C.S.
A,2,7,5,4
A,7,3,6,5
A,4,5,6,1
TSHAPE,LINE
K,1001,-2*R,-R
K,1002,2*R,-R
L,1002,1001
SAVE,temp,db ! SAVE MODEL FOR SECOND ANALYSIS
TYPE,1
AMESH,ALL ! MESH ALL AREAS
REAL,2
TYPE,2
LMESH,10
LSEL,S,LINE,,1,2,1
TYPE,3
LMESH,ALL
FINI

*CREATE,SOLV2D,MAC ! MACRO TO SOLVE MODEL
/SOLU
SOLCONTROL,0
ANTYPE,STATIC
NSEL,S,LOC,X
D,ALL,UX
NSEL,S,LOC,Y
CP,1,UY,ALL
*GET,NCEN,NODE,,NUM,MIN
ALLSEL
CNVTOL,F,,,,-1
NLGEOM,ON ! INCLUDE LARGE DEFORMATION EFFECTS
NSUBST,6 ! SPECIFY NUMBER OF SUBSTEPS IN LOAD STEP
OUTRES,,1 ! WRITE SOLUTION FOR EVERY SUBSTEP
D,NCEN,UY,-0.1 ! APPLY DISPLACEMENT UY = -0.1 TO COUPLED NODES
NROPT,FULL,,OFF
SOLVE
FINISH
*END

SOLV2D ! USE MACRO SOLVE2D

*CREATE,PLOTS,MAC ! MACRO FOR POST-PROCESSING
/POST1
/DSCALE,1,1
PLDISP,1 ! PLOT DISPLACED SHAPE
FINISH
/POST26
/AXLAB,Y,FORCE
/AXLAB,X,DISPLACEMENT
NSOL,2,NCEN,U,Y
RFORCE,3,NCEN,F,Y
PROD,2,2,,,,,,-2
PROD,3,3,,,,,,-2
XVAR,2
PLVAR,3 ! PLOT DISPLACEMENT VS FORCE
PRVAR,2,3 ! PRINT DISPLACEMENT, FORCE
*GET,F1,VARI,3,RTIME,.5
*GET,F2,VARI,3,RTIME,1
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'F @ ','F @ '
LABEL(1,2) = '.1','.2'
*VFILL,VALUE(1,1),DATA,.25,1.4
*VFILL,VALUE(1,2),DATA,F1,F2
*VFILL,VALUE(1,3),DATA,ABS(F1/.25),ABS(F2/1.4)
FINISH
*END

PLOTS ! USE MACRO PLOTS
SAVE,TABLE_1
RESUME,temp,db
/PREP7
ALLSEL
ET,1,HYPER74 ! 2-D 8-NODE MIXED U-P HYPERELASTIC SOLID
ET,2,TARGE169 ! 2-D TARGET ELEMENT
ET,3,CONTA172 ! 2-D CONTACT ELEMENT
TYPE,1
AMESH,ALL
TYPE,2
LMESH,10
LSEL,S,LINE,,1,2,1
TYPE,3
LMESH,ALL
FINISH
SOLV2D ! USE MACRO TO OBTAIN SOLUTION
PLOTS ! USE MACRO TO POSTPROCESS
SAVE,TABLE_2
/PREP7
RESUME,temp,db
ET,1,TARGE170
ET,2,HYPER58 ! 3-D 8-NODE MIXED U-P
ET,3,CONTA173 ! 3-D 4 NODE CONTACT ELEMENT
ET,4,200,6 ! 2-D 4 NODED MESH200
LDELETE,10,,,1
ALLSEL
CSYS,0
K,1001,-.1*R,-R,-.1*R
K,1002,2*R,-R,-.1*R
K,1003,2*R,-R,8*R
K,1004,-.1*R,-R,8*R
A,1004,1003,1002,1001
TSHAPE,TRI
SAVE,temp,db
ESIZE,,1
TYPE,1
AMESH,4
TYPE,4
ESIZE,,4
AMESH,1,3,1
TYPE,2
ESIZE,,4
VEXT,1,3,1,,,1
CSYS,1
ASEL,S,LOC,X,R
TYPE,3
REAL,1
AMESH,ALL
LSEL,ALL
NSEL,ALL
CSYS,0
FINISH
*CREATE,SOLV3D,MAC ! MACRO TO SOLVE MODEL
/SOLUTION
SOLCONTROL,0
ANTYPE,STATIC
D,ALL,UZ ! CONSTRAIN ALL IN Z (PLANE STRAIN)
NSEL,S,LOC,X
D,ALL,UX
NSEL,S,LOC,Y
CP,1,UY,ALL
*GET,NCEN,NODE,,NUM,MIN
NSEL,ALL
CNVTOL,F,1
NLGEOM,ON ! INCLUDE LARGE DEFORMATION EFFECTS
NSUBST,6 ! SPECIFY NUMBER OF SUBSTEPS IN LOAD STEP
NROPT,FULL,,OFF
OUTRES,,1 ! WRITE SOLUTION FOR EVERY SUBSTEP
D,NCEN,UY,-0.1 ! APPLY DISPLACEMENT UY = -0.1 TO COUPLED NODES
SOLVE
FINISH
*END
SOLV3D ! USE MACRO TO OBTAIN SOLUTION
PLOTS ! USE MACRO TO POSTPROCESS
SAVE,TABLE_3
/PREP7
RESUME,temp,db
ET,1,TARGE170
ET,2,HYPER158
ET,3,CONTA174
VEXT,1,3,1,,,1
TYPE,2
VMESH,ALL
TYPE,3
CSYS,1
ASEL,S,LOC,X,R
AMESH,ALL
ESIZE,,1
TYPE,1
ASEL,ALL
AMESH,4
ALLSEL
CSYS,0
FINI
SOLV3D
PLOTS
SAVE,TABLE_4
/COM
/OUT,vm211,vrt
/COM,------------------- VM211 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING HYPER56:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING HYPER74:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM,RESULTS USING HYPER78:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/NOPR
RESUME,TABLE_4
/GOPR
/COM,
/COM,RESULTS USING HYPER158:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/OUT
FINISH
*LIST,vm211,vrt

/DELETE,PLOTS,MAC
/DELETE,SOLV2D,MAC
/DELETE,SOLV3D,MAC
/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,TABLE_3
/DELETE,TABLE_4
/DELETE,temp,db


VM212 (Modal Analysis of a Rectangular Cavity) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM212
!! MEM 128
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM212, MODAL ANALYSIS OF A RECTANGULAR CAVITY
/COM,********************************************************************************
/COM,
/COM, INTRO TO GUIDED WAVES AND MICROWAVE CIRCUITS
/COM, ROBERT S. ELLIOT, PAGE 264
/COM,
/COM,********************************************************************************
ET,1,HF120,2 ! HF SOLID BRICK ELEMENT, 2ND ORDER
MP,MURX,1,1. ! RELATIVE PERMEABILITY
MP,PERX,1,1. ! RELATIVE PERMITTIVITY
CH=0.3 ! CAVITY HEIGTH
CW=0.4 ! CAVITY WIDTH
CL=1.0 ! CAVITY LENGTH
FRQSTR=1.0E6 ! SHIFT POINT FOR EIGENVALUE EXTRACTION
FRQEND=100E9 ! UPPER BOUND FOR FREQUNECY EXTRACTION
MODES=1 ! NUMBER OF MODES TO EXTRACT
BLOCK,0,CL,0,CW,0,CH ! CREATE CAVITY
LSEL,S,LOC,X,0
LSEL,A,LOC,X,CL
LESIZE,ALL,,,5 ! SET LINE DIVISIONS
LSEL,INVE
LESIZE,ALL,,,10
VMESH,1 ! MESH VOLUME
DA,ALL,AX,0 ! SET ELECTRIC WALL CONDITION (TANGENTIAL E=0)
ASEL,ALL
FINISH
/SOLUTION
ANTYPE,MODAL ! MODAL ANALYSIS
MODOPT,LANB,MODES,FRQSTR,FRQEND,,ON ! BLOCK LANCZOS SOLVER
MXPAND,,,,YES ! EXPAND MODE
SOLVE
FINISH
/POST1
SET,LAST
*GET,MODFRQ,ACTIVE,,SET,FREQ
MODFRQ=MODFRQ/1E9 ! GHZ.
/VIEW,,.75,.5,.6
/VUP,1,Z
/DEVICE,VECTOR,1
EPLOT
PLVECT,H,,,,VECT,NODE,ON ! DISPLAY H FIELD
PLVECT,EF,,,,VECT,NODE,ON ! DISPLAY E FIELD
*DIM,LABEL,CHAR,1
*DIM,VALUE,,1,3
LABEL(1,1)='FREQUENCY'
*VFILL,VALUE(1,1),DATA,.40389
*VFILL,VALUE(1,2),DATA,MODFRQ
*VFILL,VALUE(1,3),DATA,ABS(MODFRQ/.40389)
/OUT,vm212,vrt
/COM,------------------- VM212 RESULTS COMPARISON ----------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F10.7,' ',F10.7,' ',1F5.3)
/COM,--------------------------------------------------------------------
/OUT
FINISH
*LIST,vm212,vrt


VM213 (Harmonic Response Analysis of a Coaxial Cable) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM213
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE,VM213, HARMONIC RESPONSE ANALYSIS OF A COAXIAL CABLE
/COM,********************************************************************************
/COM,
/COM, INTRO TO GUIDED WAVES AND MICROWAVE CIRCUITS
/COM, ROBERT S. ELLIOT
/COM, SECTION 3.3, THE COAXIAL CABLE, PAGE 48
/COM,
/COM,********************************************************************************
ET,1,HF120,2 !HIGH FREQUENCY SOLID BRICK, 2ND ORDER
MP,MURX,1,1. !RELATIVE PERMEABILITY
MP,PERX,1,1. !RELATIVE PERMITTIVITY
FREQ=8E8 !FREQUENCY (HZ.)
CA=0.025 !INNER RADIUS
CB=0.075 !OUTER RADIUS
CL=0.375 !CABLE LENGTH
V0=1.0 !VOLTAGE DIFFERENCE BETWEEN CONDUCTORS
NL=15 !NUMBER OF ELEMENTS ALONG LENGTH
NR=8 !NUMBER OF ELEMENTS ALONG RADIUS
NTH=1 !NUMBER OF ELEMENT THROUGH CIRCUMFERENCE
ANG=5 !CIRCUMFERENTIAL MODEL ANGLE
CYLIND,CA,CB,0,CL,0,5 !CREATE WEDGE MODEL
CSYS,1
LSEL,S,LOC,Z,CL/2
LESIZE,ALL,,,NL,-10 !NL ELEMENTS ALONG LENGTH OF COAX, CLUSTER AT PORTS
LSEL,S,LOC,X,(CA+CB)/2
LESIZE,ALL,,,NR !NR ELEMENTS ALONG THE RADIUS
LSEL,S,LOC,Y,ANG/2
LESIZE,ALL,,,NTH !NTH ELEMENTS AROUND THE CIRCUMFERENCE
VMESH,1 !MESH THE VOLUME
ASEL,S,LOC,X,CA
ASEL,A,LOC,X,CB
DA,ALL,AX,0 !SET ELECTRIC WALL BC (TANGENTIAL E = 0)
LOCAL,11,1
CSYS,0
ASEL,S,LOC,Z,0 !SELECT AREA AT PORT 1 LOCATION
SFA,ALL,,PORT,1 !DEFINE AS PORT 1
PORTOPT,1,COAX,11,CA,CB,V0 !SPECIFY PORT OPTIONS
ASEL,S,LOC,Z,CL !SELECT AREA AT PORT 2 LOCATION
SFA,ALL,,PORT,2 !DEFINE PORT 2
PORT,2,COAX,11, CA,CB, !SPECIFY PORT OPTIONS (MATCHING PORT)
ASEL,ALL
CSYS,1
NBI=NODE(CA,0,CL) !RETRIEVE NODE AT INNER RADIUS
NBO=NODE(CB,0,CL) !RETRIEVE NODE AT OUTER RADIUS
NBA=NODE(CB,ANG,CL) !RETRIVE NODE AT OUTER RADIUS, ANGLE "ANG"
FINISH
/SOLUTION
ANTYPE,HARMIC !FULL HARMONIC ANALYSIS
HARFRQ,FREQ
SOLVE
FINISH
/POST1
SPARM,1,2 !CALCULATE S-PARAMETERS
SET,1,1,
/VIEW,,1,.5,.8
EPLOT
PLVECT,H,,,H,VECT,NODE,ON !DISPLAY H FIELD
PLVECT,EF,,,EF,VECT,NODE,ON !DISPLAY E FIELD
RSYS,1 !RETRIEVE RESULTS IN CYLINDRICAL C.S.
*GET,EFX,NODE,NBO,EF,X !RETRIEVE EF(X) AT NODE NBO
*GET,HY,NODE,NBO,H,Y !RETRIEVE H(Y) AT NODE NBO
RSYS,0
ESEL,S,SFE,PORT,1 !SELECT ELEMENTS AT PORT1
ETABLE,PS1,NMISC,5 !STORE INCIDENT POWER
SSUM !SUM FOR ALL SELECTED ELEMENTS
*GET,PINC,SSUM,,ITEM,PS1 !RETRIEVE INCIDENT POWER
PINC=PINC*360/ANG !CALCULATE POWER FOR FULL 360 DEGREES
ESEL,ALL
!
PATH,VLTG,2 !CREATE PATH FOR VOLTAGE CALC.
PPATH,1,NBI !DEFINE PATH POINTS VIA NODES
PPATH,2,NBO
PATH,CURR,2 !CREATE CURRENT PATH FOR CURRENT CALC.
PPATH,1,NBO !DEFINE PATH POINTS VIA NODES
PPATH,2,NBA
IMPD,'VLTG','CURR',1,360/ANG !CALCULATE IMPEDANCE
EX=12.14
H=.0322
S12=1.0
S11=0.0
P=.01517/2
IMP=65.87
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
LABEL(1,1) = 'EX ','HY ','S11 ','S12 ','P ','IMPD'
LABEL(1,2) = '= ','= ','= ','= ','= ','= '
*VFILL,VALUE(1,1),DATA,12.14,.0322,0,1.0,ABS(.01517/2),65.87
*VFILL,VALUE(1,2),DATA,EFX,HY,SII,SIJ,PINC,ZRE
*VFILL,VALUE(1,3),DATA,(EFX/12.14),(HY/.0322),0,(SIJ/1.0),(PINC/(.01517/2)),(ZRE/65.87)
/COM
/OUT,vm213,vrt
/COM,------------------- VM213 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,
/COM,-------------------------------------------------------------
/OUT
FINISH
*LIST,vm213,vrt


VM214 (Harmonic Response of a Rectangular Waveguide) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM214
/PREP7 $ SMRT,OFF
/TITLE,VM214, HARMONIC ANALYSIS OF A TE10-LOADED RECTANGULAR WAVEGUIDE
/COM,********************************************************************************
/COM,
/COM, INTRO TO GUIDED WAVES AND MICROWAVE CIRCUITS
/COM, ROBERT S. ELLIOT
/COM, SECTION 4.3, THE RECTANGULAR WAVEGUIDE, PAGE 82
/COM,
/COM,********************************************************************************
/PREP7 $ SMRT,OFF
ET,1,HF119 ! HIGH FREQUENCY SOLID TETRAHEDRAL
MP,MURX,1,1. ! REALTIVE PERMEABILITY
MP,PERX,1,1. ! RELATIVE PERMITTIVITY
CH=0.01 ! WIDTH
CW=0.03 ! HEIGHT
CL=0.048 ! LENGTH EQUAL TO ONE WAVELENGTH
FREQ=8E9 ! FREQUENCY (HZ.)
LAMDA=3E8/FREQ ! CALCULATE WAVELENGTH
BLOCK,-CW/2,CW/2,0,CH,0,CL ! CREATE WAVEGUIDE
ESIZE,.003 ! SET ELEMENT DIVISIONS
VMESH,1 ! MESH VOLUME
ASEL,S,LOC,X,-CW/2
ASEL,A,LOC,X,CW/2
ASEL,A,LOC,Y,0
ASEL,A,LOC,Y,CH
DA,ALL,AX,0 ! SET ELECTRIC WALL CONDITION (TANGENTIAL E=0)
LOCAL,11
PORT,1,TE10,11,CW,CH,1.0 ! INPUT PORT, 1 VOLT
PORT,2,TE10,11,CW,CH, ! OUTPUT PORT, MATCHED
ASEL,S,LOC,Z,0 ! SELECT AREAS TO ASSIGN INPUT PORT
SFA,ALL,,PORT,1 ! ASSIGN INPUT PORT TO PORT 1
ASEL,S,LOC,Z,CL ! SELECT AREAS TO ASSIGN OUTPUT PORT
SFA,ALL,,PORT,2 ! ASSIGN OUTPUT PORT TO PORT 2
ASEL,ALL
FINISH
/SOLUTION
ANTYPE,HARMIC ! FULL HARMONIC ANALYSIS
EQSLV,ICCG ! SELECT ICCG SOLVER
HARFRQ,FREQ ! SET FREQUENCY
SOLVE
FINISH
/POST1
SPARM,1,2
S11C = SII
S12C = SIJ
SET,1,1
ETABLE,PS1,NMISC,5 ! STORE INCIDENT POWER
/OUT,SCRATCH
SSUM ! SUM FOR ALL SELECTED ELEMENTS
/OUT
*GET,PINC,SSUM,,ITEM,PS1 ! RETRIEVE INCIDENT POWER
N1=NODE(0,0,0) ! INPUT PORT AT CENTERLINE
*GET,EYC,NODE,N1,EF,Y
*GET,HXC,NODE,N1,H,X
S11T=0.0
S12T=1.0
PIN=.1554E-6
EY=1.0
HX=-.2072E-2
*DIM,LABEL,CHAR,5,2
*DIM,VALUE,,5,3
LABEL(1,1) = 'S11 ','S12 ','POWER ','EY ','HX '
LABEL(1,2) = '= ','= ','= ','= ','= '
*VFILL,VALUE(1,1),DATA,S11T,S12T,PIN,EY,HX
*VFILL,VALUE(1,2),DATA,S11C,S12C,PINC,EYC,HXC
*VFILL,VALUE(1,3),DATA,0,(S12C/S12T),(PINC/PIN),(EYC/EY),(HXC/HX)
/COM
/OUT,vm214,vrt
/COM,------------------- VM214 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.8,' ',F10.8,' ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm214,vrt


VM215 (Thermal-Electric Hemispherical Shell with Hol) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM215
/PREP7
/TITLE,VM215, CONDUCTING SPHERE
ET,1,157
R,1,0.2 ! THICKNESS = 0.2
MP,RSVX,,7 ! DEFINE ELECTRICAL RESISTIVITIES PROPERTY
MP,KXX,,3 ! DEFINE THERMAL CONDUCTIVITIES PROPERTY
CSYS,2 ! SPHERICAL COORDINATE SYSTEM
N,1,10 ! 10 UNIT RADIUS SPHERE
N,21,10,,80 ! 10 DEGREE HOLE AT THE TOP
FILL,,, ,,, ,,0.1 ! SHIFT ELEMENTS TOWARD HOLE
NGEN,2,30,1,21,1,,3 ! ANALYSE A 3 DEGREE SECTOR
E,1,2,32,31 ! DEFINE ELEMENT
EGEN,20,1,-1 ! USE 20 ELEMENTS
CP,1,VOLT,1,31
CP,2,TEMP,1,31
CP,3,VOLT,21,51
CP,4,TEMP,21,51
FINISH
/SOLU
OUTPR,,1
D,21,ALL ! SET ALL VOLTAGES AND TEMPERATURES AT THE HOLE TO ZERO
D,1,VOLT,100 ! SET VOLTAGE AT THE EQUATOR TO 100
SOLVE
FINISH
/POST1
PRRSOL,AMPS ! PRINTS THE CONSTRAINED NODE REACTION AT CURRENT FLOW
PRRSOL,HEAT ! PRINTS THE CONSTRAINED NODE REACTION AT HEAT FLOW
NSEL,S,NODE,,21,51,30
FSUM
*GET,I21,FSUM,0,ITEM,AMPS
*GET,H21,FSUM,0,ITEM,HEAT
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'I AMPS ','Q WATT'
LABEL(1,2) = 'NODE 21','NODE 21'
*VFILL,VALUE(1,1),DATA,0.0614,6.14058
*VFILL,VALUE(1,2),DATA,I21,H21
*VFILL,VALUE(1,3),DATA,(I21/0.0614),(H21/6.14058)
/COM
/OUT,vm215,vrt
/COM,------------------- VM215 RESULTS COMPARISON --------------------------
/COM,
/COM, SHELL157 | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A9,A8,' ',F7.5,' ',F7.5,' ',1F5.3)
/COM,------------------------------------------------------------------------
/OUT
FINISH
*LIST,vm215,vrt


VM216 (Lateral Buckling of a Right-Angle Frame) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM216
/TITLE,VM216, LATERAL BUCKLING OF RIGHT-ANGLE FRAME
! J.C. SIMO, L. VU-QUOC, "THREE-DIMENSIONAL FINITE-STRAIN ROD
! MODEL",PART II CMAME, VOL 58, 1986, PP 79-116
/PREP7
N,1 , ,240 !DEFINE NODES
N,21,240,240
N,41,240,0
FILL,1,21
FILL,21,41
N,101,120,360
N,201,360,120
SECNUM,1
ET,1,188 !USE BEAM188 ELEMENT TYPE
*DO,I,1,20,1
E,I,I+1,101
*ENDDO
*DO,I,21,40,1
E,I,I+1,201
*ENDDO
SECTYPE,1,BEAM,ASEC
SECDATA,18.0,1350.0,0.0,0.54,0.0,2.16
MP,EX,1,71240
MP,NUXY,1,0.31
D,1,ALL
FINISH
/SOLU
NLGEOM,ON
NSUBST,2
F,41,FZ,1.0E-3 !APPLY PERTURBATION FORCE
/OUT,SCRATCH, !SUPPRESS SOLUTION DATA
SOLVE
/OUT
OUTRES,ALL,ALL
ARCLEN,ON
ARCTRM,U,60,41,UZ
F,41,FX,1.485 !APPLY END FORCE
NSUBST,10
/OUT,SCRATCH, !SUPPRESS SOLUTION DATA
SOLVE
/OUT
FINISH
/POST26
/AXLAB,X,TIP DISPLACEMENT
/AXLAB,Y,END FORCE
NSOL,2,41,U,Z,DISP
RFORCE,3,1,F,X,FORCE
PROD,4,3, , ,FORCE , , ,-1.0,1,1,
XVAR,2
/COM, THE LOAD DEFLECTION CURVE SHOWN IN VM216.GRPH
/COM, SHOW A CRITICAL LOAD OF APPROX. 1.09
PRVAR,2,4
PLVAR,4
FINISH
/POST1
SET,2,7,1
NSEL,S,LOC,X,0
FSUM
*GET,CP1,FSUM,,ITEM,FX
*DIM,LABEL1,CHAR,1
*DIM,VALUE1,,1,3
LABEL1(1) = 'FX_CRLD'
*VFILL,VALUE1(1,1),DATA,1.09
*VFILL,VALUE1(1,2),DATA,ABS(CP1)
*VFILL,VALUE1(1,3),DATA,ABS(CP1 / 1.09)
/OUT,vm216,vrt
/COM,
/COM,------------------- VM216 RESULTS COMPARISON ---------------------
/COM,
/COM,BEAM188 | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),VALUE1(1,3)
(1X,A15,' ',F10.3,' ',F10.3,' ',1F5.3)
/OUT
FINISH

/CLEAR,NOSTART !PERFORM SAME ANALYSIS WITH BEAM189
/SHOW,JPEG
/GFILE,500
JPEG,QUAL,100
/TRIAD,OFF
/PLOPTS,LOGO,0
/PLOPTS,INFO,2
/PLOPTS,WP,0
/RGB,INDEX,100,100,100,0
/RGB,INDEX,80,80,80,13
/RGB,INDEX,60,60,60,14
/RGB,INDEX,0,0,0,15
/PREP7
N,1 , ,240
N,21,240,240
N,41,240,0
FILL,1,21
FILL,21,41
N,101,120,360
N,201,360,120
SECNUM,1
ET,1,BEAM189 ! 3-D QUADRATIC BEAM
*DO,I,1,10,1
I0=(I-1)*2+1
E,I0,I0+2,I0+1,101
*ENDDO
*DO,I,11,20,1
I0=(I-1)*2+1
E,I0,I0+2,I0+1,201
*ENDDO
SECTYPE,1,BEAM,ASEC
SECDATA,18.0,1350.0,0.0,0.54,0.0,2.16
MP,EX,1,71240
MP,NUXY,1,0.31
D,1,ALL
FINISH
/SOLU
NLGEOM,ON
NSUBST,2
F,41,FZ,1.0E-3
SOLVE
OUTRES,ALL,ALL
ARCLEN,ON
ARCTRM,U,60,41,UZ
F,41,FX,1.485
NSUBST,10
/VIEW,1,1,2,3
/ANG,1
/PBC,F,,1
/PBC,U,,1
/PBC,ROT,,1
/ESHAPE,7 !SET ESHAPE FACTOR TO 7
EPLOT
/ESHAPE,0 !TURN OFF ESHAPE
/PBC,ALL,OFF
/OUT,SCRATCH,,,APPEND
SOLVE
/OUT
FINISH
/POST26
/AXLAB,X,TIP DISPLACEMENT
/AXLAB,Y,END FORCE

NSOL,2,41,U,Z,DISP
RFORCE,3,1,F,X,FORCE
PROD,4,3, , , , , ,-1.0,1,1,
XVAR,2
PRVAR,2,4
PLVAR,4
FINISH
/POST1
SET,2,7,1
NSEL,S,LOC,X,0
FSUM
*GET,CP2,FSUM,,ITEM,FX
*DIM,LABEL2,CHAR,1
*DIM,VALUE2,,1,3
LABEL2(1) = 'FX_CRLD'
*VFILL,VALUE2(1,1),DATA,1.09
*VFILL,VALUE2(1,2),DATA,ABS(CP2)
*VFILL,VALUE2(1,3),DATA,ABS(CP2 / 1.09)

SET,LAST
/AUTO,1
ALLSEL
/VIEW,1,,,1
/ANG,1
PLDISP,1
/VIEW,1,,-1
PLDISP,1

/COM
/OUT,vm216,vrt,,APPEND
/COM,
/COM,BEAM189
/COM,
*VWRITE,LABEL2(1),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A15,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,------------------------------------------------------------------
/OUT
FINISH
*LIST,vm216,vrt


VM217 (Portal Frame Under Symmetric Loading) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM217
/TITLE,VM217, PORTAL FRAME UNDER SYMMETRIC LOADING
! N. J. HOFF, THE ANALYSIS OF STRUCTURES, PG 115
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
W=-500
A=400
EX=30E6
IO=20300
MROT=((W*A*A*A)/(EX*IO))*(1/27) !CALCULATE MAX ROT TARGET VALUE
BNDM=(W*A*A)*(19/54) !CALCULATE MAX BEND MOMENT
/GRA,POWER
/GST,ON
/TRIAD,OFF
/ESHAPE,1
/PREP7
ET,1,BEAM188
ET,2,BEAM189
SECTYPE,1,BEAM,I
SECDATA,16.655,16.655,36.74,1.68,1.68,.945
SECPLOT,1
C = 1.49535
SECTYPE,2,BEAM,I
SECDATA,C*16.655,C*16.655,C*36.74,C*1.68,C*1.68,C*.945
SECPLOT,2
MP,EX,1,30E6
MP,NUXY,1,0.3
MP,EX,2,30E6
MP,NUXY,2,0.3
A = 400
COLUMDIV = 4
SPANDIV = 16
K,1
K,2,,A
K,3,2*A
K,4,2*A,A
L,2,1
L,3,4
L,4,2
LSEL,,,,1
LATT,,,,,3
LSEL,,,,2
LATT,,,,,1
LSEL,,,,3
LATT,,,,,1
ALLSEL
LESIZE,1,,,COLUMDIV
LESIZE,2,,,COLUMDIV
LESIZE,3,,,SPANDIV
TYPE,1
SECNUM,1
REAL,1
LMESH,1,2
TYPE,2
SECNUM,2
REAL,2
LMESH,3
ALLSEL
DK,1,ALL
DK,3,ALL
LSEL,,,,3
ESLL
SFBEAM,ALL,1,PRESS,-500,-500
ALLSEL
/VIEW,1,1,1,1
/ANG,1
EPLOT
FINISH

/SOLUTION
SOLVE
FINISH
/POST1
ETABLE,SMIS2,SMISC,2
ETABLE,SMIS15,SMISC,15
ETABLE,SMIS5,SMISC,5
ETABLE,SMIS18,SMISC,18
PRNSOL,DOF
PRETAB,SMIS2,SMIS15,SMIS5,SMIS18
/VIEW,1,,,1
PLLS,SMIS2,SMIS15
PLDISP,0
*GET,A,ROTZ,48 !GET ANSYS VALUE FOR MAX ROT
*GET,B,SMIS15,16 !GET ANSYS VALUE FOR MAX BEN MOMENT
/FORMAT,10,E,16

*DIM,LABEL,CHAR,2
*DIM,VALUE,,2,8
LABEL(1) = 'MAX.ROT','BEND.MOM.'
*VFILL,VALUE(1,1),DATA,ABS(MROT),ABS(BNDM)
*VFILL,VALUE(1,2),DATA,ABS(A),ABS(B)
*VFILL,VALUE(1,3),DATA,ABS(A / MROT),ABS(B / BNDM)

/COM
/OUT,vm217,vrt
/COM,------------------- VM217 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',E10.3,' ',E10.3,' ',1F5.3)
/COM,
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm217,vrt


VM218 (Hyperelastic Circular Plate) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM218
/TITLE,VM218, HYPERELASTICITY TEST: BALLOON/CIRCULAR PLATE PROBLEM
/GRAPHICS,POWER
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
ET,1,SHELL181
R,1,0.5,
N , 1 , 0., 0.
N , 2 , 0.17143, 0.
N , 3 , 0.47143, 0.
N , 4 , 0.90000, 0.
N , 5 , 1.4571, 0.
N , 6 , 2.1429, 0.
N , 7 , 2.9571, 0.
N , 8 , 3.9000, 0.
N , 9 , 4.9714, 0.
N , 10 , 6.1714, 0.
N , 11 , 7.5000, 0.
N , 101 , 0., 0.
N , 102 , 0.16996, 2.23759E-02
N , 103 , 0.46740, 6.15338E-02
N , 104 , 0.89230, 0.11747
N , 105 , 1.4447, 0.19020
N , 106 , 2.1245, 0.27970
N , 107 , 2.9318, 0.38598
N , 108 , 3.8666, 0.50905
N , 109 , 4.9289, 0.64890
N , 110 , 6.1186, 0.80553
N , 111 , 7.4358, 0.97895

E, 1, 2, 102, 102
E, 2, 3, 103, 102
E, 3, 4, 104, 103
E, 4, 5, 105, 104
E, 5, 6, 106, 105
E, 6, 7, 107, 106
E, 7, 8, 108, 107
E, 8, 9, 109, 108
E, 9, 10, 110, 109
E, 10, 11, 111, 110
MP,EX,1,1.E6
MP,NUXY,1,0.5
MP,DENS,1,0.1
TB,MOONEY,1
TBDATA,1,80.0,20.0

D, 1,UY,0.0,, 11,1 ,ROTX,ROTZ
D,102,UY,0.0,,111,1 ,ROTX,ROTZ
D, 11,UX,0.0,,111,100,UY ,UZ
D, 1,UX,0.0,, , ,UY ,ROTX,ROTY,ROTZ

LOCAL, 11, 0, 0.0,0.0,0.0, 7.5,0.0,0.0
NROTAT,102,111,1

AUTOTS,ON
NSUBST, 400, 1200,25
NLGEOM,ON
NROPT,FULL, ,OFF
OUTRES, ALL, ALL,
SF,ALL,PRES,50.0
NEQITR,20
/AUTO,1
/VIEW,1,,,1
/ANG,1
/ESHAPE,1
EPLOT
FINISH

/SOLUTION
/OUT,SCRATCH
SOLVE
/OUT
FINISH

/POST1
/NOPR !SUPPRESS GRAPHING DATA
/VIEW,1,,-1
/ANG,1
/USER
/FOCUS,1,4,,8,0 !SET UP CENTER OF GRAPHICS SCREEN FOR DISPLACEMENT PLOT
/DIST,,12 !SET DISTANCE TO ZOOM OUT
/TRIAD,OFF
SET,FIRST !SET DISPLACEMENT DATA FOR FIRST SUBSTEP
PLDISP,0 !PLOT DISPLACEMENT DATA
/NOERASE !SET DISPLAY TO OVERLAY PLOTS
SET,,10
PLDISP,0
SET,,20
PLDISP,0
SET,,25
PLDISP,0
SET,LAST
PLDISP,1 !PLOT FINAL DISPLACEMENT WITH ORIGINAL POSITION
/ERASE
/TRIAD,ON
/GOPR
/ESHAPE,0
FINISH

/POST26
/XRANGE,0,3.0
/YRANGE,0,1
/AXLAB,X,UZ OF CENTER/R-INITIAL
/AXLAB,Y,THICKNESS/ORIGINAL THICKNESS
NSOL,2,1,U,Z,UZ_1
ESOL,3,1, ,SMIS,17,TH_1
ADD,4,2, , ,UZRATIO, , ,0.13333333,0,0,
ADD,5,3, , ,SH.181, , ,2,0,0,
/COLOR,CURVE,MRED
XVAR,4
PLVAR,5
/ERASE
/NOPR
*DIM,X,TABLE,20,1
*DIM,Y,TABLE,20,1
X( 1,1)= 1.25
Y( 1,1)= 1.25
X( 2,1)= 1.8
Y( 2,1)= 2.5
X( 3,1)= 2.25
Y( 3,1)= 4.0
X( 4,1)= 2.6
Y( 4,1)= 5.9
X( 5,1)= 2.9
Y( 5,1)= 7.8
X( 6,1)= 3.2
Y( 6,1)= 9.8
X( 7,1)= 3.5
Y( 7,1)= 11.6
X( 8,1)= 3.62
Y( 8,1)= 12.6
X( 9,1)= 4.1
Y( 9,1)= 15.3
X( 10,1)= 4.9
Y( 10,1)= 18.8
X( 11,1)= 5.7
Y( 11,1)= 22.1
X( 12,1)= 6.2
Y( 12,1)= 24.0
X( 13,1)= 7.2
Y( 13,1)= 27.9
X( 14,1)= 8.3
Y( 14,1)= 31.2
X( 15,1)= 8.9
Y( 15,1)= 32.9
X( 16,1)= 9.9
Y( 16,1)= 35.8
X( 17,1)= 10.9
Y( 17,1)= 38.0
X( 18,1)= 13.1
Y( 18,1)= 42.9
X( 19,1)= 14.4
Y( 19,1)= 45
X( 20,1)= 15.2
Y( 20,1)= 46
/GOPR
/XRANGE,0,20
/YRANGE,0,60
/AXLAB,X,UZ OF CENTER (IN)
/AXLAB,Y,PRESSURE (LB/SQ IN)
/COLOR,CURVE,YGRE
*VPLOT,X(1,1),Y(1,1)
/NOERASE
NSOL,2,1,U,Z,UZ_1
PROD,7,1, , ,SH.181 , , ,50,0,0, !MULTIPLY SOLUTION BY 50
/COLOR,CURVE,MRED
XVAR,2 !SPECIFY X VARIABLE TO BE DISPLAYED
PLVAR,7 !DISPLAY SOLUTION IN GRPH FILE
/ERASE
PRVAR,7,2 !LIST VARIABLE 7 VERSUS VARIABLE 2

FINISH

/POST1
/NOPR
SET,NEAR,,,,0.08 !SELECT UZ VALUE FOR NODE 1 AT T=0.08
*GET,VR1,NODE,1,U,Z
SET,NEAR,,,,0.48 !UZ VALUE FOR NODE 1 AT T=0.48
*GET,VR2,NODE,1,U,Z
SET,NEAR,,,,0.76 !UZ VALUE FOR NODE 1 AT T=0.76
*GET,VR3,NODE,1,U,Z
PRES1 = (0.08*50) !SOLVE FOR PRES IN RESULTS TABLE
PRES2 = (0.48*50)
PRES3 = (0.76*50)

*DIM,LABEL,,3 !SETUP RESULTS TABLE DATA
*DIM,VALUE,,3,3
LABEL(1) = PRES1,PRES2,PRES3
*VFILL,VALUE(1,1),DATA,2.25,6.2,10.9
*VFILL,VALUE(1,2),DATA,VR1,VR2,VR3
*VFILL,VALUE(1,3),DATA,(2.25/VR1),(6.2/VR2),(10.9/VR3)
/GOPR

/COM
/OUT,vm218,vrt
/COM,------------------- VM218 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,PRES =
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,F8.1,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,
/COM,***VERIFIED RESULTS TABLE BASED ON GRAPHICAL DATA.
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm218,vrt


VM219 (Non-Newtonian Pressure Driven Sector Flow) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM219
/TITLE,VM219, PRESSURE DRIVEN NON-NEWTONIAN FLOW
! FLUID DYNAMICS BY HUGHES & BRIGHTON- SCHAUM SERIES
R = 1.0 ! PIPE RADIUS
DELTAP= 0.2 ! PRESSURE DROP ACROSS PIPE
L = 0.2 ! LENGTH OF PIPE
NDX = 040 ! NUMBER OF X DIVISIONS
NDY = 002 ! NUMBER OF Y DIVISIONS
RHO = 1.0 ! FLUID DENSITY
MU0 = 1.29684 ! POWER LAW COEFFICIENTS
K = 1.0
D0 = 1E-6
N = 0.8
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
DPDX = DELTAP/L ! PRESSURE GRADIENT
POWER= (N+1)/N
FACTOR = (1/POWER)*( (DPDX/(2*MU0*K))**(1/N) )

/PREP7 $SMRT,OFF
ET,1,FLUID141,,,1 ! 2D YR SYSTEM
ESHAPE,2 ! QUAD ELEMENTS
RECTNG,,R,,L
LESIZE,3,,,NDX,-10
LESIZE,1,,,NDX,-10
LESIZE,4,,,NDY
LESIZE,2,,,NDY
AMESH,ALL

!APPLY BOUNDARY CONDITIONS
NSEL,S,LOC,Y ! DEFINE UPSTREAM PRESSURE
D,ALL,PRES,DELTAP
NSEL,S,LOC,X, ! DEFINE CENTER CONSTRAINTS
D,ALL,VX
NSEL,S,LOC,X,R-1E-10,R+1E-10 ! DEFINE WALL CONSTRAINTS
D,ALL,VX
D,ALL,VY
NSEL,S,LOC,Y,L ! DEFINE DOWNSTREAM PRESSURE
D,ALL,PRES
ALLS
FINISH

/SOLUTION
FLDA,ITER,EXEC,0900 ! NUMBER OF GLOBAL ITERATIONS
FLDA,RELX,VX,0.7 ! VX RELAXATION
FLDA,RELX,VY,0.5 ! VY RELAXATION
FLDA,RELX,PRES,0.6 ! PRES RELAXATION
FLDA,NOMI,DENS,RHO ! NOMINAL DENSITY
FLDA,NOMI,VISC,MU0 ! NOMINAL VISCOSITY
FLDA,COF1,VISC,D0
FLDA,COF2,VISC,K
FLDA,COF3,VISC,N
FLDA,RELX,VISC,0.5
FLDA,PROT,VISC,POWL
FLDA,TERM,PRES,1E-30
/OUT,SCRATCH

SOLVE
/OUT
FINISH

/POST1
SET,LAST

*DIM,RES,,NDX+1,4 !STORE NODE#,X-COORD,VY(FLOTRAN),VY(ANALYTICAL)
NSEL,S,LOC,Y,L/2
*GET,MNNOD,NODE,,NUM,MIN
*GET,MXNOD,NODE,,NUM,MAX
INDEX = 0
*DO,INODE,MNNOD,MXNOD
*GET,SELECTED,NODE,INODE,NSEL
*IF,SELECTED,EQ,1,THEN
INDEX = INDEX+1
RES(INDEX,1) = INODE
RES(INDEX,2) = NX(INODE)
*GET,VYF,NODE,INODE,VY
RES(INDEX,3) = VYF !VX FLOTRAN
FACTOR2 = RES(INDEX,2)
RES(INDEX,4) = FACTOR*( R**POWER - FACTOR2**POWER ) !ANALYTICAL
*ENDIF
*ENDDO
*DIM,OLDORDER,,NDX+1
*MOPER,OLDORDER(1),RES(1,1),SORT,RES(1,2)

/COM
/COM PRINT THE RESULTS
*VWRITE
(4X,'NODE',12X,'X',9X,'VY FLOTRAN',7X,'VY ANALYTICAL')
*VWRITE,RES(1,1),RES(1,2),RES(1,3),RES(1,4)
(3X,F5.0,3(1PE17.5))
/COM
/AUTO,ALL
/VIEW,1,,,1
/ANG,1
ALLSEL
/PBC,ALL,1
EPLOT
/PBC,ALL,0
PLNSOL,VY

*GET,VR1,NODE,84,V,Y
*GET,VR2,NODE,85,V,Y
*GET,VR3,NODE,86,V,Y
*GET,VR4,NODE,87,V,Y
*GET,VR5,NODE,104,V,Y
AR1=RES(1,4)
AR2=RES(2,4)
AR3=RES(3,4)
AR4=RES(4,4)
AR5=RES(21,4)
X1=RES(1,2)
X2=RES(2,2)
X3=RES(3,2)
X4=RES(4,2)
X5=RES(21,2)

*DIM,LABEL,,5
*DIM,VALUE,,5,3
LABEL(1) = X1,X2,X3,X4,X5
*VFILL,VALUE(1,1),DATA,AR1,AR2,AR3,AR4,AR5
*VFILL,VALUE(1,2),DATA,VR1,VR2,VR3,VR4,VR5
*VFILL,VALUE(1,3),DATA,(VR1/AR1),(VR2/AR2),(VR3/AR3),(VR4/AR4),(VR5/AR5)

/OUT,vm219,vrt
/COM,-------------------- VM219 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,VY AT X =
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,F8.3,' ',F8.5,' ',F8.5,' ',1F5.3)
/COM,-------------------------------------------------------------
/OUT
FINISH
*LIST,vm219,vrt


VM220 (Eddy Current Loss in Thick Steel Plate) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM220
/TITLE,VM220, EDDY CURRENT LOSS IN THICK STEEL PLATE
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/NOPR
!
/PREP7
DD=2.5E-3 ! 1/2 HEIGTH OF PLATE
HM=2644.1 ! IMPOSED H FIELD
SIGMA=5.0E6 ! MATERIAL CONDUCTIVITY
FF=50 ! FREQUENCY (Hz.)
DX=DD/6 ! MODELED PLATE WIDTH
DY=DD/6 ! COIL HEIGTH
!
ET,1,PLANE53
MP,MURX,1,1. ! COIL RELATIVE PERMEABILITY
TB,BH,2,,25 ! PLATE B-H CURVE
TBPT,,100,.46512
TBPT,,200,.72993
TBPT,,300,.90090
TBPT,,400,1.0204
TBPT,,500,1.1086
TBPT,,600,1.1765
TBPT,,700,1.2302
TBPT,,800,1.2739
TBPT,,900,1.3100
TBPT,,1000,1.3405
TBPT,,1400,1.4257
TBPT,,1800,1.4778
TBPT,,2200,1.5131
TBPT,,2600,1.5385
TBPT,,3000,1.5576
TBPT,,3400,1.5726
TBPT,,3800,1.5847
TBPT,,4200,1.5945
TBPT,,4600,1.6028
TBPT,,5000,1.6098
TBPT,,7000,1.6332
TBPT,,9000,1.6465
TBPT,,11000,1.6551
TBPT,,13000,1.6611
TBPT,,15000,1.6656
/NUM,1
TBPLOT !PLOT B-H CURVE
MP,RSVX,2,1/SIGMA

RECT,0,DX,0,DD ! PLATE
RECT,0,DX, DD,DD+DY ! COIL
AGLUE,ALL


ASEL,S,LOC,Y,DD,DD+DY
AATT,1,0,1
ASEL,S,LOC,Y,0,DD
AATT,2,0,1
ASEL,ALL
AMESH,ALL
!
NSEL,S,LOC,Y,
D,ALL,AZ,0. ! FLUX-PARALLEL
NSEL,S,LOC,Y,DD+DY
CP,1,AZ,ALL ! COUPLE FOR FLUX-PARALLEL
NSEL,ALL
/PBC,ALL,1
/VIEW,1,,,1
/ANG,1
/PNUM,AREA,1
/NUM,1
APLOT
/PNUM,NODE,1
/PNUM,MAT,1
EPLOT !PLOT ELEMENTS
FINISH

/SOLU
ANTYPE,HARMIC
ESEL,S,MAT,,1
BFE,ALL,JS,, 0.,0.,HM/DY,0. !APPLY COIL CURRENT DENSITY
ESEL,ALL
HMAGSOLV,FF,,1E-2 ! SOLVE NONLINEAR PROBLEM
FINISH

/POST1
!
! COMPUTE LOSSES
!
SET,LAST,1,,0
ESEL,S,MAT,,2
POWERH ! EXTRACT LOSSES IN PLATE (W/m)
PAVG=PAVG*2/DX ! CONVERT TO (W/m**2)
*VWRITE,PAVG
(/'COMPUTED EDDY CURRENT LOSS:', F9.4, 'Watts/m**2')

/VIEW,1,1,1,1
/ANG,1
PLVECT,H,,,,VECT,ELEM,ON,0
*DIM,LABEL,CHAR,1
*DIM,VALUE,,1,3
LABEL(1) = 'CUR LOSS'
*VFILL,VALUE(1,1),DATA,1342.323
*VFILL,VALUE(1,2),DATA,PAVG
*VFILL,VALUE(1,3),DATA,PAVG/1342.323
/OUT,vm220,vrt
/COM
/COM,------------------- VM220 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,
/COM,***TARGET SOLUTION BASED ON GRAPHICAL RESULTS***
/COM,------------------------------------------------------------------
/OUT

FINISH
*LIST,vm220,vrt


VM221 (Inductance Calculation of a Transformer) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,vm221
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM221, ELEMENT 117 WITH LMATRIX (INDUCTANCE,FLUX) AND SENERGY MACROS
/NOPR
/COM
/COM
/COM ^ y axis : symmetry plane
/COM : : core center
/COM :<.x1.>.<.x2.>.<.x..>:
/COM : : : :
/COM --------------------------:
/COM ! : nonlin core:
/COM ! yoke ideal iron : H = Hs (B/Bs)^2; BS=2T;HS=100A/m
/COM ! :
/COM ! ------------- :....
/COM !leg ! : !nonlin: ^
/COM !ideal!coil1 :coil2 ! iron : y
/COM !iron ! : ! core : :
/COM ! ------------- :..v..> x axis
/COM ! :
/COM ! yoke ideal iron :
/COM ! :
/COM --------------------------:
/COM
/COM target
/COM
/COM nominal
/COM magnetic field in the core : Hn = (N1 I1 + N2 I2) / y = 25
/COM flux density in the core : Bn = Bs sqrt(H/Hs) = 1
/COM tangent reluctivity : dH/dB = 2 Hs/Bs B/Bs = 50
/COM absolute energy in the core : nlene = Hs/Bs^2 Bn^3/3 2xyz = 0.0166
/COM absolute coenergy in the core : nlcene = Bn Hn 2xyz - nlene = 0.0333
/COM
/COM inductances
/COM self coil 1 : L11 ~ 2 N1^2 x z / (y nui) = 0.4
/COM self coil 2 : L22 ~ 2 N2^2 x z / (y nui) = 1.6
/COM mutual between coil 1 and 2 : L12 ~ 2 N1 N2 x z / (y nui) = 0.8
/COM
/COM flux linkages
/COM coil 1 : psi1 = 2 N1 x z B0 = 0.2
/COM coil 2 : psi2 = 2 N2 x z B0 = 0.4


! GEOMETRY DATA
!
N=1 ! MESHING PARAMETER
X1=0.1 ! WIDTH (X SIZE) OF COIL 1
X2=0.1 ! WIDTH (X SIZE) OF COIL 2
X=0.1 ! WIDTH (X SIZE) OF CORE
Y=0.1 ! HIGHT OF CORE, Y SIZE OF WINDOW
Z=0.1 ! THICKNESS OF IRON IN Z DIRECTION
NUI=50 ! ABSOLUTE RELUCTIVITY OF IRON
N1=10 ! NUMBER OF TURNS IN COIL1
N2=20 ! NUMBER OF TURNS IN COIL2
!
! EXCITATION DATA USED BY LMATRIX.MAC
!
SYMFAC=2 ! SYMMETRIC FACTOR FOR INDUCTANCE COMPUTATION
NC=2 ! NUMBER OF COILS
*DIM,CUR,ARRAY,NC ! NOMINAL CURRENTS OF COILS
*DIM,COILS,CHAR,NC ! NAMES OF COIL COMPONENTS
!
CUR(1)=0.2 ! NOMINAL CURRENT OF 1ST COIL
COILS(1)='COIL1' ! NAME OF COIL 1 COMPONENT
!
CUR(2)=0.025 ! TINY NOMINAL CURRENT OF 2ND COIL
COILS(2)='COIL2' ! NAME OF COIL 2 COMPONENT
!
! DERIVED AUXILIARY PARAMETERS
!
MU0=3.1415926*4.0E-7
MURI=1/NUI/MU0 ! RELATIVE PERMEABILITY OF IRON
X3=X1+X2 ! X COORDINATE OF THE RIGHT OF COIL2
X4=X3+X ! X COORDINATE OF MIDDLE OF CORE (SYMMETRY PLANE)
JS1=CUR(1)*N1/(X1*Y) ! NOMINAL CURRENT DENSITY OF COIL1
JS2=CUR(2)*N2/(X2*Y) ! NOMINAL CURRENT DENSITY OF COIL2
!
/PREP7
SMRT,OFF
ET,1,117
!
MP,MURX,1,1 ! AIR/COIL
BS=2 ! SATURATION FLUX DENSITY
HS=100 ! SATURATION MAGNETIC FIELD
TB,BH,2 ! CORE: H = Hs (B/Bs)^2; Bs=2T;Hs=100A/m
TBPT,, 1, 0.2
TBPT,, 4, 0.4
TBPT,, 9, 0.6
TBPT,, 16, 0.8
TBPT,, 25, 1.0
TBPT,, 36, 1.2
TBPT,, 49, 1.4
TBPT,, 64, 1.6
TBPT,, 81, 1.8
TBPT,,100, 2.0
TBPT,,121, 2.2
TBPT,,144, 2.4
TBPT,,169, 2.6
TBPT,,176, 2.8
TBPT,,225, 3.0
TBPT,,256, 3.2
TBPT,,289, 3.4
TBPT,,324, 3.6
TBPT,,361, 3.8
TBPT,,400, 4.0
TBPLOT,BH,2 !PLOT BH CURVE
!
BLOCK, 0,X1,0,Y,0,Z ! COIL1
BLOCK,X1,X3,0,Y,0,Z ! COIL2
BLOCK,X3,X4,0,Y,0,Z ! CORE
!
VGLUE,ALL
!
VSEL,S,LOC,X,X1/2
VATT,1,1,1 ! COIL 1 VOLUME ATTRIBUTE
VSEL,S,LOC,X,X1+X2/2
VATT,1,2,1 ! COIL 2 VOLUME ATTRIBUTE
VSEL,S,LOC,X,X3+X/2
VATT,2,3,1 ! IRON VOLUME ATTRIBUTE
VSEL,ALL
!
ESIZE,,N
VMESH,ALL
EPLOT ! PLOT ELEMENTS
/NOPR
!
NSEL,S,LOC,X,X4 ! FLUX PARALLEL DIRICHLET AT SYMMETRY PLAIN, X=X4,Z=0,Z=Z
NSEL,A,LOC,Z,0
NSEL,A,LOC,Z,Z
D,ALL,AZ,0
! ! HOMOGENEOUS NEUMANN FLUX NORMAL AT YOKE, X=0, Y=0, Y=Y
NSEL,ALL
!
ESEL,S,REAL,,1 ! COIL 1 COMPONENT
CM,COILS(1),ELEM
BFE,ALL,JS,,,,JS1 ! CURRENT DENSITY IN COIL 1
!
ESEL,S,REAL,,2 ! COIL 2 COMPONENT
CM,COILS(2),ELEM
BFE,ALL,JS,,,,JS2 ! UNITE CURRENT DENSITY IN COIL 2
!
ALLSEL
!
FINI
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM
/COM OBTAIN OPERATING SOLUTION
/COM
!
/SOLU
CNVTOL,CSG,,1.0E-4
SOLVE
FINI
/POST1
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! COMPUTE STORED ENERGY
/COM
/COM SENERGY MACRO DOESN'T TAKE SYMMETRY OF THE PROBLEM IN CONSIDERATION
/COM SO RESULTS MUST BE MULTIPLIED BY 2.
/COM
SENERGY
STORENG=S_ENG
! COMPUTE CO-ENERGY
ALLSEL
SENERGY,1
STORCOE=C_ENG
*DIM,LABENG,CHAR,2
*DIM,VALENG,,2,2
*DIM,RESENG,,2,1
LABENG(1)='ENERGY','CO-ENERGY'
*VFILL,VALENG(1,1),DATA,0.0166,0.0333
*VFILL,RESENG(1,1),DATA,2*STORENG,2*STORCOE
*VFILL,VALENG(1,2),DATA,ABS(2*STORENG/0.0166),ABS(2*STORCOE/0.0333)
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! COMPUTE INDUCTANCE
ALLSEL
LMATRIX,SYMFAC,'COIL','CUR','IND' ! COMPUTE INDUCTANCE MATRIX
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!SET UP AND FILL VM RATIO TABLE
RAT_1 = ABS(IND(1,1)/0.40)
RAT_2 = ABS(IND(2,2)/1.60)
RAT_3 = ABS(IND(1,2)/0.80)
*DIM,LABEL,CHAR,3
*DIM,VALUE,,3,2
*DIM,RESULTS,,3,1
LABEL(1) = 'COIL1','COIL2','MUTUAL'
*VFILL,VALUE(1,1),DATA,0.40,1.60,0.80
!
!FILL RESULTS VECTOR WITH INDUCTANCE MATRIX VALUES
!
*VFILL,RESULTS(1,1),DATA,IND(1,1),IND(2,2),IND(1,2)
*VFILL,VALUE(1,2),DATA,RAT_1,RAT_2,RAT_3

*DIM,LABEL1,CHAR,2
*DIM,VALUE1,,2,2
*DIM,RESULT1,,2,1
LABEL1(1)= 'COIL1','COIL2'
*VFILL,VALUE1(1,1),DATA,0.2,0.4
!
! FILL RESULTS VECTOR WITH FLUX MATRIX VALUES
!
*VFILL,RESULT1(1,1),DATA,IND(1,3),IND(2,3)
*VFILL,VALUE1(1,2),DATA,ABS(IND(1,3)/0.2),ABS(IND(2,3)/0.4)

/OUT,vm221,vrt
/COM
/COM,------------------- VM221 RESULTS COMPARISON ---------------------
/COM
/COM, ENERGY (J) | TARGET | ANSYS | RATIO
/COM
*VWRITE,LABENG(1),VALENG(1,1),RESENG(1,1),VALENG(1,2)
(1X,A10,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM
/COM, FLUX (Weber) | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL1(1),VALUE1(1,1),RESULT1(1,1),VALUE1(1,2)
(1X,A10,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,
/COM, INDUCTANCE (H) | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),RESULTS(1,1),VALUE(1,2)
(1X,A10,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-------------------------------------------------------------------
/OUT
FINISH
*LIST,vm221,vrt


VM222 (Warping Torsion Bar) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,vm222
/TITLE,vm222, Warping Torsion Bar
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
!
/PREP7
!
!BUILD MODEL USING BEAM188 ELEMENTS
!
K,,
K,,1000
K,,500,100
L,1,2
ET,1,BEAM188
KEYOPT,1,1,1
SECT,1,BEAM,I
SECD,40,40,80,2,2,2
SECPLOT,1
!
MP,EX, 1, 217396.3331684 !SET MATERIAL PROPS
MP,NUXY,1, 0.335579823862
NEL=50
LATT,1,,,,3 !SET DEFAULT ATTRIBUTES
LESIZE,1,,,NEL
LMESH,ALL !MESH MODEL
DK,1,ALL !PIN MODEL AT KEYPOINT 1
SAVE,PREPDATA,DB !SAVE DB FOR FUTURE PARTS OF TEST
DK,2,ALL !PIN MODEL AT KEYPOINT 2
!
MLOAD1=(1000/NEL)/2
MLOAD2=MLOAD1*2
/ESHAPE,1 !TURN ESHAPE ON TO SHOW 3-D IMAGE OF MODEL
FINISH
/SOLU
OUTRES,ALL,ALL
F,ALL,MX,MLOAD2
FDEL,1,ALL
FDEL,2,ALL
F,1,MX,MLOAD1
F,2,MX,MLOAD1
SOLVE
FINISH
/POST1
PRNSOL,DOF
PRRSOL
NSORT,ROT,X
*GET,ROTX1,SORT, ,MAX !GET VERIFIED RESULT FOR PART 1
PRES,SMISC,27
ETABLE,ROTX,ROT,X
/ESHAPE,1
PLDISP !PLOT DISPLACED SHAPE
PLETAB,ROTX,NOAV
ETABLE,BIMOMENT,SMISC,27
PLETAB,BIMOMENT,NOAV
PARSAV !SAVE PARAMETERS FOR NEXT PART OF TEST
FINISH
/CLEAR,NOSTART
PARRES,CHANGE !RESTORE SAVED PARAMETERS
/PREP7
!
! REBUILD AND REMESH MODEL USING BEAM189 ELEMENTS
!
K,,
K,,1000
K,,500,100
L,1,2
ET,1,BEAM189
KEYOPT,1,1,1
SECT,1,BEAM,I
SECD,40,40,80,2,2,2

MP,EX, 1, 217396.3331684
MP,NUXY,1, 0.335579823862
NEL=50
LATT,1,,,,3
LESIZE,1,,,NEL
LMESH,ALL
!
! APPLY BOUNDRY CONDITIONS AND SET UP NEW PARAMETERS
!
DK,1,ALL
DK,2,ALL
MLOAD=(1000/NEL)/6.0
MLOAD1=MLOAD
MLOAD2=MLOAD*2
MLOAD4=MLOAD*4
FINISH
/SOLU
OUTRES,ALL,ALL
!
! SET UP LOOP TO APPLY LOADS
!
*DO,I,1,NEL,1
J=NELEM(I,1)
K=NELEM(I,2)
L=NELEM(I,3)
F,J,MX,MLOAD2
F,K,MX,MLOAD2
F,L,MX,MLOAD4
*ENDDO
F,1,MX,MLOAD1
F,2,MX,MLOAD1
FLIST
SOLVE
FINISH
/POST1
PRNSOL,DOF
NSORT,ROT,X
*GET,ROTX2,SORT, ,MAX !GET VERIFIED RESULTS FOR PART 2
PRRSOL
PRES,SMISC,4
PRES,SMISC,17
PRES,SMISC,27
T1=ROTX1
T2=ROTX2
!
!SET UP AND FILL VM RATIO TABLE
!
RAT_1 = ABS(T1/0.3292617E-3)
RAT_2 = ABS(T2/0.3292617E-3)
*DIM,LABEL,CHAR,2
*DIM,VALUE,,2,2
*DIM,RESULTS,,2,1
LABEL(1) = 'BEAM188','BEAM189'
*VFILL,VALUE(1,1),DATA,0.3292617E-3,0.3292617E-3
*VFILL,RESULTS(1,1),DATA,T1,T2
*VFILL,VALUE(1,2),DATA,RAT_1,RAT_2
/OUT,vm222,vrt
/COM
/COM,------------------- VM222 RESULTS COMPARISON ---------------------
/COM, MX TWIST
/COM, IN X-DIR | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),RESULTS(1,1),VALUE(1,2)
(1X,A10,' ',E10.4,' ',E10.4,' ',1F5.3)
/COM,-------------------------------------------------------------------
/out
*LIST,vm222,vrt
FINISH


VM223 (Frequency Response of a Pre-stressed Beam) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM223
! SET UP JPEG GRAPHIC SETTINGS TO CREATE IMAGES FOR MANUAL !
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
MP,PRXY,,0.3
/TITLE, VM223, FREQ. RESPONSE OF A PRESTRESSED BEAM
/COM REFERENCE: "FORMULAS FOR NATURAL FREQUENCY AND MODE SHAPE"
/COM PG. 144, EQN 8-20, R.D. BLEVINS, VAN NOSTRAND REINHOLD CO.
/COM 1979
/NOPR

L=150 ! BEAM LENGTH (MICROMETERS)
B=4 ! BEAM WIDTH
H=2 ! BEAM HEIGHT

I=B*H**3/12 ! BEAM MOMENT OF INERTIA

E=169E3 ! MODULUS ( MICRO NEWTONS/MICRON**2)
P=10 ! MICRON
DENS=2332E-18 ! DENSITY (KG/MICRON**3)
M=DENS*B*H ! MASS/LENGTH (KG/MICRON)
PER0=8.85E-6 ! FREE-SPACE PERMITTIVITY (PF/MICRON)
PLATEA=100 ! CAPACITOR PLATE AREA (MICRON**2)

GAPI=1 ! INITIAL GAP (MICRONS)
GAP=GAPI-P*L/E/B/H ! APPROXIMATE DEFLECTED GAP (IGNORING CAP STIFFNESS) (MICROMETER)
C3=PER0*PLATEA ! TRANDUCER REAL CONTANT
C3P=C3/(GAP**2) ! DERIVITIVE OF C3
C3PP=2*C3/(GAP**3) ! SECOND DERIVITIVE OF C3
VLT=SQRT(2*P/C3P) ! APPLIED VOLTAGE TO PLATE
KUU=C3PP*VLT**2/2 ! GAP STIFFNESS
KBEAM=E*PLATEA/L ! BEAM STIFFNESS (NOTE: GAP STIFFNESS ASSUMED << BEAM STIFFNESS)
UX2=P*L/B/H/E ! DESIRED DEFLECTION

*DIM,FREQ,,5 ! ARRAY PARAMETER FOR BEAM FREQUENCY
*DIM,PFREQ,,5 ! ARRAY PARMETER FOR BEAM PRE-STRESSED FREQUENCY

PI=4*ATAN(1)
*DO,J,1,5
LAMDA=J*PI
LAMDAP2=LAMDA**2*SQRT((1 + P*L**2/(E*I*LAMDA**2)))
LAMDAP=SQRT(LAMDAP2)
!
FREQ(J) = LAMDA**2/(2*PI*L**2)*SQRT(E*I/M)
PFREQ(J) = LAMDAP**2/(2*PI*L**2)*SQRT(E*I/M)
!
*ENDDO
!
ET,1,3
R,1,B*H,I,H ! BEAM PROPERTIES
MP,EX,1,E
MP,DENS,1,DENS
!
ET,2,126
C3=PER0*PLATEA
R,2,0,0,1,0
rmore,c3
!
! BUILD MODEL
!
N,1,-10
N,2,0
N,22,L
FILL
TYPE,2
REAL,2
E,1,2
TYPE,1
REAL,1
E,2,3
*REPEAT,20,1,1
!
!APPLY BOUNDRY CONDITIONS AND LOADS
!
NSEL,S,LOC,X,-10
NSEL,A,LOC,X,L
D,ALL,UX,0,,,,UY
NSEL,S,LOC,X,0
D,ALL,UY,0
D,ALL,VOLT,VLT
IC,ALL,VOLT,VLT
NSEL,S,LOC,X,-10
D,ALL,VOLT,0
NSEL,ALL
FINI
!
! ENTER SOLUTION TO SOLVE STATIC PART OF ANALYSIS
!
/SOLU
ANTYP,STATIC
PSTRES,ON
SOLVE
FINI
!
! NOW SOLVING FOR MODAL SOLUTION
!
/SOLU
ANTYP,MODAL
MODOPT,UNSYM,3 ! EXTRACT 3 MODES
MXPAND
PSTRES,ON
SOLVE
FINISH
!
! ENTER GENERAL POSTPROCESSOR TO DISPLAY RESULTS
!
/POST1
SET,1,1
*GET,FP1,ACTIVE,,SET,FREQ
SET,1,2
*GET,FP2,ACTIVE,,SET,FREQ
SET,1,3
*GET,FP3,ACTIVE,,SET,FREQ
! PLOT DISPLACED SHAPE AT THE THREE FREQUENCIES
SET,,,1,,FP1
/TITLE,VM223 RESULT PLOT FREQ1
PLDISP,1
SET,,,1,,FP2
/TITLE,VM223 RESULT PLOT FREQ2
PLDISP,1
SET,,,1,,FP3
/TITLE,VM223 RESULT PLOT FREQ3
PLDISP,1
FINISH
!
! SET UP ANALYTICAL SOLUTION
!
PFREQ1=PFREQ(1)
PFREQ2=PFREQ(2)
PFREQ3=PFREQ(3)
!
! SET UP VM RATIO TABLE
!
RAT_1 = ABS(FP1/PFREQ1)
RAT_2 = ABS(FP2/PFREQ2)
RAT_3 = ABS(FP3/PFREQ3)
*DIM,LABEL,CHAR,3
*DIM,VALUE,,3,2
*DIM,RESULTS,,3,1
LABEL(1) = 'FREQ1','FREQ2','FREQ3'
*VFILL,VALUE(1,1),DATA,PFREQ1,PFREQ2,PFREQ3
*VFILL,RESULTS(1,1),DATA,FP1,FP2,FP3
*VFILL,VALUE(1,2),DATA,RAT_1,RAT_2,RAT_3
/OUT,vm223,vrt
/COM
/COM,------------------- VM223 RESULTS COMPARISON ---------------------
/COM,
/COM, PRE-STRESS | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),RESULTS(1,1),VALUE(1,2)
(1X,A10,' ',E10.4,' ',E10.4,' ',1F5.3)
/COM,-------------------------------------------------------------------
/OUT
FINISH
*LIST,vm223,vrt


VM224 (Implicit Creep under Biaxial Load) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,vm224
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE,VM224, Implicit Creep Under Biaxial Load
/COM, NAFEMS Fundamental Tests of Creep Behavior, Becker and Hyde
/NOPR
/COM,
/COM, 2D CREEP TESTS WITH BIAXIAL CONSTANT LOAD,
/COM, REFERENCE: TEST 10(A) FROM NAFEMS R0027.
/COM,
/COM, EXPECTED RESULTS:
/COM, TIME | EPCRX | EPCRY
/COM, ----------------------------
/COM, 0.0 | 0.0 | -0.0
/COM, 0.1 | 0.0427 | -0.0427
/COM, 1.0 | 0.135 | -0.135
/COM, 5.0 | 0.3019 | -0.3019
/COM, 10.0 | 0.4269 | -0.4269
/COM, 50.0 | 0.9546 | -0.9546
/COM, 100.0 | 1.35 | -1.35
/COM, 500.0 | 3.019 | -3.019
/COM, 1000.0 | 4.2691 | -4.2691
/COM,
/PREP7
C*** PARAMETRIC INPUT FOR CREEP CONSTANTS (PRIMARY CREEP)!***
*SET,C1,1.5625E-14 !ASSIGN VALUE
*SET,C2,5.0 !ASSIGN VALUE
*SET,C3,-0.5 !ASSIGN VALUE
*SET,C4,0 !ASSIGN VALUE
C*** TIME PARAMETER
*SET,HOUR,1000 !ASSIGN VALUE
C*** ELASTIC CONSTANT
MP,EX,1,200E3 !DEFINE YOUNG'S MODULUS
MP,NUXY,1,0.3 !DEFINE POISON'S RATIO
TUNIF,HOT !ASSIGN TEMP TO NODES
TOFF,OFFS !SPECIFY TEMP RELATIVE TO ABSOLUTE VALUES
TB,CREEP,1,,,6 !ACTIVATE DATA TABLE
TBDATA,1,C1,C2,C3,C4 !DEFINE DATA FOR TABLE
SAVE !SAVE
/PREP7
N,1,0,0,0
N,2,100,0
N,3,100,100
N,4,0,100
N,5,50,0
N,6,100,50
N,7,50,100
N,8,0,50
N,9,50,50
ET,1,PLANE182
KEYOPT,1,1,1
KEYOPT,1,3,0
E,1,5,9,8
E,5,2,6,9
E,9,6,3,7
E,8,9,7,4
NALL
NSEL,S,LOC,X
D,ALL,UX
NSEL,S,LOC,Y
D,ALL,UY
NALL
/SOLU
NSEL,S,LOC,X,100
SF,ALL,PRES,-200
NALL
NSEL,S,LOC,Y,100
SF,ALL,PRES,200
NALL
RATE, OFF
DELT,1.0E-8,1.0E-9,1.0E-8
TIME, 1.0E-8
/OUT,SCRATCH
OUTRES,ESOL,ALL
SOLVE
/OUT
RATE, ON, ON
DELT,1E-5,1E-5,100
TIME,1000
/OUT,SCRATCH
SOLVE
/OUT
FINISH
/POST26
ESOL,2,1,,EPCR,X
ESOL,3,1,,EPCR,Y
PRVAR,2,3
PLVAR,2,3
*GET,RES1X,VARI,2,RTIME,1000
*GET,RES1Y,VARI,3,RTIME,1000
FINISH
PARSAV,ALL
RESUME
PARRES,CHANGE
/PREP7
N,1,0,0,0
N,2,100,0
N,3,100,100
N,4,0,100
N,5,50,0
N,6,100,50
N,7,50,100
N,8,0,50
ET,1,PLANE183
KEYOPT,1,3,0
E,1,2,3,4,5,6,7,8
NALL
NSEL,S,LOC,X
D,ALL,UX
NSEL,S,LOC,Y
D,ALL,UY
NALL
/SOLU
NSEL,S,LOC,X,100
SF,ALL,PRES,-200
NALL
NSEL,S,LOC,Y,100
SF,ALL,PRES,200
NALL
RATE, OFF
DELT,1.0E-8,1.0E-9,1.0E-8
TIME, 1.0E-8
/OUT,SCRATCH
SOLVE
/OUT
RATE, ON, ON
DELT,1E-5,1E-5,100
TIME,1000
/OUT,SCRATCH
OUTRES,ESOL,ALL
SOLVE
/OUT
FINISH
/POST26
ESOL,2,1,,EPCR,X
ESOL,3,1,,EPCR,Y
PRVAR,2,3
PLVAR,2,3
*GET,RES2X,VARI,2,RTIME,1000
*GET,RES2Y,VARI,3,RTIME,1000

*DIM,LABEL1,CHAR,2
*DIM,VALUE1,,2,3
LABEL1(1) = ' ECRXX ',' ECRYY '
*VFILL,VALUE1(1,1),DATA,4.2691,-4.2691
*VFILL,VALUE1(1,2),DATA,RES1X,RES1Y
*VFILL,VALUE1(1,3),DATA,ABS(RES1X/4.2691),ABS(RES1Y/(-4.2691))

*DIM,LABEL2,CHAR,2
*DIM,VALUE2,,2,3
LABEL2(1) = ' ECRXX ',' ECRYY '
*VFILL,VALUE2(1,1),DATA,4.2691,-4.2691
*VFILL,VALUE2(1,2),DATA,RES2X,RES2Y
*VFILL,VALUE2(1,3),DATA,ABS(RES2X/4.2691),ABS(RES2Y/(-4.2691))

/OUT,vm224,vrt
/COM
/COM,------------------- VM224 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM, PLANE182
/COM,
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),VALUE1(1,3)
(1X,A8,' ',F7.4,' ',F7.4,' ',1F5.3)
/COM,
/COM, PLANE183
/COM,
*VWRITE,LABEL2(1),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A8,' ',F7.4,' ',F7.4,' ',1F5.3)
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vm224,vrt





VM225 (Rectangular Cross-Section Bar with Preload) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM225
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM225, BEAM WITH PRETENSION LOAD
/COM,
/PREP7 !ENTER PREPROCESSOR
MP,PRXY,,0.3
BLOCK,,12,,1,,.5 !CREATE BLOCK
/VIEW,1,1,2,3 !CHANGE VIEW
ET,1,SOLID45 !SET ELEMENT TYPE
MP,EX,1,30E6, !DEFINE YOUNG'S MODULUS
MP,PRXY,1,0.3 !DEFINE POISSON'S RATIO
MP,DENS,1,.283, !DEFINE DENSITY
DA,2,SYMM !DEFINE SYMMETRY BC ON AREA
DA,3,SYMM !DEFINE SYMMETRY BC ON AREA
DA,5,UX !DEFINE DOF ON AREA
DA,6,UX !DEFINE DOF ON AREA
VMESH,ALL !MESH VOLUME
PSMESH, , ,1000,ALL,,0,X,6,,,,EEE,NNN !APPLY LOAD VIA PRE-TENSION ELEMENT
SLOAD,1,9,LOCK,F,125,1,2
EPLOT
FINI !EXIT PREP7
/SOLU !ENTER SOLVER
SOLVE !SOLVE
FINISH !EXIT SOLVER
/POST1 !ENTER POST PROCESSOR
NSORT,S,INT,1,0,, !SORT STRESS RESULTS
*GET,MAXNFEA2,SORT,,IMAX !GET NODE VALUE
*GET,SIGFEA2,NODE,MAXNFEA2,S,INT !GET MAXIMUM VON MISSES STRESS
NSORT,U,X,SUM,1,0,,, !SORT DEFLECTION RESULTS
*GET,MAXNFEA2,SORT,,IMAX !GET NODE VALUE
*GET,UXFEA2,NODE,MAXNFEA2,U,X,SUM !GET MAXIMUM UX VALUE
*STAT,UXFEA2 !LIST PARAMETER VALUE
*STAT,SIGFEA2 !LIST PARAMETER VALUE
/COM,**********************************
/COM,*** CLASSICAL ANALYSIS RESULTS ***
/COM,**********************************
SIGCA = 250
UXCA = 0.0001

*DIM,LABEL,CHAR,2
*DIM,VALUE,,2,3
LABEL(1) = 'SIGCA ','UXCA '
*VFILL,VALUE(1,1),DATA,SIGCA,UXCA
*VFILL,VALUE(1,2),DATA,SIGFEA2,UXFEA2
*VFILL,VALUE(1,3),DATA,ABS(SIGCA / SIGFEA2) ,ABS(UXCA / UXFEA2)
/OUT,vm225,vrt
/COM
/COM,------------------- VM225 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vm225,vrt














VM226 (Fourier Series Analysis of a Diode Rectified Circuit) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,vm226
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE,VM226, FOURIER SERIES ANALYSIS OF A DIODE RECTIFIED CIRCUIT
/COM, REF: SEDRA/SMITH "MICROELECTRONIC CIRCUITS 4TH ED." SEC. 3.7
/COM,
/COM FIRST PART: NO CAPACITANCE
/COM
PI = 4*ATAN(1)
R1=2500 ! RESISTOR VALUE
OMEGA=2*PI*60
IFINAL=3 ! NUMBER OF MODES ( 3 -> A0,A1,B1)
IFIN=IFINAL+20 ! WE MUST COMPUTE MORE COEFF THAN WE NEED
U=135

! FOR THE SECOND PART
*DIM,CAPA,ARRAY,3
CAPA(1)=1E-6,10E-6,1E-3 ! CAPACITOR VALUES
EPS=1E-09 ! ERROR CRITERIA FOR TO1

!FOR RESULTS
*DIM,RESUL,ARRAY,IFINAL,(IFINAL+1)*3
*DIM,COEFFOU,CHAR,IFINAL
*DIM,TAUARR,ARRAY,1,IFINAL+1
COEFFOU(1)='A0/2= ','A1= ','B1= '
TAUARR(1,1)=CAPA(1)*R1
TAUARR(1,2)=CAPA(2)*R1
TAUARR(1,3)=CAPA(3)*R1

/PREP7
R,1,,U,OMEGA/2/PI, !SET UP SINUSOIDAL VOLTAGE SOURCE
N,1,-0.85,0.4,0
N,2,-0.85,0.25,0
RMOD,1,15,0,1
ET,1,CIRCU124,4,1
TYPE,1
REAL,1
MAT,1
!
N,3,-0.85,0.325,0
E,1,2,3 !CREATE IND. SINUSOIDAL VOLT SOURCE
R,2,R1, !SET UP 2500 OHM RESISTOR
N,4,-0.75,0.4,0
N,5,-0.75,0.25,0
RMOD,2,15,0,2
ET,2,CIRCU124,0,0
TYPE,2
REAL,2
MAT,1
E,4,5 !CREATE 2500 OHM RESISTOR
!
! THE FOLLOWING COMMANDS ARE USED TO SET UP THE IDEAL DIODE
!
ET,3,125,
R,3
TYPE,3
REAL,3
E,1,4
!
! APPLY GROUND TO CIRCUIT
!
D,2,VOLT,0
D,5,VOLT,0
SAVE
ALLS
EPLOT
FINISH
!
! SOLVE NON-LINEAR CIRCUIT WITH T = 0 TO 0.025
! USING A TIME STEP OF 0.001 FOR EACH ITERATION
!
/SOLU
ANTYPE,TRANS
OUTRES,ALL,ALL,
TIME,0.025
AUTOTS,-1
DELTIM,0.0001, , ,1
CNVTOL,VOLT,,0.0001,2,1.0E-6 !CONVERGANCE CRITERIA
/OUT,SCRATCH
SOLVE
/OUT
FINISH


/POST26
NSOL,2,4,VOLT,,

/COLOR,CURVE,BLUE,1
/TITLE,VM226, LOAD VOLTAGE WAVEFORM WITH NO CAPACITANCE
/AXLAB,Y,OUTPUT POTENTIAL (VOLT)
PLVAR,2,
/TITLE,VM226, FOURIER SERIES ANALYSIS OF A DIODE RECTIFIED CIRCUIT
!
! SET UP TABLE ARRAYS TO DISPLAY OUTPUT RESULTS
!
*DIM,VOLTG,TABLE,251
*DIM,TARGET,ARRAY,251
*DO,INC,1,251,1
T = INC*0.0001
!TIME(INC) = T
*GET,V,VARI,2,RTIME,T
VOLTG(INC,1) = V
VOLTG(INC,0) = T
ANAL = U*SIN(OMEGA*T)
*IF,ANAL,LT,0,THEN !SET TARGET TO ZERO IF ANALYTICAL SOLUTION
TARGET(INC) = 0 ! IS NEGATIVE
*ELSE
TARGET(INC) = ANAL
*ENDIF
*ENDDO
FINISH
*DIM,COEFF,,IFIN
*DIM,MODE,TABLE,IFIN
*DIM,ISYM,TABLE,IFIN
*DIM,THETA,TABLE,121
*DIM,CURVEI,TABLE,121 ! CURVE INPUT TO PROGRAM
*DIM,CURVEO,TABLE,121

*VFILL,THETA(1),RAMP,0,3 ! THETA VALUES INCREMENT 3 DEGREES
*DO,INC,1,121,1
T=(INC-1)*3/360*2*PI/OMEGA
CURVEI(INC)=VOLTG(T,1)
*ENDDO
! CALCULATE FOURIER COEFFICIENT
MODE(1)=0
ISYM(1)=1
ISTART=2
/COM
/COM *** *DO *********************************************************
/COM
*DO,I,ISTART,IFIN,2
MODE(I)=I/2 ! FILL EVEN INDICIES OF {MODE}
ISYM(I)=1
*ENDDO
/COM
/COM *** *ENDDO WAS LAST COMMAND USED *************************************
/COM
! ! FILL ODD INDICIES OF {MODE}
ISTART=3
*DO,I,ISTART,IFIN,2
MODE(I)=(I/2)-.5
ISYM(I)=-1
*ENDDO
*MFOURI,FIT, COEFF(1),MODE(1),ISYM(1),THETA(1),CURVEI(1)
!
! CURVE WHICH WILL BE DEVELOPED FROM GENERATED COEFFICIENTS
!
*MFOURI,EVAL‎,COEFF(1),MODE(1),ISYM(1),THETA(1),CURVEO(1)


! PLOT CURVE
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TRIAD,OFF
/PLOPTS,LOGO,0
/PLOPTS,INFO,2
/PLOPTS,WP,0
/COLOR,CURVE,CBLU
/XRANGE,0,370
/YRANGE,0,140
/TSPEC,15
/TLAB,1,0.75,CAPACITANCE = 0
/TSPEC,4
/TLAB,1,0.7,BLUE->ANSYS
/TSPEC,1
/TLAB,1,0.65,RED->FOURIER
*VPLOT,THETA(1),CURVEI(1) ! PLOT INPUT CURVE VERSUS THETA
/USER
/NOERASE
/COM OVERLAY THE OUTPUT CURVE ON THE INPUT CURVE
/COLOR,CURVE,RED
/COLOR,AXLAB,BLAC
/AXLAB,X,ANGLE IN DEGREE
/AXLAB,Y,VOLT
*VPLOT,THETA(1),CURVEO(1) ! PLOT OUTPUT CURVE VERSUS THETA
/ERASE
! ANALYTICAL FOURIER COEFFICIENT
RESUL(1,2)=2*U/PI/2 ! FIRST FOURIER COEFFICIENT = A0/2
ISTART=4
*DO,I,ISTART,IFINAL,4
RESUL(I,2)=-2*U/(PI*((I/2)**2-1))
*ENDDO
*DO,I,2,IFINAL,4
RESUL(I,2)=0
*ENDDO
RESUL(3,2)=U/2
ISTART=5
*DO,I,ISTART,IFINAL,2
RESUL(I,2)=0
*ENDDO
*DO,I,1,IFINAL
RESUL(I,1)=COEFF(I)
RESUL(I,3)=RESUL(I,2)/RESUL(I,1)
*ENDDO
*DO,CAP,1,3 ! START DO LOOP ON CAPACITANCE
PARSAV,ALL
/CLEAR,NOSTART
/COM SECOND PART: CAPACITANCE VALUE
/COM
/PREP7
RESUME
PARRES,CHANGE
C1=CAPA(CAP)
TAU=TAUARR(1,CAP)
N,6,-0.65,0.4,0

ET,4,CIRCU124,2
R,4,C1
TYPE,4
REAL,4
E,4,6
!
! APPLY GROUND TO CIRCUIT
!
D,6,VOLT,0
ALLS
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
EPLOT
FINISH
!
! SOLVE NON-LINEAR CIRCUIT WITH T = 0 TO 0.025
! USING A TIME STEP OF 0.0001 FOR EACH ITERATION
!
/SOLU
ANTYPE,TRANS
OUTRES,ALL,ALL,
TIME,0.025
AUTOTS,-1
DELTIM,0.0001, , ,1
CNVTOL,VOLT,,0.0001,2,1.0E-6 !CONVERGANCE CRITERIA
/OUT,SCRATCH
SOLVE
/OUT
FINISH
/POST26
NSOL,2,4,VOLT,,
/COLOR,CURVE,BLUE,1
*IF,CAP,EQ,1,THEN
/TITLE,VM226, VLOAD WITH CAPACITANCE OF 1E-6F
*ENDIF
*IF,CAP,EQ,2,THEN
/TITLE,VM226, VLOAD WITH CAPACITANCE OF 10E-6F
*ENDIF
*IF,CAP,EQ,3,THEN
/TITLE,VM226, VLOAD WITH CAPACITANCE OF 1E-3F
*ENDIF
/AXLAB,Y,OUTPUT POTENTIAL (VOLT)
PLVAR,2,
/TITLE,VM226, FOURIER SERIES ANALYSIS OF A DIODE RECTIFIED CIRCUIT
!
! DETERMINE T0
!
T0=1/OMEGA*ATAN(1/(OMEGA*TAU))
!
! DETERMINE T0' : MACRO TO DO A BISECTION BETWEEN THE TWO CURVES
!
TINIT=2*PI/OMEGA/4
TFINAL=2*PI/OMEGA
V1=U*COS(OMEGA*TINIT)-U*COS(OMEGA*T0)*EXP(-1*(TINIT-T0)/TAU)
V2=U*COS(OMEGA*TFINAL)-U*COS(OMEGA*T0)*EXP(-1*(TFINAL-T0)/TAU)
V0=U*COS(OMEGA*T0)
*DO,I,1,10000
T3=(TINIT+TFINAL)/2
V3=U*COS(OMEGA*T3)-V0*EXP(-1*(T3-T0)/TAU)
ERROR=ABS(V1-V2)
*IF,ERROR,LT,EPS,THEN
*EXIT
*ENDIF
*IF,V3,LT,0,THEN
TINIT=T3
V1=V3
*ELSE
TFINAL=T3
V2=V3
*ENDIF
*ENDDO

T01=T3
!
! SET UP TABLE ARRAYS TO DISPLAY OUTPUT RESULTS
!
*DIM,VOLTG,TABLE,250
*DIM,TARGET,ARRAY,250
*DO,INC,1,250,1
T = INC*0.0001
!TIME(INC) = T
*GET,V,VARI,2,RTIME,T
VOLTG(INC,1) = V
VOLTG(INC,0) = T
ANAL = U*SIN(OMEGA*T)
*IF,T,LE,T0+PI/2/OMEGA,THEN !SET TARGET TO ZERO IF ANALYTICAL SOLUTION
TARGET(INC) = ANAL ! IS NEGATIVE
*ELSE
*IF,T,LE,T01+PI/2/OMEGA,THEN
TARGET(INC) = U*COS(OMEGA*T0)*EXP(-(T-T0-PI/2/OMEGA)/TAU)
*ELSE
*IF,T,LE,T0+PI/2/OMEGA+2*PI/OMEGA,THEN
TARGET(INC) = ANAL
*ELSE
TARGET(INC) = U*COS(OMEGA*T0)*EXP(-(T-T0-PI/2/OMEGA-2*PI/OMEGA)/TAU)
*ENDIF
*ENDIF
*ENDIF
*ENDDO
FINISH
*DIM,COEFF,,IFIN
*DIM,MODE,TABLE,IFIN
*DIM,ISYM,TABLE,IFIN
*DIM,THETA,TABLE,121
*DIM,CURVEI,TABLE,121 ! CURVE INPUT TO PROGRAM

*VFILL,THETA(1),RAMP,0,3 ! THETA VALUES INCREMENT 3 DEGREES
*DO,INC,1,121,1
T=(INC-1)*3/360*2*PI/OMEGA+PI/2/OMEGA
CURVEI(INC)=VOLTG(T,1)
*ENDDO
! CALCULATE FOURIER COEFFICIENT
MODE(1)=0
ISYM(1)=1
ISTART=2
/COM
*DO,I,ISTART,IFIN,2
MODE(I)=I/2 ! FILL EVEN INDICIES OF {MODE}
ISYM(I)=1
*ENDDO
/COM
! ! FILL ODD INDICIES OF {MODE}
ISTART=3
*DO,I,ISTART,IFIN,2
MODE(I)=(I/2)-.5
ISYM(I)=-1
*ENDDO
*MFOURI,FIT, COEFF(1),MODE(1),ISYM(1),THETA(1),CURVEI(1)

*IF,CAP,EQ,1,THEN
!
! CURVE WHICH WILL BE DEVELOPED FROM GENERATED COEFFICIENTS
!
*MFOURI,EVAL‎,COEFF(1),MODE(1),ISYM(1),THETA(1),CURVEO(1)


! PLOT CURVE
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TRIAD,OFF
/PLOPTS,LOGO,0
/PLOPTS,INFO,2
/PLOPTS,WP,0
/COLOR,CURVE,CBLU
/XRANGE,0,370
/YRANGE,0,140
/TSPEC,15
/TLAB,-0.25,0.75,CAPACITANCE = 1E-06 FARAD
/TSPEC,4
/TLAB,0,0.7,BLUE->ANSYS
/TSPEC,1
/TLAB,0,0.65,RED->FOURIER
*VPLOT,THETA(1),CURVEI(1) ! PLOT INPUT CURVE VERSUS THETA
/USER
/NOERASE
/COM OVERLAY THE OUTPUT CURVE ON THE INPUT CURVE
/COLOR,CURVE,RED
/COLOR,AXLAB,BLAC
/AXLAB,X,ANGLE IN DEGREE
/AXLAB,Y,VOLT
*VPLOT,THETA(1),CURVEO(1) ! PLOT OUTPUT CURVE VERSUS THETA
/ERASE
*ENDIF
!
! ANALYTICAL FOURIER COEFFICIENT
!
*DIM,ANALY,ARRAY,IFINAL

! FIRST FOURIER COEFFICIENT = A0/2

A01=U/PI*(SIN(OMEGA*T0)-SIN(OMEGA*T01))
A02=2*V0*TAU*OMEGA/2/PI*(1-EXP(-(T01-T0)/TAU))

A0=1/2*(A01+A02)

!SECOND FOURIER COEFFICIENT = A1

A11=U*OMEGA/PI*((T0-T01+2*PI/OMEGA)/2)
A12=U/PI/4*(SIN(2*OMEGA*T0)-SIN(2*OMEGA*T01))
A13=COS(OMEGA*T0)-OMEGA*TAU*SIN(OMEGA*T0)
A14=(COS(OMEGA*T01)-OMEGA*TAU*SIN(OMEGA*T01))*EXP(-(T01-T0)/TAU)

A1=A11+A12+2*V0*TAU/(1+(OMEGA*TAU)**2)*60*(A13-A14)

! THIRD FOURIER COEFFICIENT = B1

B11=U/PI/2*(SIN(OMEGA*T0)*SIN(OMEGA*T0)-SIN(OMEGA*T01)*SIN(OMEGA*T01))
B12=SIN(OMEGA*T0)+OMEGA*TAU*COS(OMEGA*T0)
B13=(SIN(OMEGA*T01)+OMEGA*TAU*COS(OMEGA*T01))*EXP(-(T01-T0)/TAU)

B1=B11+2*V0*TAU/(1+(OMEGA*TAU)**2)*60*(B12-B13)

RESUL(1,3*CAP+2)=A0,A1,B1

*DO,I,1,IFINAL
RESUL(I,3*CAP+1)=COEFF(I)
RESUL(I,3*CAP+3)=RESUL(I,3*CAP+2)/RESUL(I,3*CAP+1)
*ENDDO
*ENDDO
!
! DISPLAY RESULTS
!
/OUT,vm226,vrt
/COM
/COM,------------------- VM226 RESULTS COMPARISON -------------------------
/COM
*VWRITE,TAUARR(1,1)
(' TAU=0 TAU=',F6.4)
/COM
/COM ANSYS TARGET RATIO | ANSYS TARGET RATIO
/COM ------------------------------------------------------------------
*VWRITE,COEFFOU(1),RESUL(1,1),RESUL(1,2),RESUL(1,3),RESUL(1,4),RESUL(1,5),RESUL(1,6)
(A5,'| ',3F10.4,' |',3F10.4)
/COM
/COM
/COM
*VWRITE,TAUARR(1,2),TAUARR(1,3)
(' TAU=',F6.4,' TAU=',F6.4)
/COM
/COM ANSYS TARGET RATIO | ANSYS TARGET RATIO
/COM ------------------------------------------------------------------
*VWRITE,COEFFOU(1),RESUL(1,7),RESUL(1,8),RESUL(1,9),RESUL(1,10),RESUL(1,11),RESUL(1,12)
(A5,'| ',3F10.4,' |',3F10.4)
/COM
/COM,------------------------------------------------------------------------
/OUT
FINISH
*LIST,vm226,vrt




VM227 (Radiation Between Finite Coaxial Cylinders) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM227
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE,VM227, Radiation Between Finite Coaxial Cylinders
/COM,* EXPECTED RESULTS:
! RESULTS DERIVED FROM MODEST, RADIATIVE HEAT TRANSFER, P.791
! VIEW FACTOR EVAL‎UATIONS 44, 45
/COM,* FOR INSIDE CYLINDER-INSIDE CYLINDER VFAVG1=0
/COM,* FOR OUTSIDE CYLINDER-INSIDE CYLINDER VFAVG2=0.288
/COM,* FOR OUTSIDE CYLINDER-OUTSIDE CYLINDER VFAVG3=0.503
*SET,NDIV,20 ! ADJUSTED TO DETERMINE SPACING FOR PROBLEM.
*SET,L1,10
*SET,R1,1
*SET,R2,3
/PREP7
BLC4,0,0,R1,L1
BLC4,R2,0,R1,L1
ET,1,PLANE77 !CREATE 2D THERMAL ELEMENTS
KEYOPT,1,1,0
KEYOPT,1,3,1
LESIZE,ALL,,,10
MSHAPE,0,2D
MSHKEY,0
AMESH,ALL
SFL,2,RDSF,1, ,1,
SFL,8,RDSF,1, ,1,
FINISH
/AUX12
STEF,0.119E-10 !SET STEFAN-BOLTZMAN CONSTANT FOR MODEL
TOFFST,100 !SET TEMPERATURE OFFSET
RADOPT,0.1,0.1,0.E+00,1000,0.1,0.1 !SET RADIOSITY OPTIONS
SPCTEMP,1,0.E+00 !SET TEMPERATURE FOR RADIATION TO SPACE
!(NO RADIATION WILL APPEAR IN THIS MODEL)
HEMIOPT,1000,0.01 !SET HEMICUBE OPTIONS
V2DOPT,1,NDIV,0.E+00,200 !SET 2D CALCULATIONS TO AXISYMMETRIC
VFOPT,NEW
VFCALC !CALCULATE RADIOSITY VIEW FACTORS
ASEL,S, , , 1
ESLA,S
CM,INSIDE,ELEM
ASEL,S, , , 2
ESLA,S
CM,OUTSIDE,ELEM
CMPL
VFQUERY,INSIDE,INSIDE !EXTRACT VIEW FACTOR FROM INTERIOR CYLINDER ELEMENTS DUE TO INTERIOR CYLINDER
*GET,VFAVG1,RAD,,VFAVG !DETERMINE VIEW FACTOR FOR ENTIRE SURFACE
VFQUERY,OUTSIDE,INSIDE !EXTRACT VIEW FACTOR FROM EXTERIOR CYLINDER ELEMENTS
!DUE TO INTERIOR CYLINDER
*GET,VFAVG2,RAD,,VFAVG !DETERMINE VIEW FACTOR FOR ENTIRE SURFACE
VFQUERY,OUTSIDE,OUTSIDE !EXTRACT VIEW FACTOR FROM EXTERIOR CYLINDER ELEMENTS
!DUE TO EXTERIOR CYLINDER
*GET,VFAVG3,RAD,,VFAVG !DETERMINE VIEW FACTOR FOR ENTIRE SURFACE
*STATUS
*DIM,VALUE,,3,3
*VFILL,VALUE(1,1),DATA,0,0.288,0.503
*VFILL,VALUE(1,2),DATA,VFAVG1,VFAVG2,VFAVG3
*VFILL,VALUE(1,3),DATA,0.000,VFAVG2/0.288,VFAVG3/0.503
*DIM,LABEL,CHAR,3,2
LABEL(1,1) = 'VF(1-1)','VF(2-1)','VF(1-2)'
/OUT,vm227,vrt
/COM,
/COM,------------------- VM227 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F8.3,' ',F8.3,' ',1F7.2)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm227,vrt







VM228 (Radiation Between Infinite Coaxial Cylinders) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,vm228,
/TITLE,vm228, Radiation Between Infinite Coaxial Cylinders
TIN=1000
TOUT=100
/PREP7
ET,1,PLANE35 !CREATE 2D THERMAL ELEMENTS
MPTEMP,,,,,,,, !SET MATERIAL PROPERTIES
MPTEMP,1,0
MPDATA,EX,1,,30E6
MPDATA,PRXY,1,,.27
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,1,,.27
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,KXX,1,,1
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,C,1,,.21
CYL4,0,0,0.5,,1
CYL4,0,0,4, ,5
MSHAPE,1,2D
MSHKEY,0
SMRT,4
AMES,ALL


LSEL,S,,,1,4
LSEL,A,,,13,16
SFL,ALL,RDSF,1, ,1, !SET ALL FACING SURFACES TO EMISSIVITY 1
LSEL,S,,,9,12
DL,ALL, ,TEMP,TOUT,1 !APPLY UNIFORM TEMPERATURE TO EXTERIOR
LSEL,S,,,5,8
DL,ALL, ,TEMP,TIN,1 !APPLY UNIFORM TEMPERATURE TO INTERIOR
ASEL,S, , , 1
ESLA,S
CM,INSIDE,ELEM
ASEL,S, , , 2
ESLA,S
CM,OUTSIDE,ELEM
FINI
/AUX12
ALLSEL
!*
STFCONST=0.119E-10
STEF,STFCONST !SET STEFAN-BOLTZMAN CONSTANT FOR MODEL
TOFFST,0.E+00 !SET TEMPERATURE OFFSET
RADOPT,0.1,0.1,0.E+00,1000,0.1,0.1 !SET RADIOSITY OPTIONS
SPCTEMP,1,0.E+00 !SET TEMPERATURE FOR RADIATION TO SPACE
!(NO RADIATION WILL APPEAR IN THIS MODEL)
!*
VFCALC !CALCULATE RADIOSITY VIEW FACTORS
VFQUERY,INSIDE,INSIDE !EXTRACT VIEW FACTOR FROM INTERIOR CYLINDER ELEMENTS DUE TO INTERIOR CYLINDER
*GET,VFAVG1,RAD,,VFAVG !DETERMINE VIEW FACTOR FOR ENTIRE SURFACE
VFQUERY,OUTSIDE,INSIDE !EXTRACT VIEW FACTOR FROM EXTERIOR CYLINDER ELEMENTS DUE TO INTERIOR CYLINDER
*GET,VFAVG2,RAD,,VFAVG !DETERMINE VIEW FACTOR FOR ENTIRE SURFACE
VFQUERY,OUTSIDE,OUTSIDE !EXTRACT VIEW FACTOR FROM EXTERIOR CYLINDER ELEMENTS DUE TO EXTERIOR CYLINDER
*GET,VFAVG3,RAD,,VFAVG !DETERMINE VIEW FACTOR FOR ENTIRE SURFACE
FINISH
ALLSEL
/SOLU
SOLV
FINI
/POST1
LSEL,S, , ,1,4
LSEL,A, , ,13,16
NSLL,S,1

*GET,TI,NODE,4,TEMP !INSIDE CYLINDER SURFACE TEMP
*GET,TO,NODE,13,TEMP !OUTSIDE CYLINDER SURFACE TEMP
*GET,HFI,NODE,4,TF,SUM !INSIDE CYLINDER HEAT FLUX
*GET,HFO,NODE,13,TF,SUM !OUTSIDE CYLINDER HEAT FLUX

! CALCULATE EXPECTED RADIATION FLUX
HFIEXP=ABS(TO**4-TI**4)*STFCONST/1
HFOEXP=ABS(TO**4-TI**4)*STFCONST/4

HFIERR=(HFI/HFIEXP)
HFOERR=(HFO/HFOEXP)
*STATUS
*DIM,VALUE,,5,3
*VFILL,VALUE(1,1),DATA,0,0.25,0.75,HFI,HFO
*VFILL,VALUE(1,2),DATA,VFAVG1,VFAVG2,VFAVG3,HFIEXP,HFOEXP
*VFILL,VALUE(1,3),DATA,0.000,VFAVG2/0.25,VFAVG3/0.75,HFIERR,HFOERR
*DIM,LABEL,CHAR,10,2
LABEL(1,1) = 'VF(1-1)','VF(2-1)','VF(1-2)','HFINSIDE','HFOUTSIDE'

/COM,------------------- VM228 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F8.3,' ',F8.3,' ',1F7.2)
/COM,-----------------------------------------------------------
FINI





VM229 (Friction Heating of Sliding Block) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,vm229
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE,VM229, Friction Heating of a Sliding Block
/COM, REF: Wrigger and Miehe, Comp Meth Appl Engr 113, pp301-319
/PREP7
ET,1,PLANE13,4 ! 2-D Coupled-Field Solid
RECT,,5,,1.25
RECT,,1.25,1.25,2.5
!*
LESIZE,ALL,0.25, , ,1,1
AMESH,ALL
UIMP,1,EX, , ,70000,
UIMP,1,DENS, , ,2.7E-9,
UIMP,1,ALPX, , ,23.86E-6,
UIMP,1,NUXY, , ,0.3,
UIMP,1,MU, , ,0.2,
UIMP,1,KXX, , ,150,
UIMP,1,C, , ,9E8,
TOFFSET,460
TUNIF = 0.D0
ET,2,TARGE169 ! 2-D Target Segment
ET,3,CONTA171 ! 2-D Surface-to-Surface Contact
KEYOPT,3,1,1
ASEL,S,,,1
NSLA,S,1
NSEL,R,LOC,Y,1.25
R,1
TYPE,2
ESURF
ALLSEL
ASEL,S,,,2
NSLA,S,1
NSEL,R,LOC,Y,1.25
TYPE,3
ESURF
ALLSEL,ALL
*DIM,PRE,TABLE,2,1,1,TIME
!*
SFL,7,PRES, %PRE%
PRE(1,0,1) = 0
PRE(1,1,1) = 10
PRE(2,0,1) = 10
PRE(2,1,1) = 10


ALLSEL
/SOLU
NSUB,1
ASEL,S,,,2
NSLA,S,1
NSEL,R,LOC,X,1.25
D,ALL,UX,3.75
ALLSEL
ASEL,S,,,1
NSLA,S,1
D,ALL,UX,0
D,ALL,UY,0
ALLSEL
ANTYPE,TRANS
TIMINT,OFF,STRUC
TINTPR,,,,1.0
NLGEOM,ON
TIME,3.75E-3
AUTO,ON
NSUB,100,10000,100
OUTRES,ALL,-10
SOLVE
SAVE
TIME,1
AUTO,ON
TINTPR,,,,1.0
NSUB,100,10000,10
OUTRES,ALL,LAST
SOLVE
/POST1
ALLSEL
PLNSOL,TEMP
/COM *****************************************************************
/COM TEST FROM COMP. METH. APPL. MECH. ENG. VOL.113,P301,1994
/COM SOLUTION TEMPERATURE = 1.235
/COM *****************************************************************
ESEL,S,ENAME,,CONTA171
NSLE
PRNSOL,TEMP
*GET,TEMP1,NODE,130,TEMP
/COM *****************************************************************
/COM SOLUTION TEMPERATURE = 0.309
/COM *****************************************************************
ESEL,S,ENAME,,TARGE169
NSLE
PRNSOL,TEMP
*GET,TEMP2,NODE,40,TEMP
*DIM,LABEL,CHAR,2
*DIM,VALUE,,2,3
LABEL(1) = 'TEMP1','TEMP2 '
*VFILL,VALUE(1,1),DATA,1.235,0.309
*VFILL,VALUE(1,2),DATA,TEMP1,TEMP2
*VFILL,VALUE(1,3),DATA,ABS(TEMP1 / 1.235) ,ABS(TEMP2 / 0.309)
/OUT,vm229,vrt
/COM
/COM,------------------- VM229 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F7.4,' ',F7.4,' ',1F5.3)
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vm229,vrt





VM230 (3-D Static Force Example with DSP formulation) Input Listing

/COM,ANSYS MEDIA REL. 5.7.1 (4/9/01) REF. VERIF. MANUAL: REL. 5.7.1
/VERIFY,VM230
JPGPRF,500,100,1
/SHOW,JPEG
/TITLE, VM230, Analytical Verification of PDS Results
/COM,Probability Concepts in Engineering Planing and Design, Volume 1
/COM, A Ang, H-S Tang, Wiley, 1975
/COM,
! --------- make loop file --------
*CREATE,VM230,INP
X1 = 3.0
X2 = 3.0
X3 = 3.0
X4 = 3.0
X5 = 3.0
Y = (X1*X2*X3)/(X4*X5)
LOGY= log(Y)
*END
!
! --------- run loop file --------
/inp,VM230,INP
!
! --------- define PDS parameters --------
LMEAN1 = 1.1
LMEAN2 = 1.2
LMEAN3 = 1.3
LMEAN4 = 1.4
LMEAN5 = 1.5
LDEVI1 = 0.1
LDEVI2 = 0.2
LDEVI3 = 0.3
LDEVI4 = 0.4
LDEVI5 = 0.5
!
! --------- PDS Definitions --------
/PDS
PDANL,VM230,INP ! Define analysis file
PDVAR,X1,LOG2,LMEAN1,LDEVI1,0.0 ! Define X1 as Log-normal
PDPLOT,X1
PDVAR,X2,LOG2,LMEAN2,LDEVI2,0.0 ! Define X2 as Log-normal
PDVAR,X3,LOG2,LMEAN3,LDEVI3,0.0 ! Define X3 as Log-normal
PDVAR,X4,LOG2,LMEAN4,LDEVI4,0.0 ! Define X4 as Log-normal
PDVAR,X5,LOG2,LMEAN5,LDEVI5,0.0 ! Define X5 as Log-normal
PDVAR,Y,RESP ! Define Y as response parameter
PDVAR,LOGY,RESP ! Define LOGY as response parameter
!
! --------- PDS Methods - LHS --------
/COM, **************************************
/COM, Define and run latin hypercube samples
/COM, **************************************
PDMETH,MCS,LHS ! Set LHS as method
PDLHS,2000,1,RAND,,ALL,,,,INIT ! Define LHS options
PDEXEC,LHSRUN,SER ! Execute LHS runs
!
! --------- PDS POST-PROCESSING --------
/COM,
/COM, **************************************
/COM, Analytical results
/COM, Analytical results
/COM, **************************************
LMEANY = LMEAN1 + LMEAN2 + LMEAN3 - LMEAN4 - LMEAN5
LDEVIY = 0.0
LDEVIY = LDEVIY + LDEVI1*LDEVI1
LDEVIY = LDEVIY + LDEVI2*LDEVI2
LDEVIY = LDEVIY + LDEVI3*LDEVI3
LDEVIY = LDEVIY + LDEVI4*LDEVI4
LDEVIY = LDEVIY + LDEVI5*LDEVI5
LDEVIY = SQRT(LDEVIY)
MEANY = exp(LMEANY + 0.5*LDEVIY*LDEVIY)
HELP1 = exp(2.0*LMEANY + LDEVIY*LDEVIY)
HELP2 = exp(LDEVIY*LDEVIY) - 1.0
STDEVY = sqrt( HELP1*HELP2 )
*MSG,NOTE,LMEANY
The logarithmic mean of Y is %g
*MSG,NOTE,LDEVIY
The logarithmic deviation of Y is %g
*MSG,NOTE,MEANY
The mean value of Y is %g
*MSG,NOTE,STDEVY
The standard deviation of Y is %g
/COM,
/COM, **************************************
/COM, Plot the CDF for LHS
/COM, **************************************
PDCDF,LHSRUN,Y,LOGN
PDCDF,LHSRUN,LOGY
FINISH