Re: 선택한 블럭의 도면내 이름 전체 변경가능한 리습 문의

[drawing]

(defun c:test ( / *error* src dxf app doc old tmp def new)

    (defun *error* ( msg )
        (if (and (= 'vla-object (type dbx)) (not (vlax-object-released-p dbx)))
            (vlax-release-object dbx)
        )
        (if (not (wcmatch (strcase msg t) "*break,*cancel*,*exit*"))
            (princ (strcat "\nError: " msg))
        )
        (princ)
    )
    
    (while
        (progn
            (setvar 'errno 0)
            (setq src (car (entsel (strcat "\nSelect block reference to " "rename: "))))
            (cond
                (   (= 7 (getvar 'errno))
                    (princ "\nMissed, try again.")
                )
                (   (= 'ename (type src))
                    (setq dxf (entget src))
                    (cond
                        (   (/= "INSERT" (cdr (assoc 0 dxf)))
                            (princ "\nPlease select a block reference.")
                        )
                        (   (= 4 (logand 4 (cdr (assoc 70 (tblsearch "layer" (cdr (assoc 8 dxf)))))))
                            (princ "\nSelected block is on a locked layer.")
                        )
                    )
                )
            )
        )
    )
    (if (= 'ename (type src))
        (progn
            (setq app (vlax-get-acad-object)
                  doc (vla-get-activedocument app)
                  src (vlax-ename->vla-object src)
                  old (vlax-get-property src (if (vlax-property-available-p src 'effectivename) 'effectivename 'name))
                  tmp 0
            )
            (while (tblsearch "block" (setq def (strcat (vl-string-left-trim "*" old) "_" (itoa (setq tmp (1+ tmp)))))))
            (while
                (and (/= "" (setq new (getstring t (strcat "\nSpecify new block name <" def ">: "))))
                    (or (not (snvalid new))
                        (tblsearch "block" new)
                    )
                )
                (princ "\nBlock name invalid or already exists.")
            )
            (if (= "" new)
                (setq new def)
            )
            (vla-put-name (vla-item (vlax-get doc 'blocks) old) new)
        )
    )
(princ)
)

(vl-load-com)

(princ)

[푸쉬킨]

감사합니다... drawing님
수정요청 내용 : 내가 변경하고자 하는 블럭이 다른 큰 블럭에 속해 있어도 이름이 변경이 되었으면.. 합니다...
제가 작성한 글 내용에 오해가 생길수 있는 부분이 있었던것 같습니다.... 죄송합니다...

만들어 주신 리습에 50%는 맞습니다.. 속에 있는 블럭은 이름 변경안됨 ok
다만 내가 변경하고자 하는 블럭이 더큰 블럭속에 속해 있어도 이름은 변경이 되었으면.. 합니다...

다시한번 시간내어 주신것에 감사드립니다...
한번만 더 검토 부탁 좀 드리겠습니다.....

[drawing]

"다른 큰 블럭에 속해 있어도 이름이 변경이 되었으면.. 합니다... <> 속에 있는 블럭은 이름 변경안됨 ok"
이게 서로 맞지 않는 얘기입니다.

[푸쉬킨]

네.. 제가 원하는 b라는 블럭이 a블럭 속에 있어도 변경이 되었으면... 해서요...
b라는 블럭속에 c라는 블럭의 이름은 변경되지 않는 부분은 잘 되더라구요....
----------------------------------------------------------------------------------------------------------------------
도면을 그리도 보면 여러 객체를 블럭을 잡게 됩니다... b라는 블럭이 c라는 블럭을 포함하여 나와 있는 객체가 있고[b(c)]... a라는 블럭에 b(c)가 포함된 블럭들도 여러 존재할 경우 [a(b(c))] 가 있습니다...
혼합된 도면들이 있는데 ... 제가 a라는 블럭을 깨서 b(c)라는 블럭을 선택해서 전체 이름을 바꾸고 싶어합니다.....

[푸쉬킨]

지금 리습은 b라는 블럭의 이름을 변경하면 .... 속에 있는 c라는 블럭들의 하위그룹들도 이름이 변경되더라구요.....
a(b(c)), b(c) ,d(b(c)), c.....등등에서 b(c) 블럭 선택 이름 변경시 -> a(Y(c)), Y(c), , d(Y(c)), c...처럼 바꾸고자 하는 선택된 블럭의 객체들만 변경이 되었으면 해서요

[푸쉬킨]

drawing님이 만들어 주신 리습은b속에 있는 c의 이름이 변경이 되지 않아 좋습니다...
다만... b(c)의 블럭이 다른 블럭속에 속해 있는 그룹도 있는데... 거기는 아예 이름이 변경이 안되더라구요......
내가 변경하고자 하는 최종 블럭선택시 그 블럭 내부의 객체블럭은 이름이 변경되지 않아야 하며, 선택된 블럭이 다른 큰 블럭속에 속해 있어도 이름이 같이 변경이 되어야 한다..는게 제가 바라는 점입니다..
감사합니다.. drawing 님

[drawing]

수정했으니 확인해보세요...

[푸쉬킨]

감사합니다.. 확인했습니다...
제가 쓸데없이 풀어서 헷갈린게 아닌가 모르겠습니다... ㅜㅜ
그냥 첨부 리습에서 내부 블럭은 이름이 변경이 안돼게 해주세요.. 하면 됐을텐데.....
다시한번 감사드립니다... 기능은 제가 원하는데로 잘 됩니다~~~!!!

[drawing]

^^;; 다행이네요.