모델링 질문 pipe 모델에 관한 질문입니다.

[고니78]

아래 그림과 같이 1/4 대칭 조건의 pipe 모델을,

1/2 원통인 파이프 모델로 만들려고 합니다.

(node 까지 생성)

간단한 모델을 만들어서 vsymm 을 사용했을때(vsymm,x,all)는 됐었는데(node 도 생성되고)

이 1/4 모델을 reflect 에 관련된 명령인 vsymm 이나 ensym 등을 써봤는데,

제대로 안되는것 같습니다.

과정은 1/4 모델의 txt 파일을 엔시스에서 (Read input from..) 불러들인 후

vsymm,x,all 을 사용했습니다.(1/2 원통 파이프를 만들기 위해)

참고로 1/4 모델의 파일을 첨부합니다.

도저히 어떻게 해야 할 지....주의 깊게 봐 주세요~

답변 부탁 드립니다.

/filename,ELBOW_WALLTHIN_L400s

!-----Beginning of Basic Data--------------------------
!1in.=2.54cm=25.4mm=0.0254m

thick=20.0                ! Thick of nuclear pipe
router=400/2             ! Outer Radius of Pipe
rinner=router-thick       ! Inner Radius of Pipe
ful_li=400.               ! Wall thinning full length
li=nint(ful_li/2)         ! Symmetric length
loading= 2400             ! Full Loading point length
lo_lth=loading/2          ! Symmetric Loading point
thin=3200                 ! Wall thinning part Length
s2_lth=2400               ! Second Part Length
support=6000              ! Full Support point length
li_dm=support/2-lo_lth    ! From first loading point to support(1800)
lst_dm=thin/2+s2_lth-support/2      ! Last part (1250)
lload=thin/2+s2_lth       ! loading part(2000)
pi=3.141592653589793      ! Definition of pi
r_div=20                  ! Element dividing for radius
s_div=3                   ! Element dividing for thick
div1=8                    ! Element dividing for Z direction

!---Definition of Shape at z=0------------------------------------------
*afun,deg
alpha=90.                ! Degree of initial wall thinning
ha_alpha=alpha/2          ! Degree for 1/4 Model
t_min=18.63               ! Max depth by wall thinning
t_aloc=t_min*0.5          ! Minimum thick by degree of wall thinning in L-length
rtt=rinner+thick-t_min    ! Temp Variable
rot=router-t_aloc         ! Thin wall Y point at Z=0, t=t_aloc
rtm=router-t_min          ! Thin wall Y point at t=t_min
qtheta=90

!--Wall thinning Origin point for X-Y Plane-----------------------

!----Origin point for X-Y Plane----------------------
 a=(1/2)*((rot**2-rtt**2)/(rot-rtt*cos(alpha/2)))

!----Origin point for Y-Z Plane----------------------
 b=(rtm**2-rot**2+(ful_li**2)/4)/(2*(rot-rtm))

!----Radius of X-Y Plane------------------------
r_c=rot-a

!----Radius of Y-Z Plane------------------------
ra=b+router-t_aloc

!--Finding Z length Thinned Section-------------
z_lth=sqrt(ra**2-(-rinner-b)**2)

!--Y Point at z_lth, not 360--------------------
*if,alpha,ne,360,then
  tmp_py=sqrt(ra**2-z_lth**2)+b
  tmp_my=-sqrt(ra**2-z_lth**2)+b
  *if,tmp_py,gt,tmp_my,then
     y_lth=tmp_py
  *else
     y_lth=tmp_my
  *endif
*endif

/prep7
et,1,95                    ! Element type for 3-D Model
mp,ex,1,206058.0           ! True modulus of elasticity 1
mp,nuxy,1,0.3              ! Poison Ratio 1
mp,ex,2,206058.0           ! True modulus of elasticity 2
mp,nuxy,2,0.3              ! Poison Ratio 2

!!-----Nonlinear material property--------------------
tb,kinh,1
tbpt,,0.0014559,300.0
tbpt,,0.00384,301.03387
tbpt,,0.00936,303.78837
tbpt,,0.0237,308.90504
tbpt,,0.0254,319.70517
tbpt,,0.02742,330.65178
tbpt,,0.08103,450.12993
tbpt,,0.12457,500.96529
tbpt,,0.19271,548.43491
tbplot,kinh,1

!----Alpha=360----------------------------------------
*if,alpha,eq,360,then
  csys,0
  k                      !--Origin point at Y-Z Plane--
 *get,kp_org,kp,,num,max
  k,,,,z_lth             !--Basis point for rotation at Y-Z Plane-
 *get,ko_2,kp,,num,max
  k,,,-rot               !--Point t_aloc at X-Y Plane--
 *get,k1_no,kp,,num,max
  k,,,-router            !--Point thick at X-Y Plane--
 *get,k1_2,kp,,num,max
  k,,,-rinner,z_lth      !--Ending point of thinned wall at rinner
 *get,k2_no,kp,,num,max
  k,,,-router,z_lth      !--Ending point of thinned wall at router
 *get,k2_2,kp,,num,max

!--Generating Wall thinning part--------------------
  larc,k1_no,k2_no,kp_org,ra
 *get,s2,line,,num,max
  l,k1_no,k1_2
 *get,s2_left,line,,num,max
  l,k1_2,k2_2
 *get,s2_btm,line,,num,max
  l,k2_no,k2_2
 *get,s2_right,line,,num,max
  al,s2,s2_left,s2_btm,s2_right
 *get,ar_tmp,area,,num,max
  vrotat,ar_tmp,,,,,,kp_org,ko_2,alpha/2,1
  asel,s,loc,z,z_lth
 *get,surf_a,area,,num,max

!--Drawing out line number for lesize--
  csys,0
  lsel,s,loc,z,0
  csys,1
  lsel,u,loc,x,router
  csys,0
  lsel,u,loc,x,0
 *get,s3,line,,num,max
  csys,1
  lsel,s,loc,z,0
  lsel,r,loc,x,router
 *get,s3_up,line,,num,max
  csys,0
  lsel,s,loc,x,0
  lsel,r,loc,y,router
 *get,s1_up,line,,num,max
  lsel,s,loc,x,0
  lsel,r,loc,z,0
  lsel,r,loc,y,0,router
 *get,s1_left,line,,num,max
  lsel,s,loc,x,0
  lsel,r,loc,z,z_lth
  lsel,r,loc,y,0,router
 *get,s1_right,line,,num,max
  lsel,s,loc,x,0
  lsel,u,loc,y,router
  lsel,r,loc,y,0.1,router
  lsel,u,loc,z,0
  lsel,u,loc,z,z_lth
 *get,s1,line,,num,max
  csys,1
  lsel,s,loc,z,z_lth
  lsel,u,loc,x,router
  csys,0
  lsel,u,loc,x,0
 *get,s4,line,,num,max
  lsel,all
  lsel,s,loc,z,z_lth
  csys,1
  lsel,r,loc,x,router
 *get,s4_up,line,,num,max
  lsel,all
  asel,all
!------------------------------------
*else 
!--Alpha, 90 to 359---------------------------------
!---Definition of Original Point--------------------
  k,,,-b
 *get,kp_org,kp,,num,max
!---------------------------------------------------
  k,,,a
 *get,k1_tmp,kp,,num,max
  k,,,a,z_lth
  *get,k2_tmp,kp,,num,max
  k,,,rot
 *get,k1_no,kp,,num,max
  k,,,rinner,z_lth
 *get,k2_no,kp,,num,max
  larc,k1_no,k2_no,kp_org,ra

!---Non thinned wall Pipe Model----------------
  cyl4,,,rinner,-90,router,90,z_lth
 *get,v1_no,volu,,num,max

!---Routine for Thinned wall part volume-------
!---Drawing out Line S2; Spline at Y-Z Plane---
  csys,0
  lsel,s,loc,x,0
  lsel,u,loc,z,0
  lsel,u,loc,z,z_lth
  lsel,u,loc,y,0,-router
  lsel,r,loc,y,rinner,router
  lsel,u,loc,y,rinner
  lsel,u,loc,y,router
 *get,s2,line,,num,max
  allsel

!---Routine for creating subtracted Volume --
!------------------------------
  l,k1_no,k1_tmp
  lsel,s,loc,z,0
  lsel,r,loc,x,0
  lsel,u,loc,y,0,-router
  lsel,u,loc,y,rinner,router
 *get,s3_tmp,line,,num,max 
  allsel
!------------------------------
  l,k1_tmp,k2_tmp
  lsel,s,loc,x,0
  lsel,u,loc,z,0
  lsel,u,loc,z,z_lth
  lsel,u,loc,y,-rinner,-router
  lsel,u,loc,y,rinner,router
 *get,s1_tmp,line,,num,max
  allsel
!------------------------------
  l,k2_tmp,k2_no
  lsel,s,loc,z,z_lth
  lsel,r,loc,x,0
  lsel,u,loc,y,-rinner,-router
  lsel,u,loc,y,rinner,router
 *get,s4_tmp,line,,num,max
  allsel
!---Area to rotate for subtract----------
  al,s2,s3_tmp,s1_tmp,s4_tmp
  asel,s,loc,x,0
  asel,u,loc,y,-rinner,-router
  asel,u,loc,y,rinner,router
 *get,ar_tmp,area,,num,max
  allsel
!---Rotation for subtracted volume-------
  vrotat,ar_tmp,,,,,,k1_tmp,k2_tmp,-180,1
  vsel,u,volu,,v1_no
 *get,v2_no,volu,,num,max
  vsel,all

!---Subtract volume for drawing out inner line---
  vsbv,v1_no,v2_no
 *get,v3_no,volu,,num,max
!---Drawing out inner line---
  csys,1
  lsel,u,loc,x,router
  csys,0
  lsel,u,loc,z,0
  lsel,u,loc,z,z_lth
  lsel,u,loc,x,0
 *get,s_in,line,,num,max
!---Drawing out coordinate Y,Z for future nmodif--
  lsel,s,line,,s_in,,,1
  ldiv,all,,,div1
 *dim,kloc,,div1,2
  ksel,u,loc,z,0
  ksel,u,loc,z,z_lth
 *do,i,1,div1-1,1
   *get,ks_tmp,kp,,mnloc,z
    ks_num=kp(,,ks_tmp)
    kloc(i,1)=ky(ks_num)
    kloc(i,2)=kz(ks_num)
    ksel,u,kp,,ks_num
 *enddo
 allsel

!!--Real Processing Part for thinned wall volume------
!-----drawing out s3----------------------------------
  csys,0
  lsel,s,loc,z,0
  lsel,u,loc,x,0
  csys,1
  lsel,u,loc,x,router
!  lsel,u,line,,l1_no
  lcomb,all,,0
  lsel,s,loc,z,0,,,1
  csys,1
  lsel,u,loc,x,router
  ksel,u,loc,x,0
 *get,ks_tmp,kp,,num,max
  allsel
  ksel,s,kp,,ks_tmp
  lslk
  lsel,inve
  lsel,r,loc,z,0
  lsel,u,loc,x,router
  csys,0
  lsel,u,loc,x,0   
 *get,s3,line,,num,max
  allsel
!!-----Drawing out s3_up----------------------------
  csys,1
  lsel,s,loc,z,0
  lsel,r,loc,x,router
 *get,s3_up,line,,num,max
  allsel
!!-----Drawing out S2-------------------------------
  csys,0
  lsel,s,loc,x,0
  lsel,u,loc,z,0
  lsel,u,loc,z,z_lth
  lsel,u,loc,y,0,-router
  lsel,r,loc,y,rinner,router
  lsel,u,loc,y,rinner
  lsel,u,loc,y,router
 *get,s2,line,,num,max
!!--Drawing out router area-----------------------
  csys,1
  asel,s,loc,x,router !Select area at outer radius
 *get,rou_a,area,,num,max
  asel,all
!!----Drawing out Bottom line at Y-Z Plane---------
  csys,0
  lsel,s,loc,x,0
  lsel,r,loc,y,-router
 *get,s1_up,line,,num,max
  lsel,s,loc,x,0
  lsel,r,loc,z,0
  lsel,r,loc,y,0,-router
 *get,s1_left,line,,num,max
  lsel,s,loc,x,0
  lsel,r,loc,z,z_lth
  lsel,r,loc,y,0,-router
 *get,s1_right,line,,num,max
  lsel,s,loc,x,0
  lsel,u,loc,y,-router
  lsel,r,loc,y,0.1,-router
  lsel,u,loc,z,0
  lsel,u,loc,z,z_lth
 *get,s1,line,,num,max
!!---Drawing out Upper line at Y-Z Plane--------
  lsel,s,loc,x,0
  lsel,r,loc,y,router
 *get,s2_btm,line,,num,max
  csys,0
  lsel,s,loc,x,0
  lsel,r,loc,z,0
  lsel,r,loc,y,0,router
 *get,s2_left,line,,num,max
  lsel,s,loc,x,0
  lsel,r,loc,z,z_lth
  lsel,r,loc,y,0,router
 *get,s2_right,line,,num,max
!!---Drawing out line at Z= z_lth------------
  kp_no_z=kp(0,-rinner,z_lth)
  csys,1
  lsel,s,loc,z,z_lth
  lsel,u,loc,x,router
  csys,0
  lsel,u,loc,x,0
  ksel,s,kp,,kp_no_z
  lslk,r
 *get,s4,line,,num,max
  allsel
  lsel,s,loc,z,z_lth
  csys,1
  lsel,r,loc,x,router
 *get,s4_up,line,,num,max
!!---Creating first area at X-Y Plane----------------
  allsel
  al,s1_left,s3,s2_left,s3_up
!!---Drawing out first area for thinned wall volume--
  csys,0
  lsel,s,line,,s3
  asll
  asel,r,loc,z,0
 *get,first_a,area,,num,max
  allsel
!!---Creating inner area----------------
  al,s3,s1,s4,s2
  lsel,s,line,,s3
  asll
  asel,u,loc,z,0
 *get,rin_a,area,,num,max
  allsel
!!---Creating Upper area at Y-Z Plane------
  al,s1,s1_left,s1_up,s1_right
  asel,s,loc,x,0
  asel,r,loc,y,0,router
 *get,con1_a,area,,num,max
!!---Drawing out bottom area at Y-Z Plane--
  asel,s,loc,x,0
  asel,r,loc,y,0,-router
 *get,con2_a,area,,num,max
!!---Drawing out area at Z= z_lth----------
  asel,s,loc,z,z_lth
 *get,surf_a,area,,num,max
  allsel

!!---Creating thinned wall Volume------------------
  va,first_a,rou_a,surf_a,con2_a,con1_a,rin_a
  vsel,u,volu,,v3_no
 *get,last_v,volu,,num,max
  allsel
  vdele,v3_no,,,1
! *get,v_org,volu,,num,max

!--------------------------------------------------
!--------------------------------------------------
*endif

!--------End of Modelling--------------------------

!--Step 1 -----------------------------------------
!---For meshing------------------------------------
mshkey,1
off_di=lo_lth-z_lth !From thin to frst pnt at thin

!!---Element Size Control---------------------------
!---Thick element dividing for area mesh----
lesize,s1_left,,,s_div

!---Radius element dividing for area mesh-----------
lesize,s3,,,r_div

!---Dividing for volume direction-------------------
lesize,s2,,,div1
lesize,s2_btm,,,div1
lesize,s1,,,div1
lesize,s1_up,,,div1
vsweep,last_v

!--Step 2-------------------------------------------
!---Modifying node coordinate for non thinned wall--
asel,s,area,,rin_a
nsla,s,0
modmsh,nocheck       !--must be--
*do,i,0,div1-1,1
 csys,0
 *if,i,eq,0,then
  nsel,r,loc,z,0,kloc(i+1,2)
  nsel,r,loc,y,kloc(i+1,1),-router
 *elseif,i,eq,div1-1,then
  nsel,r,loc,z,kloc(i,2),z_lth
  nsel,r,loc,y,kloc(i,1),-router
 *else
  nsel,r,loc,z,kloc(i,2),kloc(i+1,2)
  nsel,r,loc,y,kloc(i,1),-router
 *endif
 csys,1
 nmodif,all,rinner
 asel,s,area,,rin_a
 nsla,s
*enddo
allsel
!--------------------------------------------------

!--Step 3: Generating rest part-------------------------------
!!--Division 2 Size---------------------
dv2_step=2.0
di_tmp=0
cur_sz=0
di1_sz=z_lth/div1
di2_sz=di1_sz*0.6
*do,i,1,off_di,1
    di_tmp=di_tmp+di2_sz*dv2_step
   *if,di_tmp,gt,off_di,then
    div2=i
    di2_sz=di_tmp-cur_sz
   *exit
   *endif
    di2_sz=di_tmp-cur_sz
    cur_sz=di_tmp
*enddo

!!------Line Dividing---------------------
csys,0 
extopt,on
!extopt,esize,div2,1.3
extopt,esize,18-div1,(thin/2)/ful_li
voffst,surf_a,off_di

!----------------------------------------------
asel,s,loc,z,lo_lth
*get,lst_a,area,,num,max
allsel
vsel,u,volu,,last_v
*get,vol_2,volu,,num,max
allsel
!--------------

!--Step 4 : Generating Second Part & Meshing---
!!--Division 3 Size----------------------------
dv3_step=2.0
di_tmp=0
cur3_sz=0
*if,div2,eq,1,then
 di3_sz=di1_sz*0.6
*else
 di3_sz=di2_sz*0.6
*endif
*do,i,1,li_dm,1
    di_tmp=di_tmp+di3_sz*dv3_step
   *if,di_tmp,gt,li_dm,then
    div3=i
    di3_sz=di_tmp-cur3_sz
   *exit
   *endif
    di3_sz=di_tmp-cur3_sz
    cur3_sz=di_tmp
*enddo

!!----Line Element dividing for volume3--------------
!extopt,esize,div3,1.5
extopt,esize,3,2
vext,lst_a,,,,,li_dm

!--Drawing out Area For Last Part--
asel,s,loc,z,lo_lth+li_dm
*get,a4_a,area,,num,max
asel,all

!--Step 5: Generating Volume final Part & Meshing----
extopt,esize,1
vext,a4_a,,,,,lst_dm                ! lst_dm= 1350 mm

!-------It's over about Modelling and Meshing--------

nummrg,all
numcomp,all

!------- Extended bar --------------------
mat,2
k,22,0,-router,thin/2+s2_lth
k,23,0,-rinner,thin/2+s2_lth
k,24,0,-rinner/2,thin/2+s2_lth
k,25,0,0,thin/2+s2_lth
k,26,0,rinner/2,thin/2+s2_lth 
k,27,0,rinner,thin/2+s2_lth 
k,28,0,router,thin/2+s2_lth  

k,29,rinner/2,-rinner/2,thin/2+s2_lth  
k,30,rinner/2,0,thin/2+s2_lth  
k,31,rinner/2,rinner/2,thin/2+s2_lth

csys,1
k,32,rinner,-qtheta/2,thin/2+s2_lth
k,33,rinner,qtheta-qtheta,thin/2+s2_lth  
k,34,rinner,qtheta/2,thin/2+s2_lth
k,35,router,-qtheta/2,thin/2+s2_lth
k,36,router,qtheta-qtheta,thin/2+s2_lth  
k,37,router,qtheta/2,thin/2+s2_lth

csys,0
l,22,23
l,23,24
l,24,25
l,25,26
l,26,27
l,27,28
l,24,29
l,25,30
l,26,31
l,29,30
l,30,31
l,29,32
l,30,33
l,31,34
l,32,35
l,33,36
l,34,37

csys,1
l,23,32
l,32,33
l,33,34
l,34,27
l,22,35
l,35,36
l,36,37
l,37,28

lesize,39,,,r_div/4
lesize,40,,,r_div/4
lesize,43,,,r_div/4
lesize,44,,,r_div/4
lesize,45,,,r_div/4
lesize,46,,,r_div/4
lesize,47,,,r_div/4
lesize,54,,,r_div/4
lesize,55,,,r_div/4
lesize,56,,,r_div/4
lesize,57,,,r_div/4
lesize,58,,,r_div/4
lesize,59,,,r_div/4
lesize,60,,,r_div/4
lesize,61,,,r_div/4

lesize,37,,,s_div
lesize,38,,,s_div
lesize,41,,,s_div
lesize,48,,,s_div
lesize,49,,,s_div
lesize,50,,,s_div
lesize,51,,,s_div
lesize,52,,,s_div
lesize,53,,,s_div

al,43,39,44,46
al,44,40,45,47
al,54,38,43,48
al,48,46,49,55
al,49,47,50,56
al,45,41,57,50
al,58,37,54,51
al,51,55,52,59
al,52,56,53,60
al,57,42,61,53

et,3,82                    ! Element type for 2-D Model
mp,ex,3,206058.0           ! True modulus of elasticity
mp,nuxy,3,0.3              ! Poison Ratio

type,3 
amesh,22,31

type,1 
extopt,esize,2
vext,22,31,,,,lload/2. 

allsel
csys,0
nummrg,all
numcomp,all
!
!---Boundary Condition--------------------------------------
!
!--Symmetric condition-------
nsel,s,loc,x
dsym,symm,x,0             ! for X-dir symme.
allsel
!
!!--Internal Pressure---------
csys,1
asel,s,loc,z,0,lo_lth+li_dm+lst_dm
asel,u,loc,x,router
asel,u,loc,z,0
asel,u,loc,z,lo_lth+li_dm+lst_dm
csys,0
asel,u,loc,x,0
asel,u,loc,z,z_lth
asel,u,loc,z,lo_lth
asel,u,loc,z,lo_lth+li_dm
!nsla,s,1
sfa,all,,pres,10
!
asel,s,area,,22,27
sfa,all,,pres,10
allsel
sftran
!/output,elempr1,dat
!sfelist,all
!
NWRITE,'exnode','dat',' ',0 
!EWRITE,'exelem','dat',' ',0
!
!csys,0
!nsel,s,loc,x,0
!NWRITE,'xsymnod','dat',' ',0
!allsel
!nsel,s,loc,z,0
!NWRITE,'zsymnod','dat',' ',0
!allsel

[김서형]

길긴한데 무엇을 원하시는지를 모르겠군요..-_-;...1/4을 모델링 하실떄 처럼 1/2 혹은 1/1 도 하면 안될까요? 이게 질문인가요?..잘 파악을 몬해서 죄송합니다.

[고니78]

답변 감사 드리구요~ 1/4 모델을 이용해서 1/2 원통 파이프를 만들려고 하거든요...파일을 수정해야 할까요?

[김주석]

1/4 모델하여서 해석하시고요 결과 plot하실때에1/2,1/4 등으로 보시면은 됩니다. 그럼 수고하세요...

[김주석]

그러데요 파이프 인데 한쪽이 막힌건가요...메쉬 그림을 보니 그러한것 같은데요 좀의문이네요...... 어떤 의도인지 정확이 설명을 하시면은 아마도 많은 답변이 있을 것으로 기대 됩니다....권투를 빕니다