|
성심 성의껏 질문을 작성하여 주세요, 대충하시면 답변도 대충작성합니다.^^
① CAD 종류 : autocad
② VERSION : 2018
③ 운영 체제 : windows 10
PB_v4(다중플롯)리습 사용중 작은사이즈의 도면출력시 에러가 뜨는대
확인해보니 대각선길이 70mm 이하라 플롯이 안되는것같습니다. 이런 사이즈까지 인쇄나 pdf 변환 가능하도록
수정 안될까요?
도곽 사이즈 36(가로)x25.5(세로) 입니다.
⑤ 파일첨부 (LISP/DWG) - DWG 첨부시 보다 정확한 답변을 얻을수 있습니다.
;;;
;;; CTB, PRINTER, PAPER 설정
;;;
;;; 이 부분의 변수 ctb_file, prt_name, paper_size 에 ctb파일이름,프린터설정세이브파일이름,용지설정이름으로
;;; 대체한후 AutoCAD에서 로드하여야 한다.
;;;
;;;
;Plot Device 설정
(setq prt_name "Canon iR-ADV C3525_3530 UFR II.pc3") ;; 프린터 이름 설정
(setq ctb_file "JYS.ctb") ;; 펜 설정
;(setq paper_size_A1 "A1") ;; A1 용지 설정
;(setq paper_size_A2 "A2") ;; A2 용지 설정
(setq paper_size_A3 "A3") ;; A3 용지 설정
(setq paper_size_A4 "A4") ;; A4 용지 설정
;PDF Device 설정: ACAD2012
(setq pdf_prt_name "DWG To PDF.pc3") ;; 프린터 이름 설정
(setq pdf_ctb_file "JYS.ctb") ;; 펜 설정
;(setq pdf_paper_size_A1 "ISO_expand_A1_(594.00_x_841.00_MM)") ;; A1 용지 설정
;(setq pdf_paper_size_A2 "ISO_expand_A2_(420.00_x_594.00_MM)") ;; A2 용지 설정
(setq pdf_paper_size_A3 "ISO_expand_A3_(297.00_x_420.00_MM)") ;; A3 용지 설정
(setq pdf_paper_size_A4 "ISO_expand_A4_(210.00_x_297.00_MM)") ;; A4 용지 설정
;정렬순서 선택(좌하단:"BL", 좌상단:"TL", 우상단:"TR", 우하단:"BR") -대문자로 작성-
(setq #Sort_Align "TL")
;출력용 Layer명 지정(PLOTBOX)
(setq #PlotClayer "0") ;;플롯용 박스 기본 레이어 설정 (Default: "0")
(setq #PlotColor 2) ;;플롯용 박스 색상 설정 (Default: nil)
;;;
;;; PLOT 설정값 확인
;;;
;;; 평소 사용하는 환경으로 PLOT설정을 배치에 적용한 뒤,
;;; PLOTNAME 명령으로 위의 값을 확인할 수 있다.
;;;
(defun c:PLOTNAME ()
(princ "\n플로터 이름: ") (prin1 (vla-get-ConfigName LayObj))
(princ "\n용지 이름: ") (prin1 (vla-get-CanonicalMediaName LayObj))
(princ "\n펜 이름: ") (prin1 (vla-get-StyleSheet LayObj))
(princ "\n")(princ)
)
;;;
;;;
;;; 출력 명령어 설정
;;; C:OOO 를 원하는 명령으로 바꾼다.
;;;
;;; -기본 명령어-
;;; BZ: 박스로 된 도면외각을 선택하여 출력한다.
;;; PA: 블록 및 박스로 된 도면외각을 선택하여 출력한다.
;;; PXX: 도면 전체를 출력한다.
;;; RV: 도면 출력과 동일하게 미리보기를 한다.
;;; BB: PLOT 전용 사각박스를 생성한다.
;;; BX: 박스로 된 도면외각을 PDF파일로 출력한다.
;;; CT: 출력 가능한 박스로 된 도면외각을 검사한다.
;;; CA: 출력 가능한 블록 및 박스로 된 도면외각을 검사한다.
;;;
;;;
(defun C:PI nil (C:PA));예전 버전 단축키
(defun C:BZ () (prompt (strcat "PLOTEXPRESS\n출력할 도면 선택...")) (#PLOT_EXPRESS "Plot_Mode" paper_size_A4))
(defun C:PA () (prompt (strcat "PLOTALL\n출력할 모든 도면 선택...")) (#PLOT_EXPRESS "ALLPlot_Mode" paper_size_A4))
(defun C:PXX () (prompt (strcat "PLOTEXPRESSALL\nPLOT전용 LAYER 전체 출력...")) (#PLOT_EXPRESS "AP_Mode" paper_size_A4))
(defun C:RV () (prompt (strcat "DREVIEW\n미리보기 할 도면 선택...")) (#PLOT_EXPRESS "RV_Mode" nil))
(defun C:BB () (prompt (strcat "PLOTBOX\nPLOT전용 BOX 생성...")) (c:PLOTBOX))
(defun C:BX () (prompt (strcat "PDFOUT\nPDF로 내보내기...")) (#PLOT_EXPRESS "PDF_Mode" pdf_paper_size_A4))
(defun C:CT () (prompt (strcat "CHKPLOT\nPLOT이 가능한 객체 확인하기...")) (#PLOT_EXPRESS "CHK_Mode" nil))
(defun C:CA () (prompt (strcat "CHKPLOTALL\nPLOT이 가능한 모든 객체 확인하기...")) (#PLOT_EXPRESS "ALLCHK_Mode" nil))
;;;
;;;A3 대응 명령어
;;;
(defun C:PX3 () (prompt (strcat "PLOTEXPRESS\n출력할 도면 선택...")) (#PLOT_EXPRESS "Plot_Mode" paper_size_A3))
(defun C:PA3 () (prompt (strcat "PLOTALL\n출력할 모든 도면 선택...")) (#PLOT_EXPRESS "ALLPlot_Mode" paper_size_A3))
;(defun C:PXX3 () (prompt (strcat "PLOTEXPRESSALL\nPLOT전용 LAYER 전체 출력...")) (#PLOT_EXPRESS "AP_Mode" paper_size_A3))
;(defun C:PDF3 () (prompt (strcat "PDFOUT\nPDF로 내보내기...")) (#PLOT_EXPRESS "PDF_Mode" pdf_paper_size_A3))
;;;
;;;
;;; 도면 Open 시 자동으로 플로터 확인
;;;
;;;
(vl-load-com)
(setq LayObj (vla-get-ActiveLayout (vla-get-ActiveDocument (vlax-get-acad-object))))
(and
(or
(and
(member prt_name (vlax-safearray->list (vlax-variant-value (vla-GetPlotDeviceNames LayObj))))
(member ctb_file (vlax-safearray->list (vlax-variant-value (vla-GetPlotStyleTableNames LayObj))))
;;(member paper_size (vlax-safearray->list (vlax-variant-value (vla-GetCanonicalMediaNames LayObj))))
)
(prompt "\nLISP: 플롯 설정값이 올바르지 않음. PLOTNAME 명령으로 현재 설정값을 확인하십시오.")
)
(or
(/= (vla-get-ConfigName LayObj) prt_name)
(/= (vla-get-StyleSheet LayObj) ctb_file)
(/= (vla-get-CanonicalMediaName LayObj) paper_size_A4)
)
(progn
(vla-put-ConfigName LayObj prt_name)
(vla-put-StyleSheet LayObj ctb_file)
(vla-put-CanonicalMediaName LayObj paper_size_A4)
)
)
;;;
;;;
;;; 도면 Open 시 자동으로 UCS 초기화
;;;
;;;
(if (= (getvar "worlducs") 0) (and (setvar "cmdecho" 0) (vl-cmdf "UCS" "") (setvar "cmdecho" 1) (prompt (strcat "\n **UCS Initialized** "))))
;;;
;;;
;;; 플롯박스 만들기
;;;
;;; CLA에 해당하는 layer에 4각 폴리곤을 작성한다.
;;; 해당 layer가 없을 경우 자동으로 작성한다.
;;; 4각 폴리곤을 도면폼 외곽에 씌우면 차후에 일괄출력에 활용가능하다.
;;;
;;;
(defun c:PLOTBOX ( / COL CLA pt)
(if (= (getvar "worlducs") 0) (and (setvar "cmdecho" 0) (vl-cmdf "UCS" "") (setvar "cmdecho" 1)))
(setq CLA #PlotClayer)
(setq COL #PlotColor)
(if (= nil (tblsearch "layer" CLA))
(entmake (list (cons 0 "LAYER") (cons 100 "AcDbSymbolTableRecord") (cons 100 "AcDbLayerTableRecord")
(cons 2 CLA) (cons 6 "CONTINUOUS") (cons 62 2) (cons 70 0)
)
)
)
(and (setq pt (getpoint "첫 번째 구석점 지정: "))
(cadr (setq pt (list pt (getcorner pt "다른 구석점 지정: "))))
(setq pt (list (list (caar pt) (caadr pt)) (list (cadar pt) (cadadr pt))))
)
(if (= (length pt) 2)
(entmake
(vl-remove-if 'not
(list (cons 0 "LWPOLYLINE") (cons 100 "AcDbEntity") (cons 8 CLA)
(if COL (cons 62 COL)) (cons 100 "AcDbPolyline") (cons 90 4) (cons 70 1)
(cons 10 (list (apply 'min (car pt)) (apply 'min (cadr pt))))
(cons 10 (list (apply 'max (car pt)) (apply 'min (cadr pt))))
(cons 10 (list (apply 'max (car pt)) (apply 'max (cadr pt))))
(cons 10 (list (apply 'min (car pt)) (apply 'max (cadr pt))))
)
)
)
)(princ)
)
;;;
;;;
;;; 박스 정렬
;;;
;;; 박스를 선택한 순서를 기준으로 x축 방향으로 재정렬한다.
;;;
;;;
(defun PTE:highlight (ss x) (mapcar '(lambda (ent)(redraw ent x)) (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))))
(defun #SS_Sort_Sub (ss / n buffer ss_lst)
(setq n (cadddr (car (ssnamex ss))))
(foreach x (ssnamex ss)
(if (equal n (cadddr x))
(setq buffer (append buffer (list (cadr x))))
(setq ss_lst (append ss_lst (list (list n buffer))) n (cadddr x) buffer (list (cadr x)))
)
)
(setq ss_lst (vl-remove-if '(lambda (x) (listp (car (cadr x)))) (append ss_lst (list (list n buffer)))))
ss_lst
)
(defun #SS_Sort_Main (ss / SortSS MinPt MaxPt MinPtB MaxPtB)
(setq SortSS (ssadd))
(foreach x (#SS_Sort_Sub ss)
(if (= (length (cadr x)) 1)
(ssadd (car (cadr x)) SortSS)
(mapcar '(lambda (f) (ssadd f SortSS))
(vl-sort (cadr x)
'(lambda (a b)
(if
(equal
(cadr
(progn (vla-GetBoundingBox (vlax-ename->vla-object a) 'MinPt 'MaxPt)
(if (or (= #Sort_Align "TL") (= #Sort_Align "TR")) (vlax-safearray->list MaxPt) (vlax-safearray->list MinPt))
)
)
(cadr
(progn (vla-GetBoundingBox (vlax-ename->vla-object b) 'MinPtB 'MaxPtB)
(if (or (= #Sort_Align "TL") (= #Sort_Align "TR")) (vlax-safearray->list MaxPtB) (vlax-safearray->list MinPtB))
)
)
40.0;무시하는 고저 차이값 범위
)
(if (or (= #Sort_Align "BR") (= #Sort_Align "TR"))
(< (car (vlax-safearray->list MaxPt)) (car (vlax-safearray->list MaxPtB)))
(< (car (vlax-safearray->list MinPt)) (car (vlax-safearray->list MinPtB)))
)
(if (or (= #Sort_Align "TL") (= #Sort_Align "TR"))
(> (cadr (vlax-safearray->list MaxPt)) (cadr (vlax-safearray->list MaxPtB)))
(> (cadr (vlax-safearray->list MinPt)) (cadr (vlax-safearray->list MinPtB)))
)
)
)
)
)
)
)SortSS
)
(defun List->Safearray (lst) (vlax-safearray-fill (vlax-make-safearray vlax-vbdouble (cons 0 (1- (length lst)))) lst))
(defun #PantaList ($CP $DS $LP / P0 P1 P2 P3 P4 P5)
(setq P0 (list (car $CP) (cadr $CP)))
(if (= $LP 1)
(setq P1 (polar P0 (/ pi 2.0) (* $DS 0.2))
P2 (polar P0 2.85184 (* $DS 0.35))
P3 (polar P0 3.43134 (* $DS 0.35))
P4 (polar P0 5.99343 (* $DS 0.35))
P5 (polar P0 0.289752 (* $DS 0.35))
)
(setq P1 (polar P0 (/ pi 2.0) (* $DS 0.3))
P2 (polar P0 2.32754 (* $DS 0.25))
P3 (polar P0 3.95565 (* $DS 0.25))
P4 (polar P0 5.46913 (* $DS 0.25))
P5 (polar P0 0.814053 (* $DS 0.25))
)
)(list P1 P2 P3 P4 P5)
)
(defun #BoxReaction (ss SF_List / en n MinPt MaxPt ns nb bf di LP)
(repeat (setq n (sslength ss))
(and
(setq en (ssname ss (setq n (1- n))))
(progn
(command "zoom" "object" en "")(graphscr)
(vla-GetBoundingBox (vlax-ename->vla-object en) 'MinPt 'MaxPt)
(setq MinPt (vlax-safearray->list MinPt) MaxPt (vlax-safearray->list MaxPt))
(if
(and
(< 70 (setq di (distance MinPt MaxPt)))
(or
(and (equal (setq bf (angle MinPt MaxPt)) 0.615504 0.03) (setq LP 1))
(and (equal bf 0.955293 0.03) (setq LP 0))
)
(or
(not (= (cdr (assoc 0 (setq bf (entget en)))) "INSERT"))
(not
(ssget "CP"
(#PantaList
(list (/ (+ (car MinPt) (car MaxPt)) 2) (/ (+ (cadr MinPt) (cadr MaxPt)) 2))
di
LP
)
(list (cons 0 "INSERT") (cons 2 (cdr (assoc 2 bf))))
)
)
)
)
(if (setq nb 0 ns (ssget "w" MinPt MaxPt SF_List))
(progn (ssdel en ns) (repeat (sslength ns) (ssdel (ssname ns nb) ss) (setq nb (1+ nb))))
)
(ssdel en ss)
)
)
)
)ss
)
;;;
;;; PDF 넘버링
;;;
;;; PDF파일의 넘버를 증가하거나 감소한다.
;;;
;;;
(defun $PDF_NUM_ADD ( / n TXT1 TXT2 FN F1 F2)
(setq n 0
TXT1
(vl-list->string
(reverse
(vl-remove-if '(lambda (f) (= 0 (if (= f 92) (setq n nil) n))) (reverse (vl-string->list #PDF_Filename)))
)
)
TXT2 (substr #PDF_Filename (1+ (strlen TXT1)))
FN (substr TXT2 1 (- (setq n (strlen TXT2)) 4))
)
(if (< 4 n)
(progn
(setq n 0
F2 (reverse (vl-remove-if '(lambda (f) (= nil (if (or (< f 48) (> f 57)) (setq n nil) n))) (reverse (vl-string->list FN))))
F1 (substr FN 1 (- (strlen FN) (length F2)))
)
(setq F2 (vl-string->list (itoa (fix (1+ (atoi (vl-list->string F2)))))))
(if (> 3 (length F2)) (while (> 3 (length F2)) (setq F2 (append (list 48) F2))))
(setq F2 (vl-list->string F2) FN (strcat F1 F2))
)
(setq FN (strcat FN "001"))
)(setq #PDF_Filename (strcat TXT1 FN ".pdf"))#PDF_Filename
)
(defun $PDF_NUM_MINUS ( / n TXT1 TXT2 FN F1 F2)
(setq n 0
TXT1
(vl-list->string
(reverse
(vl-remove-if '(lambda (f) (= 0 (if (= f 92) (setq n nil) n))) (reverse (vl-string->list #PDF_Filename)))
)
)
TXT2 (substr #PDF_Filename (1+ (strlen TXT1)))
FN (substr TXT2 1 (- (setq n (strlen TXT2)) 4))
)
(if (< 4 n)
(progn
(setq n 0
F2 (reverse (vl-remove-if '(lambda (f) (= nil (if (or (< f 48) (> f 57)) (setq n nil) n))) (reverse (vl-string->list FN))))
F1 (substr FN 1 (- (strlen FN) (length F2)))
)
(setq F2 (vl-string->list (itoa (fix (1- (atoi (vl-list->string F2)))))))
(if (> 3 (length F2)) (while (> 3 (length F2)) (setq F2 (append (list 48) F2))))
(setq F2 (vl-list->string F2) FN (strcat F1 F2))
)
(setq FN (strcat FN "001"))
)(setq #PDF_Filename (strcat TXT1 FN ".pdf"))#PDF_Filename
)
;;;
;;;
;;; 박스 출력
;;;
;;; 선택한 4각 폴리곤의 도면을 출력한다.
;;; 다중선택도 가능하다.
;;;
;;;
(defun #PLOT_EXPRESS ($Mode $Size / *error* AcDoc AcLay AcPlot paper_size sa ss n MinPt MaxPt LP SF_List CLA COL)
(defun *error* (x) (setvar 'cmdecho 1) (and AcDoc (vla-endundomark AcDoc)) (gc) (princ))
(if (= (getvar "worlducs") 0) (and (setvar "cmdecho" 0) (vl-cmdf "UCS" "") (setvar "cmdecho" 1)))
(setq CLA #PlotClayer);;전체 자동출력 시 Plot전용 Layer 설정값
(setq COL #PlotColor);;전체 자동출력 시 Plot전용 색상 설정값
(if (or (= $Mode "Plot_Mode") (= $Mode "CHK_Mode"))
(setq SF_List
(list
(cons -4 "<OR")
(cons -4 "<AND") (cons 0 "LWPOLYLINE") (cons 40 0) (cons 41 0) (cons 90 4) (cons -4 "AND>") ;열린 폴리선도 선택가능
(cons -4 "<AND") (cons 0 "LWPOLYLINE") (cons 40 0) (cons 41 0) (cons 90 5) (cons -4 "AND>") ;닫힌 폴리선도 선택가능
(cons -4 "OR>")
)
)
(setq SF_List
(list
(cons -4 "<OR")
(cons 0 "INSERT") ;BLOCK,BOX도곽 통합
(cons -4 "<AND") (cons 0 "LWPOLYLINE") (cons 40 0) (cons 41 0) (cons 90 4) (cons -4 "AND>") ;열린 폴리선도 선택가능
(cons -4 "<AND") (cons 0 "LWPOLYLINE") (cons 40 0) (cons 41 0) (cons 90 5) (cons -4 "AND>") ;닫힌 폴리선도 선택가능
(cons -4 "OR>")
)
)
)
(setq AcDoc (vla-get-ActiveDocument (vlax-get-acad-object))
AcLay (vla-get-activelayout AcDoc)
AcPlot (vla-get-plot AcDoc)
n 0
)
(if $Size (setq paper_size $Size) (and (= $Mode "PDF_Mode") (setq paper_size pdf_paper_size_A4)))
(if (= $Mode "PDF_Mode")
(and
(if #PDF_Filename ($PDF_NUM_ADD) (setq #PDF_Filename (strcat (getvar "dwgprefix") (substr (getvar "dwgname") 1 (- (strlen (getvar "dwgname")) 4)) "_001.pdf")))
(or
(/= (vla-get-ConfigName AcLay) pdf_prt_name)
(/= (vla-get-StyleSheet AcLay) pdf_ctb_file)
(/= (vla-get-CanonicalMediaName AcLay) paper_size)
)
(progn
(vla-put-ConfigName AcLay pdf_prt_name)
(vla-put-StyleSheet AcLay pdf_ctb_file)
(vla-put-CanonicalMediaName AcLay paper_size)
)
)
(and
$Size
(and (/= $Mode "ALLCHK_Mode") (/= $Mode "CHK_Mode"))
(or
(/= (vla-get-ConfigName AcLay) prt_name)
(/= (vla-get-StyleSheet AcLay) ctb_file)
(/= (vla-get-CanonicalMediaName AcLay) paper_size)
)
(progn
(vla-put-ConfigName AcLay prt_name)
(vla-put-StyleSheet AcLay ctb_file)
(vla-put-CanonicalMediaName AcLay paper_size)
)
)
)
(and
(if (= $Mode "PDF_Mode")
(and
(if (setq Buffer (getfiled "PDF 파일 작성" #PDF_Filename "pdf" 1))
(and
(setq #PDF_Filename Buffer)
($PDF_NUM_ADD)
($PDF_NUM_MINUS)
)
)
) T
)
(if (= $Mode "AP_Mode")
(progn
(initget "Yes No")
(if (/= (getkword (strcat "\n플롯 박스로 작성된 도면을 전체 출력하시겠습니까?(출력 레이어: \"" CLA "\"/ 색상: \"" (if COL (rtos COL 2 0) (strcat "미지정")) "\") [예(Y)/아니오(N)] <Y>: ")) "No")
(setq sa (ssget "X" (vl-remove-if 'not (list (cons 0 "LWPOLYLINE") (cons 8 CLA) (cons 62 COL) (cons 40 0) (cons 41 0) (cons 90 4)))))
(progn
(prompt (strcat "\n레이어 \"" CLA "\"/ 색상: \"" (if COL (rtos COL 2 0) (strcat "미지정")) "\" 로 작성된 플롯 박스를 선택..."))
(setq sa (ssget (vl-remove-if 'not (list (cons 0 "LWPOLYLINE") (cons 8 CLA) (cons 62 COL) (cons 40 0) (cons 41 0) (cons 90 4)))))
)
)
)
(setq sa (ssget SF_List))
)
(progn (vla-startundomark AcDoc) (setvar "cmdecho" 0) (command "zoom" "object" ss)(graphscr) (setq ss (#SS_Sort_Main sa)))
(#BoxReaction ss SF_List)
(/= (sslength ss) 0)
(if (or (= $Mode "ALLCHK_Mode") (= $Mode "CHK_Mode"))
(progn
(command "zoom" "object" ss "")(graphscr)
(setq sa (ssadd))
(repeat (sslength ss)
(vla-GetBoundingBox (vlax-ename->vla-object (ssname ss n)) 'MinPt 'MaxPt)
(setq MaxPt (vlax-safearray->list MaxPt) n (1+ n))
(entmake (list (cons 0 "CIRCLE") (cons 8 "0") (cons 62 4) (cons 10 MaxPt) (cons 40 55.0)))
(ssadd (entlast) sa)
)
(prompt (strcat "\n" (rtos n 2 0) "장 출력이 가능합니다."))
(command "group" "Create" "*" "CHKPLOT" sa "" nil)
(setvar "cmdecho" 1)
(vlr-beep-reaction)
)
T
)
(progn
(setvar "backgroundplot" 0)
(vla-put-paperunits AcLay acmillimeters)
(vla-put-standardscale AcLay acvpscaletofit)
(vla-put-centerplot AcLay :vlax-true)
(command "zoom" "object" ss "")(graphscr)
(setvar "cmdecho" 1)
(repeat (sslength ss)
(vla-GetBoundingBox (vlax-ename->vla-object (ssname ss n)) 'MinPt 'MaxPt)
(setq MinPt (vlax-safearray->list MinPt)
MaxPt (vlax-safearray->list MaxPt)
n (1+ n)
)
(ssget "W" MinPt MaxPt)
(if (< (- (car MinPt) (car MaxPt)) (- (cadr MinPt) (cadr MaxPt))) (setq LP 1) (setq LP 0))
(setq DCSFix (trans '(0 0) 2 0)
MinPt (List->Safearray (list (- (car MinPt) (car DCSFix)) (- (cadr MinPt) (cadr DCSFix))))
MaxPt (List->Safearray (list (- (car MaxPt) (car DCSFix)) (- (cadr MaxPt) (cadr DCSFix))))
)
(vla-put-PlotRotation AcLay LP)
(vla-SetWindowToPlot AcLay MinPt MaxPt)
(vla-put-PlotType AcLay AcWindow)
(if (= $Mode "RV_Mode")
(vla-DisplayPlotPreview AcPlot acPartialPreview)
(if (= $Mode "PDF_Mode")
(progn (vla-PlotToFile AcPlot #PDF_Filename) ($PDF_NUM_ADD))
(progn (vla-PlotToDevice AcPlot) (PTE:highlight (ssget "P") 2)) ;;출력객체 숨김 옵션
)
)
)
(sssetfirst nil ss) (ssget)
(setvar "cmdecho" 1)
(if (/= $Mode "RV_Mode")
(prompt
(strcat "\n" (getvar "dwgprefix")(getvar "dwgname")
(if (= $Mode "PDF_Mode") "\n" "\n\n출력된 객체를 표현하려면 Regen명령으로 재생성...\n")
(rtos n 2 0) " 장이 출력되었습니다."
)
)
(prompt (strcat "\n" (rtos n 2 0) "장을 미리보기 완료하였습니다."))
)
(if (and (/= $Mode "RV_Mode") (> n 1))
(alert
(strcat "\n\t" (getvar "dwgname") "\n\t" (rtos n 2 0) " 장이 출력되었습니다."
(if (= $Mode "PDF_Mode") "" "\n\n\t출력된 객체를 표현하려면 Regen명령으로 객체 재생성이 필요합니다.")
)
)
)(vlr-beep-reaction) ;;출력완료 신호음
)
)
(if (= $Mode "PDF_Mode") ($PDF_NUM_MINUS))
(vla-endundomark AcDoc)
(gc)
(princ)
)(gc)
(defun C:PLOTEXPRESS () (prompt (strcat "PLOTEXPRESS\n출력할 도면 선택...")) (#PLOT_EXPRESS "Plot_Mode" nil))
(defun C:PLOTALL () (prompt (strcat "PLOTALL\n출력할 모든 도면 선택...")) (#PLOT_EXPRESS "ALLPlot_Mode" nil))
(defun C:PLOTEXPRESSALL () (prompt (strcat "PLOTEXPRESSALL\nPLOT전용 LAYER 전체 출력...")) (#PLOT_EXPRESS "AP_Mode" nil))
(defun C:DREVIEW () (prompt (strcat "DREVIEW\n미리보기 할 도면 선택...")) (#PLOT_EXPRESS "RV_Mode" nil))
(defun C:PDFOUT () (prompt (strcat "PDFOUT\nPDF로 내보내기...")) (#PLOT_EXPRESS "PDF_Mode" nil))
(defun C:CHKPLOT () (prompt (strcat "CHKPLOT\nPLOT객체 확인하기...")) (#PLOT_EXPRESS "CHK_Mode" nil))
(defun C:CHKPLOTALL () (prompt (strcat "CHKPLOTALL\nPLOT이 가능한 모든 객체 확인하기...")) (#PLOT_EXPRESS "ALLCHK_Mode" nil))
※ 유의사항
- ①말머리 : 말머리를 달아야 구분이 쉽겠죠^^(필수 선택)
- ②Screenshot : 이해를 돕기위해 삽입요망.
- ③파일 첨부 : 상위버전에서 테스트할 파일이 아니면 가급적 하위버전으로 저장후 첨부.
해당리습/해당파일(DWG) 도 같이 첨부하여 주세요.
- ④제 목 : 질문 내용 반영(개략적인 내용), 예) 해치를 만들고 싶어요, pline을 연결할려면?
금지어(만들어주세요? 해주세요? 안되는데 이렇게 변경해주세요? 등등)
- ⑤질문글 삭제금지 : 질문후 댓글이 달린글은 삭제금지.
여러 리플러들이 소중한 시간을 내어서 고민한후 댓글을 작성한 이상 "강력조치" 토록 하겠음.
※ 정답만이 댓글은 아닙니다. 그 답이 맞던 틀리던 그건 그 댓글로서 존중되어야 합니다.
회원님들이 글을 읽었다는것과 댓글을 달았다는건 그만큼 관심을 가지고 있고 또 그 답을 해주기 위해
검색도 해보고 도움말도 보고 고민도 하는 일련의 과정을 거치면서 나오기 때문이죠.
이에 대한 고마움과 감사함을 모르는 테러행위(?)는 없었으면 합니다.
|